lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::Handle;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 my $pipelineq = [];
  28 my $pipet;
  29 sub process_pipelineq () {
  30         my $q = $pipelineq;
  31         $pipet = undef;
  32         $pipelineq = [];
  33         foreach (@$q) {
  34                 next if $_->{closed};
  35                 rbuf_process($_);
  36         }
  37 }
  38
  39 # Use the same configuration parameter as git since this is primarily
  40 # a slow-client sponge for git-http-backend
  41 # TODO: support per-respository http.maxRequestBuffer somehow...
  42 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  43                         (10 * 1024 * 1024);
  44
  45 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  46 my $http_date;
  47 my $prev = 0;
  48 sub http_date () {
  49         my $now = time;
  50         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  51 }
  52
  53 sub new ($$$) {
  54         my ($class, $sock, $addr, $httpd) = @_;
  55         my $self = fields::new($class);
  56         $self->SUPER::new($sock);
  57         $self->{httpd} = $httpd;
  58         $self->{rbuf} = '';
  59         ($self->{remote_addr}, $self->{remote_port}) =
  60                 PublicInbox::Daemon::host_with_port($addr);
  61         $self->watch_read(1);
  62         $self;
  63 }
  64
  65 sub event_read { # called by Danga::Socket
  66         my ($self) = @_;
  67
  68         return event_read_input($self) if defined $self->{env};
  69
  70         my $off = length($self->{rbuf});
  71         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  72         if (defined $r) {
  73                 return $self->close if $r == 0;
  74                 return rbuf_process($self);
  75         }
  76         return if $!{EAGAIN}; # no need to call watch_read(1) again
  77
  78         # common for clients to break connections without warning,
  79         # would be too noisy to log here:
  80         return $self->close;
  81 }
  82
  83 sub rbuf_process {
  84         my ($self) = @_;
  85
  86         my %env = %{$self->{httpd}->{env}}; # full hash copy
  87         my $r = parse_http_request($self->{rbuf}, \%env);
  88
  89         # We do not support Trailers in chunked requests, for now
  90         # (they are rarely-used and git (as of 2.7.2) does not use them)
  91         if ($r == -1 || $env{HTTP_TRAILER} ||
  92                         # this length-check is necessary for PURE_PERL=1:
  93                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  94                 return quit($self, 400);
  95         }
  96         return $self->watch_read(1) if $r < 0; # incomplete
  97         $self->{rbuf} = substr($self->{rbuf}, $r);
  98
  99         my $len = input_prepare($self, \%env);
 100         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 101
 102         $len ? event_read_input($self) : app_dispatch($self);
 103 }
 104
 105 sub event_read_input ($) {
 106         my ($self) = @_;
 107         my $env = $self->{env};
 108         return event_read_input_chunked($self) if env_chunked($env);
 109
 110         # env->{CONTENT_LENGTH} (identity)
 111         my $sock = $self->{sock};
 112         my $len = $self->{input_left};
 113         $self->{input_left} = undef;
 114         my $rbuf = \($self->{rbuf});
 115         my $input = $env->{'psgi.input'};
 116
 117         while ($len > 0) {
 118                 if ($$rbuf ne '') {
 119                         my $w = write_in_full($input, $rbuf, $len);
 120                         return write_err($self, $len) unless $w;
 121                         $len -= $w;
 122                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 123                         if ($len == 0) { # next request may be pipelined
 124                                 $$rbuf = substr($$rbuf, $w);
 125                                 last;
 126                         }
 127                         $$rbuf = '';
 128                 }
 129                 my $r = sysread($sock, $$rbuf, 8192);
 130                 return recv_err($self, $r, $len) unless $r;
 131                 # continue looping if $r > 0;
 132         }
 133         app_dispatch($self, $input);
 134 }
 135
 136 sub app_dispatch {
 137         my ($self, $input) = @_;
 138         $self->watch_read(0);
 139         my $env = $self->{env};
 140         $env->{REMOTE_ADDR} = $self->{remote_addr};
 141         $env->{REMOTE_PORT} = $self->{remote_port};
 142         if (my $host = $env->{HTTP_HOST}) {
 143                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 144                 $env->{SERVER_NAME} = $host;
 145         }
 146         if (defined $input) {
 147                 sysseek($input, 0, SEEK_SET) or
 148                         die "BUG: psgi.input seek failed: $!";
 149         }
 150         # note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
 151         # to do proper cleanup:
 152         $env->{'psgix.io'} = $self; # only for ->close
 153         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 154         eval {
 155                 if (ref($res) eq 'CODE') {
 156                         $res->(sub { response_write($self, $env, $_[0]) });
 157                 } else {
 158                         response_write($self, $env, $res);
 159                 }
 160         };
 161         $self->close if $@;
 162 }
 163
 164 sub response_header_write {
 165         my ($self, $env, $res) = @_;
 166         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 167         my $status = $res->[0];
 168         my $h = "$proto $status " . status_message($status) . "\r\n";
 169         my ($len, $chunked);
 170         my $headers = $res->[1];
 171
 172         for (my $i = 0; $i < @$headers; $i += 2) {
 173                 my $k = $headers->[$i];
 174                 my $v = $headers->[$i + 1];
 175                 next if $k =~ /\A(?:Connection|Date)\z/i;
 176
 177                 $len = $v if $k =~ /\AContent-Length\z/i;
 178                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 179                         $chunked = 1;
 180                 }
 181                 $h .= "$k: $v\r\n";
 182         }
 183
 184         my $conn = $env->{HTTP_CONNECTION} || '';
 185         my $term = defined($len) || $chunked;
 186         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 187         my $alive;
 188         if (!$term && $prot_persist) { # auto-chunk
 189                 $chunked = $alive = 2;
 190                 $h .= "Transfer-Encoding: chunked\r\n";
 191                 # no need for "Connection: keep-alive" with HTTP/1.1
 192         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 193                 $alive = 1;
 194                 $h .= "Connection: keep-alive\r\n";
 195         } else {
 196                 $alive = 0;
 197                 $h .= "Connection: close\r\n";
 198         }
 199         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 200
 201         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 202                 more($self, $h);
 203         } else {
 204                 $self->write($h);
 205         }
 206         $alive;
 207 }
 208
 209 # middlewares such as Deflater may write empty strings
 210 sub chunked_wcb ($) {
 211         my ($self) = @_;
 212         sub {
 213                 return if $_[0] eq '';
 214                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 215                 more($self, $_[0]);
 216
 217                 # use $self->write("\n\n") if you care about real-time
 218                 # streaming responses, public-inbox WWW does not.
 219                 more($self, "\r\n");
 220         }
 221 }
 222
 223 sub identity_wcb ($) {
 224         my ($self) = @_;
 225         sub { $self->write(\($_[0])) if $_[0] ne '' }
 226 }
 227
 228 sub next_request ($) {
 229         my ($self) = @_;
 230         $self->watch_write(0);
 231         if ($self->{rbuf} eq '') { # wait for next request
 232                 $self->watch_read(1);
 233         } else { # avoid recursion for pipelined requests
 234                 push @$pipelineq, $self;
 235                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 236         }
 237 }
 238
 239 sub response_done_cb ($$) {
 240         my ($self, $alive) = @_;
 241         sub {
 242                 my $env = $self->{env};
 243                 $self->{env} = undef;
 244                 $self->write("0\r\n\r\n") if $alive == 2;
 245                 $self->write(sub{$alive ? next_request($self) : $self->close});
 246         }
 247 }
 248
 249 sub getline_cb ($$$) {
 250         my ($self, $write, $close) = @_;
 251         local $/ = \8192;
 252         my $forward = $self->{forward};
 253         # limit our own running time for fairness with other
 254         # clients and to avoid buffering too much:
 255         if ($forward) {
 256                 my $buf = eval { $forward->getline };
 257                 if (defined $buf) {
 258                         $write->($buf); # may close in Danga::Socket::write
 259                         unless ($self->{closed}) {
 260                                 my $next = $self->{pull};
 261                                 if ($self->{write_buf_size}) {
 262                                         $self->write($next);
 263                                 } else {
 264                                         PublicInbox::EvCleanup::asap($next);
 265                                 }
 266                                 return;
 267                         }
 268                 } elsif ($@) {
 269                         err($self, "response ->getline error: $@");
 270                         $forward = undef;
 271                         $self->close;
 272                 }
 273         }
 274
 275         $self->{forward} = $self->{pull} = undef;
 276         # avoid recursion
 277         if ($forward) {
 278                 eval { $forward->close };
 279                 if ($@) {
 280                         err($self, "response ->close error: $@");
 281                         $self->close; # idempotent
 282                 }
 283         }
 284         $close->();
 285 }
 286
 287 sub getline_response ($$$) {
 288         my ($self, $write, $close) = @_;
 289         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 290         $pull->();
 291 }
 292
 293 sub response_write {
 294         my ($self, $env, $res) = @_;
 295         my $alive = response_header_write($self, $env, $res);
 296         my $close = response_done_cb($self, $alive);
 297         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 298         if (defined(my $body = $res->[2])) {
 299                 if (ref $body eq 'ARRAY') {
 300                         $write->($_) foreach @$body;
 301                         $close->();
 302                 } else {
 303                         $self->{forward} = $body;
 304                         getline_response($self, $write, $close);
 305                 }
 306         } else {
 307                 # this is returned to the calling application:
 308                 Plack::Util::inline_object(write => $write, close => $close);
 309         }
 310 }
 311
 312 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 313 sub more ($$) {
 314         my $self = $_[0];
 315         return if $self->{closed};
 316         if (MSG_MORE && !$self->{write_buf_size}) {
 317                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 318                 if (defined $n) {
 319                         my $dlen = length($_[1]);
 320                         return 1 if $n == $dlen; # all done!
 321                         $_[1] = substr($_[1], $n, $dlen - $n);
 322                         # fall through to normal write:
 323                 }
 324         }
 325         $self->write($_[1]);
 326 }
 327
 328 sub input_prepare {
 329         my ($self, $env) = @_;
 330         my $input;
 331         my $len = $env->{CONTENT_LENGTH};
 332         if ($len) {
 333                 if ($len > $MAX_REQUEST_BUFFER) {
 334                         quit($self, 413);
 335                         return;
 336                 }
 337                 open($input, '+>', undef);
 338         } elsif (env_chunked($env)) {
 339                 $len = CHUNK_START;
 340                 open($input, '+>', undef);
 341         } else {
 342                 $input = $null_io;
 343         }
 344
 345         # TODO: expire idle clients on ENFILE / EMFILE
 346         return unless $input;
 347
 348         $env->{'psgi.input'} = $input;
 349         $self->{env} = $env;
 350         $self->{input_left} = $len || 0;
 351 }
 352
 353 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 354
 355 sub err ($$) {
 356         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 357 }
 358
 359 sub write_err {
 360         my ($self, $len) = @_;
 361         my $msg = $! || '(zero write)';
 362         $msg .= " ($len bytes remaining)" if defined $len;
 363         err($self, "error buffering to input: $msg");
 364         quit($self, 500);
 365 }
 366
 367 sub recv_err {
 368         my ($self, $r, $len) = @_;
 369         return $self->close if (defined $r && $r == 0);
 370         if ($!{EAGAIN}) {
 371                 $self->{input_left} = $len;
 372                 return;
 373         }
 374         err($self, "error reading for input: $! ($len bytes remaining)");
 375         quit($self, 500);
 376 }
 377
 378 sub write_in_full {
 379         my ($fh, $rbuf, $len) = @_;
 380         my $rv = 0;
 381         my $off = 0;
 382         while ($len > 0) {
 383                 my $w = syswrite($fh, $$rbuf, $len, $off);
 384                 return ($rv ? $rv : $w) unless $w; # undef or 0
 385                 $rv += $w;
 386                 $off += $w;
 387                 $len -= $w;
 388         }
 389         $rv
 390 }
 391
 392 sub event_read_input_chunked { # unlikely...
 393         my ($self) = @_;
 394         my $input = $self->{env}->{'psgi.input'};
 395         my $sock = $self->{sock};
 396         my $len = $self->{input_left};
 397         $self->{input_left} = undef;
 398         my $rbuf = \($self->{rbuf});
 399
 400         while (1) { # chunk start
 401                 if ($len == CHUNK_ZEND) {
 402                         $$rbuf =~ s/\A\r\n//s and
 403                                 return app_dispatch($self, $input);
 404                         return quit($self, 400) if length($$rbuf) > 2;
 405                 }
 406                 if ($len == CHUNK_END) {
 407                         if ($$rbuf =~ s/\A\r\n//s) {
 408                                 $len = CHUNK_START;
 409                         } elsif (length($$rbuf) > 2) {
 410                                 return quit($self, 400);
 411                         }
 412                 }
 413                 if ($len == CHUNK_START) {
 414                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 415                                 $len = hex $1;
 416                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 417                                         return quit($self, 413);
 418                                 }
 419                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 420                                 return quit($self, 400);
 421                         }
 422                         # will break from loop since $len >= 0
 423                 }
 424
 425                 if ($len < 0) { # chunk header is trickled, read more
 426                         my $off = length($$rbuf);
 427                         my $r = sysread($sock, $$rbuf, 8192, $off);
 428                         return recv_err($self, $r, $len) unless $r;
 429                         # (implicit) goto chunk_start if $r > 0;
 430                 }
 431                 $len = CHUNK_ZEND if $len == 0;
 432
 433                 # drain the current chunk
 434                 until ($len <= 0) {
 435                         if ($$rbuf ne '') {
 436                                 my $w = write_in_full($input, $rbuf, $len);
 437                                 return write_err($self, "$len chunk") if !$w;
 438                                 $len -= $w;
 439                                 if ($len == 0) {
 440                                         # we may have leftover data to parse
 441                                         # in chunk
 442                                         $$rbuf = substr($$rbuf, $w);
 443                                         $len = CHUNK_END;
 444                                 } elsif ($len < 0) {
 445                                         die "BUG: len < 0: $len";
 446                                 } else {
 447                                         $$rbuf = '';
 448                                 }
 449                         }
 450                         if ($$rbuf eq '') {
 451                                 # read more of current chunk
 452                                 my $r = sysread($sock, $$rbuf, 8192);
 453                                 return recv_err($self, $r, $len) unless $r;
 454                         }
 455                 }
 456         }
 457 }
 458
 459 sub quit {
 460         my ($self, $status) = @_;
 461         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 462         $self->write($h);
 463         $self->close;
 464 }
 465
 466 # callbacks for Danga::Socket
 467
 468 sub event_hup { $_[0]->close }
 469 sub event_err { $_[0]->close }
 470
 471 sub close {
 472         my $self = shift;
 473         my $forward = $self->{forward};
 474         my $env = $self->{env};
 475         delete $env->{'psgix.io'} if $env; # prevent circular references
 476         $self->{pull} = $self->{forward} = $self->{env} = undef;
 477         if ($forward) {
 478                 eval { $forward->close };
 479                 err($self, "forward ->close error: $@") if $@;
 480         }
 481         $self->SUPER::close(@_);
 482 }
 483
 484 # for graceful shutdown in PublicInbox::Daemon:
 485 sub busy () {
 486         my ($self) = @_;
 487         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 488 }
 489
 490 1;