lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env input_left remote_addr remote_port forward alive);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use Plack::Util;
  19 use HTTP::Status qw(status_message);
  20 use HTTP::Date qw(time2str);
  21 use IO::Handle; # ->write
  22 use PublicInbox::DS qw(msg_more);
  23 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  24 use PublicInbox::Tmpfile;
  25 use constant {
  26         CHUNK_START => -1,   # [a-f0-9]+\r\n
  27         CHUNK_END => -2,     # \r\n
  28         CHUNK_ZEND => -3,    # \r\n
  29         CHUNK_MAX_HDR => 256,
  30 };
  31 use Errno qw(EAGAIN);
  32
  33 my $pipelineq = [];
  34 sub process_pipelineq () {
  35         my $q = $pipelineq;
  36         $pipelineq = [];
  37         foreach (@$q) {
  38                 next unless $_->{sock};
  39                 rbuf_process($_);
  40         }
  41 }
  42
  43 # Use the same configuration parameter as git since this is primarily
  44 # a slow-client sponge for git-http-backend
  45 # TODO: support per-respository http.maxRequestBuffer somehow...
  46 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  47                         (10 * 1024 * 1024);
  48
  49 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  50 my $http_date;
  51 my $prev = 0;
  52 sub http_date () {
  53         my $now = time;
  54         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  55 }
  56
  57 sub new ($$$) {
  58         my ($class, $sock, $addr, $httpd) = @_;
  59         my $self = fields::new($class);
  60         my $ev = EPOLLIN;
  61         my $wbuf;
  62         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  63                 return CORE::close($sock) if $! != EAGAIN;
  64                 $ev = PublicInbox::TLS::epollbit();
  65                 $wbuf = [ \&PublicInbox::DS::accept_tls_step ];
  66         }
  67         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  68         $self->{httpd} = $httpd;
  69         $self->{wbuf} = $wbuf if $wbuf;
  70         ($self->{remote_addr}, $self->{remote_port}) =
  71                 PublicInbox::Daemon::host_with_port($addr);
  72         $self;
  73 }
  74
  75 sub event_step { # called by PublicInbox::DS
  76         my ($self) = @_;
  77
  78         return unless $self->flush_write && $self->{sock};
  79
  80         # only read more requests if we've drained the write buffer,
  81         # otherwise we can be buffering infinitely w/o backpressure
  82
  83         return read_input($self) if defined $self->{env};
  84         my $rbuf = $self->{rbuf} // (\(my $x = ''));
  85         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or return;
  86         rbuf_process($self, $rbuf);
  87 }
  88
  89 sub rbuf_process {
  90         my ($self, $rbuf) = @_;
  91         $rbuf //= $self->{rbuf} // (\(my $x = ''));
  92
  93         my %env = %{$self->{httpd}->{env}}; # full hash copy
  94         my $r = parse_http_request($$rbuf, \%env);
  95
  96         # We do not support Trailers in chunked requests, for now
  97         # (they are rarely-used and git (as of 2.7.2) does not use them)
  98         if ($r == -1 || $env{HTTP_TRAILER} ||
  99                         # this length-check is necessary for PURE_PERL=1:
 100                         ($r == -2 && bytes::length($$rbuf) > 0x4000)) {
 101                 return quit($self, 400);
 102         }
 103         if ($r < 0) { # incomplete
 104                 $self->rbuf_idle($rbuf);
 105                 return $self->requeue;
 106         }
 107         $$rbuf = substr($$rbuf, $r);
 108         my $len = input_prepare($self, \%env);
 109         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 110
 111         $len ? read_input($self, $rbuf) : app_dispatch($self, undef, $rbuf);
 112 }
 113
 114 # IO::Handle::write returns boolean, this returns bytes written:
 115 sub xwrite ($$$) {
 116         my ($fh, $rbuf, $max) = @_;
 117         my $w = bytes::length($$rbuf);
 118         $w = $max if $w > $max;
 119         $fh->write($$rbuf, $w) or return;
 120         $w;
 121 }
 122
 123 sub read_input ($;$) {
 124         my ($self, $rbuf) = @_;
 125         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 126         my $env = $self->{env};
 127         return if $env->{REMOTE_ADDR}; # in app dispatch
 128         return read_input_chunked($self, $rbuf) if env_chunked($env);
 129
 130         # env->{CONTENT_LENGTH} (identity)
 131         my $len = delete $self->{input_left};
 132         my $input = $env->{'psgi.input'};
 133
 134         while ($len > 0) {
 135                 if ($$rbuf ne '') {
 136                         my $w = xwrite($input, $rbuf, $len);
 137                         return write_err($self, $len) unless $w;
 138                         $len -= $w;
 139                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 140                         if ($len == 0) { # next request may be pipelined
 141                                 $$rbuf = substr($$rbuf, $w);
 142                                 last;
 143                         }
 144                         $$rbuf = '';
 145                 }
 146                 $self->do_read($rbuf, 8192) or return recv_err($self, $len);
 147                 # continue looping if $r > 0;
 148         }
 149         app_dispatch($self, $input, $rbuf);
 150 }
 151
 152 sub app_dispatch {
 153         my ($self, $input, $rbuf) = @_;
 154         $self->rbuf_idle($rbuf);
 155         my $env = $self->{env};
 156         $env->{REMOTE_ADDR} = $self->{remote_addr};
 157         $env->{REMOTE_PORT} = $self->{remote_port};
 158         if (my $host = $env->{HTTP_HOST}) {
 159                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 160                 $env->{SERVER_NAME} = $host;
 161         }
 162         if (defined $input) {
 163                 sysseek($input, 0, SEEK_SET) or
 164                         die "BUG: psgi.input seek failed: $!";
 165         }
 166         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 167         # to do proper cleanup:
 168         $env->{'psgix.io'} = $self; # for ->close or async_pass
 169         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 170         eval {
 171                 if (ref($res) eq 'CODE') {
 172                         $res->(sub { response_write($self, $env, $_[0]) });
 173                 } else {
 174                         response_write($self, $env, $res);
 175                 }
 176         };
 177         $self->close if $@;
 178 }
 179
 180 sub response_header_write {
 181         my ($self, $env, $res) = @_;
 182         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 183         my $status = $res->[0];
 184         my $h = "$proto $status " . status_message($status) . "\r\n";
 185         my ($len, $chunked);
 186         my $headers = $res->[1];
 187
 188         for (my $i = 0; $i < @$headers; $i += 2) {
 189                 my $k = $headers->[$i];
 190                 my $v = $headers->[$i + 1];
 191                 next if $k =~ /\A(?:Connection|Date)\z/i;
 192
 193                 $len = $v if $k =~ /\AContent-Length\z/i;
 194                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 195                         $chunked = 1;
 196                 }
 197                 $h .= "$k: $v\r\n";
 198         }
 199
 200         my $conn = $env->{HTTP_CONNECTION} || '';
 201         my $term = defined($len) || $chunked;
 202         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 203         my $alive;
 204         if (!$term && $prot_persist) { # auto-chunk
 205                 $chunked = $alive = 2;
 206                 $h .= "Transfer-Encoding: chunked\r\n";
 207                 # no need for "Connection: keep-alive" with HTTP/1.1
 208         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 209                 $alive = 1;
 210                 $h .= "Connection: keep-alive\r\n";
 211         } else {
 212                 $alive = 0;
 213                 $h .= "Connection: close\r\n";
 214         }
 215         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 216
 217         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 218                 msg_more($self, $h);
 219         } else {
 220                 $self->write(\$h);
 221         }
 222         $alive;
 223 }
 224
 225 # middlewares such as Deflater may write empty strings
 226 sub chunked_write ($$) {
 227         my $self = $_[0];
 228         return if $_[1] eq '';
 229         msg_more($self, sprintf("%x\r\n", bytes::length($_[1])));
 230         msg_more($self, $_[1]);
 231
 232         # use $self->write(\"\n\n") if you care about real-time
 233         # streaming responses, public-inbox WWW does not.
 234         msg_more($self, "\r\n");
 235 }
 236
 237 sub identity_write ($$) {
 238         my $self = $_[0];
 239         $self->write(\($_[1])) if $_[1] ne '';
 240 }
 241
 242 sub next_request ($) {
 243         my ($self) = @_;
 244         if ($self->{rbuf}) {
 245                 # avoid recursion for pipelined requests
 246                 PublicInbox::DS::requeue(\&process_pipelineq) if !@$pipelineq;
 247                 push @$pipelineq, $self;
 248         } else { # wait for next request
 249                 $self->requeue;
 250         }
 251 }
 252
 253 sub response_done {
 254         my ($self, $alive) = @_;
 255         delete $self->{env}; # we're no longer busy
 256         $self->write(\"0\r\n\r\n") if $alive == 2;
 257         $self->write($alive ? \&next_request : \&close);
 258 }
 259
 260 sub getline_pull {
 261         my ($self) = @_;
 262         my $forward = $self->{forward};
 263
 264         # limit our own running time for fairness with other
 265         # clients and to avoid buffering too much:
 266         my $buf = eval {
 267                 local $/ = \8192;
 268                 $forward->getline;
 269         } if $forward;
 270
 271         if (defined $buf) {
 272                 # may close in PublicInbox::DS::write
 273                 if ($self->{alive} == 2) {
 274                         chunked_write($self, $buf);
 275                 } else {
 276                         identity_write($self, $buf);
 277                 }
 278
 279                 if ($self->{sock}) {
 280                         my $wbuf = $self->{wbuf} //= [];
 281                         push @$wbuf, \&getline_pull;
 282
 283                         # wbuf may be populated by {chunked,identity}_write()
 284                         # above, no need to rearm if so:
 285                         $self->requeue if scalar(@$wbuf) == 1;
 286                         return; # likely
 287                 }
 288         } elsif ($@) {
 289                 err($self, "response ->getline error: $@");
 290                 $self->close;
 291         }
 292         # avoid recursion
 293         if (delete $self->{forward}) {
 294                 eval { $forward->close };
 295                 if ($@) {
 296                         err($self, "response ->close error: $@");
 297                         $self->close; # idempotent
 298                 }
 299         }
 300         response_done($self, delete $self->{alive});
 301 }
 302
 303 sub response_write {
 304         my ($self, $env, $res) = @_;
 305         my $alive = response_header_write($self, $env, $res);
 306         if (defined(my $body = $res->[2])) {
 307                 if (ref $body eq 'ARRAY') {
 308                         if ($alive == 2) {
 309                                 chunked_write($self, $_) for @$body;
 310                         } else {
 311                                 identity_write($self, $_) for @$body;
 312                         }
 313                         response_done($self, $alive);
 314                 } else {
 315                         $self->{forward} = $body;
 316                         $self->{alive} = $alive;
 317                         getline_pull($self); # kick-off!
 318                 }
 319         # these are returned to the calling application:
 320         } elsif ($alive == 2) {
 321                 bless [ $self, $alive ], 'PublicInbox::HTTP::Chunked';
 322         } else {
 323                 bless [ $self, $alive ], 'PublicInbox::HTTP::Identity';
 324         }
 325 }
 326
 327 sub input_tmpfile ($) {
 328         my $input = tmpfile('http.input', $_[0]->{sock}) or return;
 329         $input->autoflush(1);
 330         $input;
 331 }
 332
 333 sub input_prepare {
 334         my ($self, $env) = @_;
 335         my $input;
 336         my $len = $env->{CONTENT_LENGTH};
 337         if ($len) {
 338                 if ($len > $MAX_REQUEST_BUFFER) {
 339                         quit($self, 413);
 340                         return;
 341                 }
 342                 $input = input_tmpfile($self);
 343         } elsif (env_chunked($env)) {
 344                 $len = CHUNK_START;
 345                 $input = input_tmpfile($self);
 346         } else {
 347                 $input = $null_io;
 348         }
 349
 350         # TODO: expire idle clients on ENFILE / EMFILE
 351         return unless $input;
 352
 353         $env->{'psgi.input'} = $input;
 354         $self->{env} = $env;
 355         $self->{input_left} = $len || 0;
 356 }
 357
 358 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 359
 360 sub err ($$) {
 361         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 362 }
 363
 364 sub write_err {
 365         my ($self, $len) = @_;
 366         my $msg = $! || '(zero write)';
 367         $msg .= " ($len bytes remaining)" if defined $len;
 368         err($self, "error buffering to input: $msg");
 369         quit($self, 500);
 370 }
 371
 372 sub recv_err {
 373         my ($self, $len) = @_;
 374         if ($! == EAGAIN) { # epoll/kevent watch already set by do_read
 375                 $self->{input_left} = $len;
 376         } else {
 377                 err($self, "error reading input: $! ($len bytes remaining)");
 378         }
 379 }
 380
 381 sub read_input_chunked { # unlikely...
 382         my ($self, $rbuf) = @_;
 383         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 384         my $input = $self->{env}->{'psgi.input'};
 385         my $len = delete $self->{input_left};
 386
 387         while (1) { # chunk start
 388                 if ($len == CHUNK_ZEND) {
 389                         $$rbuf =~ s/\A\r\n//s and
 390                                 return app_dispatch($self, $input, $rbuf);
 391
 392                         return quit($self, 400) if bytes::length($$rbuf) > 2;
 393                 }
 394                 if ($len == CHUNK_END) {
 395                         if ($$rbuf =~ s/\A\r\n//s) {
 396                                 $len = CHUNK_START;
 397                         } elsif (bytes::length($$rbuf) > 2) {
 398                                 return quit($self, 400);
 399                         }
 400                 }
 401                 if ($len == CHUNK_START) {
 402                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 403                                 $len = hex $1;
 404                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 405                                         return quit($self, 413);
 406                                 }
 407                         } elsif (bytes::length($$rbuf) > CHUNK_MAX_HDR) {
 408                                 return quit($self, 400);
 409                         }
 410                         # will break from loop since $len >= 0
 411                 }
 412
 413                 if ($len < 0) { # chunk header is trickled, read more
 414                         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or
 415                                 return recv_err($self, $len);
 416                         # (implicit) goto chunk_start if $r > 0;
 417                 }
 418                 $len = CHUNK_ZEND if $len == 0;
 419
 420                 # drain the current chunk
 421                 until ($len <= 0) {
 422                         if ($$rbuf ne '') {
 423                                 my $w = xwrite($input, $rbuf, $len);
 424                                 return write_err($self, "$len chunk") if !$w;
 425                                 $len -= $w;
 426                                 if ($len == 0) {
 427                                         # we may have leftover data to parse
 428                                         # in chunk
 429                                         $$rbuf = substr($$rbuf, $w);
 430                                         $len = CHUNK_END;
 431                                 } elsif ($len < 0) {
 432                                         die "BUG: len < 0: $len";
 433                                 } else {
 434                                         $$rbuf = '';
 435                                 }
 436                         }
 437                         if ($$rbuf eq '') {
 438                                 # read more of current chunk
 439                                 $self->do_read($rbuf, 8192) or
 440                                         return recv_err($self, $len);
 441                         }
 442                 }
 443         }
 444 }
 445
 446 sub quit {
 447         my ($self, $status) = @_;
 448         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 449         $self->write(\$h);
 450         $self->close;
 451 }
 452
 453 sub close {
 454         my $self = $_[0];
 455         delete $self->{env}; # prevent circular references
 456         if (my $forward = delete $self->{forward}) {
 457                 eval { $forward->close };
 458                 err($self, "forward ->close error: $@") if $@;
 459         }
 460         $self->SUPER::close; # PublicInbox::DS::close
 461 }
 462
 463 # for graceful shutdown in PublicInbox::Daemon:
 464 sub busy () {
 465         my ($self) = @_;
 466         ($self->{rbuf} || $self->{env} || $self->{wbuf});
 467 }
 468
 469 # Chunked and Identity packages are used for writing responses.
 470 # They may be exposed to the PSGI application when the PSGI app
 471 # returns a CODE ref for "push"-based responses
 472 package PublicInbox::HTTP::Chunked;
 473 use strict;
 474
 475 sub write {
 476         # ([$http], $buf) = @_;
 477         PublicInbox::HTTP::chunked_write($_[0]->[0], $_[1])
 478 }
 479
 480 sub close {
 481         # $_[0] = [$http, $alive]
 482         PublicInbox::HTTP::response_done(@{$_[0]});
 483 }
 484
 485 package PublicInbox::HTTP::Identity;
 486 use strict;
 487 our @ISA = qw(PublicInbox::HTTP::Chunked);
 488
 489 sub write {
 490         # ([$http], $buf) = @_;
 491         PublicInbox::HTTP::identity_write($_[0]->[0], $_[1]);
 492 }
 493
 494 1;