lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 use constant {
  23         CHUNK_START => -1,   # [a-f0-9]+\r\n
  24         CHUNK_END => -2,     # \r\n
  25         CHUNK_ZEND => -3,    # \r\n
  26         CHUNK_MAX_HDR => 256,
  27 };
  28
  29 my $pipelineq = [];
  30 my $pipet;
  31 sub process_pipelineq () {
  32         my $q = $pipelineq;
  33         $pipet = undef;
  34         $pipelineq = [];
  35         foreach (@$q) {
  36                 next unless $_->{sock};
  37                 rbuf_process($_);
  38         }
  39 }
  40
  41 # Use the same configuration parameter as git since this is primarily
  42 # a slow-client sponge for git-http-backend
  43 # TODO: support per-respository http.maxRequestBuffer somehow...
  44 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  45                         (10 * 1024 * 1024);
  46
  47 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  48 my $http_date;
  49 my $prev = 0;
  50 sub http_date () {
  51         my $now = time;
  52         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  53 }
  54
  55 sub new ($$$) {
  56         my ($class, $sock, $addr, $httpd) = @_;
  57         my $self = fields::new($class);
  58         $self->SUPER::new($sock);
  59         $self->{httpd} = $httpd;
  60         $self->{rbuf} = '';
  61         ($self->{remote_addr}, $self->{remote_port}) =
  62                 PublicInbox::Daemon::host_with_port($addr);
  63         $self->watch_read(1);
  64         $self;
  65 }
  66
  67 sub event_step { # called by PublicInbox::DS
  68         my ($self) = @_;
  69
  70         return unless $self->flush_write && $self->{sock};
  71
  72         # only read more requests if we've drained the write buffer,
  73         # otherwise we can be buffering infinitely w/o backpressure
  74
  75         return read_input($self) if defined $self->{env};
  76
  77         my $off = length($self->{rbuf});
  78         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  79         if (defined $r) {
  80                 return $self->close if $r == 0;
  81                 return rbuf_process($self);
  82         }
  83         return if $!{EAGAIN}; # no need to call watch_read(1) again
  84
  85         # common for clients to break connections without warning,
  86         # would be too noisy to log here:
  87         return $self->close;
  88 }
  89
  90 sub rbuf_process {
  91         my ($self) = @_;
  92
  93         my %env = %{$self->{httpd}->{env}}; # full hash copy
  94         my $r = parse_http_request($self->{rbuf}, \%env);
  95
  96         # We do not support Trailers in chunked requests, for now
  97         # (they are rarely-used and git (as of 2.7.2) does not use them)
  98         if ($r == -1 || $env{HTTP_TRAILER} ||
  99                         # this length-check is necessary for PURE_PERL=1:
 100                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
 101                 return quit($self, 400);
 102         }
 103         return $self->watch_read(1) if $r < 0; # incomplete
 104         $self->{rbuf} = substr($self->{rbuf}, $r);
 105
 106         my $len = input_prepare($self, \%env);
 107         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 108
 109         $len ? read_input($self) : app_dispatch($self);
 110 }
 111
 112 sub read_input ($) {
 113         my ($self) = @_;
 114         my $env = $self->{env};
 115         return if $env->{REMOTE_ADDR}; # in app dispatch
 116         return read_input_chunked($self) if env_chunked($env);
 117
 118         # env->{CONTENT_LENGTH} (identity)
 119         my $sock = $self->{sock};
 120         my $len = $self->{input_left};
 121         $self->{input_left} = undef;
 122         my $rbuf = \($self->{rbuf});
 123         my $input = $env->{'psgi.input'};
 124
 125         while ($len > 0) {
 126                 if ($$rbuf ne '') {
 127                         my $w = write_in_full($input, $rbuf, $len);
 128                         return write_err($self, $len) unless $w;
 129                         $len -= $w;
 130                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 131                         if ($len == 0) { # next request may be pipelined
 132                                 $$rbuf = substr($$rbuf, $w);
 133                                 last;
 134                         }
 135                         $$rbuf = '';
 136                 }
 137                 my $r = sysread($sock, $$rbuf, 8192);
 138                 return recv_err($self, $r, $len) unless $r;
 139                 # continue looping if $r > 0;
 140         }
 141         app_dispatch($self, $input);
 142 }
 143
 144 sub app_dispatch {
 145         my ($self, $input) = @_;
 146         $self->watch_read(0);
 147         my $env = $self->{env};
 148         $env->{REMOTE_ADDR} = $self->{remote_addr};
 149         $env->{REMOTE_PORT} = $self->{remote_port};
 150         if (my $host = $env->{HTTP_HOST}) {
 151                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 152                 $env->{SERVER_NAME} = $host;
 153         }
 154         if (defined $input) {
 155                 sysseek($input, 0, SEEK_SET) or
 156                         die "BUG: psgi.input seek failed: $!";
 157         }
 158         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 159         # to do proper cleanup:
 160         $env->{'psgix.io'} = $self; # only for ->close
 161         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 162         eval {
 163                 if (ref($res) eq 'CODE') {
 164                         $res->(sub { response_write($self, $env, $_[0]) });
 165                 } else {
 166                         response_write($self, $env, $res);
 167                 }
 168         };
 169         $self->close if $@;
 170 }
 171
 172 sub response_header_write {
 173         my ($self, $env, $res) = @_;
 174         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 175         my $status = $res->[0];
 176         my $h = "$proto $status " . status_message($status) . "\r\n";
 177         my ($len, $chunked);
 178         my $headers = $res->[1];
 179
 180         for (my $i = 0; $i < @$headers; $i += 2) {
 181                 my $k = $headers->[$i];
 182                 my $v = $headers->[$i + 1];
 183                 next if $k =~ /\A(?:Connection|Date)\z/i;
 184
 185                 $len = $v if $k =~ /\AContent-Length\z/i;
 186                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 187                         $chunked = 1;
 188                 }
 189                 $h .= "$k: $v\r\n";
 190         }
 191
 192         my $conn = $env->{HTTP_CONNECTION} || '';
 193         my $term = defined($len) || $chunked;
 194         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 195         my $alive;
 196         if (!$term && $prot_persist) { # auto-chunk
 197                 $chunked = $alive = 2;
 198                 $h .= "Transfer-Encoding: chunked\r\n";
 199                 # no need for "Connection: keep-alive" with HTTP/1.1
 200         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 201                 $alive = 1;
 202                 $h .= "Connection: keep-alive\r\n";
 203         } else {
 204                 $alive = 0;
 205                 $h .= "Connection: close\r\n";
 206         }
 207         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 208
 209         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 210                 more($self, $h);
 211         } else {
 212                 $self->write(\$h);
 213         }
 214         $alive;
 215 }
 216
 217 # middlewares such as Deflater may write empty strings
 218 sub chunked_wcb ($) {
 219         my ($self) = @_;
 220         sub {
 221                 return if $_[0] eq '';
 222                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 223                 more($self, $_[0]);
 224
 225                 # use $self->write(\"\n\n") if you care about real-time
 226                 # streaming responses, public-inbox WWW does not.
 227                 more($self, "\r\n");
 228         }
 229 }
 230
 231 sub identity_wcb ($) {
 232         my ($self) = @_;
 233         sub { $self->write(\($_[0])) if $_[0] ne '' }
 234 }
 235
 236 sub next_request ($) {
 237         my ($self) = @_;
 238         if ($self->{rbuf} eq '') { # wait for next request
 239                 $self->watch_read(1);
 240         } else { # avoid recursion for pipelined requests
 241                 push @$pipelineq, $self;
 242                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 243         }
 244 }
 245
 246 sub response_done_cb ($$) {
 247         my ($self, $alive) = @_;
 248         sub {
 249                 my $env = $self->{env};
 250                 $self->{env} = undef;
 251                 $self->write(\"0\r\n\r\n") if $alive == 2;
 252                 $self->write(sub{$alive ? next_request($self) : $self->close});
 253         }
 254 }
 255
 256 sub getline_cb ($$$) {
 257         my ($self, $write, $close) = @_;
 258         local $/ = \8192;
 259         my $forward = $self->{forward};
 260         # limit our own running time for fairness with other
 261         # clients and to avoid buffering too much:
 262         if ($forward) {
 263                 my $buf = eval { $forward->getline };
 264                 if (defined $buf) {
 265                         $write->($buf); # may close in PublicInbox::DS::write
 266                         if ($self->{sock}) {
 267                                 my $next = $self->{pull};
 268                                 if ($self->{wbuf}) {
 269                                         $self->write($next);
 270                                 } else {
 271                                         PublicInbox::EvCleanup::asap($next);
 272                                 }
 273                                 return;
 274                         }
 275                 } elsif ($@) {
 276                         err($self, "response ->getline error: $@");
 277                         $forward = undef;
 278                         $self->close;
 279                 }
 280         }
 281
 282         $self->{forward} = $self->{pull} = undef;
 283         # avoid recursion
 284         if ($forward) {
 285                 eval { $forward->close };
 286                 if ($@) {
 287                         err($self, "response ->close error: $@");
 288                         $self->close; # idempotent
 289                 }
 290         }
 291         $close->();
 292 }
 293
 294 sub getline_response ($$$) {
 295         my ($self, $write, $close) = @_;
 296         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 297         $pull->();
 298 }
 299
 300 sub response_write {
 301         my ($self, $env, $res) = @_;
 302         my $alive = response_header_write($self, $env, $res);
 303         my $close = response_done_cb($self, $alive);
 304         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 305         if (defined(my $body = $res->[2])) {
 306                 if (ref $body eq 'ARRAY') {
 307                         $write->($_) foreach @$body;
 308                         $close->();
 309                 } else {
 310                         $self->{forward} = $body;
 311                         getline_response($self, $write, $close);
 312                 }
 313         } else {
 314                 # this is returned to the calling application:
 315                 Plack::Util::inline_object(write => $write, close => $close);
 316         }
 317 }
 318
 319 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 320 sub more ($$) {
 321         my $self = $_[0];
 322         return unless $self->{sock};
 323         if (MSG_MORE && !$self->{wbuf}) {
 324                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 325                 if (defined $n) {
 326                         my $nlen = length($_[1]) - $n;
 327                         return 1 if $nlen == 0; # all done!
 328
 329                         # PublicInbox::DS::write queues the unwritten substring:
 330                         return $self->write(substr($_[1], $n, $nlen));
 331                 }
 332         }
 333         $self->write(\($_[1]));
 334 }
 335
 336 sub input_prepare {
 337         my ($self, $env) = @_;
 338         my $input;
 339         my $len = $env->{CONTENT_LENGTH};
 340         if ($len) {
 341                 if ($len > $MAX_REQUEST_BUFFER) {
 342                         quit($self, 413);
 343                         return;
 344                 }
 345                 open($input, '+>', undef);
 346         } elsif (env_chunked($env)) {
 347                 $len = CHUNK_START;
 348                 open($input, '+>', undef);
 349         } else {
 350                 $input = $null_io;
 351         }
 352
 353         # TODO: expire idle clients on ENFILE / EMFILE
 354         return unless $input;
 355
 356         $env->{'psgi.input'} = $input;
 357         $self->{env} = $env;
 358         $self->{input_left} = $len || 0;
 359 }
 360
 361 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 362
 363 sub err ($$) {
 364         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 365 }
 366
 367 sub write_err {
 368         my ($self, $len) = @_;
 369         my $msg = $! || '(zero write)';
 370         $msg .= " ($len bytes remaining)" if defined $len;
 371         err($self, "error buffering to input: $msg");
 372         quit($self, 500);
 373 }
 374
 375 sub recv_err {
 376         my ($self, $r, $len) = @_;
 377         return $self->close if (defined $r && $r == 0);
 378         if ($!{EAGAIN}) {
 379                 $self->{input_left} = $len;
 380                 return;
 381         }
 382         err($self, "error reading for input: $! ($len bytes remaining)");
 383         quit($self, 500);
 384 }
 385
 386 sub write_in_full {
 387         my ($fh, $rbuf, $len) = @_;
 388         my $rv = 0;
 389         my $off = 0;
 390         while ($len > 0) {
 391                 my $w = syswrite($fh, $$rbuf, $len, $off);
 392                 return ($rv ? $rv : $w) unless $w; # undef or 0
 393                 $rv += $w;
 394                 $off += $w;
 395                 $len -= $w;
 396         }
 397         $rv
 398 }
 399
 400 sub read_input_chunked { # unlikely...
 401         my ($self) = @_;
 402         my $input = $self->{env}->{'psgi.input'};
 403         my $sock = $self->{sock};
 404         my $len = $self->{input_left};
 405         $self->{input_left} = undef;
 406         my $rbuf = \($self->{rbuf});
 407
 408         while (1) { # chunk start
 409                 if ($len == CHUNK_ZEND) {
 410                         $$rbuf =~ s/\A\r\n//s and
 411                                 return app_dispatch($self, $input);
 412                         return quit($self, 400) if length($$rbuf) > 2;
 413                 }
 414                 if ($len == CHUNK_END) {
 415                         if ($$rbuf =~ s/\A\r\n//s) {
 416                                 $len = CHUNK_START;
 417                         } elsif (length($$rbuf) > 2) {
 418                                 return quit($self, 400);
 419                         }
 420                 }
 421                 if ($len == CHUNK_START) {
 422                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 423                                 $len = hex $1;
 424                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 425                                         return quit($self, 413);
 426                                 }
 427                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 428                                 return quit($self, 400);
 429                         }
 430                         # will break from loop since $len >= 0
 431                 }
 432
 433                 if ($len < 0) { # chunk header is trickled, read more
 434                         my $off = length($$rbuf);
 435                         my $r = sysread($sock, $$rbuf, 8192, $off);
 436                         return recv_err($self, $r, $len) unless $r;
 437                         # (implicit) goto chunk_start if $r > 0;
 438                 }
 439                 $len = CHUNK_ZEND if $len == 0;
 440
 441                 # drain the current chunk
 442                 until ($len <= 0) {
 443                         if ($$rbuf ne '') {
 444                                 my $w = write_in_full($input, $rbuf, $len);
 445                                 return write_err($self, "$len chunk") if !$w;
 446                                 $len -= $w;
 447                                 if ($len == 0) {
 448                                         # we may have leftover data to parse
 449                                         # in chunk
 450                                         $$rbuf = substr($$rbuf, $w);
 451                                         $len = CHUNK_END;
 452                                 } elsif ($len < 0) {
 453                                         die "BUG: len < 0: $len";
 454                                 } else {
 455                                         $$rbuf = '';
 456                                 }
 457                         }
 458                         if ($$rbuf eq '') {
 459                                 # read more of current chunk
 460                                 my $r = sysread($sock, $$rbuf, 8192);
 461                                 return recv_err($self, $r, $len) unless $r;
 462                         }
 463                 }
 464         }
 465 }
 466
 467 sub quit {
 468         my ($self, $status) = @_;
 469         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 470         $self->write(\$h);
 471         $self->close;
 472 }
 473
 474 sub close {
 475         my $self = shift;
 476         my $forward = $self->{forward};
 477         my $env = $self->{env};
 478         delete $env->{'psgix.io'} if $env; # prevent circular references
 479         $self->{pull} = $self->{forward} = $self->{env} = undef;
 480         if ($forward) {
 481                 eval { $forward->close };
 482                 err($self, "forward ->close error: $@") if $@;
 483         }
 484         $self->SUPER::close(@_);
 485 }
 486
 487 # for graceful shutdown in PublicInbox::Daemon:
 488 sub busy () {
 489         my ($self) = @_;
 490         ($self->{rbuf} ne '' || $self->{env} || $self->{wbuf});
 491 }
 492
 493 1;