lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 PublicInbox::DS->import(qw(msg_more));
  23 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  24 use constant {
  25         CHUNK_START => -1,   # [a-f0-9]+\r\n
  26         CHUNK_END => -2,     # \r\n
  27         CHUNK_ZEND => -3,    # \r\n
  28         CHUNK_MAX_HDR => 256,
  29 };
  30 use Errno qw(EAGAIN);
  31
  32 my $pipelineq = [];
  33 sub process_pipelineq () {
  34         my $q = $pipelineq;
  35         $pipelineq = [];
  36         foreach (@$q) {
  37                 next unless $_->{sock};
  38                 rbuf_process($_);
  39         }
  40 }
  41
  42 # Use the same configuration parameter as git since this is primarily
  43 # a slow-client sponge for git-http-backend
  44 # TODO: support per-respository http.maxRequestBuffer somehow...
  45 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  46                         (10 * 1024 * 1024);
  47
  48 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  49 my $http_date;
  50 my $prev = 0;
  51 sub http_date () {
  52         my $now = time;
  53         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  54 }
  55
  56 sub new ($$$) {
  57         my ($class, $sock, $addr, $httpd) = @_;
  58         my $self = fields::new($class);
  59         $self->SUPER::new($sock, EPOLLIN | EPOLLONESHOT);
  60         $self->{httpd} = $httpd;
  61         ($self->{remote_addr}, $self->{remote_port}) =
  62                 PublicInbox::Daemon::host_with_port($addr);
  63         $self;
  64 }
  65
  66 sub event_step { # called by PublicInbox::DS
  67         my ($self) = @_;
  68
  69         return unless $self->flush_write && $self->{sock};
  70
  71         # only read more requests if we've drained the write buffer,
  72         # otherwise we can be buffering infinitely w/o backpressure
  73
  74         return read_input($self) if defined $self->{env};
  75         my $rbuf = $self->{rbuf} // (\(my $x = ''));
  76         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or return;
  77         rbuf_process($self, $rbuf);
  78 }
  79
  80 sub rbuf_process {
  81         my ($self, $rbuf) = @_;
  82         $rbuf //= $self->{rbuf} // (\(my $x = ''));
  83
  84         my %env = %{$self->{httpd}->{env}}; # full hash copy
  85         my $r = parse_http_request($$rbuf, \%env);
  86
  87         # We do not support Trailers in chunked requests, for now
  88         # (they are rarely-used and git (as of 2.7.2) does not use them)
  89         if ($r == -1 || $env{HTTP_TRAILER} ||
  90                         # this length-check is necessary for PURE_PERL=1:
  91                         ($r == -2 && bytes::length($$rbuf) > 0x4000)) {
  92                 return quit($self, 400);
  93         }
  94         if ($r < 0) { # incomplete
  95                 $self->rbuf_idle($rbuf);
  96                 return $self->requeue;
  97         }
  98         $$rbuf = substr($$rbuf, $r);
  99         my $len = input_prepare($self, \%env);
 100         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 101
 102         $len ? read_input($self, $rbuf) : app_dispatch($self, undef, $rbuf);
 103 }
 104
 105 # IO::Handle::write returns boolean, this returns bytes written:
 106 sub xwrite ($$$) {
 107         my ($fh, $rbuf, $max) = @_;
 108         my $w = bytes::length($$rbuf);
 109         $w = $max if $w > $max;
 110         $fh->write($$rbuf, $w) or return;
 111         $w;
 112 }
 113
 114 sub read_input ($;$) {
 115         my ($self, $rbuf) = @_;
 116         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 117         my $env = $self->{env};
 118         return if $env->{REMOTE_ADDR}; # in app dispatch
 119         return read_input_chunked($self, $rbuf) if env_chunked($env);
 120
 121         # env->{CONTENT_LENGTH} (identity)
 122         my $len = delete $self->{input_left};
 123         my $input = $env->{'psgi.input'};
 124
 125         while ($len > 0) {
 126                 if ($$rbuf ne '') {
 127                         my $w = xwrite($input, $rbuf, $len);
 128                         return write_err($self, $len) unless $w;
 129                         $len -= $w;
 130                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 131                         if ($len == 0) { # next request may be pipelined
 132                                 $$rbuf = substr($$rbuf, $w);
 133                                 last;
 134                         }
 135                         $$rbuf = '';
 136                 }
 137                 $self->do_read($rbuf, 8192) or return recv_err($self, $len);
 138                 # continue looping if $r > 0;
 139         }
 140         app_dispatch($self, $input, $rbuf);
 141 }
 142
 143 sub app_dispatch {
 144         my ($self, $input, $rbuf) = @_;
 145         $self->rbuf_idle($rbuf);
 146         my $env = $self->{env};
 147         $env->{REMOTE_ADDR} = $self->{remote_addr};
 148         $env->{REMOTE_PORT} = $self->{remote_port};
 149         if (my $host = $env->{HTTP_HOST}) {
 150                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 151                 $env->{SERVER_NAME} = $host;
 152         }
 153         if (defined $input) {
 154                 sysseek($input, 0, SEEK_SET) or
 155                         die "BUG: psgi.input seek failed: $!";
 156         }
 157         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 158         # to do proper cleanup:
 159         $env->{'psgix.io'} = $self; # only for ->close
 160         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 161         eval {
 162                 if (ref($res) eq 'CODE') {
 163                         $res->(sub { response_write($self, $env, $_[0]) });
 164                 } else {
 165                         response_write($self, $env, $res);
 166                 }
 167         };
 168         $self->close if $@;
 169 }
 170
 171 sub response_header_write {
 172         my ($self, $env, $res) = @_;
 173         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 174         my $status = $res->[0];
 175         my $h = "$proto $status " . status_message($status) . "\r\n";
 176         my ($len, $chunked);
 177         my $headers = $res->[1];
 178
 179         for (my $i = 0; $i < @$headers; $i += 2) {
 180                 my $k = $headers->[$i];
 181                 my $v = $headers->[$i + 1];
 182                 next if $k =~ /\A(?:Connection|Date)\z/i;
 183
 184                 $len = $v if $k =~ /\AContent-Length\z/i;
 185                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 186                         $chunked = 1;
 187                 }
 188                 $h .= "$k: $v\r\n";
 189         }
 190
 191         my $conn = $env->{HTTP_CONNECTION} || '';
 192         my $term = defined($len) || $chunked;
 193         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 194         my $alive;
 195         if (!$term && $prot_persist) { # auto-chunk
 196                 $chunked = $alive = 2;
 197                 $h .= "Transfer-Encoding: chunked\r\n";
 198                 # no need for "Connection: keep-alive" with HTTP/1.1
 199         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 200                 $alive = 1;
 201                 $h .= "Connection: keep-alive\r\n";
 202         } else {
 203                 $alive = 0;
 204                 $h .= "Connection: close\r\n";
 205         }
 206         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 207
 208         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 209                 msg_more($self, $h);
 210         } else {
 211                 $self->write(\$h);
 212         }
 213         $alive;
 214 }
 215
 216 # middlewares such as Deflater may write empty strings
 217 sub chunked_wcb ($) {
 218         my ($self) = @_;
 219         sub {
 220                 return if $_[0] eq '';
 221                 msg_more($self, sprintf("%x\r\n", bytes::length($_[0])));
 222                 msg_more($self, $_[0]);
 223
 224                 # use $self->write(\"\n\n") if you care about real-time
 225                 # streaming responses, public-inbox WWW does not.
 226                 msg_more($self, "\r\n");
 227         }
 228 }
 229
 230 sub identity_wcb ($) {
 231         my ($self) = @_;
 232         sub { $self->write(\($_[0])) if $_[0] ne '' }
 233 }
 234
 235 sub next_request ($) {
 236         my ($self) = @_;
 237         if ($self->{rbuf}) {
 238                 # avoid recursion for pipelined requests
 239                 PublicInbox::DS::requeue(\&process_pipelineq) if !@$pipelineq;
 240                 push @$pipelineq, $self;
 241         } else { # wait for next request
 242                 $self->requeue;
 243         }
 244 }
 245
 246 sub response_done_cb ($$) {
 247         my ($self, $alive) = @_;
 248         sub {
 249                 my $env = delete $self->{env};
 250                 $self->write(\"0\r\n\r\n") if $alive == 2;
 251                 $self->write($alive ? \&next_request : \&close);
 252         }
 253 }
 254
 255 sub getline_cb ($$$) {
 256         my ($self, $write, $close) = @_;
 257         local $/ = \8192;
 258         my $forward = $self->{forward};
 259         # limit our own running time for fairness with other
 260         # clients and to avoid buffering too much:
 261         if ($forward) {
 262                 my $buf = eval { $forward->getline };
 263                 if (defined $buf) {
 264                         $write->($buf); # may close in PublicInbox::DS::write
 265                         if ($self->{sock}) {
 266                                 my $next = $self->{pull};
 267                                 if ($self->{wbuf}) {
 268                                         $self->write($next);
 269                                 } else {
 270                                         PublicInbox::DS::requeue($next);
 271                                 }
 272                                 return;
 273                         }
 274                 } elsif ($@) {
 275                         err($self, "response ->getline error: $@");
 276                         $forward = undef;
 277                         $self->close;
 278                 }
 279         }
 280
 281         delete @$self{qw(forward pull)};
 282         # avoid recursion
 283         if ($forward) {
 284                 eval { $forward->close };
 285                 if ($@) {
 286                         err($self, "response ->close error: $@");
 287                         $self->close; # idempotent
 288                 }
 289         }
 290         $close->();
 291 }
 292
 293 sub getline_response ($$$) {
 294         my ($self, $write, $close) = @_;
 295         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 296         $pull->();
 297 }
 298
 299 sub response_write {
 300         my ($self, $env, $res) = @_;
 301         my $alive = response_header_write($self, $env, $res);
 302         my $close = response_done_cb($self, $alive);
 303         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 304         if (defined(my $body = $res->[2])) {
 305                 if (ref $body eq 'ARRAY') {
 306                         $write->($_) foreach @$body;
 307                         $close->();
 308                 } else {
 309                         $self->{forward} = $body;
 310                         getline_response($self, $write, $close);
 311                 }
 312         } else {
 313                 # this is returned to the calling application:
 314                 Plack::Util::inline_object(write => $write, close => $close);
 315         }
 316 }
 317
 318 sub input_tmpfile ($) {
 319         open($_[0], '+>', undef);
 320         $_[0]->autoflush(1);
 321 }
 322
 323 sub input_prepare {
 324         my ($self, $env) = @_;
 325         my $input;
 326         my $len = $env->{CONTENT_LENGTH};
 327         if ($len) {
 328                 if ($len > $MAX_REQUEST_BUFFER) {
 329                         quit($self, 413);
 330                         return;
 331                 }
 332                 input_tmpfile($input);
 333         } elsif (env_chunked($env)) {
 334                 $len = CHUNK_START;
 335                 input_tmpfile($input);
 336         } else {
 337                 $input = $null_io;
 338         }
 339
 340         # TODO: expire idle clients on ENFILE / EMFILE
 341         return unless $input;
 342
 343         $env->{'psgi.input'} = $input;
 344         $self->{env} = $env;
 345         $self->{input_left} = $len || 0;
 346 }
 347
 348 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 349
 350 sub err ($$) {
 351         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 352 }
 353
 354 sub write_err {
 355         my ($self, $len) = @_;
 356         my $msg = $! || '(zero write)';
 357         $msg .= " ($len bytes remaining)" if defined $len;
 358         err($self, "error buffering to input: $msg");
 359         quit($self, 500);
 360 }
 361
 362 sub recv_err {
 363         my ($self, $len) = @_;
 364         if ($! == EAGAIN) { # epoll/kevent watch already set by do_read
 365                 $self->{input_left} = $len;
 366         } else {
 367                 err($self, "error reading input: $! ($len bytes remaining)");
 368         }
 369 }
 370
 371 sub read_input_chunked { # unlikely...
 372         my ($self, $rbuf) = @_;
 373         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 374         my $input = $self->{env}->{'psgi.input'};
 375         my $len = delete $self->{input_left};
 376
 377         while (1) { # chunk start
 378                 if ($len == CHUNK_ZEND) {
 379                         $$rbuf =~ s/\A\r\n//s and
 380                                 return app_dispatch($self, $input, $rbuf);
 381
 382                         return quit($self, 400) if bytes::length($$rbuf) > 2;
 383                 }
 384                 if ($len == CHUNK_END) {
 385                         if ($$rbuf =~ s/\A\r\n//s) {
 386                                 $len = CHUNK_START;
 387                         } elsif (bytes::length($$rbuf) > 2) {
 388                                 return quit($self, 400);
 389                         }
 390                 }
 391                 if ($len == CHUNK_START) {
 392                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 393                                 $len = hex $1;
 394                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 395                                         return quit($self, 413);
 396                                 }
 397                         } elsif (bytes::length($$rbuf) > CHUNK_MAX_HDR) {
 398                                 return quit($self, 400);
 399                         }
 400                         # will break from loop since $len >= 0
 401                 }
 402
 403                 if ($len < 0) { # chunk header is trickled, read more
 404                         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or
 405                                 return recv_err($self, $len);
 406                         # (implicit) goto chunk_start if $r > 0;
 407                 }
 408                 $len = CHUNK_ZEND if $len == 0;
 409
 410                 # drain the current chunk
 411                 until ($len <= 0) {
 412                         if ($$rbuf ne '') {
 413                                 my $w = xwrite($input, $rbuf, $len);
 414                                 return write_err($self, "$len chunk") if !$w;
 415                                 $len -= $w;
 416                                 if ($len == 0) {
 417                                         # we may have leftover data to parse
 418                                         # in chunk
 419                                         $$rbuf = substr($$rbuf, $w);
 420                                         $len = CHUNK_END;
 421                                 } elsif ($len < 0) {
 422                                         die "BUG: len < 0: $len";
 423                                 } else {
 424                                         $$rbuf = '';
 425                                 }
 426                         }
 427                         if ($$rbuf eq '') {
 428                                 # read more of current chunk
 429                                 $self->do_read($rbuf, 8192) or
 430                                         return recv_err($self, $len);
 431                         }
 432                 }
 433         }
 434 }
 435
 436 sub quit {
 437         my ($self, $status) = @_;
 438         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 439         $self->write(\$h);
 440         $self->close;
 441 }
 442
 443 sub close {
 444         my $self = $_[0];
 445         if (my $env = delete $self->{env}) {
 446                 delete $env->{'psgix.io'}; # prevent circular references
 447         }
 448         delete $self->{pull};
 449         if (my $forward = delete $self->{forward}) {
 450                 eval { $forward->close };
 451                 err($self, "forward ->close error: $@") if $@;
 452         }
 453         $self->SUPER::close; # PublicInbox::DS::close
 454 }
 455
 456 # for graceful shutdown in PublicInbox::Daemon:
 457 sub busy () {
 458         my ($self) = @_;
 459         ($self->{rbuf} || $self->{env} || $self->{wbuf});
 460 }
 461
 462 # fires after pending writes are complete:
 463 sub restart_pass ($) {
 464         $_[0]->{forward}->restart_read; # see PublicInbox::HTTPD::Async
 465 }
 466
 467 sub enqueue_restart_pass ($) { $_[0]->write(\&restart_pass) }
 468
 469 1;