lib/PublicInbox/GitHTTPBackend.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # when no endpoints match, fallback to this and serve a static file
   5 # or smart HTTP
   6 package PublicInbox::GitHTTPBackend;
   7 use strict;
   8 use warnings;
   9 use Fcntl qw(:seek);
  10 use IO::File;
  11 use HTTP::Date qw(time2str);
  12 use HTTP::Status qw(status_message);
  13 use Plack::Util;
  14 use PublicInbox::Qspawn;
  15
  16 # n.b. serving "description" and "cloneurl" should be innocuous enough to
  17 # not cause problems.  serving "config" might...
  18 my @text = qw[HEAD info/refs
  19         objects/info/(?:http-alternates|alternates|packs)
  20         cloneurl description];
  21
  22 my @binary = qw!
  23         objects/[a-f0-9]{2}/[a-f0-9]{38}
  24         objects/pack/pack-[a-f0-9]{40}\.(?:pack|idx)
  25         !;
  26
  27 our $ANY = join('|', @binary, @text, 'git-upload-pack');
  28 my $BIN = join('|', @binary);
  29 my $TEXT = join('|', @text);
  30
  31 my @no_cache = ('Expires', 'Fri, 01 Jan 1980 00:00:00 GMT',
  32                 'Pragma', 'no-cache',
  33                 'Cache-Control', 'no-cache, max-age=0, must-revalidate');
  34
  35 sub r ($;$) {
  36         my ($code, $msg) = @_;
  37         $msg ||= status_message($code);
  38         my $len = length($msg);
  39         [ $code, [qw(Content-Type text/plain Content-Length), $len, @no_cache],
  40                 [$msg] ]
  41 }
  42
  43 sub serve {
  44         my ($env, $git, $path) = @_;
  45
  46         # Documentation/technical/http-protocol.txt in git.git
  47         # requires one and exactly one query parameter:
  48         if ($env->{QUERY_STRING} =~ /\Aservice=git-\w+-pack\z/ ||
  49                                 $path =~ /\Agit-\w+-pack\z/) {
  50                 my $ok = serve_smart($env, $git, $path);
  51                 return $ok if $ok;
  52         }
  53
  54         serve_dumb($env, $git, $path);
  55 }
  56
  57 sub err ($@) {
  58         my ($env, @msg) = @_;
  59         $env->{'psgi.errors'}->print(@msg, "\n");
  60 }
  61
  62 sub drop_client ($) {
  63         if (my $io = $_[0]->{'psgix.io'}) {
  64                 $io->close; # this is Danga::Socket::close
  65         }
  66 }
  67
  68 my $prev = 0;
  69 my $exp;
  70 sub cache_one_year {
  71         my ($h) = @_;
  72         my $t = time + 31536000;
  73         push @$h, 'Expires', $t == $prev ? $exp : ($exp = time2str($prev = $t)),
  74                 'Cache-Control', 'public, max-age=31536000';
  75 }
  76
  77 sub serve_dumb {
  78         my ($env, $git, $path) = @_;
  79
  80         my @h;
  81         my $type;
  82         if ($path =~ m!\Aobjects/[a-f0-9]{2}/[a-f0-9]{38}\z!) {
  83                 $type = 'application/x-git-loose-object';
  84                 cache_one_year(\@h);
  85         } elsif ($path =~ m!\Aobjects/pack/pack-[a-f0-9]{40}\.pack\z!) {
  86                 $type = 'application/x-git-packed-objects';
  87                 cache_one_year(\@h);
  88         } elsif ($path =~ m!\Aobjects/pack/pack-[a-f0-9]{40}\.idx\z!) {
  89                 $type = 'application/x-git-packed-objects-toc';
  90                 cache_one_year(\@h);
  91         } elsif ($path =~ /\A(?:$TEXT)\z/o) {
  92                 $type = 'text/plain';
  93                 push @h, @no_cache;
  94         } else {
  95                 return r(404);
  96         }
  97
  98         my $f = (ref $git ? $git->{git_dir} : $git) . '/' . $path;
  99         return r(404) unless -f $f && -r _; # just in case it's a FIFO :P
 100         my $size = -s _;
 101
 102         # TODO: If-Modified-Since and Last-Modified?
 103         open my $in, '<', $f or return r(404);
 104         my $len = $size;
 105         my $code = 200;
 106         push @h, 'Content-Type', $type;
 107         if (($env->{HTTP_RANGE} || '') =~ /\bbytes=(\d*)-(\d*)\z/) {
 108                 ($code, $len) = prepare_range($env, $in, \@h, $1, $2, $size);
 109                 if ($code == 416) {
 110                         push @h, 'Content-Range', "bytes */$size";
 111                         return [ 416, \@h, [] ];
 112                 }
 113         }
 114         push @h, 'Content-Length', $len;
 115         my $n = 65536;
 116         [ $code, \@h, Plack::Util::inline_object(close => sub { close $in },
 117                 getline => sub {
 118                         return if $len == 0;
 119                         $n = $len if $len < $n;
 120                         my $r = sysread($in, my $buf, $n);
 121                         if (!defined $r) {
 122                                 err($env, "$f read error: $!");
 123                         } elsif ($r <= 0) {
 124                                 err($env, "$f EOF with $len bytes left");
 125                         } else {
 126                                 $len -= $r;
 127                                 $n = 8192;
 128                                 return $buf;
 129                         }
 130                         drop_client($env);
 131                         return;
 132                 })]
 133 }
 134
 135 sub prepare_range {
 136         my ($env, $in, $h, $beg, $end, $size) = @_;
 137         my $code = 200;
 138         my $len = $size;
 139         if ($beg eq '') {
 140                 if ($end ne '') { # "bytes=-$end" => last N bytes
 141                         $beg = $size - $end;
 142                         $beg = 0 if $beg < 0;
 143                         $end = $size - 1;
 144                         $code = 206;
 145                 } else {
 146                         $code = 416;
 147                 }
 148         } else {
 149                 if ($beg > $size) {
 150                         $code = 416;
 151                 } elsif ($end eq '' || $end >= $size) {
 152                         $end = $size - 1;
 153                         $code = 206;
 154                 } elsif ($end < $size) {
 155                         $code = 206;
 156                 } else {
 157                         $code = 416;
 158                 }
 159         }
 160         if ($code == 206) {
 161                 $len = $end - $beg + 1;
 162                 if ($len <= 0) {
 163                         $code = 416;
 164                 } else {
 165                         sysseek($in, $beg, SEEK_SET) or return [ 500, [], [] ];
 166                         push @$h, qw(Accept-Ranges bytes Content-Range);
 167                         push @$h, "bytes $beg-$end/$size";
 168
 169                         # FIXME: Plack::Middleware::Deflater bug?
 170                         $env->{'psgix.no-compress'} = 1;
 171                 }
 172         }
 173         ($code, $len);
 174 }
 175
 176 # returns undef if 403 so it falls back to dumb HTTP
 177 sub serve_smart {
 178         my ($env, $git, $path) = @_;
 179         my $in = $env->{'psgi.input'};
 180         my $fd = eval { fileno($in) };
 181         unless (defined $fd && $fd >= 0) {
 182                 $in = input_to_file($env) or return r(500);
 183         }
 184         my %env = %ENV;
 185         # GIT_COMMITTER_NAME, GIT_COMMITTER_EMAIL
 186         # may be set in the server-process and are passed as-is
 187         foreach my $name (qw(QUERY_STRING
 188                                 REMOTE_USER REMOTE_ADDR
 189                                 HTTP_CONTENT_ENCODING
 190                                 CONTENT_TYPE
 191                                 SERVER_PROTOCOL
 192                                 REQUEST_METHOD)) {
 193                 my $val = $env->{$name};
 194                 $env{$name} = $val if defined $val;
 195         }
 196         my $git_dir = ref $git ? $git->{git_dir} : $git;
 197         $env{GIT_HTTP_EXPORT_ALL} = '1';
 198         $env{PATH_TRANSLATED} = "$git_dir/$path";
 199         my %rdr = ( 0 => fileno($in) );
 200         my $x = PublicInbox::Qspawn->new([qw(git http-backend)], \%env, \%rdr);
 201         my ($fh, $rpipe);
 202         my $end = sub {
 203                 if (my $err = $x->finish) {
 204                         err($env, "git http-backend ($git_dir): $err");
 205                 }
 206                 $fh->close if $fh; # async-only
 207         };
 208
 209         # Danga::Socket users, we queue up the read_enable callback to
 210         # fire after pending writes are complete:
 211         my $buf = '';
 212         my $rd_hdr = sub {
 213                 my $r = sysread($rpipe, $buf, 1024, length($buf));
 214                 return if !defined($r) && ($!{EINTR} || $!{EAGAIN});
 215                 return r(500, 'http-backend error') unless $r;
 216                 $r = parse_cgi_headers(\$buf) or return; # incomplete headers
 217                 $r->[0] == 403 ? serve_dumb($env, $git, $path) : $r;
 218         };
 219         my $res;
 220         my $async = $env->{'pi-httpd.async'};
 221         my $io = $env->{'psgix.io'};
 222         my $cb = sub {
 223                 my $r = $rd_hdr->() or return;
 224                 $rd_hdr = undef;
 225                 if (scalar(@$r) == 3) { # error:
 226                         if ($async) {
 227                                 $async->close; # calls rpipe->close
 228                         } else {
 229                                 $rpipe->close;
 230                                 $end->();
 231                         }
 232                         return $res->($r);
 233                 }
 234                 if ($async) {
 235                         $fh = $res->($r);
 236                         return $async->async_pass($io, $fh, \$buf);
 237                 }
 238
 239                 # for synchronous PSGI servers
 240                 require PublicInbox::GetlineBody;
 241                 $r->[2] = PublicInbox::GetlineBody->new($rpipe, $end, $buf);
 242                 $res->($r);
 243         };
 244         sub {
 245                 ($res) = @_;
 246
 247                 # hopefully this doesn't break any middlewares,
 248                 # holding the input here is a waste of FDs and memory
 249                 $env->{'psgi.input'} = undef;
 250
 251                 $x->start(sub { # may run later, much later...
 252                         ($rpipe) = @_;
 253                         $in = undef;
 254                         if ($async) {
 255                                 $async = $async->($rpipe, $cb, $end);
 256                         } else { # generic PSGI
 257                                 $cb->() while $rd_hdr;
 258                         }
 259                 });
 260         };
 261 }
 262
 263 sub input_to_file {
 264         my ($env) = @_;
 265         my $in = IO::File->new_tmpfile;
 266         my $input = $env->{'psgi.input'};
 267         my $buf;
 268         while (1) {
 269                 my $r = $input->read($buf, 8192);
 270                 unless (defined $r) {
 271                         err($env, "error reading input: $!");
 272                         return;
 273                 }
 274                 last if ($r == 0);
 275                 $in->write($buf);
 276         }
 277         $in->flush;
 278         $in->sysseek(0, SEEK_SET);
 279         return $in;
 280 }
 281
 282 sub parse_cgi_headers {
 283         my ($bref) = @_;
 284         $$bref =~ s/\A(.*?)\r\n\r\n//s or return;
 285         my $h = $1;
 286         my $code = 200;
 287         my @h;
 288         foreach my $l (split(/\r\n/, $h)) {
 289                 my ($k, $v) = split(/:\s*/, $l, 2);
 290                 if ($k =~ /\AStatus\z/i) {
 291                         ($code) = ($v =~ /\b(\d+)\b/);
 292                 } else {
 293                         push @h, $k, $v;
 294                 }
 295         }
 296         [ $code, \@h ]
 297 }
 298
 299 1;