lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use Scalar::Util qw(weaken);
  20 use IO::File;
  21 use constant {
  22         CHUNK_START => -1,   # [a-f0-9]+\r\n
  23         CHUNK_END => -2,     # \r\n
  24         CHUNK_ZEND => -3,    # \r\n
  25         CHUNK_MAX_HDR => 256,
  26 };
  27
  28 # FIXME: duplicated code with NNTP.pm, layering violation
  29 my $WEAKEN = {}; # string(inbox) -> inbox
  30 my $weakt;
  31 sub weaken_task () {
  32         $weakt = undef;
  33         $_->weaken_all for values %$WEAKEN;
  34         $WEAKEN = {};
  35 }
  36
  37 my $pipelineq = [];
  38 my $pipet;
  39 sub process_pipelineq () {
  40         my $q = $pipelineq;
  41         $pipet = undef;
  42         $pipelineq = [];
  43         foreach (@$q) {
  44                 next if $_->{closed};
  45                 rbuf_process($_);
  46         }
  47 }
  48
  49 # Use the same configuration parameter as git since this is primarily
  50 # a slow-client sponge for git-http-backend
  51 # TODO: support per-respository http.maxRequestBuffer somehow...
  52 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  53                         (10 * 1024 * 1024);
  54
  55 my $null_io = IO::File->new('/dev/null', '<');
  56 my $http_date;
  57 my $prev = 0;
  58 sub http_date () {
  59         my $now = time;
  60         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  61 }
  62
  63 sub new ($$$) {
  64         my ($class, $sock, $addr, $httpd) = @_;
  65         my $self = fields::new($class);
  66         $self->SUPER::new($sock);
  67         $self->{httpd} = $httpd;
  68         $self->{rbuf} = '';
  69         ($self->{remote_addr}, $self->{remote_port}) =
  70                 PublicInbox::Daemon::host_with_port($addr);
  71         $self->watch_read(1);
  72         $self;
  73 }
  74
  75 sub event_read { # called by Danga::Socket
  76         my ($self) = @_;
  77
  78         return event_read_input($self) if defined $self->{env};
  79
  80         my $off = length($self->{rbuf});
  81         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  82         if (defined $r) {
  83                 return $self->close if $r == 0;
  84                 return rbuf_process($self);
  85         }
  86         return if $!{EAGAIN}; # no need to call watch_read(1) again
  87
  88         # common for clients to break connections without warning,
  89         # would be too noisy to log here:
  90         return $self->close;
  91 }
  92
  93 sub rbuf_process {
  94         my ($self) = @_;
  95
  96         my %env = %{$self->{httpd}->{env}}; # full hash copy
  97         my $r = parse_http_request($self->{rbuf}, \%env);
  98
  99         # We do not support Trailers in chunked requests, for now
 100         # (they are rarely-used and git (as of 2.7.2) does not use them)
 101         if ($r == -1 || $env{HTTP_TRAILER} ||
 102                         # this length-check is necessary for PURE_PERL=1:
 103                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
 104                 return quit($self, 400);
 105         }
 106         return $self->watch_read(1) if $r < 0; # incomplete
 107         $self->{rbuf} = substr($self->{rbuf}, $r);
 108
 109         my $len = input_prepare($self, \%env);
 110         defined $len or return write_err($self); # EMFILE/ENFILE
 111
 112         $len ? event_read_input($self) : app_dispatch($self);
 113 }
 114
 115 sub event_read_input ($) {
 116         my ($self) = @_;
 117         my $env = $self->{env};
 118         return event_read_input_chunked($self) if env_chunked($env);
 119
 120         # env->{CONTENT_LENGTH} (identity)
 121         my $sock = $self->{sock};
 122         my $len = $self->{input_left};
 123         $self->{input_left} = undef;
 124         my $rbuf = \($self->{rbuf});
 125         my $input = $env->{'psgi.input'};
 126
 127         while ($len > 0) {
 128                 if ($$rbuf ne '') {
 129                         my $w = write_in_full($input, $rbuf, $len);
 130                         return write_err($self) unless $w;
 131                         $len -= $w;
 132                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 133                         if ($len == 0) { # next request may be pipelined
 134                                 $$rbuf = substr($$rbuf, $w);
 135                                 last;
 136                         }
 137                         $$rbuf = '';
 138                 }
 139                 my $r = sysread($sock, $$rbuf, 8192);
 140                 return recv_err($self, $r, $len) unless $r;
 141                 # continue looping if $r > 0;
 142         }
 143         app_dispatch($self, $input);
 144 }
 145
 146 sub app_dispatch {
 147         my ($self, $input) = @_;
 148         $self->watch_read(0);
 149         my $env = $self->{env};
 150         $env->{REMOTE_ADDR} = $self->{remote_addr};
 151         $env->{REMOTE_PORT} = $self->{remote_port};
 152         if (my $host = $env->{HTTP_HOST}) {
 153                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 154                 $env->{SERVER_NAME} = $host;
 155         }
 156         if (defined $input) {
 157                 sysseek($input, 0, SEEK_SET) or
 158                         die "BUG: psgi.input seek failed: $!";
 159         }
 160         # note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
 161         # to do proper cleanup:
 162         $env->{'psgix.io'} = $self; # only for ->close
 163         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 164         eval {
 165                 if (ref($res) eq 'CODE') {
 166                         $res->(sub { response_write($self, $env, $_[0]) });
 167                 } else {
 168                         response_write($self, $env, $res);
 169                 }
 170         };
 171         $self->close if $@;
 172 }
 173
 174 sub response_header_write {
 175         my ($self, $env, $res) = @_;
 176         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 177         my $status = $res->[0];
 178         my $h = "$proto $status " . status_message($status) . "\r\n";
 179         my ($len, $chunked);
 180         my $headers = $res->[1];
 181
 182         for (my $i = 0; $i < @$headers; $i += 2) {
 183                 my $k = $headers->[$i];
 184                 my $v = $headers->[$i + 1];
 185                 next if $k =~ /\A(?:Connection|Date)\z/i;
 186
 187                 $len = $v if $k =~ /\AContent-Length\z/i;
 188                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 189                         $chunked = 1;
 190                 }
 191                 $h .= "$k: $v\r\n";
 192         }
 193
 194         my $conn = $env->{HTTP_CONNECTION} || '';
 195         my $term = defined($len) || $chunked;
 196         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 197         my $alive;
 198         if (!$term && $prot_persist) { # auto-chunk
 199                 $chunked = $alive = 2;
 200                 $h .= "Transfer-Encoding: chunked\r\n";
 201                 # no need for "Connection: keep-alive" with HTTP/1.1
 202         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 203                 $alive = 1;
 204                 $h .= "Connection: keep-alive\r\n";
 205         } else {
 206                 $alive = 0;
 207                 $h .= "Connection: close\r\n";
 208         }
 209         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 210
 211         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 212                 more($self, $h);
 213         } else {
 214                 $self->write($h);
 215         }
 216         $alive;
 217 }
 218
 219 # middlewares such as Deflater may write empty strings
 220 sub chunked_wcb ($) {
 221         my ($self) = @_;
 222         sub {
 223                 return if $_[0] eq '';
 224                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 225                 more($self, $_[0]);
 226                 $self->write("\r\n");
 227         }
 228 }
 229
 230 sub identity_wcb ($) {
 231         my ($self) = @_;
 232         sub { $self->write(\($_[0])) if $_[0] ne '' }
 233 }
 234
 235 sub next_request ($) {
 236         my ($self) = @_;
 237         $self->watch_write(0);
 238         if ($self->{rbuf} eq '') { # wait for next request
 239                 $self->watch_read(1);
 240         } else { # avoid recursion for pipelined requests
 241                 push @$pipelineq, $self;
 242                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 243         }
 244 }
 245
 246 sub response_done ($$) {
 247         my ($self, $alive) = @_;
 248         my $env = $self->{env};
 249         $self->{env} = undef;
 250         $self->write("0\r\n\r\n") if $alive == 2;
 251         $self->write(sub { $alive ? next_request($self) : $self->close });
 252
 253         # FIXME: layering violation
 254         if (my $obj = $env->{'pi-httpd.inbox'}) {
 255                 # grace period for reaping resources
 256                 $WEAKEN->{"$obj"} = $obj;
 257                 PublicInbox::EvCleanup::later(*weaken_task);
 258         }
 259 }
 260
 261 sub getline_response {
 262         my ($self, $body, $write, $close) = @_;
 263         $self->{forward} = $body;
 264         weaken($self);
 265         my $pull = $self->{pull} = sub {
 266                 local $/ = \8192;
 267                 my $forward = $self->{forward};
 268                 # limit our own running time for fairness with other
 269                 # clients and to avoid buffering too much:
 270                 my $n = 100;
 271                 while ($forward && defined(my $buf = $forward->getline)) {
 272                         $write->($buf);
 273                         last if $self->{closed};
 274                         if ((--$n) <= 0 || $self->{write_buf_size}) {
 275                                 $self->write($self->{pull});
 276                                 return;
 277                         }
 278                 }
 279                 $self->{forward} = $self->{pull} = undef;
 280                 $forward->close if $forward; # avoid recursion
 281                 $close->();
 282         };
 283         $pull->();
 284 }
 285
 286 sub response_write {
 287         my ($self, $env, $res) = @_;
 288         my $alive = response_header_write($self, $env, $res);
 289
 290         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 291         my $close = sub { response_done($self, $alive) };
 292         if (defined(my $body = $res->[2])) {
 293                 if (ref $body eq 'ARRAY') {
 294                         $write->($_) foreach @$body;
 295                         $close->();
 296                 } else {
 297                         getline_response($self, $body, $write, $close);
 298                 }
 299         } else {
 300                 # this is returned to the calling application:
 301                 Plack::Util::inline_object(write => $write, close => $close);
 302         }
 303 }
 304
 305 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 306 sub more ($$) {
 307         my $self = $_[0];
 308         return if $self->{closed};
 309         if (MSG_MORE && !$self->{write_buf_size}) {
 310                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 311                 if (defined $n) {
 312                         my $dlen = length($_[1]);
 313                         return 1 if $n == $dlen; # all done!
 314                         $_[1] = substr($_[1], $n, $dlen - $n);
 315                         # fall through to normal write:
 316                 }
 317         }
 318         $self->write($_[1]);
 319 }
 320
 321 sub input_prepare {
 322         my ($self, $env) = @_;
 323         my $input = $null_io;
 324         my $len = $env->{CONTENT_LENGTH};
 325         if ($len) {
 326                 if ($len > $MAX_REQUEST_BUFFER) {
 327                         quit($self, 413);
 328                         return;
 329                 }
 330                 $input = IO::File->new_tmpfile;
 331         } elsif (env_chunked($env)) {
 332                 $len = CHUNK_START;
 333                 $input = IO::File->new_tmpfile;
 334         }
 335
 336         # TODO: expire idle clients on ENFILE / EMFILE
 337         return unless $input;
 338
 339         $env->{'psgi.input'} = $input;
 340         $self->{env} = $env;
 341         $self->{input_left} = $len || 0;
 342 }
 343
 344 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 345
 346 sub write_err {
 347         my ($self) = @_;
 348         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 349         my $msg = $! || '(zero write)';
 350         $err->print("error buffering to input: $msg\n");
 351         quit($self, 500);
 352 }
 353
 354 sub recv_err {
 355         my ($self, $r, $len) = @_;
 356         return $self->close if (defined $r && $r == 0);
 357         if ($!{EAGAIN}) {
 358                 $self->{input_left} = $len;
 359                 return;
 360         }
 361         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 362         $err->print("error reading for input: $! ($len bytes remaining)\n");
 363         quit($self, 500);
 364 }
 365
 366 sub write_in_full {
 367         my ($fh, $rbuf, $len) = @_;
 368         my $rv = 0;
 369         my $off = 0;
 370         while ($len > 0) {
 371                 my $w = syswrite($fh, $$rbuf, $len, $off);
 372                 return ($rv ? $rv : $w) unless $w; # undef or 0
 373                 $rv += $w;
 374                 $off += $w;
 375                 $len -= $w;
 376         }
 377         $rv
 378 }
 379
 380 sub event_read_input_chunked { # unlikely...
 381         my ($self) = @_;
 382         my $input = $self->{env}->{'psgi.input'};
 383         my $sock = $self->{sock};
 384         my $len = $self->{input_left};
 385         $self->{input_left} = undef;
 386         my $rbuf = \($self->{rbuf});
 387
 388         while (1) { # chunk start
 389                 if ($len == CHUNK_ZEND) {
 390                         $$rbuf =~ s/\A\r\n//s and
 391                                 return app_dispatch($self, $input);
 392                         return quit($self, 400) if length($$rbuf) > 2;
 393                 }
 394                 if ($len == CHUNK_END) {
 395                         if ($$rbuf =~ s/\A\r\n//s) {
 396                                 $len = CHUNK_START;
 397                         } elsif (length($$rbuf) > 2) {
 398                                 return quit($self, 400);
 399                         }
 400                 }
 401                 if ($len == CHUNK_START) {
 402                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 403                                 $len = hex $1;
 404                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 405                                         return quit($self, 413);
 406                                 }
 407                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 408                                 return quit($self, 400);
 409                         }
 410                         # will break from loop since $len >= 0
 411                 }
 412
 413                 if ($len < 0) { # chunk header is trickled, read more
 414                         my $off = length($$rbuf);
 415                         my $r = sysread($sock, $$rbuf, 8192, $off);
 416                         return recv_err($self, $r, $len) unless $r;
 417                         # (implicit) goto chunk_start if $r > 0;
 418                 }
 419                 $len = CHUNK_ZEND if $len == 0;
 420
 421                 # drain the current chunk
 422                 until ($len <= 0) {
 423                         if ($$rbuf ne '') {
 424                                 my $w = write_in_full($input, $rbuf, $len);
 425                                 return write_err($self) unless $w;
 426                                 $len -= $w;
 427                                 if ($len == 0) {
 428                                         # we may have leftover data to parse
 429                                         # in chunk
 430                                         $$rbuf = substr($$rbuf, $w);
 431                                         $len = CHUNK_END;
 432                                 } elsif ($len < 0) {
 433                                         die "BUG: len < 0: $len";
 434                                 } else {
 435                                         $$rbuf = '';
 436                                 }
 437                         }
 438                         if ($$rbuf eq '') {
 439                                 # read more of current chunk
 440                                 my $r = sysread($sock, $$rbuf, 8192);
 441                                 return recv_err($self, $r, $len) unless $r;
 442                         }
 443                 }
 444         }
 445 }
 446
 447 sub quit {
 448         my ($self, $status) = @_;
 449         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 450         $self->write($h);
 451         $self->close;
 452 }
 453
 454 # callbacks for Danga::Socket
 455
 456 sub event_hup { $_[0]->close }
 457 sub event_err { $_[0]->close }
 458
 459 sub close {
 460         my $self = shift;
 461         my $forward = $self->{forward};
 462         my $env = $self->{env};
 463         delete $env->{'psgix.io'} if $env; # prevent circular referernces
 464         $self->{pull} = $self->{forward} = $self->{env} = undef;
 465         $forward->close if $forward;
 466         $self->SUPER::close(@_);
 467 }
 468
 469 # for graceful shutdown in PublicInbox::Daemon:
 470 sub busy () {
 471         my ($self) = @_;
 472         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 473 }
 474
 475 1;