lib/PublicInbox/GitAsyncCat.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # internal class used by PublicInbox::Git + PublicInbox::DS
   5 # This parses the output pipe of "git cat-file --batch"
   6 package PublicInbox::GitAsyncCat;
   7 use strict;
   8 use parent qw(PublicInbox::DS Exporter);
   9 use POSIX qw(WNOHANG);
  10 use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
  11 our @EXPORT = qw(git_async_cat git_async_prefetch);
  12 use PublicInbox::Git ();
  13
  14 our $GCF2C; # singleton PublicInbox::Gcf2Client
  15
  16 sub close {
  17         my ($self) = @_;
  18         if (my $git = delete $self->{git}) {
  19                 $git->cat_async_abort;
  20         }
  21         $self->SUPER::close; # PublicInbox::DS::close
  22 }
  23
  24 sub event_step {
  25         my ($self) = @_;
  26         my $git = $self->{git} or return;
  27         return $self->close if ($git->{in} // 0) != ($self->{sock} // 1);
  28         my $inflight = $git->{inflight};
  29         if ($inflight && @$inflight) {
  30                 $git->cat_async_step($inflight);
  31
  32                 # child death?
  33                 if (($git->{in} // 0) != ($self->{sock} // 1)) {
  34                         $self->close;
  35                 } elsif (@$inflight || exists $git->{cat_rbuf}) {
  36                         # ok, more to do, requeue for fairness
  37                         $self->requeue;
  38                 }
  39         } elsif ((my $pid = waitpid($git->{pid}, WNOHANG)) > 0) {
  40                 # May happen if the child process is killed by a BOFH
  41                 # (or segfaults)
  42                 delete $git->{pid};
  43                 warn "E: git $pid exited with \$?=$?\n";
  44                 $self->close;
  45         }
  46 }
  47
  48 sub git_async_cat ($$$$) {
  49         my ($git, $oid, $cb, $arg) = @_;
  50         if ($GCF2C //= eval {
  51                 require PublicInbox::Gcf2Client;
  52                 PublicInbox::Gcf2Client::new();
  53         } // 0) { # 0: do not retry if libgit2 or Inline::C are missing
  54                 $GCF2C->gcf2_async(\"$oid $git->{git_dir}\n", $cb, $arg);
  55                 \undef;
  56         } else { # read-only end of git-cat-file pipe
  57                 $git->cat_async($oid, $cb, $arg);
  58                 $git->{async_cat} //= do {
  59                         my $self = bless { git => $git }, __PACKAGE__;
  60                         $git->{in}->blocking(0);
  61                         $self->SUPER::new($git->{in}, EPOLLIN|EPOLLET);
  62                         \undef; # this is a true ref()
  63                 };
  64         }
  65 }
  66
  67 # this is safe to call inside $cb, but not guaranteed to enqueue
  68 # returns true if successful, undef if not.
  69 sub git_async_prefetch {
  70         my ($git, $oid, $cb, $arg) = @_;
  71         if ($GCF2C) {
  72                 if (!$GCF2C->{wbuf}) {
  73                         $oid .= " $git->{git_dir}\n";
  74                         return $GCF2C->gcf2_async(\$oid, $cb, $arg); # true
  75                 }
  76         } elsif ($git->{async_cat} && (my $inflight = $git->{inflight})) {
  77                 # we could use MAX_INFLIGHT here w/o the halving,
  78                 # but lets not allow one client to monopolize a git process
  79                 if (@$inflight < int(PublicInbox::Git::MAX_INFLIGHT/2)) {
  80                         print { $git->{out} } $oid, "\n" or
  81                                                 $git->fail("write error: $!");
  82                         return push(@$inflight, $oid, $cb, $arg);
  83                 }
  84         }
  85         undef;
  86 }
  87
  88 1;