lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 PublicInbox::DS->import(qw(msg_more write_in_full));
  23 use constant {
  24         CHUNK_START => -1,   # [a-f0-9]+\r\n
  25         CHUNK_END => -2,     # \r\n
  26         CHUNK_ZEND => -3,    # \r\n
  27         CHUNK_MAX_HDR => 256,
  28 };
  29
  30 my $pipelineq = [];
  31 my $pipet;
  32 sub process_pipelineq () {
  33         my $q = $pipelineq;
  34         $pipet = undef;
  35         $pipelineq = [];
  36         foreach (@$q) {
  37                 next unless $_->{sock};
  38                 rbuf_process($_);
  39         }
  40 }
  41
  42 # Use the same configuration parameter as git since this is primarily
  43 # a slow-client sponge for git-http-backend
  44 # TODO: support per-respository http.maxRequestBuffer somehow...
  45 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  46                         (10 * 1024 * 1024);
  47
  48 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  49 my $http_date;
  50 my $prev = 0;
  51 sub http_date () {
  52         my $now = time;
  53         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  54 }
  55
  56 sub new ($$$) {
  57         my ($class, $sock, $addr, $httpd) = @_;
  58         my $self = fields::new($class);
  59         $self->SUPER::new($sock);
  60         $self->{httpd} = $httpd;
  61         $self->{rbuf} = '';
  62         ($self->{remote_addr}, $self->{remote_port}) =
  63                 PublicInbox::Daemon::host_with_port($addr);
  64         $self->watch_read(1);
  65         $self;
  66 }
  67
  68 sub event_step { # called by PublicInbox::DS
  69         my ($self) = @_;
  70
  71         return unless $self->flush_write && $self->{sock};
  72
  73         # only read more requests if we've drained the write buffer,
  74         # otherwise we can be buffering infinitely w/o backpressure
  75
  76         return read_input($self) if defined $self->{env};
  77
  78         my $off = length($self->{rbuf});
  79         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  80         if (defined $r) {
  81                 return $self->close if $r == 0;
  82                 return rbuf_process($self);
  83         }
  84         return if $!{EAGAIN}; # no need to call watch_read(1) again
  85
  86         # common for clients to break connections without warning,
  87         # would be too noisy to log here:
  88         return $self->close;
  89 }
  90
  91 sub rbuf_process {
  92         my ($self) = @_;
  93
  94         my %env = %{$self->{httpd}->{env}}; # full hash copy
  95         my $r = parse_http_request($self->{rbuf}, \%env);
  96
  97         # We do not support Trailers in chunked requests, for now
  98         # (they are rarely-used and git (as of 2.7.2) does not use them)
  99         if ($r == -1 || $env{HTTP_TRAILER} ||
 100                         # this length-check is necessary for PURE_PERL=1:
 101                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
 102                 return quit($self, 400);
 103         }
 104         return $self->watch_read(1) if $r < 0; # incomplete
 105         $self->{rbuf} = substr($self->{rbuf}, $r);
 106
 107         my $len = input_prepare($self, \%env);
 108         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 109
 110         $len ? read_input($self) : app_dispatch($self);
 111 }
 112
 113 sub read_input ($) {
 114         my ($self) = @_;
 115         my $env = $self->{env};
 116         return if $env->{REMOTE_ADDR}; # in app dispatch
 117         return read_input_chunked($self) if env_chunked($env);
 118
 119         # env->{CONTENT_LENGTH} (identity)
 120         my $sock = $self->{sock};
 121         my $len = $self->{input_left};
 122         $self->{input_left} = undef;
 123         my $rbuf = \($self->{rbuf});
 124         my $input = $env->{'psgi.input'};
 125
 126         while ($len > 0) {
 127                 if ($$rbuf ne '') {
 128                         my $w = write_in_full($input, $rbuf, $len, 0);
 129                         return write_err($self, $len) unless $w;
 130                         $len -= $w;
 131                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 132                         if ($len == 0) { # next request may be pipelined
 133                                 $$rbuf = substr($$rbuf, $w);
 134                                 last;
 135                         }
 136                         $$rbuf = '';
 137                 }
 138                 my $r = sysread($sock, $$rbuf, 8192);
 139                 return recv_err($self, $r, $len) unless $r;
 140                 # continue looping if $r > 0;
 141         }
 142         app_dispatch($self, $input);
 143 }
 144
 145 sub app_dispatch {
 146         my ($self, $input) = @_;
 147         $self->watch_read(0);
 148         my $env = $self->{env};
 149         $env->{REMOTE_ADDR} = $self->{remote_addr};
 150         $env->{REMOTE_PORT} = $self->{remote_port};
 151         if (my $host = $env->{HTTP_HOST}) {
 152                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 153                 $env->{SERVER_NAME} = $host;
 154         }
 155         if (defined $input) {
 156                 sysseek($input, 0, SEEK_SET) or
 157                         die "BUG: psgi.input seek failed: $!";
 158         }
 159         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 160         # to do proper cleanup:
 161         $env->{'psgix.io'} = $self; # only for ->close
 162         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 163         eval {
 164                 if (ref($res) eq 'CODE') {
 165                         $res->(sub { response_write($self, $env, $_[0]) });
 166                 } else {
 167                         response_write($self, $env, $res);
 168                 }
 169         };
 170         $self->close if $@;
 171 }
 172
 173 sub response_header_write {
 174         my ($self, $env, $res) = @_;
 175         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 176         my $status = $res->[0];
 177         my $h = "$proto $status " . status_message($status) . "\r\n";
 178         my ($len, $chunked);
 179         my $headers = $res->[1];
 180
 181         for (my $i = 0; $i < @$headers; $i += 2) {
 182                 my $k = $headers->[$i];
 183                 my $v = $headers->[$i + 1];
 184                 next if $k =~ /\A(?:Connection|Date)\z/i;
 185
 186                 $len = $v if $k =~ /\AContent-Length\z/i;
 187                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 188                         $chunked = 1;
 189                 }
 190                 $h .= "$k: $v\r\n";
 191         }
 192
 193         my $conn = $env->{HTTP_CONNECTION} || '';
 194         my $term = defined($len) || $chunked;
 195         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 196         my $alive;
 197         if (!$term && $prot_persist) { # auto-chunk
 198                 $chunked = $alive = 2;
 199                 $h .= "Transfer-Encoding: chunked\r\n";
 200                 # no need for "Connection: keep-alive" with HTTP/1.1
 201         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 202                 $alive = 1;
 203                 $h .= "Connection: keep-alive\r\n";
 204         } else {
 205                 $alive = 0;
 206                 $h .= "Connection: close\r\n";
 207         }
 208         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 209
 210         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 211                 msg_more($self, $h);
 212         } else {
 213                 $self->write(\$h);
 214         }
 215         $alive;
 216 }
 217
 218 # middlewares such as Deflater may write empty strings
 219 sub chunked_wcb ($) {
 220         my ($self) = @_;
 221         sub {
 222                 return if $_[0] eq '';
 223                 msg_more($self, sprintf("%x\r\n", bytes::length($_[0])));
 224                 msg_more($self, $_[0]);
 225
 226                 # use $self->write(\"\n\n") if you care about real-time
 227                 # streaming responses, public-inbox WWW does not.
 228                 msg_more($self, "\r\n");
 229         }
 230 }
 231
 232 sub identity_wcb ($) {
 233         my ($self) = @_;
 234         sub { $self->write(\($_[0])) if $_[0] ne '' }
 235 }
 236
 237 sub next_request ($) {
 238         my ($self) = @_;
 239         if ($self->{rbuf} eq '') { # wait for next request
 240                 $self->watch_read(1);
 241         } else { # avoid recursion for pipelined requests
 242                 push @$pipelineq, $self;
 243                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 244         }
 245 }
 246
 247 sub response_done_cb ($$) {
 248         my ($self, $alive) = @_;
 249         sub {
 250                 my $env = $self->{env};
 251                 $self->{env} = undef;
 252                 $self->write(\"0\r\n\r\n") if $alive == 2;
 253                 $self->write(sub{$alive ? next_request($self) : $self->close});
 254         }
 255 }
 256
 257 sub getline_cb ($$$) {
 258         my ($self, $write, $close) = @_;
 259         local $/ = \8192;
 260         my $forward = $self->{forward};
 261         # limit our own running time for fairness with other
 262         # clients and to avoid buffering too much:
 263         if ($forward) {
 264                 my $buf = eval { $forward->getline };
 265                 if (defined $buf) {
 266                         $write->($buf); # may close in PublicInbox::DS::write
 267                         if ($self->{sock}) {
 268                                 my $next = $self->{pull};
 269                                 if ($self->{wbuf}) {
 270                                         $self->write($next);
 271                                 } else {
 272                                         PublicInbox::EvCleanup::asap($next);
 273                                 }
 274                                 return;
 275                         }
 276                 } elsif ($@) {
 277                         err($self, "response ->getline error: $@");
 278                         $forward = undef;
 279                         $self->close;
 280                 }
 281         }
 282
 283         $self->{forward} = $self->{pull} = undef;
 284         # avoid recursion
 285         if ($forward) {
 286                 eval { $forward->close };
 287                 if ($@) {
 288                         err($self, "response ->close error: $@");
 289                         $self->close; # idempotent
 290                 }
 291         }
 292         $close->();
 293 }
 294
 295 sub getline_response ($$$) {
 296         my ($self, $write, $close) = @_;
 297         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 298         $pull->();
 299 }
 300
 301 sub response_write {
 302         my ($self, $env, $res) = @_;
 303         my $alive = response_header_write($self, $env, $res);
 304         my $close = response_done_cb($self, $alive);
 305         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 306         if (defined(my $body = $res->[2])) {
 307                 if (ref $body eq 'ARRAY') {
 308                         $write->($_) foreach @$body;
 309                         $close->();
 310                 } else {
 311                         $self->{forward} = $body;
 312                         getline_response($self, $write, $close);
 313                 }
 314         } else {
 315                 # this is returned to the calling application:
 316                 Plack::Util::inline_object(write => $write, close => $close);
 317         }
 318 }
 319
 320 sub input_prepare {
 321         my ($self, $env) = @_;
 322         my $input;
 323         my $len = $env->{CONTENT_LENGTH};
 324         if ($len) {
 325                 if ($len > $MAX_REQUEST_BUFFER) {
 326                         quit($self, 413);
 327                         return;
 328                 }
 329                 open($input, '+>', undef);
 330         } elsif (env_chunked($env)) {
 331                 $len = CHUNK_START;
 332                 open($input, '+>', undef);
 333         } else {
 334                 $input = $null_io;
 335         }
 336
 337         # TODO: expire idle clients on ENFILE / EMFILE
 338         return unless $input;
 339
 340         $env->{'psgi.input'} = $input;
 341         $self->{env} = $env;
 342         $self->{input_left} = $len || 0;
 343 }
 344
 345 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 346
 347 sub err ($$) {
 348         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 349 }
 350
 351 sub write_err {
 352         my ($self, $len) = @_;
 353         my $msg = $! || '(zero write)';
 354         $msg .= " ($len bytes remaining)" if defined $len;
 355         err($self, "error buffering to input: $msg");
 356         quit($self, 500);
 357 }
 358
 359 sub recv_err {
 360         my ($self, $r, $len) = @_;
 361         return $self->close if (defined $r && $r == 0);
 362         if ($!{EAGAIN}) {
 363                 $self->{input_left} = $len;
 364                 return;
 365         }
 366         err($self, "error reading for input: $! ($len bytes remaining)");
 367         quit($self, 500);
 368 }
 369
 370 sub read_input_chunked { # unlikely...
 371         my ($self) = @_;
 372         my $input = $self->{env}->{'psgi.input'};
 373         my $sock = $self->{sock};
 374         my $len = $self->{input_left};
 375         $self->{input_left} = undef;
 376         my $rbuf = \($self->{rbuf});
 377
 378         while (1) { # chunk start
 379                 if ($len == CHUNK_ZEND) {
 380                         $$rbuf =~ s/\A\r\n//s and
 381                                 return app_dispatch($self, $input);
 382                         return quit($self, 400) if length($$rbuf) > 2;
 383                 }
 384                 if ($len == CHUNK_END) {
 385                         if ($$rbuf =~ s/\A\r\n//s) {
 386                                 $len = CHUNK_START;
 387                         } elsif (length($$rbuf) > 2) {
 388                                 return quit($self, 400);
 389                         }
 390                 }
 391                 if ($len == CHUNK_START) {
 392                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 393                                 $len = hex $1;
 394                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 395                                         return quit($self, 413);
 396                                 }
 397                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 398                                 return quit($self, 400);
 399                         }
 400                         # will break from loop since $len >= 0
 401                 }
 402
 403                 if ($len < 0) { # chunk header is trickled, read more
 404                         my $off = length($$rbuf);
 405                         my $r = sysread($sock, $$rbuf, 8192, $off);
 406                         return recv_err($self, $r, $len) unless $r;
 407                         # (implicit) goto chunk_start if $r > 0;
 408                 }
 409                 $len = CHUNK_ZEND if $len == 0;
 410
 411                 # drain the current chunk
 412                 until ($len <= 0) {
 413                         if ($$rbuf ne '') {
 414                                 my $w = write_in_full($input, $rbuf, $len, 0);
 415                                 return write_err($self, "$len chunk") if !$w;
 416                                 $len -= $w;
 417                                 if ($len == 0) {
 418                                         # we may have leftover data to parse
 419                                         # in chunk
 420                                         $$rbuf = substr($$rbuf, $w);
 421                                         $len = CHUNK_END;
 422                                 } elsif ($len < 0) {
 423                                         die "BUG: len < 0: $len";
 424                                 } else {
 425                                         $$rbuf = '';
 426                                 }
 427                         }
 428                         if ($$rbuf eq '') {
 429                                 # read more of current chunk
 430                                 my $r = sysread($sock, $$rbuf, 8192);
 431                                 return recv_err($self, $r, $len) unless $r;
 432                         }
 433                 }
 434         }
 435 }
 436
 437 sub quit {
 438         my ($self, $status) = @_;
 439         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 440         $self->write(\$h);
 441         $self->close;
 442 }
 443
 444 sub close {
 445         my $self = shift;
 446         my $forward = $self->{forward};
 447         my $env = $self->{env};
 448         delete $env->{'psgix.io'} if $env; # prevent circular references
 449         $self->{pull} = $self->{forward} = $self->{env} = undef;
 450         if ($forward) {
 451                 eval { $forward->close };
 452                 err($self, "forward ->close error: $@") if $@;
 453         }
 454         $self->SUPER::close(@_);
 455 }
 456
 457 # for graceful shutdown in PublicInbox::Daemon:
 458 sub busy () {
 459         my ($self) = @_;
 460         ($self->{rbuf} ne '' || $self->{env} || $self->{wbuf});
 461 }
 462
 463 1;