lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 PublicInbox::DS->import(qw(msg_more write_in_full));
  23 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  24 use constant {
  25         CHUNK_START => -1,   # [a-f0-9]+\r\n
  26         CHUNK_END => -2,     # \r\n
  27         CHUNK_ZEND => -3,    # \r\n
  28         CHUNK_MAX_HDR => 256,
  29 };
  30 use Errno qw(EAGAIN);
  31
  32 my $pipelineq = [];
  33 my $pipet;
  34 sub process_pipelineq () {
  35         my $q = $pipelineq;
  36         $pipet = undef;
  37         $pipelineq = [];
  38         foreach (@$q) {
  39                 next unless $_->{sock};
  40                 rbuf_process($_);
  41         }
  42 }
  43
  44 # Use the same configuration parameter as git since this is primarily
  45 # a slow-client sponge for git-http-backend
  46 # TODO: support per-respository http.maxRequestBuffer somehow...
  47 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  48                         (10 * 1024 * 1024);
  49
  50 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  51 my $http_date;
  52 my $prev = 0;
  53 sub http_date () {
  54         my $now = time;
  55         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  56 }
  57
  58 sub new ($$$) {
  59         my ($class, $sock, $addr, $httpd) = @_;
  60         my $self = fields::new($class);
  61         $self->SUPER::new($sock, EPOLLIN | EPOLLONESHOT);
  62         $self->{httpd} = $httpd;
  63         $self->{rbuf} = '';
  64         ($self->{remote_addr}, $self->{remote_port}) =
  65                 PublicInbox::Daemon::host_with_port($addr);
  66         $self;
  67 }
  68
  69 sub event_step { # called by PublicInbox::DS
  70         my ($self) = @_;
  71
  72         return unless $self->flush_write && $self->{sock};
  73
  74         # only read more requests if we've drained the write buffer,
  75         # otherwise we can be buffering infinitely w/o backpressure
  76
  77         return read_input($self) if defined $self->{env};
  78
  79         my $off = length($self->{rbuf});
  80         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  81         if (defined $r) {
  82                 return $self->close if $r == 0;
  83                 return rbuf_process($self);
  84         }
  85
  86         # common for clients to break connections without warning,
  87         # would be too noisy to log here:
  88         $! == EAGAIN ? $self->watch_in1 : $self->close;
  89 }
  90
  91 sub rbuf_process {
  92         my ($self) = @_;
  93
  94         my %env = %{$self->{httpd}->{env}}; # full hash copy
  95         my $r = parse_http_request($self->{rbuf}, \%env);
  96
  97         # We do not support Trailers in chunked requests, for now
  98         # (they are rarely-used and git (as of 2.7.2) does not use them)
  99         if ($r == -1 || $env{HTTP_TRAILER} ||
 100                         # this length-check is necessary for PURE_PERL=1:
 101                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
 102                 return quit($self, 400);
 103         }
 104         return $self->watch_in1 if $r < 0; # incomplete
 105         $self->{rbuf} = substr($self->{rbuf}, $r);
 106
 107         my $len = input_prepare($self, \%env);
 108         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 109
 110         $len ? read_input($self) : app_dispatch($self);
 111 }
 112
 113 sub read_input ($) {
 114         my ($self) = @_;
 115         my $env = $self->{env};
 116         return if $env->{REMOTE_ADDR}; # in app dispatch
 117         return read_input_chunked($self) if env_chunked($env);
 118
 119         # env->{CONTENT_LENGTH} (identity)
 120         my $sock = $self->{sock};
 121         my $len = delete $self->{input_left};
 122         my $rbuf = \($self->{rbuf});
 123         my $input = $env->{'psgi.input'};
 124
 125         while ($len > 0) {
 126                 if ($$rbuf ne '') {
 127                         my $w = write_in_full($input, $rbuf, $len, 0);
 128                         return write_err($self, $len) unless $w;
 129                         $len -= $w;
 130                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 131                         if ($len == 0) { # next request may be pipelined
 132                                 $$rbuf = substr($$rbuf, $w);
 133                                 last;
 134                         }
 135                         $$rbuf = '';
 136                 }
 137                 my $r = sysread($sock, $$rbuf, 8192);
 138                 return recv_err($self, $r, $len) unless $r;
 139                 # continue looping if $r > 0;
 140         }
 141         app_dispatch($self, $input);
 142 }
 143
 144 sub app_dispatch {
 145         my ($self, $input) = @_;
 146         my $env = $self->{env};
 147         $env->{REMOTE_ADDR} = $self->{remote_addr};
 148         $env->{REMOTE_PORT} = $self->{remote_port};
 149         if (my $host = $env->{HTTP_HOST}) {
 150                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 151                 $env->{SERVER_NAME} = $host;
 152         }
 153         if (defined $input) {
 154                 sysseek($input, 0, SEEK_SET) or
 155                         die "BUG: psgi.input seek failed: $!";
 156         }
 157         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 158         # to do proper cleanup:
 159         $env->{'psgix.io'} = $self; # only for ->close
 160         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 161         eval {
 162                 if (ref($res) eq 'CODE') {
 163                         $res->(sub { response_write($self, $env, $_[0]) });
 164                 } else {
 165                         response_write($self, $env, $res);
 166                 }
 167         };
 168         $self->close if $@;
 169 }
 170
 171 sub response_header_write {
 172         my ($self, $env, $res) = @_;
 173         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 174         my $status = $res->[0];
 175         my $h = "$proto $status " . status_message($status) . "\r\n";
 176         my ($len, $chunked);
 177         my $headers = $res->[1];
 178
 179         for (my $i = 0; $i < @$headers; $i += 2) {
 180                 my $k = $headers->[$i];
 181                 my $v = $headers->[$i + 1];
 182                 next if $k =~ /\A(?:Connection|Date)\z/i;
 183
 184                 $len = $v if $k =~ /\AContent-Length\z/i;
 185                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 186                         $chunked = 1;
 187                 }
 188                 $h .= "$k: $v\r\n";
 189         }
 190
 191         my $conn = $env->{HTTP_CONNECTION} || '';
 192         my $term = defined($len) || $chunked;
 193         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 194         my $alive;
 195         if (!$term && $prot_persist) { # auto-chunk
 196                 $chunked = $alive = 2;
 197                 $h .= "Transfer-Encoding: chunked\r\n";
 198                 # no need for "Connection: keep-alive" with HTTP/1.1
 199         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 200                 $alive = 1;
 201                 $h .= "Connection: keep-alive\r\n";
 202         } else {
 203                 $alive = 0;
 204                 $h .= "Connection: close\r\n";
 205         }
 206         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 207
 208         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 209                 msg_more($self, $h);
 210         } else {
 211                 $self->write(\$h);
 212         }
 213         $alive;
 214 }
 215
 216 # middlewares such as Deflater may write empty strings
 217 sub chunked_wcb ($) {
 218         my ($self) = @_;
 219         sub {
 220                 return if $_[0] eq '';
 221                 msg_more($self, sprintf("%x\r\n", bytes::length($_[0])));
 222                 msg_more($self, $_[0]);
 223
 224                 # use $self->write(\"\n\n") if you care about real-time
 225                 # streaming responses, public-inbox WWW does not.
 226                 msg_more($self, "\r\n");
 227         }
 228 }
 229
 230 sub identity_wcb ($) {
 231         my ($self) = @_;
 232         sub { $self->write(\($_[0])) if $_[0] ne '' }
 233 }
 234
 235 sub next_request ($) {
 236         my ($self) = @_;
 237         if ($self->{rbuf} eq '') { # wait for next request
 238                 $self->watch_in1;
 239         } else { # avoid recursion for pipelined requests
 240                 push @$pipelineq, $self;
 241                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 242         }
 243 }
 244
 245 sub response_done_cb ($$) {
 246         my ($self, $alive) = @_;
 247         sub {
 248                 my $env = delete $self->{env};
 249                 $self->write(\"0\r\n\r\n") if $alive == 2;
 250                 $self->write(sub{$alive ? next_request($self) : $self->close});
 251         }
 252 }
 253
 254 sub getline_cb ($$$) {
 255         my ($self, $write, $close) = @_;
 256         local $/ = \8192;
 257         my $forward = $self->{forward};
 258         # limit our own running time for fairness with other
 259         # clients and to avoid buffering too much:
 260         if ($forward) {
 261                 my $buf = eval { $forward->getline };
 262                 if (defined $buf) {
 263                         $write->($buf); # may close in PublicInbox::DS::write
 264                         if ($self->{sock}) {
 265                                 my $next = $self->{pull};
 266                                 if ($self->{wbuf}) {
 267                                         $self->write($next);
 268                                 } else {
 269                                         PublicInbox::EvCleanup::asap($next);
 270                                 }
 271                                 return;
 272                         }
 273                 } elsif ($@) {
 274                         err($self, "response ->getline error: $@");
 275                         $forward = undef;
 276                         $self->close;
 277                 }
 278         }
 279
 280         delete @$self{qw(forward pull)};
 281         # avoid recursion
 282         if ($forward) {
 283                 eval { $forward->close };
 284                 if ($@) {
 285                         err($self, "response ->close error: $@");
 286                         $self->close; # idempotent
 287                 }
 288         }
 289         $close->();
 290 }
 291
 292 sub getline_response ($$$) {
 293         my ($self, $write, $close) = @_;
 294         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 295         $pull->();
 296 }
 297
 298 sub response_write {
 299         my ($self, $env, $res) = @_;
 300         my $alive = response_header_write($self, $env, $res);
 301         my $close = response_done_cb($self, $alive);
 302         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 303         if (defined(my $body = $res->[2])) {
 304                 if (ref $body eq 'ARRAY') {
 305                         $write->($_) foreach @$body;
 306                         $close->();
 307                 } else {
 308                         $self->{forward} = $body;
 309                         getline_response($self, $write, $close);
 310                 }
 311         } else {
 312                 # this is returned to the calling application:
 313                 Plack::Util::inline_object(write => $write, close => $close);
 314         }
 315 }
 316
 317 sub input_prepare {
 318         my ($self, $env) = @_;
 319         my $input;
 320         my $len = $env->{CONTENT_LENGTH};
 321         if ($len) {
 322                 if ($len > $MAX_REQUEST_BUFFER) {
 323                         quit($self, 413);
 324                         return;
 325                 }
 326                 open($input, '+>', undef);
 327         } elsif (env_chunked($env)) {
 328                 $len = CHUNK_START;
 329                 open($input, '+>', undef);
 330         } else {
 331                 $input = $null_io;
 332         }
 333
 334         # TODO: expire idle clients on ENFILE / EMFILE
 335         return unless $input;
 336
 337         $env->{'psgi.input'} = $input;
 338         $self->{env} = $env;
 339         $self->{input_left} = $len || 0;
 340 }
 341
 342 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 343
 344 sub err ($$) {
 345         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 346 }
 347
 348 sub write_err {
 349         my ($self, $len) = @_;
 350         my $msg = $! || '(zero write)';
 351         $msg .= " ($len bytes remaining)" if defined $len;
 352         err($self, "error buffering to input: $msg");
 353         quit($self, 500);
 354 }
 355
 356 sub recv_err {
 357         my ($self, $r, $len) = @_;
 358         return $self->close if (defined $r && $r == 0);
 359         if ($! == EAGAIN) {
 360                 $self->{input_left} = $len;
 361                 return $self->watch_in1;
 362         }
 363         err($self, "error reading for input: $! ($len bytes remaining)");
 364         quit($self, 500);
 365 }
 366
 367 sub read_input_chunked { # unlikely...
 368         my ($self) = @_;
 369         my $input = $self->{env}->{'psgi.input'};
 370         my $sock = $self->{sock};
 371         my $len = delete $self->{input_left};
 372         my $rbuf = \($self->{rbuf});
 373
 374         while (1) { # chunk start
 375                 if ($len == CHUNK_ZEND) {
 376                         $$rbuf =~ s/\A\r\n//s and
 377                                 return app_dispatch($self, $input);
 378                         return quit($self, 400) if length($$rbuf) > 2;
 379                 }
 380                 if ($len == CHUNK_END) {
 381                         if ($$rbuf =~ s/\A\r\n//s) {
 382                                 $len = CHUNK_START;
 383                         } elsif (length($$rbuf) > 2) {
 384                                 return quit($self, 400);
 385                         }
 386                 }
 387                 if ($len == CHUNK_START) {
 388                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 389                                 $len = hex $1;
 390                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 391                                         return quit($self, 413);
 392                                 }
 393                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 394                                 return quit($self, 400);
 395                         }
 396                         # will break from loop since $len >= 0
 397                 }
 398
 399                 if ($len < 0) { # chunk header is trickled, read more
 400                         my $off = length($$rbuf);
 401                         my $r = sysread($sock, $$rbuf, 8192, $off);
 402                         return recv_err($self, $r, $len) unless $r;
 403                         # (implicit) goto chunk_start if $r > 0;
 404                 }
 405                 $len = CHUNK_ZEND if $len == 0;
 406
 407                 # drain the current chunk
 408                 until ($len <= 0) {
 409                         if ($$rbuf ne '') {
 410                                 my $w = write_in_full($input, $rbuf, $len, 0);
 411                                 return write_err($self, "$len chunk") if !$w;
 412                                 $len -= $w;
 413                                 if ($len == 0) {
 414                                         # we may have leftover data to parse
 415                                         # in chunk
 416                                         $$rbuf = substr($$rbuf, $w);
 417                                         $len = CHUNK_END;
 418                                 } elsif ($len < 0) {
 419                                         die "BUG: len < 0: $len";
 420                                 } else {
 421                                         $$rbuf = '';
 422                                 }
 423                         }
 424                         if ($$rbuf eq '') {
 425                                 # read more of current chunk
 426                                 my $r = sysread($sock, $$rbuf, 8192);
 427                                 return recv_err($self, $r, $len) unless $r;
 428                         }
 429                 }
 430         }
 431 }
 432
 433 sub quit {
 434         my ($self, $status) = @_;
 435         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 436         $self->write(\$h);
 437         $self->close;
 438 }
 439
 440 sub close {
 441         my $self = $_[0];
 442         if (my $env = delete $self->{env}) {
 443                 delete $env->{'psgix.io'}; # prevent circular references
 444         }
 445         delete $self->{pull};
 446         if (my $forward = delete $self->{forward}) {
 447                 eval { $forward->close };
 448                 err($self, "forward ->close error: $@") if $@;
 449         }
 450         $self->SUPER::close; # PublicInbox::DS::close
 451 }
 452
 453 # for graceful shutdown in PublicInbox::Daemon:
 454 sub busy () {
 455         my ($self) = @_;
 456         ($self->{rbuf} ne '' || $self->{env} || $self->{wbuf});
 457 }
 458
 459 1;