lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left);
  15 use Fcntl qw(:seek);
  16 use HTTP::Parser::XS qw(parse_http_request); # supports pure Perl fallback
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 my $null_io = IO::File->new('/dev/null', '<');
  28 my $http_date;
  29 my $prev = 0;
  30 sub http_date () {
  31         my $now = time;
  32         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  33 }
  34
  35 sub new ($$$) {
  36         my ($class, $sock, $addr, $httpd) = @_;
  37         my $self = fields::new($class);
  38         $self->SUPER::new($sock);
  39         $self->{httpd} = $httpd;
  40         $self->{rbuf} = '';
  41         $self->watch_read(1);
  42         $self;
  43 }
  44
  45 sub event_read { # called by Danga::Socket
  46         my ($self) = @_;
  47
  48         return event_read_input($self) if defined $self->{env};
  49
  50         my $off = length($self->{rbuf});
  51         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  52         if (defined $r) {
  53                 return $self->close if $r == 0;
  54                 return rbuf_process($self);
  55         }
  56         return if $!{EAGAIN}; # no need to call watch_read(1) again
  57
  58         # common for clients to break connections without warning,
  59         # would be too noisy to log here:
  60         return $self->close;
  61 }
  62
  63 sub rbuf_process {
  64         my ($self) = @_;
  65
  66         my %env = %{$self->{httpd}->{env}}; # full hash copy
  67         my $r = parse_http_request($self->{rbuf}, \%env);
  68
  69         # We do not support Trailers in chunked requests, for now
  70         # (they are rarely-used and git (as of 2.7.2) does not use them)
  71         return quit($self, 400) if $r == -1 || $env{HTTP_TRAILER};
  72         return $self->watch_read(1) if $r < 0; # incomplete
  73         $self->{rbuf} = substr($self->{rbuf}, $r);
  74
  75         my $len = input_prepare($self, \%env);
  76         defined $len or return write_err($self); # EMFILE/ENFILE
  77
  78         $len ? event_read_input($self) : app_dispatch($self);
  79 }
  80
  81 sub event_read_input ($) {
  82         my ($self) = @_;
  83         my $env = $self->{env};
  84         return event_read_input_chunked($self) if env_chunked($env);
  85
  86         # env->{CONTENT_LENGTH} (identity)
  87         my $sock = $self->{sock};
  88         my $len = $self->{input_left};
  89         $self->{input_left} = undef;
  90         my $rbuf = \($self->{rbuf});
  91         my $input = $env->{'psgi.input'};
  92
  93         while ($len > 0) {
  94                 if ($$rbuf ne '') {
  95                         my $w = write_in_full($input, $rbuf, $len);
  96                         return write_err($self) unless $w;
  97                         $len -= $w;
  98                         die "BUG: $len < 0 (w=$w)" if $len < 0;
  99                         if ($len == 0) { # next request may be pipelined
 100                                 $$rbuf = substr($$rbuf, $w);
 101                                 last;
 102                         }
 103                         $$rbuf = '';
 104                 }
 105                 my $r = sysread($sock, $$rbuf, 8192);
 106                 return recv_err($self, $r, $len) unless $r;
 107                 # continue looping if $r > 0;
 108         }
 109         app_dispatch($self);
 110 }
 111
 112 sub app_dispatch ($) {
 113         my ($self) = @_;
 114         $self->watch_read(0);
 115         my $env = $self->{env};
 116         $env->{REMOTE_ADDR} = $self->peer_ip_string; # Danga::Socket
 117         $env->{REMOTE_PORT} = $self->{peer_port}; # set by peer_ip_string
 118         if (my $host = $env->{HTTP_HOST}) {
 119                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 120                 $env->{SERVER_NAME} = $host;
 121         }
 122
 123         sysseek($env->{'psgi.input'}, 0, SEEK_SET) or
 124                         die "BUG: psgi.input seek failed: $!";
 125
 126         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 127         eval {
 128                 if (ref($res) eq 'CODE') {
 129                         $res->(sub { response_write($self, $env, $_[0]) });
 130                 } else {
 131                         response_write($self, $env, $res);
 132                 }
 133         };
 134         $self->close if $@;
 135 }
 136
 137 sub response_header_write {
 138         my ($self, $env, $res) = @_;
 139         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 140         my $status = $res->[0];
 141         my $h = "$proto $status " . status_message($status) . "\r\n";
 142         my ($len, $chunked);
 143         my $headers = $res->[1];
 144
 145         for (my $i = 0; $i < @$headers; $i += 2) {
 146                 my $k = $headers->[$i];
 147                 my $v = $headers->[$i + 1];
 148                 next if $k =~ /\A(?:Connection|Date)\z/i;
 149
 150                 $len = $v if $k =~ /\AContent-Length\z/i;
 151                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 152                         $chunked = 1;
 153                 }
 154
 155                 $h .= "$k: $v\r\n";
 156         }
 157
 158         my $conn = $env->{HTTP_CONNECTION} || '';
 159         my $alive = (defined($len) || $chunked) &&
 160                         ($proto eq 'HTTP/1.1' && $conn !~ /\bclose\b/i) ||
 161                         ($conn =~ /\bkeep-alive\b/i);
 162
 163         $h .= 'Connection: ' . ($alive ? 'keep-alive' : 'close');
 164         $h .= "\r\nDate: " . http_date() . "\r\n\r\n";
 165
 166         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 167                 more($self, $h);
 168         } else {
 169                 $self->write($h);
 170         }
 171         ($alive, $chunked);
 172 }
 173
 174 sub response_write {
 175         my ($self, $env, $res) = @_;
 176         my ($alive, $chunked) = response_header_write($self, $env, $res);
 177         my $write = sub { $self->write($_[0]) };
 178         my $close = sub {
 179                 if ($alive) {
 180                         $self->event_write; # watch for readability if done
 181                 } else {
 182                         $self->write(sub { $self->close });
 183                 }
 184                 $self->{env} = undef;
 185         };
 186
 187         if (defined $res->[2]) {
 188                 Plack::Util::foreach($res->[2], $write);
 189                 $close->();
 190         } else {
 191                 # this is returned to the calling application:
 192                 Plack::Util::inline_object(write => $write, close => $close);
 193         }
 194 }
 195
 196 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 197 sub more ($$) {
 198         my $self = $_[0];
 199         if (MSG_MORE && !$self->{write_buf_size}) {
 200                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 201                 if (defined $n) {
 202                         my $dlen = length($_[1]);
 203                         return 1 if $n == $dlen; # all done!
 204                         $_[1] = substr($_[1], $n, $dlen - $n);
 205                         # fall through to normal write:
 206                 }
 207         }
 208         $self->write($_[1]);
 209 }
 210
 211 # overrides existing Danga::Socket method
 212 sub event_write {
 213         my ($self) = @_;
 214         # only continue watching for readability when we are done writing:
 215         return if $self->write(undef) != 1;
 216
 217         if ($self->{rbuf} eq '') { # wait for next request
 218                 $self->watch_read(1);
 219         } else { # avoid recursion for pipelined requests
 220                 Danga::Socket->AddTimer(0, sub { rbuf_process($self) });
 221         }
 222 }
 223
 224 sub input_prepare {
 225         my ($self, $env) = @_;
 226         my $input = $null_io;
 227         my $len = $env->{CONTENT_LENGTH};
 228         if ($len) {
 229                 $input = IO::File->new_tmpfile;
 230         } elsif (env_chunked($env)) {
 231                 $len = CHUNK_START;
 232                 $input = IO::File->new_tmpfile;
 233         }
 234
 235         # TODO: expire idle clients on ENFILE / EMFILE
 236         return unless $input;
 237
 238         binmode $input;
 239         $env->{'psgi.input'} = $input;
 240         $self->{env} = $env;
 241         $self->{input_left} = $len || 0;
 242 }
 243
 244 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 245
 246 sub write_err {
 247         my ($self) = @_;
 248         my $err = $self->{env}->{'psgi.errors'};
 249         my $msg = $! || '(zero write)';
 250         $err->print("error buffering to input: $msg\n");
 251         quit($self, 500);
 252 }
 253
 254 sub recv_err {
 255         my ($self, $r, $len) = @_;
 256         return $self->close if (defined $r && $r == 0);
 257         if ($!{EAGAIN}) {
 258                 $self->{input_left} = $len;
 259                 return;
 260         }
 261         my $err = $self->{env}->{'psgi.errors'};
 262         $err->print("error reading for input: $! ($len bytes remaining)\n");
 263         quit($self, 500);
 264 }
 265
 266 sub write_in_full {
 267         my ($fh, $rbuf, $len) = @_;
 268         my $rv = 0;
 269         my $off = 0;
 270         while ($len > 0) {
 271                 my $w = syswrite($fh, $$rbuf, $len, $off);
 272                 return ($rv ? $rv : $w) unless $w; # undef or 0
 273                 $rv += $w;
 274                 $off += $w;
 275                 $len -= $w;
 276         }
 277         $rv
 278 }
 279
 280 sub event_read_input_chunked { # unlikely...
 281         my ($self) = @_;
 282         my $input = $self->{env}->{'psgi.input'};
 283         my $sock = $self->{sock};
 284         my $len = $self->{input_left};
 285         $self->{input_left} = undef;
 286         my $rbuf = \($self->{rbuf});
 287
 288         while (1) { # chunk start
 289                 if ($len == CHUNK_ZEND) {
 290                         return app_dispatch($self) if $$rbuf =~ s/\A\r\n//s;
 291                         return quit($self, 400) if length($$rbuf) > 2;
 292                 }
 293                 if ($len == CHUNK_END) {
 294                         if ($$rbuf =~ s/\A\r\n//s) {
 295                                 $len = CHUNK_START;
 296                         } elsif (length($$rbuf) > 2) {
 297                                 return quit($self, 400);
 298                         }
 299                 }
 300                 if ($len == CHUNK_START) {
 301                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 302                                 $len = hex $1;
 303                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 304                                 return quit($self, 400);
 305                         }
 306                         # will break from loop since $len >= 0
 307                 }
 308
 309                 if ($len < 0) { # chunk header is trickled, read more
 310                         my $off = length($$rbuf);
 311                         my $r = sysread($sock, $$rbuf, 8192, $off);
 312                         return recv_err($self, $r, $len) unless $r;
 313                         # (implicit) goto chunk_start if $r > 0;
 314                 }
 315                 $len = CHUNK_ZEND if $len == 0;
 316
 317                 # drain the current chunk
 318                 until ($len <= 0) {
 319                         if ($$rbuf ne '') {
 320                                 my $w = write_in_full($input, $rbuf, $len);
 321                                 return write_err($self) unless $w;
 322                                 $len -= $w;
 323                                 if ($len == 0) {
 324                                         # we may have leftover data to parse
 325                                         # in chunk
 326                                         $$rbuf = substr($$rbuf, $w);
 327                                         $len = CHUNK_END;
 328                                 } elsif ($len < 0) {
 329                                         die "BUG: len < 0: $len";
 330                                 } else {
 331                                         $$rbuf = '';
 332                                 }
 333                         }
 334                         if ($$rbuf eq '') {
 335                                 # read more of current chunk
 336                                 my $r = sysread($sock, $$rbuf, 8192);
 337                                 return recv_err($self, $r, $len) unless $r;
 338                         }
 339                 }
 340         }
 341 }
 342
 343 sub quit {
 344         my ($self, $status) = @_;
 345         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 346         $self->write($h);
 347         $self->close;
 348 }
 349
 350 # callbacks for Danga::Socket
 351
 352 sub event_hup { $_[0]->close }
 353 sub event_err { $_[0]->close }
 354
 355 # for graceful shutdown in PublicInbox::Daemon:
 356 sub busy () {
 357         my ($self) = @_;
 358         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 359 }
 360
 361 1;