]> Sergey Matveev's repositories - public-inbox.git/blob - lib/PublicInbox/HTTP.pm
http: get rid of anonymous subs for write/close
[public-inbox.git] / lib / PublicInbox / HTTP.pm
1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
3 #
4 # Generic PSGI server for convenience.  It aims to provide
5 # a consistent experience for public-inbox admins so they don't have
6 # to learn different ways to admin both NNTP and HTTP components.
7 # There's nothing which depends on public-inbox, here.
8 # Each instance of this class represents a HTTP client socket
9
10 package PublicInbox::HTTP;
11 use strict;
12 use warnings;
13 use base qw(PublicInbox::DS);
14 use fields qw(httpd env input_left remote_addr remote_port forward);
15 use bytes (); # only for bytes::length
16 use Fcntl qw(:seek);
17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
18 use HTTP::Status qw(status_message);
19 use HTTP::Date qw(time2str);
20 use IO::Handle;
21 use PublicInbox::DS qw(msg_more);
22 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
23 use PublicInbox::Tmpfile;
24 use constant {
25         CHUNK_START => -1,   # [a-f0-9]+\r\n
26         CHUNK_END => -2,     # \r\n
27         CHUNK_ZEND => -3,    # \r\n
28         CHUNK_MAX_HDR => 256,
29 };
30 use Errno qw(EAGAIN);
31
32 my $pipelineq = [];
33 sub process_pipelineq () {
34         my $q = $pipelineq;
35         $pipelineq = [];
36         foreach (@$q) {
37                 next unless $_->{sock};
38                 rbuf_process($_);
39         }
40 }
41
42 # Use the same configuration parameter as git since this is primarily
43 # a slow-client sponge for git-http-backend
44 # TODO: support per-respository http.maxRequestBuffer somehow...
45 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
46                         (10 * 1024 * 1024);
47
48 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
49 my $http_date;
50 my $prev = 0;
51 sub http_date () {
52         my $now = time;
53         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
54 }
55
56 sub new ($$$) {
57         my ($class, $sock, $addr, $httpd) = @_;
58         my $self = fields::new($class);
59         my $ev = EPOLLIN;
60         my $wbuf;
61         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
62                 return CORE::close($sock) if $! != EAGAIN;
63                 $ev = PublicInbox::TLS::epollbit();
64                 $wbuf = [ \&PublicInbox::DS::accept_tls_step ];
65         }
66         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
67         $self->{httpd} = $httpd;
68         $self->{wbuf} = $wbuf if $wbuf;
69         ($self->{remote_addr}, $self->{remote_port}) =
70                 PublicInbox::Daemon::host_with_port($addr);
71         $self;
72 }
73
74 sub event_step { # called by PublicInbox::DS
75         my ($self) = @_;
76
77         return unless $self->flush_write && $self->{sock};
78
79         # only read more requests if we've drained the write buffer,
80         # otherwise we can be buffering infinitely w/o backpressure
81
82         return read_input($self) if defined $self->{env};
83         my $rbuf = $self->{rbuf} // (\(my $x = ''));
84         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or return;
85         rbuf_process($self, $rbuf);
86 }
87
88 sub rbuf_process {
89         my ($self, $rbuf) = @_;
90         $rbuf //= $self->{rbuf} // (\(my $x = ''));
91
92         my %env = %{$self->{httpd}->{env}}; # full hash copy
93         my $r = parse_http_request($$rbuf, \%env);
94
95         # We do not support Trailers in chunked requests, for now
96         # (they are rarely-used and git (as of 2.7.2) does not use them)
97         if ($r == -1 || $env{HTTP_TRAILER} ||
98                         # this length-check is necessary for PURE_PERL=1:
99                         ($r == -2 && bytes::length($$rbuf) > 0x4000)) {
100                 return quit($self, 400);
101         }
102         if ($r < 0) { # incomplete
103                 $self->rbuf_idle($rbuf);
104                 return $self->requeue;
105         }
106         $$rbuf = substr($$rbuf, $r);
107         my $len = input_prepare($self, \%env);
108         defined $len or return write_err($self, undef); # EMFILE/ENFILE
109
110         $len ? read_input($self, $rbuf) : app_dispatch($self, undef, $rbuf);
111 }
112
113 # IO::Handle::write returns boolean, this returns bytes written:
114 sub xwrite ($$$) {
115         my ($fh, $rbuf, $max) = @_;
116         my $w = bytes::length($$rbuf);
117         $w = $max if $w > $max;
118         $fh->write($$rbuf, $w) or return;
119         $w;
120 }
121
122 sub read_input ($;$) {
123         my ($self, $rbuf) = @_;
124         $rbuf //= $self->{rbuf} // (\(my $x = ''));
125         my $env = $self->{env};
126         return if $env->{REMOTE_ADDR}; # in app dispatch
127         return read_input_chunked($self, $rbuf) if env_chunked($env);
128
129         # env->{CONTENT_LENGTH} (identity)
130         my $len = delete $self->{input_left};
131         my $input = $env->{'psgi.input'};
132
133         while ($len > 0) {
134                 if ($$rbuf ne '') {
135                         my $w = xwrite($input, $rbuf, $len);
136                         return write_err($self, $len) unless $w;
137                         $len -= $w;
138                         die "BUG: $len < 0 (w=$w)" if $len < 0;
139                         if ($len == 0) { # next request may be pipelined
140                                 $$rbuf = substr($$rbuf, $w);
141                                 last;
142                         }
143                         $$rbuf = '';
144                 }
145                 $self->do_read($rbuf, 8192) or return recv_err($self, $len);
146                 # continue looping if $r > 0;
147         }
148         app_dispatch($self, $input, $rbuf);
149 }
150
151 sub app_dispatch {
152         my ($self, $input, $rbuf) = @_;
153         $self->rbuf_idle($rbuf);
154         my $env = $self->{env};
155         $env->{REMOTE_ADDR} = $self->{remote_addr};
156         $env->{REMOTE_PORT} = $self->{remote_port};
157         if (my $host = $env->{HTTP_HOST}) {
158                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
159                 $env->{SERVER_NAME} = $host;
160         }
161         if (defined $input) {
162                 sysseek($input, 0, SEEK_SET) or
163                         die "BUG: psgi.input seek failed: $!";
164         }
165         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
166         # to do proper cleanup:
167         $env->{'psgix.io'} = $self; # only for ->close
168         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
169         eval {
170                 if (ref($res) eq 'CODE') {
171                         $res->(sub { response_write($self, $env, $_[0]) });
172                 } else {
173                         response_write($self, $env, $res);
174                 }
175         };
176         $self->close if $@;
177 }
178
179 sub response_header_write {
180         my ($self, $env, $res) = @_;
181         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
182         my $status = $res->[0];
183         my $h = "$proto $status " . status_message($status) . "\r\n";
184         my ($len, $chunked);
185         my $headers = $res->[1];
186
187         for (my $i = 0; $i < @$headers; $i += 2) {
188                 my $k = $headers->[$i];
189                 my $v = $headers->[$i + 1];
190                 next if $k =~ /\A(?:Connection|Date)\z/i;
191
192                 $len = $v if $k =~ /\AContent-Length\z/i;
193                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
194                         $chunked = 1;
195                 }
196                 $h .= "$k: $v\r\n";
197         }
198
199         my $conn = $env->{HTTP_CONNECTION} || '';
200         my $term = defined($len) || $chunked;
201         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
202         my $alive;
203         if (!$term && $prot_persist) { # auto-chunk
204                 $chunked = $alive = 2;
205                 $h .= "Transfer-Encoding: chunked\r\n";
206                 # no need for "Connection: keep-alive" with HTTP/1.1
207         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
208                 $alive = 1;
209                 $h .= "Connection: keep-alive\r\n";
210         } else {
211                 $alive = 0;
212                 $h .= "Connection: close\r\n";
213         }
214         $h .= 'Date: ' . http_date() . "\r\n\r\n";
215
216         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
217                 msg_more($self, $h);
218         } else {
219                 $self->write(\$h);
220         }
221         $alive;
222 }
223
224 # middlewares such as Deflater may write empty strings
225 sub chunked_write ($$) {
226         my $self = $_[0];
227         return if $_[1] eq '';
228         msg_more($self, sprintf("%x\r\n", bytes::length($_[1])));
229         msg_more($self, $_[1]);
230
231         # use $self->write(\"\n\n") if you care about real-time
232         # streaming responses, public-inbox WWW does not.
233         msg_more($self, "\r\n");
234 }
235
236 sub identity_write ($$) {
237         my $self = $_[0];
238         $self->write(\($_[1])) if $_[1] ne '';
239 }
240
241 sub next_request ($) {
242         my ($self) = @_;
243         if ($self->{rbuf}) {
244                 # avoid recursion for pipelined requests
245                 PublicInbox::DS::requeue(\&process_pipelineq) if !@$pipelineq;
246                 push @$pipelineq, $self;
247         } else { # wait for next request
248                 $self->requeue;
249         }
250 }
251
252 sub response_done {
253         my ($self, $alive) = @_;
254         delete $self->{env}; # we're no longer busy
255         $self->write(\"0\r\n\r\n") if $alive == 2;
256         $self->write($alive ? \&next_request : \&close);
257 }
258
259 sub getline_response ($$) {
260         my ($self, $alive) = @_;
261         my $write = $alive == 2 ? \&chunked_write : \&identity_write;
262         my $pull; # DANGER: self-referential
263         $pull = sub {
264                 my $forward = $self->{forward};
265                 # limit our own running time for fairness with other
266                 # clients and to avoid buffering too much:
267                 my $buf = eval {
268                         local $/ = \8192;
269                         $forward->getline;
270                 } if $forward;
271
272                 if (defined $buf) {
273                         # may close in PublicInbox::DS::write
274                         $write->($self, $buf);
275
276                         if ($self->{sock}) {
277                                 my $wbuf = $self->{wbuf} ||= [];
278                                 push @$wbuf, $pull;
279
280                                 # wbuf may be populated by $write->(...$buf),
281                                 # no need to rearm if so:
282                                 $self->requeue if scalar(@$wbuf) == 1;
283                                 return; # likely
284                         }
285                 } elsif ($@) {
286                         err($self, "response ->getline error: $@");
287                         $self->close;
288                 }
289
290                 $pull = undef; # all done!
291                 # avoid recursion
292                 if (delete $self->{forward}) {
293                         eval { $forward->close };
294                         if ($@) {
295                                 err($self, "response ->close error: $@");
296                                 $self->close; # idempotent
297                         }
298                 }
299                 $forward = undef;
300                 response_done($self, $alive);
301         };
302
303         $pull->(); # kick-off!
304 }
305
306 sub response_write {
307         my ($self, $env, $res) = @_;
308         my $alive = response_header_write($self, $env, $res);
309         if (defined(my $body = $res->[2])) {
310                 if (ref $body eq 'ARRAY') {
311                         if ($alive == 2) {
312                                 chunked_write($self, $_) for @$body;
313                         } else {
314                                 identity_write($self, $_) for @$body;
315                         }
316                         response_done($self, $alive);
317                 } else {
318                         $self->{forward} = $body;
319                         getline_response($self, $alive);
320                 }
321         # these are returned to the calling application:
322         } elsif ($alive == 2) {
323                 bless [ $self, $alive ], 'PublicInbox::HTTP::Chunked';
324         } else {
325                 bless [ $self, $alive ], 'PublicInbox::HTTP::Identity';
326         }
327 }
328
329 sub input_tmpfile ($) {
330         my $input = tmpfile('http.input', $_[0]->{sock}) or return;
331         $input->autoflush(1);
332         $input;
333 }
334
335 sub input_prepare {
336         my ($self, $env) = @_;
337         my $input;
338         my $len = $env->{CONTENT_LENGTH};
339         if ($len) {
340                 if ($len > $MAX_REQUEST_BUFFER) {
341                         quit($self, 413);
342                         return;
343                 }
344                 $input = input_tmpfile($self);
345         } elsif (env_chunked($env)) {
346                 $len = CHUNK_START;
347                 $input = input_tmpfile($self);
348         } else {
349                 $input = $null_io;
350         }
351
352         # TODO: expire idle clients on ENFILE / EMFILE
353         return unless $input;
354
355         $env->{'psgi.input'} = $input;
356         $self->{env} = $env;
357         $self->{input_left} = $len || 0;
358 }
359
360 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
361
362 sub err ($$) {
363         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
364 }
365
366 sub write_err {
367         my ($self, $len) = @_;
368         my $msg = $! || '(zero write)';
369         $msg .= " ($len bytes remaining)" if defined $len;
370         err($self, "error buffering to input: $msg");
371         quit($self, 500);
372 }
373
374 sub recv_err {
375         my ($self, $len) = @_;
376         if ($! == EAGAIN) { # epoll/kevent watch already set by do_read
377                 $self->{input_left} = $len;
378         } else {
379                 err($self, "error reading input: $! ($len bytes remaining)");
380         }
381 }
382
383 sub read_input_chunked { # unlikely...
384         my ($self, $rbuf) = @_;
385         $rbuf //= $self->{rbuf} // (\(my $x = ''));
386         my $input = $self->{env}->{'psgi.input'};
387         my $len = delete $self->{input_left};
388
389         while (1) { # chunk start
390                 if ($len == CHUNK_ZEND) {
391                         $$rbuf =~ s/\A\r\n//s and
392                                 return app_dispatch($self, $input, $rbuf);
393
394                         return quit($self, 400) if bytes::length($$rbuf) > 2;
395                 }
396                 if ($len == CHUNK_END) {
397                         if ($$rbuf =~ s/\A\r\n//s) {
398                                 $len = CHUNK_START;
399                         } elsif (bytes::length($$rbuf) > 2) {
400                                 return quit($self, 400);
401                         }
402                 }
403                 if ($len == CHUNK_START) {
404                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
405                                 $len = hex $1;
406                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
407                                         return quit($self, 413);
408                                 }
409                         } elsif (bytes::length($$rbuf) > CHUNK_MAX_HDR) {
410                                 return quit($self, 400);
411                         }
412                         # will break from loop since $len >= 0
413                 }
414
415                 if ($len < 0) { # chunk header is trickled, read more
416                         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or
417                                 return recv_err($self, $len);
418                         # (implicit) goto chunk_start if $r > 0;
419                 }
420                 $len = CHUNK_ZEND if $len == 0;
421
422                 # drain the current chunk
423                 until ($len <= 0) {
424                         if ($$rbuf ne '') {
425                                 my $w = xwrite($input, $rbuf, $len);
426                                 return write_err($self, "$len chunk") if !$w;
427                                 $len -= $w;
428                                 if ($len == 0) {
429                                         # we may have leftover data to parse
430                                         # in chunk
431                                         $$rbuf = substr($$rbuf, $w);
432                                         $len = CHUNK_END;
433                                 } elsif ($len < 0) {
434                                         die "BUG: len < 0: $len";
435                                 } else {
436                                         $$rbuf = '';
437                                 }
438                         }
439                         if ($$rbuf eq '') {
440                                 # read more of current chunk
441                                 $self->do_read($rbuf, 8192) or
442                                         return recv_err($self, $len);
443                         }
444                 }
445         }
446 }
447
448 sub quit {
449         my ($self, $status) = @_;
450         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
451         $self->write(\$h);
452         $self->close;
453 }
454
455 sub close {
456         my $self = $_[0];
457         delete $self->{env}; # prevent circular references
458         if (my $forward = delete $self->{forward}) {
459                 eval { $forward->close };
460                 err($self, "forward ->close error: $@") if $@;
461         }
462         $self->SUPER::close; # PublicInbox::DS::close
463 }
464
465 # for graceful shutdown in PublicInbox::Daemon:
466 sub busy () {
467         my ($self) = @_;
468         ($self->{rbuf} || $self->{env} || $self->{wbuf});
469 }
470
471 # Chunked and Identity packages are used for writing responses.
472 # They may be exposed to the PSGI application when the PSGI app
473 # returns a CODE ref for "push"-based responses
474 package PublicInbox::HTTP::Chunked;
475 use strict;
476
477 sub write {
478         # ([$http], $buf) = @_;
479         PublicInbox::HTTP::chunked_write($_[0]->[0], $_[1])
480 }
481
482 sub close {
483         # $_[0] = [$http, $alive]
484         PublicInbox::HTTP::response_done(@{$_[0]});
485 }
486
487 package PublicInbox::HTTP::Identity;
488 use strict;
489 our @ISA = qw(PublicInbox::HTTP::Chunked);
490
491 sub write {
492         # ([$http], $buf) = @_;
493         PublicInbox::HTTP::identity_write($_[0]->[0], $_[1]);
494 }
495
496 1;