lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9 #
  10 # fields:
  11 # httpd: PublicInbox::HTTPD ref
  12 # env: PSGI env hashref
  13 # input_left: bytes left to read in request body (e.g. POST/PUT)
  14 # remote_addr: remote IP address as a string (e.g. "127.0.0.1")
  15 # remote_port: peer port
  16 # forward: response body object, response to ->getline + ->close
  17 # alive: HTTP keepalive state:
  18 #       0: drop connection when done
  19 #       1: keep connection when done
  20 #       2: keep connection, chunk responses
  21 package PublicInbox::HTTP;
  22 use strict;
  23 use parent qw(PublicInbox::DS);
  24 use Fcntl qw(:seek);
  25 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  26 use Plack::Util;
  27 use HTTP::Status qw(status_message);
  28 use HTTP::Date qw(time2str);
  29 use PublicInbox::DS qw(msg_more);
  30 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  31 use PublicInbox::Tmpfile;
  32 use constant {
  33         CHUNK_START => -1,   # [a-f0-9]+\r\n
  34         CHUNK_END => -2,     # \r\n
  35         CHUNK_ZEND => -3,    # \r\n
  36         CHUNK_MAX_HDR => 256,
  37 };
  38 use Errno qw(EAGAIN);
  39
  40 # Use the same configuration parameter as git since this is primarily
  41 # a slow-client sponge for git-http-backend
  42 # TODO: support per-respository http.maxRequestBuffer somehow...
  43 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  44                         (10 * 1024 * 1024);
  45
  46 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  47 my $http_date;
  48 my $prev = 0;
  49 sub http_date () {
  50         my $now = time;
  51         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  52 }
  53
  54 sub new ($$$) {
  55         my ($class, $sock, $addr, $httpd) = @_;
  56         my $self = bless { httpd => $httpd }, $class;
  57         my $ev = EPOLLIN;
  58         my $wbuf;
  59         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  60                 return CORE::close($sock) if $! != EAGAIN;
  61                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  62                 $wbuf = [ \&PublicInbox::DS::accept_tls_step ];
  63         }
  64         $self->{wbuf} = $wbuf if $wbuf;
  65         ($self->{remote_addr}, $self->{remote_port}) =
  66                 PublicInbox::Daemon::host_with_port($addr);
  67         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  68 }
  69
  70 sub event_step { # called by PublicInbox::DS
  71         my ($self) = @_;
  72
  73         return unless $self->flush_write && $self->{sock};
  74
  75         # only read more requests if we've drained the write buffer,
  76         # otherwise we can be buffering infinitely w/o backpressure
  77
  78         return read_input($self) if ref($self->{env});
  79
  80         my $rbuf = $self->{rbuf} // (\(my $x = ''));
  81         my %env = %{$self->{httpd}->{env}}; # full hash copy
  82         my $r;
  83         while (($r = parse_http_request($$rbuf, \%env)) < 0) {
  84                 # We do not support Trailers in chunked requests, for
  85                 # now (they are rarely-used and git (as of 2.7.2) does
  86                 # not use them).
  87                 # this length-check is necessary for PURE_PERL=1:
  88                 if ($r == -1 || $env{HTTP_TRAILER} ||
  89                                 ($r == -2 && length($$rbuf) > 0x4000)) {
  90                         return quit($self, 400);
  91                 }
  92                 $self->do_read($rbuf, 8192, length($$rbuf)) or return;
  93         }
  94         return quit($self, 400) if grep(/\s/, keys %env); # stop smugglers
  95         $$rbuf = substr($$rbuf, $r);
  96         my $len = input_prepare($self, \%env) //
  97                 return write_err($self, undef); # EMFILE/ENFILE
  98
  99         $len ? read_input($self, $rbuf) : app_dispatch($self, undef, $rbuf);
 100 }
 101
 102 sub read_input ($;$) {
 103         my ($self, $rbuf) = @_;
 104         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 105         my $env = $self->{env};
 106         return read_input_chunked($self, $rbuf) if env_chunked($env);
 107
 108         # env->{CONTENT_LENGTH} (identity)
 109         my $len = delete $self->{input_left};
 110         my $input = $env->{'psgi.input'};
 111
 112         while ($len > 0) {
 113                 if ($$rbuf ne '') {
 114                         my $w = syswrite($input, $$rbuf, $len);
 115                         return write_err($self, $len) unless $w;
 116                         $len -= $w;
 117                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 118                         if ($len == 0) { # next request may be pipelined
 119                                 $$rbuf = substr($$rbuf, $w);
 120                                 last;
 121                         }
 122                         $$rbuf = '';
 123                 }
 124                 $self->do_read($rbuf, 8192) or return recv_err($self, $len);
 125                 # continue looping if $r > 0;
 126         }
 127         app_dispatch($self, $input, $rbuf);
 128 }
 129
 130 sub app_dispatch {
 131         my ($self, $input, $rbuf) = @_;
 132         $self->rbuf_idle($rbuf);
 133         my $env = $self->{env};
 134         $self->{env} = undef; # for exists() check in ->busy
 135         $env->{REMOTE_ADDR} = $self->{remote_addr};
 136         $env->{REMOTE_PORT} = $self->{remote_port};
 137         if (defined(my $host = $env->{HTTP_HOST})) {
 138                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 139                 $env->{SERVER_NAME} = $host;
 140         }
 141         if (defined $input) {
 142                 sysseek($input, 0, SEEK_SET) or
 143                         die "BUG: psgi.input seek failed: $!";
 144         }
 145         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 146         # to do proper cleanup:
 147         $env->{'psgix.io'} = $self; # for ->close or async_pass
 148         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 149         eval {
 150                 if (ref($res) eq 'CODE') {
 151                         $res->(sub { response_write($self, $env, $_[0]) });
 152                 } else {
 153                         response_write($self, $env, $res);
 154                 }
 155         };
 156         if ($@) {
 157                 warn "response_write error: $@";
 158                 $self->close;
 159         }
 160 }
 161
 162 sub response_header_write {
 163         my ($self, $env, $res) = @_;
 164         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 165         my $status = $res->[0];
 166         my $h = "$proto $status " . status_message($status) . "\r\n";
 167         my ($len, $chunked);
 168         my $headers = $res->[1];
 169
 170         for (my $i = 0; $i < @$headers; $i += 2) {
 171                 my $k = $headers->[$i];
 172                 my $v = $headers->[$i + 1];
 173                 next if $k =~ /\A(?:Connection|Date)\z/i;
 174
 175                 $len = $v if $k =~ /\AContent-Length\z/i;
 176                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 177                         $chunked = 1;
 178                 }
 179                 $h .= "$k: $v\r\n";
 180         }
 181
 182         my $conn = $env->{HTTP_CONNECTION} || '';
 183         my $term = defined($len) || $chunked;
 184         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 185         my $alive;
 186         if (!$term && $prot_persist) { # auto-chunk
 187                 $chunked = $alive = 2;
 188                 $h .= "Transfer-Encoding: chunked\r\n";
 189                 # no need for "Connection: keep-alive" with HTTP/1.1
 190         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 191                 $alive = 1;
 192                 $h .= "Connection: keep-alive\r\n";
 193         } else {
 194                 $alive = 0;
 195                 $h .= "Connection: close\r\n";
 196         }
 197         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 198
 199         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 200                 msg_more($self, $h);
 201         } else {
 202                 $self->write(\$h);
 203         }
 204         $alive;
 205 }
 206
 207 # middlewares such as Deflater may write empty strings
 208 sub chunked_write ($$) {
 209         my $self = $_[0];
 210         return if $_[1] eq '';
 211         msg_more($self, sprintf("%x\r\n", length($_[1])));
 212         msg_more($self, $_[1]);
 213
 214         # use $self->write(\"\n\n") if you care about real-time
 215         # streaming responses, public-inbox WWW does not.
 216         msg_more($self, "\r\n");
 217 }
 218
 219 sub identity_write ($$) {
 220         my $self = $_[0];
 221         $self->write(\($_[1])) if $_[1] ne '';
 222 }
 223
 224 sub response_done {
 225         my ($self, $alive) = @_;
 226         delete $self->{env}; # we're no longer busy
 227         $self->write(\"0\r\n\r\n") if $alive == 2;
 228         $self->write($alive ? $self->can('requeue') : \&close);
 229 }
 230
 231 sub getline_pull {
 232         my ($self) = @_;
 233         my $forward = $self->{forward};
 234
 235         # limit our own running time for fairness with other
 236         # clients and to avoid buffering too much:
 237         my $buf = eval {
 238                 local $/ = \65536;
 239                 $forward->getline;
 240         } if $forward;
 241
 242         if (defined $buf) {
 243                 # may close in PublicInbox::DS::write
 244                 if ($self->{alive} == 2) {
 245                         chunked_write($self, $buf);
 246                 } else {
 247                         identity_write($self, $buf);
 248                 }
 249
 250                 if ($self->{sock}) {
 251                         # autovivify wbuf
 252                         my $new_size = push(@{$self->{wbuf}}, \&getline_pull);
 253
 254                         # wbuf may be populated by {chunked,identity}_write()
 255                         # above, no need to rearm if so:
 256                         $self->requeue if $new_size == 1;
 257                         return; # likely
 258                 }
 259         } elsif ($@) {
 260                 warn "response ->getline error: $@";
 261                 $self->close;
 262         }
 263         # avoid recursion
 264         if (delete $self->{forward}) {
 265                 eval { $forward->close };
 266                 if ($@) {
 267                         warn "response ->close error: $@";
 268                         $self->close; # idempotent
 269                 }
 270         }
 271         response_done($self, delete $self->{alive});
 272 }
 273
 274 sub response_write {
 275         my ($self, $env, $res) = @_;
 276         my $alive = response_header_write($self, $env, $res);
 277         if (defined(my $body = $res->[2])) {
 278                 if (ref $body eq 'ARRAY') {
 279                         if ($alive == 2) {
 280                                 chunked_write($self, $_) for @$body;
 281                         } else {
 282                                 identity_write($self, $_) for @$body;
 283                         }
 284                         response_done($self, $alive);
 285                 } else {
 286                         $self->{forward} = $body;
 287                         $self->{alive} = $alive;
 288                         getline_pull($self); # kick-off!
 289                 }
 290         # these are returned to the calling application:
 291         } elsif ($alive == 2) {
 292                 bless [ $self, $alive ], 'PublicInbox::HTTP::Chunked';
 293         } else {
 294                 bless [ $self, $alive ], 'PublicInbox::HTTP::Identity';
 295         }
 296 }
 297
 298 sub input_prepare {
 299         my ($self, $env) = @_;
 300         my ($input, $len);
 301
 302         # rfc 7230 3.3.2, 3.3.3,: favor Transfer-Encoding over Content-Length
 303         my $hte = $env->{HTTP_TRANSFER_ENCODING};
 304         if (defined $hte) {
 305                 # rfc7230 3.3.3, point 3 says only chunked is accepted
 306                 # as the final encoding.  Since neither public-inbox-httpd,
 307                 # git-http-backend, or our WWW-related code uses "gzip",
 308                 # "deflate" or "compress" as the Transfer-Encoding, we'll
 309                 # reject them:
 310                 return quit($self, 400) if $hte !~ /\Achunked\z/i;
 311
 312                 $len = CHUNK_START;
 313                 $input = tmpfile('http.input', $self->{sock});
 314         } else {
 315                 $len = $env->{CONTENT_LENGTH};
 316                 if (defined $len) {
 317                         # rfc7230 3.3.3.4
 318                         return quit($self, 400) if $len !~ /\A[0-9]+\z/;
 319                         return quit($self, 413) if $len > $MAX_REQUEST_BUFFER;
 320                         $input = $len ? tmpfile('http.input', $self->{sock})
 321                                 : $null_io;
 322                 } else {
 323                         $input = $null_io;
 324                 }
 325         }
 326
 327         # TODO: expire idle clients on ENFILE / EMFILE
 328         $env->{'psgi.input'} = $input // return;
 329         $self->{env} = $env;
 330         $self->{input_left} = $len || 0;
 331 }
 332
 333 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} // '') =~ /\Achunked\z/i }
 334
 335 sub write_err {
 336         my ($self, $len) = @_;
 337         my $msg = $! || '(zero write)';
 338         $msg .= " ($len bytes remaining)" if defined $len;
 339         warn "error buffering to input: $msg";
 340         quit($self, 500);
 341 }
 342
 343 sub recv_err {
 344         my ($self, $len) = @_;
 345         if ($! == EAGAIN) { # epoll/kevent watch already set by do_read
 346                 $self->{input_left} = $len;
 347         } else {
 348                 warn "error reading input: $! ($len bytes remaining)";
 349         }
 350 }
 351
 352 sub read_input_chunked { # unlikely...
 353         my ($self, $rbuf) = @_;
 354         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 355         my $input = $self->{env}->{'psgi.input'};
 356         my $len = delete $self->{input_left};
 357
 358         while (1) { # chunk start
 359                 if ($len == CHUNK_ZEND) {
 360                         $$rbuf =~ s/\A\r\n//s and
 361                                 return app_dispatch($self, $input, $rbuf);
 362
 363                         return quit($self, 400) if length($$rbuf) > 2;
 364                 }
 365                 if ($len == CHUNK_END) {
 366                         if ($$rbuf =~ s/\A\r\n//s) {
 367                                 $len = CHUNK_START;
 368                         } elsif (length($$rbuf) > 2) {
 369                                 return quit($self, 400);
 370                         }
 371                 }
 372                 if ($len == CHUNK_START) {
 373                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 374                                 $len = hex $1;
 375                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 376                                         return quit($self, 413);
 377                                 }
 378                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 379                                 return quit($self, 400);
 380                         }
 381                         # will break from loop since $len >= 0
 382                 }
 383
 384                 if ($len < 0) { # chunk header is trickled, read more
 385                         $self->do_read($rbuf, 8192, length($$rbuf)) or
 386                                 return recv_err($self, $len);
 387                         # (implicit) goto chunk_start if $r > 0;
 388                 }
 389                 $len = CHUNK_ZEND if $len == 0;
 390
 391                 # drain the current chunk
 392                 until ($len <= 0) {
 393                         if ($$rbuf ne '') {
 394                                 my $w = syswrite($input, $$rbuf, $len);
 395                                 return write_err($self, "$len chunk") if !$w;
 396                                 $len -= $w;
 397                                 if ($len == 0) {
 398                                         # we may have leftover data to parse
 399                                         # in chunk
 400                                         $$rbuf = substr($$rbuf, $w);
 401                                         $len = CHUNK_END;
 402                                 } elsif ($len < 0) {
 403                                         die "BUG: len < 0: $len";
 404                                 } else {
 405                                         $$rbuf = '';
 406                                 }
 407                         }
 408                         if ($$rbuf eq '') {
 409                                 # read more of current chunk
 410                                 $self->do_read($rbuf, 8192) or
 411                                         return recv_err($self, $len);
 412                         }
 413                 }
 414         }
 415 }
 416
 417 sub quit {
 418         my ($self, $status) = @_;
 419         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 420         $self->write(\$h);
 421         $self->close;
 422         undef; # input_prepare expects this
 423 }
 424
 425 sub close {
 426         my $self = $_[0];
 427         if (my $forward = delete $self->{forward}) {
 428                 eval { $forward->close };
 429                 warn "forward ->close error: $@" if $@;
 430         }
 431         $self->SUPER::close; # PublicInbox::DS::close
 432 }
 433
 434 sub busy { # for graceful shutdown in PublicInbox::Daemon:
 435         my ($self) = @_;
 436         defined($self->{rbuf}) || exists($self->{env}) || defined($self->{wbuf})
 437 }
 438
 439 # runs $cb on the next iteration of the event loop at earliest
 440 sub next_step {
 441         my ($self, $cb) = @_;
 442         return unless exists $self->{sock};
 443         $self->requeue if 1 == push(@{$self->{wbuf}}, $cb);
 444 }
 445
 446 # Chunked and Identity packages are used for writing responses.
 447 # They may be exposed to the PSGI application when the PSGI app
 448 # returns a CODE ref for "push"-based responses
 449 package PublicInbox::HTTP::Chunked;
 450 use strict;
 451
 452 sub write {
 453         # ([$http], $buf) = @_;
 454         PublicInbox::HTTP::chunked_write($_[0]->[0], $_[1])
 455 }
 456
 457 sub close {
 458         # $_[0] = [$http, $alive]
 459         PublicInbox::HTTP::response_done(@{$_[0]});
 460 }
 461
 462 package PublicInbox::HTTP::Identity;
 463 use strict;
 464 our @ISA = qw(PublicInbox::HTTP::Chunked);
 465
 466 sub write {
 467         # ([$http], $buf) = @_;
 468         PublicInbox::HTTP::identity_write($_[0]->[0], $_[1]);
 469 }
 470
 471 1;