lib/PublicInbox/GitHTTPBackend.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # when no endpoints match, fallback to this and serve a static file
   5 # or smart HTTP
   6 package PublicInbox::GitHTTPBackend;
   7 use strict;
   8 use warnings;
   9 use Fcntl qw(:seek);
  10 use IO::File;
  11 use HTTP::Date qw(time2str);
  12 use HTTP::Status qw(status_message);
  13 use PublicInbox::Qspawn;
  14
  15 # n.b. serving "description" and "cloneurl" should be innocuous enough to
  16 # not cause problems.  serving "config" might...
  17 my @text = qw[HEAD info/refs
  18         objects/info/(?:http-alternates|alternates|packs)
  19         cloneurl description];
  20
  21 my @binary = qw!
  22         objects/[a-f0-9]{2}/[a-f0-9]{38}
  23         objects/pack/pack-[a-f0-9]{40}\.(?:pack|idx)
  24         !;
  25
  26 our $ANY = join('|', @binary, @text, 'git-upload-pack');
  27 my $BIN = join('|', @binary);
  28 my $TEXT = join('|', @text);
  29
  30 my @no_cache = ('Expires', 'Fri, 01 Jan 1980 00:00:00 GMT',
  31                 'Pragma', 'no-cache',
  32                 'Cache-Control', 'no-cache, max-age=0, must-revalidate');
  33
  34 sub r ($;$) {
  35         my ($code, $msg) = @_;
  36         $msg ||= status_message($code);
  37         my $len = length($msg);
  38         [ $code, [qw(Content-Type text/plain Content-Length), $len, @no_cache],
  39                 [$msg] ]
  40 }
  41
  42 sub serve {
  43         my ($env, $git, $path) = @_;
  44
  45         # Documentation/technical/http-protocol.txt in git.git
  46         # requires one and exactly one query parameter:
  47         if ($env->{QUERY_STRING} =~ /\Aservice=git-\w+-pack\z/ ||
  48                                 $path =~ /\Agit-\w+-pack\z/) {
  49                 my $ok = serve_smart($env, $git, $path);
  50                 return $ok if $ok;
  51         }
  52
  53         serve_dumb($env, $git, $path);
  54 }
  55
  56 sub err ($@) {
  57         my ($env, @msg) = @_;
  58         $env->{'psgi.errors'}->print(@msg, "\n");
  59 }
  60
  61 sub drop_client ($) {
  62         if (my $io = $_[0]->{'psgix.io'}) {
  63                 $io->close; # this is Danga::Socket::close
  64         }
  65 }
  66
  67 sub serve_dumb {
  68         my ($env, $git, $path) = @_;
  69
  70         my @h;
  71         my $type;
  72         if ($path =~ /\A(?:$BIN)\z/o) {
  73                 $type = 'application/octet-stream';
  74                 push @h, 'Expires', time2str(time + 31536000);
  75                 push @h, 'Cache-Control', 'public, max-age=31536000';
  76         } elsif ($path =~ /\A(?:$TEXT)\z/o) {
  77                 $type = 'text/plain';
  78                 push @h, @no_cache;
  79         } else {
  80                 return r(404);
  81         }
  82
  83         my $f = (ref $git ? $git->{git_dir} : $git) . '/' . $path;
  84         return r(404) unless -f $f && -r _; # just in case it's a FIFO :P
  85         my @st = stat(_);
  86         my $size = $st[7];
  87
  88         # TODO: If-Modified-Since and Last-Modified?
  89         open my $in, '<', $f or return r(404);
  90         my $len = $size;
  91         my $code = 200;
  92         push @h, 'Content-Type', $type;
  93         if (($env->{HTTP_RANGE} || '') =~ /\bbytes=(\d*)-(\d*)\z/) {
  94                 ($code, $len) = prepare_range($env, $in, \@h, $1, $2, $size);
  95                 if ($code == 416) {
  96                         push @h, 'Content-Range', "bytes */$size";
  97                         return [ 416, \@h, [] ];
  98                 }
  99         }
 100         push @h, 'Content-Length', $len;
 101         my $n = 65536;
 102         [ $code, \@h, Plack::Util::inline_object(close => sub { close $in },
 103                 getline => sub {
 104                         return if $len == 0;
 105                         $n = $len if $len < $n;
 106                         my $r = sysread($in, my $buf, $n);
 107                         if (!defined $r) {
 108                                 err($env, "$f read error: $!");
 109                         } elsif ($r <= 0) {
 110                                 err($env, "$f EOF with $len bytes left");
 111                         } else {
 112                                 $len -= $r;
 113                                 $n = 8192;
 114                                 return $buf;
 115                         }
 116                         drop_client($env);
 117                         return;
 118                 })]
 119 }
 120
 121 sub prepare_range {
 122         my ($env, $in, $h, $beg, $end, $size) = @_;
 123         my $code = 200;
 124         my $len = $size;
 125         if ($beg eq '') {
 126                 if ($end ne '') { # "bytes=-$end" => last N bytes
 127                         $beg = $size - $end;
 128                         $beg = 0 if $beg < 0;
 129                         $end = $size - 1;
 130                         $code = 206;
 131                 } else {
 132                         $code = 416;
 133                 }
 134         } else {
 135                 if ($beg > $size) {
 136                         $code = 416;
 137                 } elsif ($end eq '' || $end >= $size) {
 138                         $end = $size - 1;
 139                         $code = 206;
 140                 } elsif ($end < $size) {
 141                         $code = 206;
 142                 } else {
 143                         $code = 416;
 144                 }
 145         }
 146         if ($code == 206) {
 147                 $len = $end - $beg + 1;
 148                 if ($len <= 0) {
 149                         $code = 416;
 150                 } else {
 151                         sysseek($in, $beg, SEEK_SET) or return [ 500, [], [] ];
 152                         push @$h, qw(Accept-Ranges bytes Content-Range);
 153                         push @$h, "bytes $beg-$end/$size";
 154
 155                         # FIXME: Plack::Middleware::Deflater bug?
 156                         $env->{'psgix.no-compress'} = 1;
 157                 }
 158         }
 159         ($code, $len);
 160 }
 161
 162 # returns undef if 403 so it falls back to dumb HTTP
 163 sub serve_smart {
 164         my ($env, $git, $path) = @_;
 165         my $in = $env->{'psgi.input'};
 166         my $fd = eval { fileno($in) };
 167         unless (defined $fd && $fd >= 0) {
 168                 $in = input_to_file($env) or return r(500);
 169         }
 170         my %env = %ENV;
 171         # GIT_COMMITTER_NAME, GIT_COMMITTER_EMAIL
 172         # may be set in the server-process and are passed as-is
 173         foreach my $name (qw(QUERY_STRING
 174                                 REMOTE_USER REMOTE_ADDR
 175                                 HTTP_CONTENT_ENCODING
 176                                 CONTENT_TYPE
 177                                 SERVER_PROTOCOL
 178                                 REQUEST_METHOD)) {
 179                 my $val = $env->{$name};
 180                 $env{$name} = $val if defined $val;
 181         }
 182         my $git_dir = ref $git ? $git->{git_dir} : $git;
 183         $env{GIT_HTTP_EXPORT_ALL} = '1';
 184         $env{PATH_TRANSLATED} = "$git_dir/$path";
 185         my %rdr = ( 0 => fileno($in) );
 186         my $x = PublicInbox::Qspawn->new([qw(git http-backend)], \%env, \%rdr);
 187         my ($fh, $rpipe);
 188         my $end = sub {
 189                 if (my $err = $x->finish) {
 190                         err($env, "git http-backend ($git_dir): $err");
 191                 }
 192                 $fh->close if $fh; # async-only
 193         };
 194
 195         # Danga::Socket users, we queue up the read_enable callback to
 196         # fire after pending writes are complete:
 197         my $buf = '';
 198         my $rd_hdr = sub {
 199                 my $r = sysread($rpipe, $buf, 1024, length($buf));
 200                 return if !defined($r) && ($!{EINTR} || $!{EAGAIN});
 201                 return r(500, 'http-backend error') unless $r;
 202                 $r = parse_cgi_headers(\$buf) or return; # incomplete headers
 203                 $r->[0] == 403 ? serve_dumb($env, $git, $path) : $r;
 204         };
 205         my $res;
 206         my $async = $env->{'pi-httpd.async'};
 207         my $io = $env->{'psgix.io'};
 208         my $cb = sub {
 209                 my $r = $rd_hdr->() or return;
 210                 $rd_hdr = undef;
 211                 if (scalar(@$r) == 3) { # error:
 212                         if ($async) {
 213                                 $async->close; # calls rpipe->close
 214                         } else {
 215                                 $rpipe->close;
 216                                 $end->();
 217                         }
 218                         return $res->($r);
 219                 }
 220                 if ($async) {
 221                         $fh = $res->($r);
 222                         return $async->async_pass($io, $fh, \$buf);
 223                 }
 224
 225                 # for synchronous PSGI servers
 226                 require PublicInbox::GetlineBody;
 227                 $r->[2] = PublicInbox::GetlineBody->new($rpipe, $end, $buf);
 228                 $res->($r);
 229         };
 230         sub {
 231                 ($res) = @_;
 232
 233                 # hopefully this doesn't break any middlewares,
 234                 # holding the input here is a waste of FDs and memory
 235                 $env->{'psgi.input'} = undef;
 236
 237                 $x->start(sub { # may run later, much later...
 238                         ($rpipe) = @_;
 239                         $in = undef;
 240                         if ($async) {
 241                                 $async = $async->($rpipe, $cb, $end);
 242                         } else { # generic PSGI
 243                                 $cb->() while $rd_hdr;
 244                         }
 245                 });
 246         };
 247 }
 248
 249 sub input_to_file {
 250         my ($env) = @_;
 251         my $in = IO::File->new_tmpfile;
 252         my $input = $env->{'psgi.input'};
 253         my $buf;
 254         while (1) {
 255                 my $r = $input->read($buf, 8192);
 256                 unless (defined $r) {
 257                         err($env, "error reading input: $!");
 258                         return;
 259                 }
 260                 last if ($r == 0);
 261                 $in->write($buf);
 262         }
 263         $in->flush;
 264         $in->sysseek(0, SEEK_SET);
 265         return $in;
 266 }
 267
 268 sub parse_cgi_headers {
 269         my ($bref) = @_;
 270         $$bref =~ s/\A(.*?)\r\n\r\n//s or return;
 271         my $h = $1;
 272         my $code = 200;
 273         my @h;
 274         foreach my $l (split(/\r\n/, $h)) {
 275                 my ($k, $v) = split(/:\s*/, $l, 2);
 276                 if ($k =~ /\AStatus\z/i) {
 277                         ($code) = ($v =~ /\b(\d+)\b/);
 278                 } else {
 279                         push @h, $k, $v;
 280                 }
 281         }
 282         [ $code, \@h ]
 283 }
 284
 285 1;