lib/PublicInbox/GitHTTPBackend.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # when no endpoints match, fallback to this and serve a static file
   5 # or smart HTTP.  This is our wrapper for git-http-backend(1)
   6 package PublicInbox::GitHTTPBackend;
   7 use strict;
   8 use warnings;
   9 use Fcntl qw(:seek);
  10 use IO::Handle;
  11 use HTTP::Date qw(time2str);
  12 use HTTP::Status qw(status_message);
  13 use Plack::Util;
  14 use PublicInbox::Qspawn;
  15
  16 # 32 is same as the git-daemon connection limit
  17 my $default_limiter = PublicInbox::Qspawn::Limiter->new(32);
  18
  19 # n.b. serving "description" and "cloneurl" should be innocuous enough to
  20 # not cause problems.  serving "config" might...
  21 my @text = qw[HEAD info/refs info/attributes
  22         objects/info/(?:http-alternates|alternates|packs)
  23         cloneurl description];
  24
  25 my @binary = qw!
  26         objects/[a-f0-9]{2}/[a-f0-9]{38}
  27         objects/pack/pack-[a-f0-9]{40}\.(?:pack|idx)
  28         !;
  29
  30 our $ANY = join('|', @binary, @text, 'git-upload-pack');
  31 my $BIN = join('|', @binary);
  32 my $TEXT = join('|', @text);
  33
  34 my @no_cache = ('Expires', 'Fri, 01 Jan 1980 00:00:00 GMT',
  35                 'Pragma', 'no-cache',
  36                 'Cache-Control', 'no-cache, max-age=0, must-revalidate');
  37
  38 sub r ($;$) {
  39         my ($code, $msg) = @_;
  40         $msg ||= status_message($code);
  41         my $len = length($msg);
  42         [ $code, [qw(Content-Type text/plain Content-Length), $len, @no_cache],
  43                 [$msg] ]
  44 }
  45
  46 sub serve {
  47         my ($env, $git, $path) = @_;
  48
  49         # XXX compatibility... ugh, can we stop supporting this?
  50         $git = PublicInbox::Git->new($git) unless ref($git);
  51
  52         # Documentation/technical/http-protocol.txt in git.git
  53         # requires one and exactly one query parameter:
  54         if ($env->{QUERY_STRING} =~ /\Aservice=git-[A-Za-z0-9_]+-pack\z/ ||
  55                                 $path =~ /\Agit-[A-Za-z0-9_]+-pack\z/) {
  56                 my $ok = serve_smart($env, $git, $path);
  57                 return $ok if $ok;
  58         }
  59
  60         serve_dumb($env, $git, $path);
  61 }
  62
  63 sub err ($@) {
  64         my ($env, @msg) = @_;
  65         $env->{'psgi.errors'}->print(@msg, "\n");
  66 }
  67
  68 sub drop_client ($) {
  69         if (my $io = $_[0]->{'psgix.io'}) {
  70                 $io->close; # this is PublicInbox::DS::close
  71         }
  72 }
  73
  74 my $prev = 0;
  75 my $exp;
  76 sub cache_one_year {
  77         my ($h) = @_;
  78         my $t = time + 31536000;
  79         push @$h, 'Expires', $t == $prev ? $exp : ($exp = time2str($prev = $t)),
  80                 'Cache-Control', 'public, max-age=31536000';
  81 }
  82
  83 sub static_result ($$$$) {
  84         my ($env, $h, $f, $type) = @_;
  85         return r(404) unless -f $f && -r _; # just in case it's a FIFO :P
  86
  87         # TODO: If-Modified-Since and Last-Modified?
  88         open my $in, '<', $f or return r(404);
  89         my $size = -s $in;
  90         my $len = $size;
  91         my $code = 200;
  92         push @$h, 'Content-Type', $type;
  93         if (($env->{HTTP_RANGE} || '') =~ /\bbytes=([0-9]*)-([0-9]*)\z/) {
  94                 ($code, $len) = prepare_range($env, $in, $h, $1, $2, $size);
  95                 if ($code == 416) {
  96                         push @$h, 'Content-Range', "bytes */$size";
  97                         return [ 416, $h, [] ];
  98                 }
  99         }
 100         push @$h, 'Content-Length', $len;
 101         my $n = 65536;
 102         [ $code, $h, Plack::Util::inline_object(close => sub { close $in },
 103                 getline => sub {
 104                         return if $len == 0;
 105                         $n = $len if $len < $n;
 106                         my $r = sysread($in, my $buf, $n);
 107                         if (!defined $r) {
 108                                 err($env, "$f read error: $!");
 109                         } elsif ($r <= 0) {
 110                                 err($env, "$f EOF with $len bytes left");
 111                         } else {
 112                                 $len -= $r;
 113                                 $n = 8192;
 114                                 return $buf;
 115                         }
 116                         drop_client($env);
 117                         return;
 118                 })]
 119 }
 120
 121 sub serve_dumb {
 122         my ($env, $git, $path) = @_;
 123
 124         my $h = [];
 125         my $type;
 126         if ($path =~ m!\Aobjects/[a-f0-9]{2}/[a-f0-9]{38}\z!) {
 127                 $type = 'application/x-git-loose-object';
 128                 cache_one_year($h);
 129         } elsif ($path =~ m!\Aobjects/pack/pack-[a-f0-9]{40}\.pack\z!) {
 130                 $type = 'application/x-git-packed-objects';
 131                 cache_one_year($h);
 132         } elsif ($path =~ m!\Aobjects/pack/pack-[a-f0-9]{40}\.idx\z!) {
 133                 $type = 'application/x-git-packed-objects-toc';
 134                 cache_one_year($h);
 135         } elsif ($path =~ /\A(?:$TEXT)\z/o) {
 136                 $type = 'text/plain';
 137                 push @$h, @no_cache;
 138         } else {
 139                 return r(404);
 140         }
 141
 142         static_result($env, $h, "$git->{git_dir}/$path", $type);
 143 }
 144
 145 sub prepare_range {
 146         my ($env, $in, $h, $beg, $end, $size) = @_;
 147         my $code = 200;
 148         my $len = $size;
 149         if ($beg eq '') {
 150                 if ($end ne '') { # "bytes=-$end" => last N bytes
 151                         $beg = $size - $end;
 152                         $beg = 0 if $beg < 0;
 153                         $end = $size - 1;
 154                         $code = 206;
 155                 } else {
 156                         $code = 416;
 157                 }
 158         } else {
 159                 if ($beg > $size) {
 160                         $code = 416;
 161                 } elsif ($end eq '' || $end >= $size) {
 162                         $end = $size - 1;
 163                         $code = 206;
 164                 } elsif ($end < $size) {
 165                         $code = 206;
 166                 } else {
 167                         $code = 416;
 168                 }
 169         }
 170         if ($code == 206) {
 171                 $len = $end - $beg + 1;
 172                 if ($len <= 0) {
 173                         $code = 416;
 174                 } else {
 175                         sysseek($in, $beg, SEEK_SET) or return [ 500, [], [] ];
 176                         push @$h, qw(Accept-Ranges bytes Content-Range);
 177                         push @$h, "bytes $beg-$end/$size";
 178
 179                         # FIXME: Plack::Middleware::Deflater bug?
 180                         $env->{'psgix.no-compress'} = 1;
 181                 }
 182         }
 183         ($code, $len);
 184 }
 185
 186 # returns undef if 403 so it falls back to dumb HTTP
 187 sub serve_smart {
 188         my ($env, $git, $path) = @_;
 189         my %env = %ENV;
 190         # GIT_COMMITTER_NAME, GIT_COMMITTER_EMAIL
 191         # may be set in the server-process and are passed as-is
 192         foreach my $name (qw(QUERY_STRING
 193                                 REMOTE_USER REMOTE_ADDR
 194                                 HTTP_CONTENT_ENCODING
 195                                 CONTENT_TYPE
 196                                 SERVER_PROTOCOL
 197                                 REQUEST_METHOD)) {
 198                 my $val = $env->{$name};
 199                 $env{$name} = $val if defined $val;
 200         }
 201         my $limiter = $git->{-httpbackend_limiter} || $default_limiter;
 202         $env{GIT_HTTP_EXPORT_ALL} = '1';
 203         $env{PATH_TRANSLATED} = "$git->{git_dir}/$path";
 204         my $rdr = input_prepare($env) or return r(500);
 205         my $qsp = PublicInbox::Qspawn->new([qw(git http-backend)], \%env, $rdr);
 206         $qsp->psgi_return($env, $limiter, sub {
 207                 my ($r, $bref) = @_;
 208                 my $res = parse_cgi_headers($r, $bref) or return; # incomplete
 209                 $res->[0] == 403 ? serve_dumb($env, $git, $path) : $res;
 210         });
 211 }
 212
 213 sub input_prepare {
 214         my ($env) = @_;
 215
 216         my $input = $env->{'psgi.input'};
 217         my $fd = eval { fileno($input) };
 218         if (defined $fd && $fd >= 0) {
 219                 return { 0 => $fd };
 220         }
 221         open(my $in, '+>', undef);
 222         unless (defined $in) {
 223                 err($env, "could not open temporary file: $!");
 224                 return;
 225         }
 226         my $buf;
 227         while (1) {
 228                 my $r = $input->read($buf, 8192);
 229                 unless (defined $r) {
 230                         err($env, "error reading input: $!");
 231                         return;
 232                 }
 233                 last if $r == 0;
 234                 unless (print $in $buf) {
 235                         err($env, "error writing temporary file: $!");
 236                         return;
 237                 }
 238         }
 239         # ensure it's visible to git-http-backend(1):
 240         unless ($in->flush) {
 241                 err($env, "error writing temporary file: $!");
 242                 return;
 243         }
 244         unless (defined(sysseek($in, 0, SEEK_SET))) {
 245                 err($env, "error seeking temporary file: $!");
 246                 return;
 247         }
 248         { 0 => fileno($in), -hold => $in };
 249 }
 250
 251 sub parse_cgi_headers {
 252         my ($r, $bref) = @_;
 253         return r(500) unless defined $r && $r >= 0;
 254         $$bref =~ s/\A(.*?)\r?\n\r?\n//s or return $r == 0 ? r(500) : undef;
 255         my $h = $1;
 256         my $code = 200;
 257         my @h;
 258         foreach my $l (split(/\r?\n/, $h)) {
 259                 my ($k, $v) = split(/:\s*/, $l, 2);
 260                 if ($k =~ /\AStatus\z/i) {
 261                         ($code) = ($v =~ /\b([0-9]+)\b/);
 262                 } else {
 263                         push @h, $k, $v;
 264                 }
 265         }
 266         [ $code, \@h ]
 267 }
 268
 269 1;