lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use Scalar::Util qw(weaken);
  20 use IO::File;
  21 use constant {
  22         CHUNK_START => -1,   # [a-f0-9]+\r\n
  23         CHUNK_END => -2,     # \r\n
  24         CHUNK_ZEND => -3,    # \r\n
  25         CHUNK_MAX_HDR => 256,
  26 };
  27
  28 # FIXME: duplicated code with NNTP.pm, layering violation
  29 my $WEAKEN = {}; # string(inbox) -> inbox
  30 my $weakt;
  31 sub weaken_task () {
  32         $weakt = undef;
  33         $_->weaken_all for values %$WEAKEN;
  34         $WEAKEN = {};
  35 }
  36
  37 my $pipelineq = [];
  38 my $pipet;
  39 sub process_pipelineq () {
  40         my $q = $pipelineq;
  41         $pipet = undef;
  42         $pipelineq = [];
  43         foreach (@$q) {
  44                 next if $_->{closed};
  45                 rbuf_process($_);
  46         }
  47 }
  48
  49 # Use the same configuration parameter as git since this is primarily
  50 # a slow-client sponge for git-http-backend
  51 # TODO: support per-respository http.maxRequestBuffer somehow...
  52 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  53                         (10 * 1024 * 1024);
  54
  55 my $null_io = IO::File->new('/dev/null', '<');
  56 my $http_date;
  57 my $prev = 0;
  58 sub http_date () {
  59         my $now = time;
  60         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  61 }
  62
  63 sub new ($$$) {
  64         my ($class, $sock, $addr, $httpd) = @_;
  65         my $self = fields::new($class);
  66         $self->SUPER::new($sock);
  67         $self->{httpd} = $httpd;
  68         $self->{rbuf} = '';
  69         ($self->{remote_addr}, $self->{remote_port}) =
  70                 PublicInbox::Daemon::host_with_port($addr);
  71         $self->watch_read(1);
  72         $self;
  73 }
  74
  75 sub event_read { # called by Danga::Socket
  76         my ($self) = @_;
  77
  78         return event_read_input($self) if defined $self->{env};
  79
  80         my $off = length($self->{rbuf});
  81         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  82         if (defined $r) {
  83                 return $self->close if $r == 0;
  84                 return rbuf_process($self);
  85         }
  86         return if $!{EAGAIN}; # no need to call watch_read(1) again
  87
  88         # common for clients to break connections without warning,
  89         # would be too noisy to log here:
  90         return $self->close;
  91 }
  92
  93 sub rbuf_process {
  94         my ($self) = @_;
  95
  96         my %env = %{$self->{httpd}->{env}}; # full hash copy
  97         my $r = parse_http_request($self->{rbuf}, \%env);
  98
  99         # We do not support Trailers in chunked requests, for now
 100         # (they are rarely-used and git (as of 2.7.2) does not use them)
 101         if ($r == -1 || $env{HTTP_TRAILER} ||
 102                         # this length-check is necessary for PURE_PERL=1:
 103                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
 104                 return quit($self, 400);
 105         }
 106         return $self->watch_read(1) if $r < 0; # incomplete
 107         $self->{rbuf} = substr($self->{rbuf}, $r);
 108
 109         my $len = input_prepare($self, \%env);
 110         defined $len or return write_err($self); # EMFILE/ENFILE
 111
 112         $len ? event_read_input($self) : app_dispatch($self);
 113 }
 114
 115 sub event_read_input ($) {
 116         my ($self) = @_;
 117         my $env = $self->{env};
 118         return event_read_input_chunked($self) if env_chunked($env);
 119
 120         # env->{CONTENT_LENGTH} (identity)
 121         my $sock = $self->{sock};
 122         my $len = $self->{input_left};
 123         $self->{input_left} = undef;
 124         my $rbuf = \($self->{rbuf});
 125         my $input = $env->{'psgi.input'};
 126
 127         while ($len > 0) {
 128                 if ($$rbuf ne '') {
 129                         my $w = write_in_full($input, $rbuf, $len);
 130                         return write_err($self) unless $w;
 131                         $len -= $w;
 132                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 133                         if ($len == 0) { # next request may be pipelined
 134                                 $$rbuf = substr($$rbuf, $w);
 135                                 last;
 136                         }
 137                         $$rbuf = '';
 138                 }
 139                 my $r = sysread($sock, $$rbuf, 8192);
 140                 return recv_err($self, $r, $len) unless $r;
 141                 # continue looping if $r > 0;
 142         }
 143         app_dispatch($self, $input);
 144 }
 145
 146 sub app_dispatch {
 147         my ($self, $input) = @_;
 148         $self->watch_read(0);
 149         my $env = $self->{env};
 150         $env->{REMOTE_ADDR} = $self->{remote_addr};
 151         $env->{REMOTE_PORT} = $self->{remote_port};
 152         if (my $host = $env->{HTTP_HOST}) {
 153                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 154                 $env->{SERVER_NAME} = $host;
 155         }
 156         if (defined $input) {
 157                 sysseek($input, 0, SEEK_SET) or
 158                         die "BUG: psgi.input seek failed: $!";
 159         }
 160         # note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
 161         # to do proper cleanup:
 162         $env->{'psgix.io'} = $self; # only for ->close
 163         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 164         eval {
 165                 if (ref($res) eq 'CODE') {
 166                         $res->(sub { response_write($self, $env, $_[0]) });
 167                 } else {
 168                         response_write($self, $env, $res);
 169                 }
 170         };
 171         $self->close if $@;
 172 }
 173
 174 sub response_header_write {
 175         my ($self, $env, $res) = @_;
 176         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 177         my $status = $res->[0];
 178         my $h = "$proto $status " . status_message($status) . "\r\n";
 179         my ($len, $chunked);
 180         my $headers = $res->[1];
 181
 182         for (my $i = 0; $i < @$headers; $i += 2) {
 183                 my $k = $headers->[$i];
 184                 my $v = $headers->[$i + 1];
 185                 next if $k =~ /\A(?:Connection|Date)\z/i;
 186
 187                 $len = $v if $k =~ /\AContent-Length\z/i;
 188                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 189                         $chunked = 1;
 190                 }
 191                 $h .= "$k: $v\r\n";
 192         }
 193
 194         my $conn = $env->{HTTP_CONNECTION} || '';
 195         my $term = defined($len) || $chunked;
 196         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 197         my $alive;
 198         if (!$term && $prot_persist) { # auto-chunk
 199                 $chunked = $alive = 2;
 200                 $h .= "Transfer-Encoding: chunked\r\n";
 201                 # no need for "Connection: keep-alive" with HTTP/1.1
 202         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 203                 $alive = 1;
 204                 $h .= "Connection: keep-alive\r\n";
 205         } else {
 206                 $alive = 0;
 207                 $h .= "Connection: close\r\n";
 208         }
 209         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 210
 211         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 212                 more($self, $h);
 213         } else {
 214                 $self->write($h);
 215         }
 216         $alive;
 217 }
 218
 219 # middlewares such as Deflater may write empty strings
 220 sub chunked_wcb ($) {
 221         my ($self) = @_;
 222         sub {
 223                 return if $_[0] eq '';
 224                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 225                 more($self, $_[0]);
 226
 227                 # use $self->write("\n\n") if you care about real-time
 228                 # streaming responses, public-inbox WWW does not.
 229                 more($self, "\r\n");
 230         }
 231 }
 232
 233 sub identity_wcb ($) {
 234         my ($self) = @_;
 235         sub { $self->write(\($_[0])) if $_[0] ne '' }
 236 }
 237
 238 sub next_request ($) {
 239         my ($self) = @_;
 240         $self->watch_write(0);
 241         if ($self->{rbuf} eq '') { # wait for next request
 242                 $self->watch_read(1);
 243         } else { # avoid recursion for pipelined requests
 244                 push @$pipelineq, $self;
 245                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 246         }
 247 }
 248
 249 sub response_done ($$) {
 250         my ($self, $alive) = @_;
 251         my $env = $self->{env};
 252         $self->{env} = undef;
 253         $self->write("0\r\n\r\n") if $alive == 2;
 254         $self->write(sub { $alive ? next_request($self) : $self->close });
 255
 256         # FIXME: layering violation
 257         if (my $obj = $env->{'pi-httpd.inbox'}) {
 258                 # grace period for reaping resources
 259                 $WEAKEN->{"$obj"} = $obj;
 260                 PublicInbox::EvCleanup::later(*weaken_task);
 261         }
 262 }
 263
 264 sub getline_response {
 265         my ($self, $body, $write, $close) = @_;
 266         $self->{forward} = $body;
 267         weaken($self);
 268         my $pull = $self->{pull} = sub {
 269                 local $/ = \8192;
 270                 my $forward = $self->{forward};
 271                 # limit our own running time for fairness with other
 272                 # clients and to avoid buffering too much:
 273                 while ($forward && defined(my $buf = $forward->getline)) {
 274                         $write->($buf);
 275                         last if $self->{closed};
 276                         if ($self->{write_buf_size}) {
 277                                 $self->write($self->{pull});
 278                         } else {
 279                                 PublicInbox::EvCleanup::asap($self->{pull});
 280                         }
 281                         return;
 282                 }
 283                 $self->{forward} = $self->{pull} = undef;
 284                 $forward->close if $forward; # avoid recursion
 285                 $close->();
 286         };
 287         $pull->();
 288 }
 289
 290 sub response_write {
 291         my ($self, $env, $res) = @_;
 292         my $alive = response_header_write($self, $env, $res);
 293
 294         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 295         my $close = sub { response_done($self, $alive) };
 296         if (defined(my $body = $res->[2])) {
 297                 if (ref $body eq 'ARRAY') {
 298                         $write->($_) foreach @$body;
 299                         $close->();
 300                 } else {
 301                         getline_response($self, $body, $write, $close);
 302                 }
 303         } else {
 304                 # this is returned to the calling application:
 305                 Plack::Util::inline_object(write => $write, close => $close);
 306         }
 307 }
 308
 309 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 310 sub more ($$) {
 311         my $self = $_[0];
 312         return if $self->{closed};
 313         if (MSG_MORE && !$self->{write_buf_size}) {
 314                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 315                 if (defined $n) {
 316                         my $dlen = length($_[1]);
 317                         return 1 if $n == $dlen; # all done!
 318                         $_[1] = substr($_[1], $n, $dlen - $n);
 319                         # fall through to normal write:
 320                 }
 321         }
 322         $self->write($_[1]);
 323 }
 324
 325 sub input_prepare {
 326         my ($self, $env) = @_;
 327         my $input = $null_io;
 328         my $len = $env->{CONTENT_LENGTH};
 329         if ($len) {
 330                 if ($len > $MAX_REQUEST_BUFFER) {
 331                         quit($self, 413);
 332                         return;
 333                 }
 334                 $input = IO::File->new_tmpfile;
 335         } elsif (env_chunked($env)) {
 336                 $len = CHUNK_START;
 337                 $input = IO::File->new_tmpfile;
 338         }
 339
 340         # TODO: expire idle clients on ENFILE / EMFILE
 341         return unless $input;
 342
 343         $env->{'psgi.input'} = $input;
 344         $self->{env} = $env;
 345         $self->{input_left} = $len || 0;
 346 }
 347
 348 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 349
 350 sub write_err {
 351         my ($self) = @_;
 352         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 353         my $msg = $! || '(zero write)';
 354         $err->print("error buffering to input: $msg\n");
 355         quit($self, 500);
 356 }
 357
 358 sub recv_err {
 359         my ($self, $r, $len) = @_;
 360         return $self->close if (defined $r && $r == 0);
 361         if ($!{EAGAIN}) {
 362                 $self->{input_left} = $len;
 363                 return;
 364         }
 365         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 366         $err->print("error reading for input: $! ($len bytes remaining)\n");
 367         quit($self, 500);
 368 }
 369
 370 sub write_in_full {
 371         my ($fh, $rbuf, $len) = @_;
 372         my $rv = 0;
 373         my $off = 0;
 374         while ($len > 0) {
 375                 my $w = syswrite($fh, $$rbuf, $len, $off);
 376                 return ($rv ? $rv : $w) unless $w; # undef or 0
 377                 $rv += $w;
 378                 $off += $w;
 379                 $len -= $w;
 380         }
 381         $rv
 382 }
 383
 384 sub event_read_input_chunked { # unlikely...
 385         my ($self) = @_;
 386         my $input = $self->{env}->{'psgi.input'};
 387         my $sock = $self->{sock};
 388         my $len = $self->{input_left};
 389         $self->{input_left} = undef;
 390         my $rbuf = \($self->{rbuf});
 391
 392         while (1) { # chunk start
 393                 if ($len == CHUNK_ZEND) {
 394                         $$rbuf =~ s/\A\r\n//s and
 395                                 return app_dispatch($self, $input);
 396                         return quit($self, 400) if length($$rbuf) > 2;
 397                 }
 398                 if ($len == CHUNK_END) {
 399                         if ($$rbuf =~ s/\A\r\n//s) {
 400                                 $len = CHUNK_START;
 401                         } elsif (length($$rbuf) > 2) {
 402                                 return quit($self, 400);
 403                         }
 404                 }
 405                 if ($len == CHUNK_START) {
 406                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 407                                 $len = hex $1;
 408                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 409                                         return quit($self, 413);
 410                                 }
 411                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 412                                 return quit($self, 400);
 413                         }
 414                         # will break from loop since $len >= 0
 415                 }
 416
 417                 if ($len < 0) { # chunk header is trickled, read more
 418                         my $off = length($$rbuf);
 419                         my $r = sysread($sock, $$rbuf, 8192, $off);
 420                         return recv_err($self, $r, $len) unless $r;
 421                         # (implicit) goto chunk_start if $r > 0;
 422                 }
 423                 $len = CHUNK_ZEND if $len == 0;
 424
 425                 # drain the current chunk
 426                 until ($len <= 0) {
 427                         if ($$rbuf ne '') {
 428                                 my $w = write_in_full($input, $rbuf, $len);
 429                                 return write_err($self) unless $w;
 430                                 $len -= $w;
 431                                 if ($len == 0) {
 432                                         # we may have leftover data to parse
 433                                         # in chunk
 434                                         $$rbuf = substr($$rbuf, $w);
 435                                         $len = CHUNK_END;
 436                                 } elsif ($len < 0) {
 437                                         die "BUG: len < 0: $len";
 438                                 } else {
 439                                         $$rbuf = '';
 440                                 }
 441                         }
 442                         if ($$rbuf eq '') {
 443                                 # read more of current chunk
 444                                 my $r = sysread($sock, $$rbuf, 8192);
 445                                 return recv_err($self, $r, $len) unless $r;
 446                         }
 447                 }
 448         }
 449 }
 450
 451 sub quit {
 452         my ($self, $status) = @_;
 453         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 454         $self->write($h);
 455         $self->close;
 456 }
 457
 458 # callbacks for Danga::Socket
 459
 460 sub event_hup { $_[0]->close }
 461 sub event_err { $_[0]->close }
 462
 463 sub close {
 464         my $self = shift;
 465         my $forward = $self->{forward};
 466         my $env = $self->{env};
 467         delete $env->{'psgix.io'} if $env; # prevent circular referernces
 468         $self->{pull} = $self->{forward} = $self->{env} = undef;
 469         $forward->close if $forward;
 470         $self->SUPER::close(@_);
 471 }
 472
 473 # for graceful shutdown in PublicInbox::Daemon:
 474 sub busy () {
 475         my ($self) = @_;
 476         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 477 }
 478
 479 1;