lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port);
  15 use Fcntl qw(:seek);
  16 use HTTP::Parser::XS qw(parse_http_request); # supports pure Perl fallback
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 my $null_io = IO::File->new('/dev/null', '<');
  28 my $http_date;
  29 my $prev = 0;
  30 sub http_date () {
  31         my $now = time;
  32         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  33 }
  34
  35 sub new ($$$) {
  36         my ($class, $sock, $addr, $httpd) = @_;
  37         my $self = fields::new($class);
  38         $self->SUPER::new($sock);
  39         $self->{httpd} = $httpd;
  40         $self->{rbuf} = '';
  41         ($self->{remote_addr}, $self->{remote_port}) =
  42                 PublicInbox::Daemon::host_with_port($addr);
  43         $self->watch_read(1);
  44         $self;
  45 }
  46
  47 sub event_read { # called by Danga::Socket
  48         my ($self) = @_;
  49
  50         return event_read_input($self) if defined $self->{env};
  51
  52         my $off = length($self->{rbuf});
  53         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  54         if (defined $r) {
  55                 return $self->close if $r == 0;
  56                 return rbuf_process($self);
  57         }
  58         return if $!{EAGAIN}; # no need to call watch_read(1) again
  59
  60         # common for clients to break connections without warning,
  61         # would be too noisy to log here:
  62         return $self->close;
  63 }
  64
  65 sub rbuf_process {
  66         my ($self) = @_;
  67
  68         my %env = %{$self->{httpd}->{env}}; # full hash copy
  69         my $r = parse_http_request($self->{rbuf}, \%env);
  70
  71         # We do not support Trailers in chunked requests, for now
  72         # (they are rarely-used and git (as of 2.7.2) does not use them)
  73         if ($r == -1 || $env{HTTP_TRAILER} ||
  74                         # this length-check is necessary for PURE_PERL=1:
  75                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  76                 return quit($self, 400);
  77         }
  78         return $self->watch_read(1) if $r < 0; # incomplete
  79         $self->{rbuf} = substr($self->{rbuf}, $r);
  80
  81         my $len = input_prepare($self, \%env);
  82         defined $len or return write_err($self); # EMFILE/ENFILE
  83
  84         $len ? event_read_input($self) : app_dispatch($self);
  85 }
  86
  87 sub event_read_input ($) {
  88         my ($self) = @_;
  89         my $env = $self->{env};
  90         return event_read_input_chunked($self) if env_chunked($env);
  91
  92         # env->{CONTENT_LENGTH} (identity)
  93         my $sock = $self->{sock};
  94         my $len = $self->{input_left};
  95         $self->{input_left} = undef;
  96         my $rbuf = \($self->{rbuf});
  97         my $input = $env->{'psgi.input'};
  98
  99         while ($len > 0) {
 100                 if ($$rbuf ne '') {
 101                         my $w = write_in_full($input, $rbuf, $len);
 102                         return write_err($self) unless $w;
 103                         $len -= $w;
 104                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 105                         if ($len == 0) { # next request may be pipelined
 106                                 $$rbuf = substr($$rbuf, $w);
 107                                 last;
 108                         }
 109                         $$rbuf = '';
 110                 }
 111                 my $r = sysread($sock, $$rbuf, 8192);
 112                 return recv_err($self, $r, $len) unless $r;
 113                 # continue looping if $r > 0;
 114         }
 115         app_dispatch($self);
 116 }
 117
 118 sub app_dispatch ($) {
 119         my ($self) = @_;
 120         $self->watch_read(0);
 121         my $env = $self->{env};
 122         $env->{REMOTE_ADDR} = $self->{remote_addr};
 123         $env->{REMOTE_PORT} = $self->{remote_port};
 124         if (my $host = $env->{HTTP_HOST}) {
 125                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 126                 $env->{SERVER_NAME} = $host;
 127         }
 128
 129         sysseek($env->{'psgi.input'}, 0, SEEK_SET) or
 130                         die "BUG: psgi.input seek failed: $!";
 131
 132         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 133         eval {
 134                 if (ref($res) eq 'CODE') {
 135                         $res->(sub { response_write($self, $env, $_[0]) });
 136                 } else {
 137                         response_write($self, $env, $res);
 138                 }
 139         };
 140         $self->close if $@;
 141 }
 142
 143 sub response_header_write {
 144         my ($self, $env, $res) = @_;
 145         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 146         my $status = $res->[0];
 147         my $h = "$proto $status " . status_message($status) . "\r\n";
 148         my ($len, $chunked);
 149         my $headers = $res->[1];
 150
 151         for (my $i = 0; $i < @$headers; $i += 2) {
 152                 my $k = $headers->[$i];
 153                 my $v = $headers->[$i + 1];
 154                 next if $k =~ /\A(?:Connection|Date)\z/i;
 155
 156                 $len = $v if $k =~ /\AContent-Length\z/i;
 157                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 158                         $chunked = 1;
 159                 }
 160
 161                 $h .= "$k: $v\r\n";
 162         }
 163
 164         my $conn = $env->{HTTP_CONNECTION} || '';
 165         my $alive = (defined($len) || $chunked) &&
 166                         ($proto eq 'HTTP/1.1' && $conn !~ /\bclose\b/i) ||
 167                         ($conn =~ /\bkeep-alive\b/i);
 168
 169         $h .= 'Connection: ' . ($alive ? 'keep-alive' : 'close');
 170         $h .= "\r\nDate: " . http_date() . "\r\n\r\n";
 171
 172         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 173                 more($self, $h);
 174         } else {
 175                 $self->write($h);
 176         }
 177         ($alive, $chunked);
 178 }
 179
 180 sub response_write {
 181         my ($self, $env, $res) = @_;
 182         my ($alive, $chunked) = response_header_write($self, $env, $res);
 183         my $write = sub { $self->write($_[0]) };
 184         my $close = sub {
 185                 if ($alive) {
 186                         $self->event_write; # watch for readability if done
 187                 } else {
 188                         $self->write(sub { $self->close });
 189                 }
 190                 $self->{env} = undef;
 191         };
 192
 193         if (defined $res->[2]) {
 194                 Plack::Util::foreach($res->[2], $write);
 195                 $close->();
 196         } else {
 197                 # this is returned to the calling application:
 198                 Plack::Util::inline_object(write => $write, close => $close);
 199         }
 200 }
 201
 202 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 203 sub more ($$) {
 204         my $self = $_[0];
 205         if (MSG_MORE && !$self->{write_buf_size}) {
 206                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 207                 if (defined $n) {
 208                         my $dlen = length($_[1]);
 209                         return 1 if $n == $dlen; # all done!
 210                         $_[1] = substr($_[1], $n, $dlen - $n);
 211                         # fall through to normal write:
 212                 }
 213         }
 214         $self->write($_[1]);
 215 }
 216
 217 # overrides existing Danga::Socket method
 218 sub event_write {
 219         my ($self) = @_;
 220         # only continue watching for readability when we are done writing:
 221         return if $self->write(undef) != 1;
 222
 223         if ($self->{rbuf} eq '') { # wait for next request
 224                 $self->watch_read(1);
 225         } else { # avoid recursion for pipelined requests
 226                 Danga::Socket->AddTimer(0, sub { rbuf_process($self) });
 227         }
 228 }
 229
 230 sub input_prepare {
 231         my ($self, $env) = @_;
 232         my $input = $null_io;
 233         my $len = $env->{CONTENT_LENGTH};
 234         if ($len) {
 235                 $input = IO::File->new_tmpfile;
 236         } elsif (env_chunked($env)) {
 237                 $len = CHUNK_START;
 238                 $input = IO::File->new_tmpfile;
 239         }
 240
 241         # TODO: expire idle clients on ENFILE / EMFILE
 242         return unless $input;
 243
 244         binmode $input;
 245         $env->{'psgi.input'} = $input;
 246         $self->{env} = $env;
 247         $self->{input_left} = $len || 0;
 248 }
 249
 250 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 251
 252 sub write_err {
 253         my ($self) = @_;
 254         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 255         my $msg = $! || '(zero write)';
 256         $err->print("error buffering to input: $msg\n");
 257         quit($self, 500);
 258 }
 259
 260 sub recv_err {
 261         my ($self, $r, $len) = @_;
 262         return $self->close if (defined $r && $r == 0);
 263         if ($!{EAGAIN}) {
 264                 $self->{input_left} = $len;
 265                 return;
 266         }
 267         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 268         $err->print("error reading for input: $! ($len bytes remaining)\n");
 269         quit($self, 500);
 270 }
 271
 272 sub write_in_full {
 273         my ($fh, $rbuf, $len) = @_;
 274         my $rv = 0;
 275         my $off = 0;
 276         while ($len > 0) {
 277                 my $w = syswrite($fh, $$rbuf, $len, $off);
 278                 return ($rv ? $rv : $w) unless $w; # undef or 0
 279                 $rv += $w;
 280                 $off += $w;
 281                 $len -= $w;
 282         }
 283         $rv
 284 }
 285
 286 sub event_read_input_chunked { # unlikely...
 287         my ($self) = @_;
 288         my $input = $self->{env}->{'psgi.input'};
 289         my $sock = $self->{sock};
 290         my $len = $self->{input_left};
 291         $self->{input_left} = undef;
 292         my $rbuf = \($self->{rbuf});
 293
 294         while (1) { # chunk start
 295                 if ($len == CHUNK_ZEND) {
 296                         return app_dispatch($self) if $$rbuf =~ s/\A\r\n//s;
 297                         return quit($self, 400) if length($$rbuf) > 2;
 298                 }
 299                 if ($len == CHUNK_END) {
 300                         if ($$rbuf =~ s/\A\r\n//s) {
 301                                 $len = CHUNK_START;
 302                         } elsif (length($$rbuf) > 2) {
 303                                 return quit($self, 400);
 304                         }
 305                 }
 306                 if ($len == CHUNK_START) {
 307                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 308                                 $len = hex $1;
 309                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 310                                 return quit($self, 400);
 311                         }
 312                         # will break from loop since $len >= 0
 313                 }
 314
 315                 if ($len < 0) { # chunk header is trickled, read more
 316                         my $off = length($$rbuf);
 317                         my $r = sysread($sock, $$rbuf, 8192, $off);
 318                         return recv_err($self, $r, $len) unless $r;
 319                         # (implicit) goto chunk_start if $r > 0;
 320                 }
 321                 $len = CHUNK_ZEND if $len == 0;
 322
 323                 # drain the current chunk
 324                 until ($len <= 0) {
 325                         if ($$rbuf ne '') {
 326                                 my $w = write_in_full($input, $rbuf, $len);
 327                                 return write_err($self) unless $w;
 328                                 $len -= $w;
 329                                 if ($len == 0) {
 330                                         # we may have leftover data to parse
 331                                         # in chunk
 332                                         $$rbuf = substr($$rbuf, $w);
 333                                         $len = CHUNK_END;
 334                                 } elsif ($len < 0) {
 335                                         die "BUG: len < 0: $len";
 336                                 } else {
 337                                         $$rbuf = '';
 338                                 }
 339                         }
 340                         if ($$rbuf eq '') {
 341                                 # read more of current chunk
 342                                 my $r = sysread($sock, $$rbuf, 8192);
 343                                 return recv_err($self, $r, $len) unless $r;
 344                         }
 345                 }
 346         }
 347 }
 348
 349 sub quit {
 350         my ($self, $status) = @_;
 351         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 352         $self->write($h);
 353         $self->close;
 354 }
 355
 356 # callbacks for Danga::Socket
 357
 358 sub event_hup { $_[0]->close }
 359 sub event_err { $_[0]->close }
 360
 361 # for graceful shutdown in PublicInbox::Daemon:
 362 sub busy () {
 363         my ($self) = @_;
 364         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 365 }
 366
 367 1;