lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 PublicInbox::DS->import(qw(msg_more));
  23 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  24 use constant {
  25         CHUNK_START => -1,   # [a-f0-9]+\r\n
  26         CHUNK_END => -2,     # \r\n
  27         CHUNK_ZEND => -3,    # \r\n
  28         CHUNK_MAX_HDR => 256,
  29 };
  30 use Errno qw(EAGAIN);
  31
  32 my $pipelineq = [];
  33 my $pipet;
  34 sub process_pipelineq () {
  35         my $q = $pipelineq;
  36         $pipet = undef;
  37         $pipelineq = [];
  38         foreach (@$q) {
  39                 next unless $_->{sock};
  40                 rbuf_process($_);
  41         }
  42 }
  43
  44 # Use the same configuration parameter as git since this is primarily
  45 # a slow-client sponge for git-http-backend
  46 # TODO: support per-respository http.maxRequestBuffer somehow...
  47 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  48                         (10 * 1024 * 1024);
  49
  50 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  51 my $http_date;
  52 my $prev = 0;
  53 sub http_date () {
  54         my $now = time;
  55         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  56 }
  57
  58 sub new ($$$) {
  59         my ($class, $sock, $addr, $httpd) = @_;
  60         my $self = fields::new($class);
  61         $self->SUPER::new($sock, EPOLLIN | EPOLLONESHOT);
  62         $self->{httpd} = $httpd;
  63         ($self->{remote_addr}, $self->{remote_port}) =
  64                 PublicInbox::Daemon::host_with_port($addr);
  65         $self;
  66 }
  67
  68 sub event_step { # called by PublicInbox::DS
  69         my ($self) = @_;
  70
  71         return unless $self->flush_write && $self->{sock};
  72
  73         # only read more requests if we've drained the write buffer,
  74         # otherwise we can be buffering infinitely w/o backpressure
  75
  76         return read_input($self) if defined $self->{env};
  77         my $rbuf = $self->{rbuf} // (\(my $x = ''));
  78         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or return;
  79         rbuf_process($self, $rbuf);
  80 }
  81
  82 sub rbuf_process {
  83         my ($self, $rbuf) = @_;
  84         $rbuf //= $self->{rbuf} // (\(my $x = ''));
  85
  86         my %env = %{$self->{httpd}->{env}}; # full hash copy
  87         my $r = parse_http_request($$rbuf, \%env);
  88
  89         # We do not support Trailers in chunked requests, for now
  90         # (they are rarely-used and git (as of 2.7.2) does not use them)
  91         if ($r == -1 || $env{HTTP_TRAILER} ||
  92                         # this length-check is necessary for PURE_PERL=1:
  93                         ($r == -2 && bytes::length($$rbuf) > 0x4000)) {
  94                 return quit($self, 400);
  95         }
  96         if ($r < 0) { # incomplete
  97                 $self->rbuf_idle($rbuf);
  98                 return $self->watch_in1;
  99         }
 100         $$rbuf = substr($$rbuf, $r);
 101         my $len = input_prepare($self, \%env);
 102         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 103
 104         $len ? read_input($self, $rbuf) : app_dispatch($self, undef, $rbuf);
 105 }
 106
 107 # IO::Handle::write returns boolean, this returns bytes written:
 108 sub xwrite ($$$) {
 109         my ($fh, $rbuf, $max) = @_;
 110         my $w = bytes::length($$rbuf);
 111         $w = $max if $w > $max;
 112         $fh->write($$rbuf, $w) or return;
 113         $w;
 114 }
 115
 116 sub read_input ($;$) {
 117         my ($self, $rbuf) = @_;
 118         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 119         my $env = $self->{env};
 120         return if $env->{REMOTE_ADDR}; # in app dispatch
 121         return read_input_chunked($self, $rbuf) if env_chunked($env);
 122
 123         # env->{CONTENT_LENGTH} (identity)
 124         my $len = delete $self->{input_left};
 125         my $input = $env->{'psgi.input'};
 126
 127         while ($len > 0) {
 128                 if ($$rbuf ne '') {
 129                         my $w = xwrite($input, $rbuf, $len);
 130                         return write_err($self, $len) unless $w;
 131                         $len -= $w;
 132                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 133                         if ($len == 0) { # next request may be pipelined
 134                                 $$rbuf = substr($$rbuf, $w);
 135                                 last;
 136                         }
 137                         $$rbuf = '';
 138                 }
 139                 $self->do_read($rbuf, 8192) or return recv_err($self, $len);
 140                 # continue looping if $r > 0;
 141         }
 142         app_dispatch($self, $input, $rbuf);
 143 }
 144
 145 sub app_dispatch {
 146         my ($self, $input, $rbuf) = @_;
 147         $self->rbuf_idle($rbuf);
 148         my $env = $self->{env};
 149         $env->{REMOTE_ADDR} = $self->{remote_addr};
 150         $env->{REMOTE_PORT} = $self->{remote_port};
 151         if (my $host = $env->{HTTP_HOST}) {
 152                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 153                 $env->{SERVER_NAME} = $host;
 154         }
 155         if (defined $input) {
 156                 sysseek($input, 0, SEEK_SET) or
 157                         die "BUG: psgi.input seek failed: $!";
 158         }
 159         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 160         # to do proper cleanup:
 161         $env->{'psgix.io'} = $self; # only for ->close
 162         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 163         eval {
 164                 if (ref($res) eq 'CODE') {
 165                         $res->(sub { response_write($self, $env, $_[0]) });
 166                 } else {
 167                         response_write($self, $env, $res);
 168                 }
 169         };
 170         $self->close if $@;
 171 }
 172
 173 sub response_header_write {
 174         my ($self, $env, $res) = @_;
 175         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 176         my $status = $res->[0];
 177         my $h = "$proto $status " . status_message($status) . "\r\n";
 178         my ($len, $chunked);
 179         my $headers = $res->[1];
 180
 181         for (my $i = 0; $i < @$headers; $i += 2) {
 182                 my $k = $headers->[$i];
 183                 my $v = $headers->[$i + 1];
 184                 next if $k =~ /\A(?:Connection|Date)\z/i;
 185
 186                 $len = $v if $k =~ /\AContent-Length\z/i;
 187                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 188                         $chunked = 1;
 189                 }
 190                 $h .= "$k: $v\r\n";
 191         }
 192
 193         my $conn = $env->{HTTP_CONNECTION} || '';
 194         my $term = defined($len) || $chunked;
 195         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 196         my $alive;
 197         if (!$term && $prot_persist) { # auto-chunk
 198                 $chunked = $alive = 2;
 199                 $h .= "Transfer-Encoding: chunked\r\n";
 200                 # no need for "Connection: keep-alive" with HTTP/1.1
 201         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 202                 $alive = 1;
 203                 $h .= "Connection: keep-alive\r\n";
 204         } else {
 205                 $alive = 0;
 206                 $h .= "Connection: close\r\n";
 207         }
 208         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 209
 210         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 211                 msg_more($self, $h);
 212         } else {
 213                 $self->write(\$h);
 214         }
 215         $alive;
 216 }
 217
 218 # middlewares such as Deflater may write empty strings
 219 sub chunked_wcb ($) {
 220         my ($self) = @_;
 221         sub {
 222                 return if $_[0] eq '';
 223                 msg_more($self, sprintf("%x\r\n", bytes::length($_[0])));
 224                 msg_more($self, $_[0]);
 225
 226                 # use $self->write(\"\n\n") if you care about real-time
 227                 # streaming responses, public-inbox WWW does not.
 228                 msg_more($self, "\r\n");
 229         }
 230 }
 231
 232 sub identity_wcb ($) {
 233         my ($self) = @_;
 234         sub { $self->write(\($_[0])) if $_[0] ne '' }
 235 }
 236
 237 sub next_request ($) {
 238         my ($self) = @_;
 239         if ($self->{rbuf}) {
 240                 # avoid recursion for pipelined requests
 241                 push @$pipelineq, $self;
 242                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 243         } else { # wait for next request
 244                 $self->watch_in1;
 245         }
 246 }
 247
 248 sub response_done_cb ($$) {
 249         my ($self, $alive) = @_;
 250         sub {
 251                 my $env = delete $self->{env};
 252                 $self->write(\"0\r\n\r\n") if $alive == 2;
 253                 $self->write($alive ? \&next_request : \&close);
 254         }
 255 }
 256
 257 sub getline_cb ($$$) {
 258         my ($self, $write, $close) = @_;
 259         local $/ = \8192;
 260         my $forward = $self->{forward};
 261         # limit our own running time for fairness with other
 262         # clients and to avoid buffering too much:
 263         if ($forward) {
 264                 my $buf = eval { $forward->getline };
 265                 if (defined $buf) {
 266                         $write->($buf); # may close in PublicInbox::DS::write
 267                         if ($self->{sock}) {
 268                                 my $next = $self->{pull};
 269                                 if ($self->{wbuf}) {
 270                                         $self->write($next);
 271                                 } else {
 272                                         PublicInbox::EvCleanup::asap($next);
 273                                 }
 274                                 return;
 275                         }
 276                 } elsif ($@) {
 277                         err($self, "response ->getline error: $@");
 278                         $forward = undef;
 279                         $self->close;
 280                 }
 281         }
 282
 283         delete @$self{qw(forward pull)};
 284         # avoid recursion
 285         if ($forward) {
 286                 eval { $forward->close };
 287                 if ($@) {
 288                         err($self, "response ->close error: $@");
 289                         $self->close; # idempotent
 290                 }
 291         }
 292         $close->();
 293 }
 294
 295 sub getline_response ($$$) {
 296         my ($self, $write, $close) = @_;
 297         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 298         $pull->();
 299 }
 300
 301 sub response_write {
 302         my ($self, $env, $res) = @_;
 303         my $alive = response_header_write($self, $env, $res);
 304         my $close = response_done_cb($self, $alive);
 305         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 306         if (defined(my $body = $res->[2])) {
 307                 if (ref $body eq 'ARRAY') {
 308                         $write->($_) foreach @$body;
 309                         $close->();
 310                 } else {
 311                         $self->{forward} = $body;
 312                         getline_response($self, $write, $close);
 313                 }
 314         } else {
 315                 # this is returned to the calling application:
 316                 Plack::Util::inline_object(write => $write, close => $close);
 317         }
 318 }
 319
 320 sub input_tmpfile ($) {
 321         open($_[0], '+>', undef);
 322         $_[0]->autoflush(1);
 323 }
 324
 325 sub input_prepare {
 326         my ($self, $env) = @_;
 327         my $input;
 328         my $len = $env->{CONTENT_LENGTH};
 329         if ($len) {
 330                 if ($len > $MAX_REQUEST_BUFFER) {
 331                         quit($self, 413);
 332                         return;
 333                 }
 334                 input_tmpfile($input);
 335         } elsif (env_chunked($env)) {
 336                 $len = CHUNK_START;
 337                 input_tmpfile($input);
 338         } else {
 339                 $input = $null_io;
 340         }
 341
 342         # TODO: expire idle clients on ENFILE / EMFILE
 343         return unless $input;
 344
 345         $env->{'psgi.input'} = $input;
 346         $self->{env} = $env;
 347         $self->{input_left} = $len || 0;
 348 }
 349
 350 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 351
 352 sub err ($$) {
 353         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 354 }
 355
 356 sub write_err {
 357         my ($self, $len) = @_;
 358         my $msg = $! || '(zero write)';
 359         $msg .= " ($len bytes remaining)" if defined $len;
 360         err($self, "error buffering to input: $msg");
 361         quit($self, 500);
 362 }
 363
 364 sub recv_err {
 365         my ($self, $len) = @_;
 366         if ($! == EAGAIN) { # epoll/kevent watch already set by do_read
 367                 $self->{input_left} = $len;
 368         } else {
 369                 err($self, "error reading input: $! ($len bytes remaining)");
 370         }
 371 }
 372
 373 sub read_input_chunked { # unlikely...
 374         my ($self, $rbuf) = @_;
 375         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 376         my $input = $self->{env}->{'psgi.input'};
 377         my $len = delete $self->{input_left};
 378
 379         while (1) { # chunk start
 380                 if ($len == CHUNK_ZEND) {
 381                         $$rbuf =~ s/\A\r\n//s and
 382                                 return app_dispatch($self, $input, $rbuf);
 383
 384                         return quit($self, 400) if bytes::length($$rbuf) > 2;
 385                 }
 386                 if ($len == CHUNK_END) {
 387                         if ($$rbuf =~ s/\A\r\n//s) {
 388                                 $len = CHUNK_START;
 389                         } elsif (bytes::length($$rbuf) > 2) {
 390                                 return quit($self, 400);
 391                         }
 392                 }
 393                 if ($len == CHUNK_START) {
 394                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 395                                 $len = hex $1;
 396                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 397                                         return quit($self, 413);
 398                                 }
 399                         } elsif (bytes::length($$rbuf) > CHUNK_MAX_HDR) {
 400                                 return quit($self, 400);
 401                         }
 402                         # will break from loop since $len >= 0
 403                 }
 404
 405                 if ($len < 0) { # chunk header is trickled, read more
 406                         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or
 407                                 return recv_err($self, $len);
 408                         # (implicit) goto chunk_start if $r > 0;
 409                 }
 410                 $len = CHUNK_ZEND if $len == 0;
 411
 412                 # drain the current chunk
 413                 until ($len <= 0) {
 414                         if ($$rbuf ne '') {
 415                                 my $w = xwrite($input, $rbuf, $len);
 416                                 return write_err($self, "$len chunk") if !$w;
 417                                 $len -= $w;
 418                                 if ($len == 0) {
 419                                         # we may have leftover data to parse
 420                                         # in chunk
 421                                         $$rbuf = substr($$rbuf, $w);
 422                                         $len = CHUNK_END;
 423                                 } elsif ($len < 0) {
 424                                         die "BUG: len < 0: $len";
 425                                 } else {
 426                                         $$rbuf = '';
 427                                 }
 428                         }
 429                         if ($$rbuf eq '') {
 430                                 # read more of current chunk
 431                                 $self->do_read($rbuf, 8192) or
 432                                         return recv_err($self, $len);
 433                         }
 434                 }
 435         }
 436 }
 437
 438 sub quit {
 439         my ($self, $status) = @_;
 440         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 441         $self->write(\$h);
 442         $self->close;
 443 }
 444
 445 sub close {
 446         my $self = $_[0];
 447         if (my $env = delete $self->{env}) {
 448                 delete $env->{'psgix.io'}; # prevent circular references
 449         }
 450         delete $self->{pull};
 451         if (my $forward = delete $self->{forward}) {
 452                 eval { $forward->close };
 453                 err($self, "forward ->close error: $@") if $@;
 454         }
 455         $self->SUPER::close; # PublicInbox::DS::close
 456 }
 457
 458 # for graceful shutdown in PublicInbox::Daemon:
 459 sub busy () {
 460         my ($self) = @_;
 461         ($self->{rbuf} || $self->{env} || $self->{wbuf});
 462 }
 463
 464 # fires after pending writes are complete:
 465 sub restart_pass ($) {
 466         $_[0]->{forward}->restart_read; # see PublicInbox::HTTPD::Async
 467 }
 468
 469 sub enqueue_restart_pass ($) { $_[0]->write(\&restart_pass) }
 470
 471 1;