lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left);
  15 use Fcntl qw(:seek);
  16 use HTTP::Parser::XS qw(parse_http_request); # supports pure Perl fallback
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 my $null_io = IO::File->new('/dev/null', '<');
  21 use constant {
  22         CHUNK_START => -1,   # [a-f0-9]+\r\n
  23         CHUNK_END => -2,     # \r\n
  24         CHUNK_ZEND => -3,    # \r\n
  25         CHUNK_MAX_HDR => 256,
  26 };
  27
  28 sub new ($$$) {
  29         my ($class, $sock, $addr, $httpd) = @_;
  30         my $self = fields::new($class);
  31         $self->SUPER::new($sock);
  32         $self->{httpd} = $httpd;
  33         $self->{rbuf} = '';
  34         $self->watch_read(1);
  35         $self;
  36 }
  37
  38 sub event_read { # called by Danga::Socket
  39         my ($self) = @_;
  40
  41         return event_read_input($self) if defined $self->{env};
  42
  43         my $off = $self->{rbuf} eq '' ? 0 : length($self->{rbuf});
  44         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  45         if (defined $r) {
  46                 return $self->close if $r == 0;
  47                 return rbuf_process($self);
  48         }
  49         return if $!{EAGAIN}; # no need to call watch_read(1) again
  50
  51         # common for clients to break connections without warning,
  52         # would be too noisy to log here:
  53         return $self->close;
  54 }
  55
  56 sub rbuf_process {
  57         my ($self) = @_;
  58
  59         my %env = %{$self->{httpd}->{env}}; # full hash copy
  60         my $r = parse_http_request($self->{rbuf}, \%env);
  61
  62         # We do not support Trailers in chunked requests, for now
  63         # (they are rarely-used and git (as of 2.7.2) does not use them)
  64         return $self->quit(400) if $r == -1 || $env{HTTP_TRAILER};
  65         return $self->watch_read(1) if $r < 0; # incomplete
  66         $self->{rbuf} = substr($self->{rbuf}, $r);
  67         my $len = input_prepare($self, \%env);
  68         $len ? event_read_input($self) : app_dispatch($self);
  69 }
  70
  71 sub event_read_input ($) {
  72         my ($self) = @_;
  73         my $env = $self->{env};
  74         return event_read_input_chunked($self) if env_chunked($env);
  75
  76         # env->{CONTENT_LENGTH} (identity)
  77         my $sock = $self->{sock};
  78         my $len = $self->{input_left};
  79         $self->{input_left} = undef;
  80         my $rbuf = \($self->{rbuf});
  81         my $input = $env->{'psgi.input'};
  82
  83         while ($len > 0) {
  84                 if ($$rbuf ne '') {
  85                         my $w = write_in_full($input, $rbuf, $len);
  86                         return $self->write_err unless $w;
  87                         $len -= $w;
  88                         die "BUG: $len < 0 (w=$w)" if $len < 0;
  89                         if ($len == 0) { # next request may be pipelined
  90                                 $$rbuf = substr($$rbuf, $w);
  91                                 last;
  92                         }
  93                         $$rbuf = '';
  94                 }
  95                 my $r = sysread($sock, $$rbuf, 8192);
  96                 return $self->recv_err($r, $len) unless $r;
  97                 # continue looping if $r > 0;
  98         }
  99         app_dispatch($self);
 100 }
 101
 102 sub app_dispatch ($) {
 103         my ($self) = @_;
 104         $self->watch_read(0);
 105         my $env = $self->{env};
 106         $self->{env} = undef;
 107         $env->{REMOTE_ADDR} = $self->peer_ip_string; # Danga::Socket
 108         $env->{REMOTE_PORT} = $self->{peer_port}; # set by peer_ip_string
 109         if (my $host = $env->{HTTP_HOST}) {
 110                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 111                 $env->{SERVER_NAME} = $host;
 112         }
 113         $env->{'psgi.input'}->seek(0, SEEK_SET);
 114         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 115         eval {
 116                 if (ref($res) eq 'CODE') {
 117                         $res->(sub { response_write($self, $env, $_[0]) });
 118                 } else {
 119                         response_write($self, $env, $res);
 120                 }
 121         };
 122         $self->close if $@;
 123 }
 124
 125 sub response_header_write {
 126         my ($self, $env, $res) = @_;
 127         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 128         my $status = $res->[0];
 129         my $h = "$proto $status " . status_message($status) . "\r\n";
 130         my ($len, $chunked);
 131         my $headers = $res->[1];
 132
 133         for (my $i = 0; $i < @$headers; $i += 2) {
 134                 my $k = $headers->[$i];
 135                 my $v = $headers->[$i + 1];
 136                 next if $k =~ /\A(?:Connection|Date)\z/i;
 137
 138                 $len = $v if $k =~ /\AContent-Length\z/i;
 139                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 140                         $chunked = 1;
 141                 }
 142
 143                 $h .= "$k: $v\r\n";
 144         }
 145
 146         my $conn = $env->{HTTP_CONNECTION} || '';
 147         my $alive = (defined($len) || $chunked) &&
 148                         ($proto eq 'HTTP/1.1' && $conn !~ /\bclose\b/i) ||
 149                         ($conn =~ /\bkeep-alive\b/i);
 150
 151         $h .= 'Connection: ' . ($alive ? 'keep-alive' : 'close');
 152         $h .= "\r\nDate: " . time2str(time) . "\r\n\r\n";
 153
 154         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 155                 more($self, $h);
 156         } else {
 157                 $self->write($h);
 158         }
 159         ($alive, $chunked);
 160 }
 161
 162 sub response_write {
 163         my ($self, $env, $res) = @_;
 164         my ($alive, $chunked) = response_header_write($self, $env, $res);
 165         my $write = sub { $self->write($_[0]) };
 166         my $close = sub {
 167                 if ($alive) {
 168                         $self->event_write; # watch for readability if done
 169                 } else {
 170                         $self->write(sub { $self->close });
 171                 }
 172         };
 173
 174         if (defined $res->[2]) {
 175                 Plack::Util::foreach($res->[2], $write);
 176                 $close->();
 177         } else {
 178                 # this is returned to the calling application:
 179                 Plack::Util::inline_object(write => $write, close => $close);
 180         }
 181 }
 182
 183 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 184 sub more ($$) {
 185         my $self = $_[0];
 186         if (MSG_MORE && !$self->{write_buf_size}) {
 187                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 188                 if (defined $n) {
 189                         my $dlen = length($_[1]);
 190                         return 1 if $n == $dlen; # all done!
 191                         $_[1] = substr($_[1], $n, $dlen - $n);
 192                         # fall through to normal write:
 193                 }
 194         }
 195         $self->write($_[1]);
 196 }
 197
 198 # overrides existing Danga::Socket method
 199 sub event_write {
 200         my ($self) = @_;
 201         # only continue watching for readability when we are done writing:
 202         return if $self->write(undef) != 1;
 203
 204         if ($self->{rbuf} eq '') {
 205                 $self->watch_read(1);
 206         } else {
 207                 # avoid recursion
 208                 Danga::Socket->AddTimer(0, sub { rbuf_process($self) });
 209         }
 210 }
 211
 212 sub input_prepare {
 213         my ($self, $env) = @_;
 214         my $input = $null_io;
 215         my $len = $env->{CONTENT_LENGTH};
 216         if ($len) {
 217                 $input = IO::File->new_tmpfile;
 218         } elsif (env_chunked($env)) {
 219                 $input = IO::File->new_tmpfile;
 220                 $len = CHUNK_START;
 221         }
 222         binmode $input;
 223         $env->{'psgi.input'} = $input;
 224         $self->{env} = $env;
 225         $self->{input_left} = $len;
 226 }
 227
 228 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 229
 230 sub write_err {
 231         my ($self) = @_;
 232         my $err = $self->{env}->{'psgi.errors'};
 233         my $msg = $! || '(zero write)';
 234         $err->print("error buffering to input: $msg\n");
 235         $self->quit(500);
 236 }
 237
 238 sub recv_err {
 239         my ($self, $r, $len) = @_;
 240         return $self->close if (defined $r && $r == 0);
 241         if ($!{EAGAIN}) {
 242                 $self->{input_left} = $len;
 243                 return;
 244         }
 245         my $err = $self->{env}->{'psgi.errors'};
 246         $err->print("error reading for input: $! ($len bytes remaining)\n");
 247         $self->quit(500);
 248 }
 249
 250 sub write_in_full {
 251         my ($fh, $rbuf, $len) = @_;
 252         my $rv = 0;
 253         my $off = 0;
 254         while ($len > 0) {
 255                 my $w = syswrite($fh, $$rbuf, $len, $off);
 256                 return ($rv ? $rv : $w) unless $w; # undef or 0
 257                 $rv += $w;
 258                 $off += $w;
 259                 $len -= $w;
 260         }
 261         $rv
 262 }
 263
 264 sub event_read_input_chunked { # unlikely...
 265         my ($self) = @_;
 266         my $input = $self->{env}->{'psgi.input'};
 267         my $sock = $self->{sock};
 268         my $len = $self->{input_left};
 269         $self->{input_left} = undef;
 270         my $rbuf = \($self->{rbuf});
 271
 272         while (1) { # chunk start
 273                 if ($len == CHUNK_ZEND) {
 274                         return app_dispatch($self) if $$rbuf =~ s/\A\r\n//s;
 275                         return $self->quit(400) if length($$rbuf) > 2;
 276                 }
 277                 if ($len == CHUNK_END) {
 278                         if ($$rbuf =~ s/\A\r\n//s) {
 279                                 $len = CHUNK_START;
 280                         } elsif (length($$rbuf) > 2) {
 281                                 return $self->quit(400);
 282                         }
 283                 }
 284                 if ($len == CHUNK_START) {
 285                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 286                                 $len = hex $1;
 287                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 288                                 return $self->quit(400);
 289                         }
 290                         # will break from loop since $len >= 0
 291                 }
 292
 293                 if ($len < 0) { # chunk header is trickled, read more
 294                         my $off = length($$rbuf);
 295                         my $r = sysread($sock, $$rbuf, 8192, $off);
 296                         return $self->recv_err($r, $len) unless $r;
 297                         # (implicit) goto chunk_start if $r > 0;
 298                 }
 299                 $len = CHUNK_ZEND if $len == 0;
 300
 301                 # drain the current chunk
 302                 until ($len <= 0) {
 303                         if ($$rbuf ne '') {
 304                                 my $w = write_in_full($input, $rbuf, $len);
 305                                 return $self->write_err unless $w;
 306                                 $len -= $w;
 307                                 if ($len == 0) {
 308                                         # we may have leftover data to parse
 309                                         # in chunk
 310                                         $$rbuf = substr($$rbuf, $w);
 311                                         $len = CHUNK_END;
 312                                 } elsif ($len < 0) {
 313                                         die "BUG: len < 0: $len";
 314                                 } else {
 315                                         $$rbuf = '';
 316                                 }
 317                         }
 318                         if ($$rbuf eq '') {
 319                                 # read more of current chunk
 320                                 my $r = sysread($sock, $$rbuf, 8192);
 321                                 return $self->recv_err($r, $len) unless $r;
 322                         }
 323                 }
 324         }
 325 }
 326
 327 sub quit {
 328         my ($self, $status) = @_;
 329         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 330         $self->write($h);
 331         $self->close;
 332 }
 333
 334 # callbacks for Danga::Socket
 335
 336 sub event_hup { $_[0]->close }
 337 sub event_err { $_[0]->close }
 338
 339 1;