lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 use constant {
  23         CHUNK_START => -1,   # [a-f0-9]+\r\n
  24         CHUNK_END => -2,     # \r\n
  25         CHUNK_ZEND => -3,    # \r\n
  26         CHUNK_MAX_HDR => 256,
  27 };
  28
  29 my $pipelineq = [];
  30 my $pipet;
  31 sub process_pipelineq () {
  32         my $q = $pipelineq;
  33         $pipet = undef;
  34         $pipelineq = [];
  35         foreach (@$q) {
  36                 next if $_->{closed};
  37                 rbuf_process($_);
  38         }
  39 }
  40
  41 # Use the same configuration parameter as git since this is primarily
  42 # a slow-client sponge for git-http-backend
  43 # TODO: support per-respository http.maxRequestBuffer somehow...
  44 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  45                         (10 * 1024 * 1024);
  46
  47 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  48 my $http_date;
  49 my $prev = 0;
  50 sub http_date () {
  51         my $now = time;
  52         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  53 }
  54
  55 sub new ($$$) {
  56         my ($class, $sock, $addr, $httpd) = @_;
  57         my $self = fields::new($class);
  58         $self->SUPER::new($sock);
  59         $self->{httpd} = $httpd;
  60         $self->{rbuf} = '';
  61         ($self->{remote_addr}, $self->{remote_port}) =
  62                 PublicInbox::Daemon::host_with_port($addr);
  63         $self->watch_read(1);
  64         $self;
  65 }
  66
  67 sub event_read { # called by PublicInbox::DS
  68         my ($self) = @_;
  69
  70         return event_read_input($self) if defined $self->{env};
  71
  72         my $off = length($self->{rbuf});
  73         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  74         if (defined $r) {
  75                 return $self->close if $r == 0;
  76                 return rbuf_process($self);
  77         }
  78         return if $!{EAGAIN}; # no need to call watch_read(1) again
  79
  80         # common for clients to break connections without warning,
  81         # would be too noisy to log here:
  82         return $self->close;
  83 }
  84
  85 sub rbuf_process {
  86         my ($self) = @_;
  87
  88         my %env = %{$self->{httpd}->{env}}; # full hash copy
  89         my $r = parse_http_request($self->{rbuf}, \%env);
  90
  91         # We do not support Trailers in chunked requests, for now
  92         # (they are rarely-used and git (as of 2.7.2) does not use them)
  93         if ($r == -1 || $env{HTTP_TRAILER} ||
  94                         # this length-check is necessary for PURE_PERL=1:
  95                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  96                 return quit($self, 400);
  97         }
  98         return $self->watch_read(1) if $r < 0; # incomplete
  99         $self->{rbuf} = substr($self->{rbuf}, $r);
 100
 101         my $len = input_prepare($self, \%env);
 102         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 103
 104         $len ? event_read_input($self) : app_dispatch($self);
 105 }
 106
 107 sub event_read_input ($) {
 108         my ($self) = @_;
 109         my $env = $self->{env};
 110         return event_read_input_chunked($self) if env_chunked($env);
 111
 112         # env->{CONTENT_LENGTH} (identity)
 113         my $sock = $self->{sock};
 114         my $len = $self->{input_left};
 115         $self->{input_left} = undef;
 116         my $rbuf = \($self->{rbuf});
 117         my $input = $env->{'psgi.input'};
 118
 119         while ($len > 0) {
 120                 if ($$rbuf ne '') {
 121                         my $w = write_in_full($input, $rbuf, $len);
 122                         return write_err($self, $len) unless $w;
 123                         $len -= $w;
 124                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 125                         if ($len == 0) { # next request may be pipelined
 126                                 $$rbuf = substr($$rbuf, $w);
 127                                 last;
 128                         }
 129                         $$rbuf = '';
 130                 }
 131                 my $r = sysread($sock, $$rbuf, 8192);
 132                 return recv_err($self, $r, $len) unless $r;
 133                 # continue looping if $r > 0;
 134         }
 135         app_dispatch($self, $input);
 136 }
 137
 138 sub app_dispatch {
 139         my ($self, $input) = @_;
 140         $self->watch_read(0);
 141         my $env = $self->{env};
 142         $env->{REMOTE_ADDR} = $self->{remote_addr};
 143         $env->{REMOTE_PORT} = $self->{remote_port};
 144         if (my $host = $env->{HTTP_HOST}) {
 145                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 146                 $env->{SERVER_NAME} = $host;
 147         }
 148         if (defined $input) {
 149                 sysseek($input, 0, SEEK_SET) or
 150                         die "BUG: psgi.input seek failed: $!";
 151         }
 152         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 153         # to do proper cleanup:
 154         $env->{'psgix.io'} = $self; # only for ->close
 155         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 156         eval {
 157                 if (ref($res) eq 'CODE') {
 158                         $res->(sub { response_write($self, $env, $_[0]) });
 159                 } else {
 160                         response_write($self, $env, $res);
 161                 }
 162         };
 163         $self->close if $@;
 164 }
 165
 166 sub response_header_write {
 167         my ($self, $env, $res) = @_;
 168         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 169         my $status = $res->[0];
 170         my $h = "$proto $status " . status_message($status) . "\r\n";
 171         my ($len, $chunked);
 172         my $headers = $res->[1];
 173
 174         for (my $i = 0; $i < @$headers; $i += 2) {
 175                 my $k = $headers->[$i];
 176                 my $v = $headers->[$i + 1];
 177                 next if $k =~ /\A(?:Connection|Date)\z/i;
 178
 179                 $len = $v if $k =~ /\AContent-Length\z/i;
 180                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 181                         $chunked = 1;
 182                 }
 183                 $h .= "$k: $v\r\n";
 184         }
 185
 186         my $conn = $env->{HTTP_CONNECTION} || '';
 187         my $term = defined($len) || $chunked;
 188         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 189         my $alive;
 190         if (!$term && $prot_persist) { # auto-chunk
 191                 $chunked = $alive = 2;
 192                 $h .= "Transfer-Encoding: chunked\r\n";
 193                 # no need for "Connection: keep-alive" with HTTP/1.1
 194         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 195                 $alive = 1;
 196                 $h .= "Connection: keep-alive\r\n";
 197         } else {
 198                 $alive = 0;
 199                 $h .= "Connection: close\r\n";
 200         }
 201         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 202
 203         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 204                 more($self, $h);
 205         } else {
 206                 $self->write($h);
 207         }
 208         $alive;
 209 }
 210
 211 # middlewares such as Deflater may write empty strings
 212 sub chunked_wcb ($) {
 213         my ($self) = @_;
 214         sub {
 215                 return if $_[0] eq '';
 216                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 217                 more($self, $_[0]);
 218
 219                 # use $self->write("\n\n") if you care about real-time
 220                 # streaming responses, public-inbox WWW does not.
 221                 more($self, "\r\n");
 222         }
 223 }
 224
 225 sub identity_wcb ($) {
 226         my ($self) = @_;
 227         sub { $self->write(\($_[0])) if $_[0] ne '' }
 228 }
 229
 230 sub next_request ($) {
 231         my ($self) = @_;
 232         $self->watch_write(0);
 233         if ($self->{rbuf} eq '') { # wait for next request
 234                 $self->watch_read(1);
 235         } else { # avoid recursion for pipelined requests
 236                 push @$pipelineq, $self;
 237                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 238         }
 239 }
 240
 241 sub response_done_cb ($$) {
 242         my ($self, $alive) = @_;
 243         sub {
 244                 my $env = $self->{env};
 245                 $self->{env} = undef;
 246                 $self->write("0\r\n\r\n") if $alive == 2;
 247                 $self->write(sub{$alive ? next_request($self) : $self->close});
 248         }
 249 }
 250
 251 sub getline_cb ($$$) {
 252         my ($self, $write, $close) = @_;
 253         local $/ = \8192;
 254         my $forward = $self->{forward};
 255         # limit our own running time for fairness with other
 256         # clients and to avoid buffering too much:
 257         if ($forward) {
 258                 my $buf = eval { $forward->getline };
 259                 if (defined $buf) {
 260                         $write->($buf); # may close in PublicInbox::DS::write
 261                         unless ($self->{closed}) {
 262                                 my $next = $self->{pull};
 263                                 if ($self->{write_buf_size}) {
 264                                         $self->write($next);
 265                                 } else {
 266                                         PublicInbox::EvCleanup::asap($next);
 267                                 }
 268                                 return;
 269                         }
 270                 } elsif ($@) {
 271                         err($self, "response ->getline error: $@");
 272                         $forward = undef;
 273                         $self->close;
 274                 }
 275         }
 276
 277         $self->{forward} = $self->{pull} = undef;
 278         # avoid recursion
 279         if ($forward) {
 280                 eval { $forward->close };
 281                 if ($@) {
 282                         err($self, "response ->close error: $@");
 283                         $self->close; # idempotent
 284                 }
 285         }
 286         $close->();
 287 }
 288
 289 sub getline_response ($$$) {
 290         my ($self, $write, $close) = @_;
 291         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 292         $pull->();
 293 }
 294
 295 sub response_write {
 296         my ($self, $env, $res) = @_;
 297         my $alive = response_header_write($self, $env, $res);
 298         my $close = response_done_cb($self, $alive);
 299         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 300         if (defined(my $body = $res->[2])) {
 301                 if (ref $body eq 'ARRAY') {
 302                         $write->($_) foreach @$body;
 303                         $close->();
 304                 } else {
 305                         $self->{forward} = $body;
 306                         getline_response($self, $write, $close);
 307                 }
 308         } else {
 309                 # this is returned to the calling application:
 310                 Plack::Util::inline_object(write => $write, close => $close);
 311         }
 312 }
 313
 314 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 315 sub more ($$) {
 316         my $self = $_[0];
 317         return if $self->{closed};
 318         if (MSG_MORE && !$self->{write_buf_size}) {
 319                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 320                 if (defined $n) {
 321                         my $nlen = length($_[1]) - $n;
 322                         return 1 if $nlen == 0; # all done!
 323
 324                         # PublicInbox::DS::write queues the unwritten substring:
 325                         return $self->write(substr($_[1], $n, $nlen));
 326                 }
 327         }
 328         $self->write($_[1]);
 329 }
 330
 331 sub input_prepare {
 332         my ($self, $env) = @_;
 333         my $input;
 334         my $len = $env->{CONTENT_LENGTH};
 335         if ($len) {
 336                 if ($len > $MAX_REQUEST_BUFFER) {
 337                         quit($self, 413);
 338                         return;
 339                 }
 340                 open($input, '+>', undef);
 341         } elsif (env_chunked($env)) {
 342                 $len = CHUNK_START;
 343                 open($input, '+>', undef);
 344         } else {
 345                 $input = $null_io;
 346         }
 347
 348         # TODO: expire idle clients on ENFILE / EMFILE
 349         return unless $input;
 350
 351         $env->{'psgi.input'} = $input;
 352         $self->{env} = $env;
 353         $self->{input_left} = $len || 0;
 354 }
 355
 356 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 357
 358 sub err ($$) {
 359         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 360 }
 361
 362 sub write_err {
 363         my ($self, $len) = @_;
 364         my $msg = $! || '(zero write)';
 365         $msg .= " ($len bytes remaining)" if defined $len;
 366         err($self, "error buffering to input: $msg");
 367         quit($self, 500);
 368 }
 369
 370 sub recv_err {
 371         my ($self, $r, $len) = @_;
 372         return $self->close if (defined $r && $r == 0);
 373         if ($!{EAGAIN}) {
 374                 $self->{input_left} = $len;
 375                 return;
 376         }
 377         err($self, "error reading for input: $! ($len bytes remaining)");
 378         quit($self, 500);
 379 }
 380
 381 sub write_in_full {
 382         my ($fh, $rbuf, $len) = @_;
 383         my $rv = 0;
 384         my $off = 0;
 385         while ($len > 0) {
 386                 my $w = syswrite($fh, $$rbuf, $len, $off);
 387                 return ($rv ? $rv : $w) unless $w; # undef or 0
 388                 $rv += $w;
 389                 $off += $w;
 390                 $len -= $w;
 391         }
 392         $rv
 393 }
 394
 395 sub event_read_input_chunked { # unlikely...
 396         my ($self) = @_;
 397         my $input = $self->{env}->{'psgi.input'};
 398         my $sock = $self->{sock};
 399         my $len = $self->{input_left};
 400         $self->{input_left} = undef;
 401         my $rbuf = \($self->{rbuf});
 402
 403         while (1) { # chunk start
 404                 if ($len == CHUNK_ZEND) {
 405                         $$rbuf =~ s/\A\r\n//s and
 406                                 return app_dispatch($self, $input);
 407                         return quit($self, 400) if length($$rbuf) > 2;
 408                 }
 409                 if ($len == CHUNK_END) {
 410                         if ($$rbuf =~ s/\A\r\n//s) {
 411                                 $len = CHUNK_START;
 412                         } elsif (length($$rbuf) > 2) {
 413                                 return quit($self, 400);
 414                         }
 415                 }
 416                 if ($len == CHUNK_START) {
 417                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 418                                 $len = hex $1;
 419                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 420                                         return quit($self, 413);
 421                                 }
 422                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 423                                 return quit($self, 400);
 424                         }
 425                         # will break from loop since $len >= 0
 426                 }
 427
 428                 if ($len < 0) { # chunk header is trickled, read more
 429                         my $off = length($$rbuf);
 430                         my $r = sysread($sock, $$rbuf, 8192, $off);
 431                         return recv_err($self, $r, $len) unless $r;
 432                         # (implicit) goto chunk_start if $r > 0;
 433                 }
 434                 $len = CHUNK_ZEND if $len == 0;
 435
 436                 # drain the current chunk
 437                 until ($len <= 0) {
 438                         if ($$rbuf ne '') {
 439                                 my $w = write_in_full($input, $rbuf, $len);
 440                                 return write_err($self, "$len chunk") if !$w;
 441                                 $len -= $w;
 442                                 if ($len == 0) {
 443                                         # we may have leftover data to parse
 444                                         # in chunk
 445                                         $$rbuf = substr($$rbuf, $w);
 446                                         $len = CHUNK_END;
 447                                 } elsif ($len < 0) {
 448                                         die "BUG: len < 0: $len";
 449                                 } else {
 450                                         $$rbuf = '';
 451                                 }
 452                         }
 453                         if ($$rbuf eq '') {
 454                                 # read more of current chunk
 455                                 my $r = sysread($sock, $$rbuf, 8192);
 456                                 return recv_err($self, $r, $len) unless $r;
 457                         }
 458                 }
 459         }
 460 }
 461
 462 sub quit {
 463         my ($self, $status) = @_;
 464         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 465         $self->write($h);
 466         $self->close;
 467 }
 468
 469 # callbacks for PublicInbox::DS
 470
 471 sub event_hup { $_[0]->close }
 472 sub event_err { $_[0]->close }
 473
 474 sub close {
 475         my $self = shift;
 476         my $forward = $self->{forward};
 477         my $env = $self->{env};
 478         delete $env->{'psgix.io'} if $env; # prevent circular references
 479         $self->{pull} = $self->{forward} = $self->{env} = undef;
 480         if ($forward) {
 481                 eval { $forward->close };
 482                 err($self, "forward ->close error: $@") if $@;
 483         }
 484         $self->SUPER::close(@_);
 485 }
 486
 487 # for graceful shutdown in PublicInbox::Daemon:
 488 sub busy () {
 489         my ($self) = @_;
 490         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 491 }
 492
 493 1;