lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 # FIXME: duplicated code with NNTP.pm
  28 my $WEAKEN = {}; # string(inbox) -> inbox
  29 my $WEAKTIMER;
  30 sub weaken_task () {
  31         $WEAKTIMER = undef;
  32         $_->weaken_all for values %$WEAKEN;
  33         $WEAKEN = {};
  34 }
  35
  36 # Use the same configuration parameter as git since this is primarily
  37 # a slow-client sponge for git-http-backend
  38 # TODO: support per-respository http.maxRequestBuffer somehow...
  39 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  40                         (10 * 1024 * 1024);
  41
  42 my $null_io = IO::File->new('/dev/null', '<');
  43 my $http_date;
  44 my $prev = 0;
  45 sub http_date () {
  46         my $now = time;
  47         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  48 }
  49
  50 sub new ($$$) {
  51         my ($class, $sock, $addr, $httpd) = @_;
  52         my $self = fields::new($class);
  53         $self->SUPER::new($sock);
  54         $self->{httpd} = $httpd;
  55         $self->{rbuf} = '';
  56         ($self->{remote_addr}, $self->{remote_port}) =
  57                 PublicInbox::Daemon::host_with_port($addr);
  58         $self->watch_read(1);
  59         $self;
  60 }
  61
  62 sub event_read { # called by Danga::Socket
  63         my ($self) = @_;
  64
  65         return event_read_input($self) if defined $self->{env};
  66
  67         my $off = length($self->{rbuf});
  68         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  69         if (defined $r) {
  70                 return $self->close if $r == 0;
  71                 return rbuf_process($self);
  72         }
  73         return if $!{EAGAIN}; # no need to call watch_read(1) again
  74
  75         # common for clients to break connections without warning,
  76         # would be too noisy to log here:
  77         return $self->close;
  78 }
  79
  80 sub rbuf_process {
  81         my ($self) = @_;
  82
  83         my %env = %{$self->{httpd}->{env}}; # full hash copy
  84         my $r = parse_http_request($self->{rbuf}, \%env);
  85
  86         # We do not support Trailers in chunked requests, for now
  87         # (they are rarely-used and git (as of 2.7.2) does not use them)
  88         if ($r == -1 || $env{HTTP_TRAILER} ||
  89                         # this length-check is necessary for PURE_PERL=1:
  90                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  91                 return quit($self, 400);
  92         }
  93         return $self->watch_read(1) if $r < 0; # incomplete
  94         $self->{rbuf} = substr($self->{rbuf}, $r);
  95
  96         my $len = input_prepare($self, \%env);
  97         defined $len or return write_err($self); # EMFILE/ENFILE
  98
  99         $len ? event_read_input($self) : app_dispatch($self);
 100 }
 101
 102 sub event_read_input ($) {
 103         my ($self) = @_;
 104         my $env = $self->{env};
 105         return event_read_input_chunked($self) if env_chunked($env);
 106
 107         # env->{CONTENT_LENGTH} (identity)
 108         my $sock = $self->{sock};
 109         my $len = $self->{input_left};
 110         $self->{input_left} = undef;
 111         my $rbuf = \($self->{rbuf});
 112         my $input = $env->{'psgi.input'};
 113
 114         while ($len > 0) {
 115                 if ($$rbuf ne '') {
 116                         my $w = write_in_full($input, $rbuf, $len);
 117                         return write_err($self) unless $w;
 118                         $len -= $w;
 119                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 120                         if ($len == 0) { # next request may be pipelined
 121                                 $$rbuf = substr($$rbuf, $w);
 122                                 last;
 123                         }
 124                         $$rbuf = '';
 125                 }
 126                 my $r = sysread($sock, $$rbuf, 8192);
 127                 return recv_err($self, $r, $len) unless $r;
 128                 # continue looping if $r > 0;
 129         }
 130         app_dispatch($self, $input);
 131 }
 132
 133 sub app_dispatch {
 134         my ($self, $input) = @_;
 135         $self->watch_read(0);
 136         my $env = $self->{env};
 137         $env->{REMOTE_ADDR} = $self->{remote_addr};
 138         $env->{REMOTE_PORT} = $self->{remote_port};
 139         if (my $host = $env->{HTTP_HOST}) {
 140                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 141                 $env->{SERVER_NAME} = $host;
 142         }
 143         if (defined $input) {
 144                 sysseek($input, 0, SEEK_SET) or
 145                         die "BUG: psgi.input seek failed: $!";
 146         }
 147         # note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
 148         # to do proper cleanup:
 149         $env->{'psgix.io'} = $self; # only for ->close
 150         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 151         eval {
 152                 if (ref($res) eq 'CODE') {
 153                         $res->(sub { response_write($self, $env, $_[0]) });
 154                 } else {
 155                         response_write($self, $env, $res);
 156                 }
 157         };
 158         $self->close if $@;
 159 }
 160
 161 sub response_header_write {
 162         my ($self, $env, $res) = @_;
 163         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 164         my $status = $res->[0];
 165         my $h = "$proto $status " . status_message($status) . "\r\n";
 166         my ($len, $chunked);
 167         my $headers = $res->[1];
 168
 169         for (my $i = 0; $i < @$headers; $i += 2) {
 170                 my $k = $headers->[$i];
 171                 my $v = $headers->[$i + 1];
 172                 next if $k =~ /\A(?:Connection|Date)\z/i;
 173
 174                 $len = $v if $k =~ /\AContent-Length\z/i;
 175                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 176                         $chunked = 1;
 177                 }
 178                 $h .= "$k: $v\r\n";
 179         }
 180
 181         my $conn = $env->{HTTP_CONNECTION} || '';
 182         my $term = defined($len) || $chunked;
 183         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 184         my $alive;
 185         if (!$term && $prot_persist) { # auto-chunk
 186                 $chunked = $alive = 2;
 187                 $h .= "Transfer-Encoding: chunked\r\n";
 188                 # no need for "Connection: keep-alive" with HTTP/1.1
 189         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 190                 $alive = 1;
 191                 $h .= "Connection: keep-alive\r\n";
 192         } else {
 193                 $h .= "Connection: close\r\n";
 194         }
 195         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 196
 197         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 198                 more($self, $h);
 199         } else {
 200                 $self->write($h);
 201         }
 202         $alive;
 203 }
 204
 205 # middlewares such as Deflater may write empty strings
 206 sub chunked_wcb ($) {
 207         my ($self) = @_;
 208         sub {
 209                 return if $_[0] eq '';
 210                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 211                 more($self, $_[0]);
 212                 $self->write("\r\n");
 213         }
 214 }
 215
 216 sub identity_wcb ($) {
 217         my ($self) = @_;
 218         sub { $self->write(\($_[0])) if $_[0] ne '' }
 219 }
 220
 221 sub response_write {
 222         my ($self, $env, $res) = @_;
 223         my $alive = response_header_write($self, $env, $res);
 224
 225         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 226         my $close = sub {
 227                 $self->write("0\r\n\r\n") if $alive == 2;
 228                 if ($alive) {
 229                         $self->event_write; # watch for readability if done
 230                 } else {
 231                         Danga::Socket::write($self, sub { $self->close });
 232                 }
 233                 if (my $obj = $env->{'pi-httpd.inbox'}) {
 234                         # grace period for reaping resources
 235                         $WEAKEN->{"$obj"} = $obj;
 236                         $WEAKTIMER ||= Danga::Socket->AddTimer(60, *weaken_task);
 237                 }
 238                 $self->{env} = undef;
 239         };
 240
 241         if (defined(my $body = $res->[2])) {
 242                 if (ref $body eq 'ARRAY') {
 243                         $write->($_) foreach @$body;
 244                         $close->();
 245                 } else {
 246                         my $pull;
 247                         $pull = sub {
 248                                 local $/ = \8192;
 249                                 while (defined(my $buf = $body->getline)) {
 250                                         $write->($buf);
 251                                         if ($self->{write_buf_size}) {
 252                                                 $self->write($pull);
 253                                                 return;
 254                                         }
 255                                 }
 256                                 $pull = undef;
 257                                 $body->close();
 258                                 $close->();
 259                         };
 260                         $pull->();
 261                 }
 262         } else {
 263                 # this is returned to the calling application:
 264                 Plack::Util::inline_object(write => $write, close => $close);
 265         }
 266 }
 267
 268 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 269 sub more ($$) {
 270         my $self = $_[0];
 271         if (MSG_MORE && !$self->{write_buf_size}) {
 272                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 273                 if (defined $n) {
 274                         my $dlen = length($_[1]);
 275                         return 1 if $n == $dlen; # all done!
 276                         $_[1] = substr($_[1], $n, $dlen - $n);
 277                         # fall through to normal write:
 278                 }
 279         }
 280         $self->write($_[1]);
 281 }
 282
 283 my $pipelineq = [];
 284 my $next_tick;
 285 sub process_pipelineq () {
 286         $next_tick = undef;
 287         my $q = $pipelineq;
 288         $pipelineq = [];
 289         rbuf_process($_) foreach @$q;
 290 }
 291
 292 # overrides existing Danga::Socket method
 293 sub event_write {
 294         my ($self) = @_;
 295         # only continue watching for readability when we are done writing:
 296         return if $self->write(undef) != 1;
 297
 298         if ($self->{rbuf} eq '') { # wait for next request
 299                 $self->watch_read(1);
 300         } else { # avoid recursion for pipelined requests
 301                 push @$pipelineq, $self;
 302                 $next_tick ||= Danga::Socket->AddTimer(0, *process_pipelineq);
 303         }
 304 }
 305
 306 sub input_prepare {
 307         my ($self, $env) = @_;
 308         my $input = $null_io;
 309         my $len = $env->{CONTENT_LENGTH};
 310         if ($len) {
 311                 if ($len > $MAX_REQUEST_BUFFER) {
 312                         quit($self, 413);
 313                         return;
 314                 }
 315                 $input = IO::File->new_tmpfile;
 316         } elsif (env_chunked($env)) {
 317                 $len = CHUNK_START;
 318                 $input = IO::File->new_tmpfile;
 319         }
 320
 321         # TODO: expire idle clients on ENFILE / EMFILE
 322         return unless $input;
 323
 324         $env->{'psgi.input'} = $input;
 325         $self->{env} = $env;
 326         $self->{input_left} = $len || 0;
 327 }
 328
 329 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 330
 331 sub write_err {
 332         my ($self) = @_;
 333         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 334         my $msg = $! || '(zero write)';
 335         $err->print("error buffering to input: $msg\n");
 336         quit($self, 500);
 337 }
 338
 339 sub recv_err {
 340         my ($self, $r, $len) = @_;
 341         return $self->close if (defined $r && $r == 0);
 342         if ($!{EAGAIN}) {
 343                 $self->{input_left} = $len;
 344                 return;
 345         }
 346         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 347         $err->print("error reading for input: $! ($len bytes remaining)\n");
 348         quit($self, 500);
 349 }
 350
 351 sub write_in_full {
 352         my ($fh, $rbuf, $len) = @_;
 353         my $rv = 0;
 354         my $off = 0;
 355         while ($len > 0) {
 356                 my $w = syswrite($fh, $$rbuf, $len, $off);
 357                 return ($rv ? $rv : $w) unless $w; # undef or 0
 358                 $rv += $w;
 359                 $off += $w;
 360                 $len -= $w;
 361         }
 362         $rv
 363 }
 364
 365 sub event_read_input_chunked { # unlikely...
 366         my ($self) = @_;
 367         my $input = $self->{env}->{'psgi.input'};
 368         my $sock = $self->{sock};
 369         my $len = $self->{input_left};
 370         $self->{input_left} = undef;
 371         my $rbuf = \($self->{rbuf});
 372
 373         while (1) { # chunk start
 374                 if ($len == CHUNK_ZEND) {
 375                         $$rbuf =~ s/\A\r\n//s and
 376                                 return app_dispatch($self, $input);
 377                         return quit($self, 400) if length($$rbuf) > 2;
 378                 }
 379                 if ($len == CHUNK_END) {
 380                         if ($$rbuf =~ s/\A\r\n//s) {
 381                                 $len = CHUNK_START;
 382                         } elsif (length($$rbuf) > 2) {
 383                                 return quit($self, 400);
 384                         }
 385                 }
 386                 if ($len == CHUNK_START) {
 387                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 388                                 $len = hex $1;
 389                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 390                                         return quit($self, 413);
 391                                 }
 392                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 393                                 return quit($self, 400);
 394                         }
 395                         # will break from loop since $len >= 0
 396                 }
 397
 398                 if ($len < 0) { # chunk header is trickled, read more
 399                         my $off = length($$rbuf);
 400                         my $r = sysread($sock, $$rbuf, 8192, $off);
 401                         return recv_err($self, $r, $len) unless $r;
 402                         # (implicit) goto chunk_start if $r > 0;
 403                 }
 404                 $len = CHUNK_ZEND if $len == 0;
 405
 406                 # drain the current chunk
 407                 until ($len <= 0) {
 408                         if ($$rbuf ne '') {
 409                                 my $w = write_in_full($input, $rbuf, $len);
 410                                 return write_err($self) unless $w;
 411                                 $len -= $w;
 412                                 if ($len == 0) {
 413                                         # we may have leftover data to parse
 414                                         # in chunk
 415                                         $$rbuf = substr($$rbuf, $w);
 416                                         $len = CHUNK_END;
 417                                 } elsif ($len < 0) {
 418                                         die "BUG: len < 0: $len";
 419                                 } else {
 420                                         $$rbuf = '';
 421                                 }
 422                         }
 423                         if ($$rbuf eq '') {
 424                                 # read more of current chunk
 425                                 my $r = sysread($sock, $$rbuf, 8192);
 426                                 return recv_err($self, $r, $len) unless $r;
 427                         }
 428                 }
 429         }
 430 }
 431
 432 sub quit {
 433         my ($self, $status) = @_;
 434         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 435         $self->write($h);
 436         $self->close;
 437 }
 438
 439 # callbacks for Danga::Socket
 440
 441 sub event_hup { $_[0]->close }
 442 sub event_err { $_[0]->close }
 443
 444 sub close {
 445         my $self = shift;
 446         my $forward = $self->{forward};
 447         $forward->close if $forward;
 448         $self->{forward} = $self->{env} = undef;
 449         $self->SUPER::close(@_);
 450 }
 451
 452 # for graceful shutdown in PublicInbox::Daemon:
 453 sub busy () {
 454         my ($self) = @_;
 455         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 456 }
 457
 458 1;