lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 use constant {
  22         CHUNK_START => -1,   # [a-f0-9]+\r\n
  23         CHUNK_END => -2,     # \r\n
  24         CHUNK_ZEND => -3,    # \r\n
  25         CHUNK_MAX_HDR => 256,
  26 };
  27
  28 my $pipelineq = [];
  29 my $pipet;
  30 sub process_pipelineq () {
  31         my $q = $pipelineq;
  32         $pipet = undef;
  33         $pipelineq = [];
  34         foreach (@$q) {
  35                 next if $_->{closed};
  36                 rbuf_process($_);
  37         }
  38 }
  39
  40 # Use the same configuration parameter as git since this is primarily
  41 # a slow-client sponge for git-http-backend
  42 # TODO: support per-respository http.maxRequestBuffer somehow...
  43 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  44                         (10 * 1024 * 1024);
  45
  46 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  47 my $http_date;
  48 my $prev = 0;
  49 sub http_date () {
  50         my $now = time;
  51         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  52 }
  53
  54 sub new ($$$) {
  55         my ($class, $sock, $addr, $httpd) = @_;
  56         my $self = fields::new($class);
  57         $self->SUPER::new($sock);
  58         $self->{httpd} = $httpd;
  59         $self->{rbuf} = '';
  60         ($self->{remote_addr}, $self->{remote_port}) =
  61                 PublicInbox::Daemon::host_with_port($addr);
  62         $self->watch_read(1);
  63         $self;
  64 }
  65
  66 sub event_read { # called by PublicInbox::DS
  67         my ($self) = @_;
  68
  69         return event_read_input($self) if defined $self->{env};
  70
  71         my $off = length($self->{rbuf});
  72         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  73         if (defined $r) {
  74                 return $self->close if $r == 0;
  75                 return rbuf_process($self);
  76         }
  77         return if $!{EAGAIN}; # no need to call watch_read(1) again
  78
  79         # common for clients to break connections without warning,
  80         # would be too noisy to log here:
  81         return $self->close;
  82 }
  83
  84 sub rbuf_process {
  85         my ($self) = @_;
  86
  87         my %env = %{$self->{httpd}->{env}}; # full hash copy
  88         my $r = parse_http_request($self->{rbuf}, \%env);
  89
  90         # We do not support Trailers in chunked requests, for now
  91         # (they are rarely-used and git (as of 2.7.2) does not use them)
  92         if ($r == -1 || $env{HTTP_TRAILER} ||
  93                         # this length-check is necessary for PURE_PERL=1:
  94                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  95                 return quit($self, 400);
  96         }
  97         return $self->watch_read(1) if $r < 0; # incomplete
  98         $self->{rbuf} = substr($self->{rbuf}, $r);
  99
 100         my $len = input_prepare($self, \%env);
 101         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 102
 103         $len ? event_read_input($self) : app_dispatch($self);
 104 }
 105
 106 sub event_read_input ($) {
 107         my ($self) = @_;
 108         my $env = $self->{env};
 109         return event_read_input_chunked($self) if env_chunked($env);
 110
 111         # env->{CONTENT_LENGTH} (identity)
 112         my $sock = $self->{sock};
 113         my $len = $self->{input_left};
 114         $self->{input_left} = undef;
 115         my $rbuf = \($self->{rbuf});
 116         my $input = $env->{'psgi.input'};
 117
 118         while ($len > 0) {
 119                 if ($$rbuf ne '') {
 120                         my $w = write_in_full($input, $rbuf, $len);
 121                         return write_err($self, $len) unless $w;
 122                         $len -= $w;
 123                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 124                         if ($len == 0) { # next request may be pipelined
 125                                 $$rbuf = substr($$rbuf, $w);
 126                                 last;
 127                         }
 128                         $$rbuf = '';
 129                 }
 130                 my $r = sysread($sock, $$rbuf, 8192);
 131                 return recv_err($self, $r, $len) unless $r;
 132                 # continue looping if $r > 0;
 133         }
 134         app_dispatch($self, $input);
 135 }
 136
 137 sub app_dispatch {
 138         my ($self, $input) = @_;
 139         $self->watch_read(0);
 140         my $env = $self->{env};
 141         $env->{REMOTE_ADDR} = $self->{remote_addr};
 142         $env->{REMOTE_PORT} = $self->{remote_port};
 143         if (my $host = $env->{HTTP_HOST}) {
 144                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 145                 $env->{SERVER_NAME} = $host;
 146         }
 147         if (defined $input) {
 148                 sysseek($input, 0, SEEK_SET) or
 149                         die "BUG: psgi.input seek failed: $!";
 150         }
 151         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 152         # to do proper cleanup:
 153         $env->{'psgix.io'} = $self; # only for ->close
 154         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 155         eval {
 156                 if (ref($res) eq 'CODE') {
 157                         $res->(sub { response_write($self, $env, $_[0]) });
 158                 } else {
 159                         response_write($self, $env, $res);
 160                 }
 161         };
 162         $self->close if $@;
 163 }
 164
 165 sub response_header_write {
 166         my ($self, $env, $res) = @_;
 167         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 168         my $status = $res->[0];
 169         my $h = "$proto $status " . status_message($status) . "\r\n";
 170         my ($len, $chunked);
 171         my $headers = $res->[1];
 172
 173         for (my $i = 0; $i < @$headers; $i += 2) {
 174                 my $k = $headers->[$i];
 175                 my $v = $headers->[$i + 1];
 176                 next if $k =~ /\A(?:Connection|Date)\z/i;
 177
 178                 $len = $v if $k =~ /\AContent-Length\z/i;
 179                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 180                         $chunked = 1;
 181                 }
 182                 $h .= "$k: $v\r\n";
 183         }
 184
 185         my $conn = $env->{HTTP_CONNECTION} || '';
 186         my $term = defined($len) || $chunked;
 187         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 188         my $alive;
 189         if (!$term && $prot_persist) { # auto-chunk
 190                 $chunked = $alive = 2;
 191                 $h .= "Transfer-Encoding: chunked\r\n";
 192                 # no need for "Connection: keep-alive" with HTTP/1.1
 193         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 194                 $alive = 1;
 195                 $h .= "Connection: keep-alive\r\n";
 196         } else {
 197                 $alive = 0;
 198                 $h .= "Connection: close\r\n";
 199         }
 200         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 201
 202         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 203                 more($self, $h);
 204         } else {
 205                 $self->write($h);
 206         }
 207         $alive;
 208 }
 209
 210 # middlewares such as Deflater may write empty strings
 211 sub chunked_wcb ($) {
 212         my ($self) = @_;
 213         sub {
 214                 return if $_[0] eq '';
 215                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 216                 more($self, $_[0]);
 217
 218                 # use $self->write("\n\n") if you care about real-time
 219                 # streaming responses, public-inbox WWW does not.
 220                 more($self, "\r\n");
 221         }
 222 }
 223
 224 sub identity_wcb ($) {
 225         my ($self) = @_;
 226         sub { $self->write(\($_[0])) if $_[0] ne '' }
 227 }
 228
 229 sub next_request ($) {
 230         my ($self) = @_;
 231         $self->watch_write(0);
 232         if ($self->{rbuf} eq '') { # wait for next request
 233                 $self->watch_read(1);
 234         } else { # avoid recursion for pipelined requests
 235                 push @$pipelineq, $self;
 236                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 237         }
 238 }
 239
 240 sub response_done_cb ($$) {
 241         my ($self, $alive) = @_;
 242         sub {
 243                 my $env = $self->{env};
 244                 $self->{env} = undef;
 245                 $self->write("0\r\n\r\n") if $alive == 2;
 246                 $self->write(sub{$alive ? next_request($self) : $self->close});
 247         }
 248 }
 249
 250 sub getline_cb ($$$) {
 251         my ($self, $write, $close) = @_;
 252         local $/ = \8192;
 253         my $forward = $self->{forward};
 254         # limit our own running time for fairness with other
 255         # clients and to avoid buffering too much:
 256         if ($forward) {
 257                 my $buf = eval { $forward->getline };
 258                 if (defined $buf) {
 259                         $write->($buf); # may close in PublicInbox::DS::write
 260                         unless ($self->{closed}) {
 261                                 my $next = $self->{pull};
 262                                 if ($self->{write_buf_size}) {
 263                                         $self->write($next);
 264                                 } else {
 265                                         PublicInbox::EvCleanup::asap($next);
 266                                 }
 267                                 return;
 268                         }
 269                 } elsif ($@) {
 270                         err($self, "response ->getline error: $@");
 271                         $forward = undef;
 272                         $self->close;
 273                 }
 274         }
 275
 276         $self->{forward} = $self->{pull} = undef;
 277         # avoid recursion
 278         if ($forward) {
 279                 eval { $forward->close };
 280                 if ($@) {
 281                         err($self, "response ->close error: $@");
 282                         $self->close; # idempotent
 283                 }
 284         }
 285         $close->();
 286 }
 287
 288 sub getline_response ($$$) {
 289         my ($self, $write, $close) = @_;
 290         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 291         $pull->();
 292 }
 293
 294 sub response_write {
 295         my ($self, $env, $res) = @_;
 296         my $alive = response_header_write($self, $env, $res);
 297         my $close = response_done_cb($self, $alive);
 298         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 299         if (defined(my $body = $res->[2])) {
 300                 if (ref $body eq 'ARRAY') {
 301                         $write->($_) foreach @$body;
 302                         $close->();
 303                 } else {
 304                         $self->{forward} = $body;
 305                         getline_response($self, $write, $close);
 306                 }
 307         } else {
 308                 # this is returned to the calling application:
 309                 Plack::Util::inline_object(write => $write, close => $close);
 310         }
 311 }
 312
 313 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 314 sub more ($$) {
 315         my $self = $_[0];
 316         return if $self->{closed};
 317         if (MSG_MORE && !$self->{write_buf_size}) {
 318                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 319                 if (defined $n) {
 320                         my $nlen = length($_[1]) - $n;
 321                         return 1 if $nlen == 0; # all done!
 322
 323                         # PublicInbox::DS::write queues the unwritten substring:
 324                         return $self->write(substr($_[1], $n, $nlen));
 325                 }
 326         }
 327         $self->write($_[1]);
 328 }
 329
 330 sub input_prepare {
 331         my ($self, $env) = @_;
 332         my $input;
 333         my $len = $env->{CONTENT_LENGTH};
 334         if ($len) {
 335                 if ($len > $MAX_REQUEST_BUFFER) {
 336                         quit($self, 413);
 337                         return;
 338                 }
 339                 open($input, '+>', undef);
 340         } elsif (env_chunked($env)) {
 341                 $len = CHUNK_START;
 342                 open($input, '+>', undef);
 343         } else {
 344                 $input = $null_io;
 345         }
 346
 347         # TODO: expire idle clients on ENFILE / EMFILE
 348         return unless $input;
 349
 350         $env->{'psgi.input'} = $input;
 351         $self->{env} = $env;
 352         $self->{input_left} = $len || 0;
 353 }
 354
 355 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 356
 357 sub err ($$) {
 358         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 359 }
 360
 361 sub write_err {
 362         my ($self, $len) = @_;
 363         my $msg = $! || '(zero write)';
 364         $msg .= " ($len bytes remaining)" if defined $len;
 365         err($self, "error buffering to input: $msg");
 366         quit($self, 500);
 367 }
 368
 369 sub recv_err {
 370         my ($self, $r, $len) = @_;
 371         return $self->close if (defined $r && $r == 0);
 372         if ($!{EAGAIN}) {
 373                 $self->{input_left} = $len;
 374                 return;
 375         }
 376         err($self, "error reading for input: $! ($len bytes remaining)");
 377         quit($self, 500);
 378 }
 379
 380 sub write_in_full {
 381         my ($fh, $rbuf, $len) = @_;
 382         my $rv = 0;
 383         my $off = 0;
 384         while ($len > 0) {
 385                 my $w = syswrite($fh, $$rbuf, $len, $off);
 386                 return ($rv ? $rv : $w) unless $w; # undef or 0
 387                 $rv += $w;
 388                 $off += $w;
 389                 $len -= $w;
 390         }
 391         $rv
 392 }
 393
 394 sub event_read_input_chunked { # unlikely...
 395         my ($self) = @_;
 396         my $input = $self->{env}->{'psgi.input'};
 397         my $sock = $self->{sock};
 398         my $len = $self->{input_left};
 399         $self->{input_left} = undef;
 400         my $rbuf = \($self->{rbuf});
 401
 402         while (1) { # chunk start
 403                 if ($len == CHUNK_ZEND) {
 404                         $$rbuf =~ s/\A\r\n//s and
 405                                 return app_dispatch($self, $input);
 406                         return quit($self, 400) if length($$rbuf) > 2;
 407                 }
 408                 if ($len == CHUNK_END) {
 409                         if ($$rbuf =~ s/\A\r\n//s) {
 410                                 $len = CHUNK_START;
 411                         } elsif (length($$rbuf) > 2) {
 412                                 return quit($self, 400);
 413                         }
 414                 }
 415                 if ($len == CHUNK_START) {
 416                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 417                                 $len = hex $1;
 418                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 419                                         return quit($self, 413);
 420                                 }
 421                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 422                                 return quit($self, 400);
 423                         }
 424                         # will break from loop since $len >= 0
 425                 }
 426
 427                 if ($len < 0) { # chunk header is trickled, read more
 428                         my $off = length($$rbuf);
 429                         my $r = sysread($sock, $$rbuf, 8192, $off);
 430                         return recv_err($self, $r, $len) unless $r;
 431                         # (implicit) goto chunk_start if $r > 0;
 432                 }
 433                 $len = CHUNK_ZEND if $len == 0;
 434
 435                 # drain the current chunk
 436                 until ($len <= 0) {
 437                         if ($$rbuf ne '') {
 438                                 my $w = write_in_full($input, $rbuf, $len);
 439                                 return write_err($self, "$len chunk") if !$w;
 440                                 $len -= $w;
 441                                 if ($len == 0) {
 442                                         # we may have leftover data to parse
 443                                         # in chunk
 444                                         $$rbuf = substr($$rbuf, $w);
 445                                         $len = CHUNK_END;
 446                                 } elsif ($len < 0) {
 447                                         die "BUG: len < 0: $len";
 448                                 } else {
 449                                         $$rbuf = '';
 450                                 }
 451                         }
 452                         if ($$rbuf eq '') {
 453                                 # read more of current chunk
 454                                 my $r = sysread($sock, $$rbuf, 8192);
 455                                 return recv_err($self, $r, $len) unless $r;
 456                         }
 457                 }
 458         }
 459 }
 460
 461 sub quit {
 462         my ($self, $status) = @_;
 463         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 464         $self->write($h);
 465         $self->close;
 466 }
 467
 468 # callbacks for PublicInbox::DS
 469
 470 sub event_hup { $_[0]->close }
 471 sub event_err { $_[0]->close }
 472
 473 sub close {
 474         my $self = shift;
 475         my $forward = $self->{forward};
 476         my $env = $self->{env};
 477         delete $env->{'psgix.io'} if $env; # prevent circular references
 478         $self->{pull} = $self->{forward} = $self->{env} = undef;
 479         if ($forward) {
 480                 eval { $forward->close };
 481                 err($self, "forward ->close error: $@") if $@;
 482         }
 483         $self->SUPER::close(@_);
 484 }
 485
 486 # for graceful shutdown in PublicInbox::Daemon:
 487 sub busy () {
 488         my ($self) = @_;
 489         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 490 }
 491
 492 1;