lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 PublicInbox::DS->import(qw(msg_more));
  23 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  24 use constant {
  25         CHUNK_START => -1,   # [a-f0-9]+\r\n
  26         CHUNK_END => -2,     # \r\n
  27         CHUNK_ZEND => -3,    # \r\n
  28         CHUNK_MAX_HDR => 256,
  29 };
  30 use Errno qw(EAGAIN);
  31
  32 my $pipelineq = [];
  33 my $pipet;
  34 sub process_pipelineq () {
  35         my $q = $pipelineq;
  36         $pipet = undef;
  37         $pipelineq = [];
  38         foreach (@$q) {
  39                 next unless $_->{sock};
  40                 rbuf_process($_);
  41         }
  42 }
  43
  44 # Use the same configuration parameter as git since this is primarily
  45 # a slow-client sponge for git-http-backend
  46 # TODO: support per-respository http.maxRequestBuffer somehow...
  47 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  48                         (10 * 1024 * 1024);
  49
  50 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  51 my $http_date;
  52 my $prev = 0;
  53 sub http_date () {
  54         my $now = time;
  55         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  56 }
  57
  58 sub new ($$$) {
  59         my ($class, $sock, $addr, $httpd) = @_;
  60         my $self = fields::new($class);
  61         $self->SUPER::new($sock, EPOLLIN | EPOLLONESHOT);
  62         $self->{httpd} = $httpd;
  63         $self->{rbuf} = '';
  64         ($self->{remote_addr}, $self->{remote_port}) =
  65                 PublicInbox::Daemon::host_with_port($addr);
  66         $self;
  67 }
  68
  69 sub event_step { # called by PublicInbox::DS
  70         my ($self) = @_;
  71
  72         return unless $self->flush_write && $self->{sock};
  73
  74         # only read more requests if we've drained the write buffer,
  75         # otherwise we can be buffering infinitely w/o backpressure
  76
  77         return read_input($self) if defined $self->{env};
  78         my $rbuf = \($self->{rbuf});
  79         my $off = bytes::length($$rbuf);
  80         $self->do_read($rbuf, 8192, $off) and rbuf_process($self);
  81 }
  82
  83 sub rbuf_process {
  84         my ($self) = @_;
  85
  86         my %env = %{$self->{httpd}->{env}}; # full hash copy
  87         my $r = parse_http_request($self->{rbuf}, \%env);
  88
  89         # We do not support Trailers in chunked requests, for now
  90         # (they are rarely-used and git (as of 2.7.2) does not use them)
  91         if ($r == -1 || $env{HTTP_TRAILER} ||
  92                         # this length-check is necessary for PURE_PERL=1:
  93                         ($r == -2 && bytes::length($self->{rbuf}) > 0x4000)) {
  94                 return quit($self, 400);
  95         }
  96         return $self->watch_in1 if $r < 0; # incomplete
  97         $self->{rbuf} = substr($self->{rbuf}, $r);
  98
  99         my $len = input_prepare($self, \%env);
 100         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 101
 102         $len ? read_input($self) : app_dispatch($self);
 103 }
 104
 105 # IO::Handle::write returns boolean, this returns bytes written:
 106 sub xwrite ($$$) {
 107         my ($fh, $rbuf, $max) = @_;
 108         my $w = bytes::length($$rbuf);
 109         $w = $max if $w > $max;
 110         $fh->write($$rbuf, $w) or return;
 111         $w;
 112 }
 113
 114 sub read_input ($) {
 115         my ($self) = @_;
 116         my $env = $self->{env};
 117         return if $env->{REMOTE_ADDR}; # in app dispatch
 118         return read_input_chunked($self) if env_chunked($env);
 119
 120         # env->{CONTENT_LENGTH} (identity)
 121         my $sock = $self->{sock};
 122         my $len = delete $self->{input_left};
 123         my $rbuf = \($self->{rbuf});
 124         my $input = $env->{'psgi.input'};
 125
 126         while ($len > 0) {
 127                 if ($$rbuf ne '') {
 128                         my $w = xwrite($input, $rbuf, $len);
 129                         return write_err($self, $len) unless $w;
 130                         $len -= $w;
 131                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 132                         if ($len == 0) { # next request may be pipelined
 133                                 $$rbuf = substr($$rbuf, $w);
 134                                 last;
 135                         }
 136                         $$rbuf = '';
 137                 }
 138                 my $r = sysread($sock, $$rbuf, 8192);
 139                 return recv_err($self, $r, $len) unless $r;
 140                 # continue looping if $r > 0;
 141         }
 142         app_dispatch($self, $input);
 143 }
 144
 145 sub app_dispatch {
 146         my ($self, $input) = @_;
 147         my $env = $self->{env};
 148         $env->{REMOTE_ADDR} = $self->{remote_addr};
 149         $env->{REMOTE_PORT} = $self->{remote_port};
 150         if (my $host = $env->{HTTP_HOST}) {
 151                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 152                 $env->{SERVER_NAME} = $host;
 153         }
 154         if (defined $input) {
 155                 sysseek($input, 0, SEEK_SET) or
 156                         die "BUG: psgi.input seek failed: $!";
 157         }
 158         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 159         # to do proper cleanup:
 160         $env->{'psgix.io'} = $self; # only for ->close
 161         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 162         eval {
 163                 if (ref($res) eq 'CODE') {
 164                         $res->(sub { response_write($self, $env, $_[0]) });
 165                 } else {
 166                         response_write($self, $env, $res);
 167                 }
 168         };
 169         $self->close if $@;
 170 }
 171
 172 sub response_header_write {
 173         my ($self, $env, $res) = @_;
 174         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 175         my $status = $res->[0];
 176         my $h = "$proto $status " . status_message($status) . "\r\n";
 177         my ($len, $chunked);
 178         my $headers = $res->[1];
 179
 180         for (my $i = 0; $i < @$headers; $i += 2) {
 181                 my $k = $headers->[$i];
 182                 my $v = $headers->[$i + 1];
 183                 next if $k =~ /\A(?:Connection|Date)\z/i;
 184
 185                 $len = $v if $k =~ /\AContent-Length\z/i;
 186                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 187                         $chunked = 1;
 188                 }
 189                 $h .= "$k: $v\r\n";
 190         }
 191
 192         my $conn = $env->{HTTP_CONNECTION} || '';
 193         my $term = defined($len) || $chunked;
 194         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 195         my $alive;
 196         if (!$term && $prot_persist) { # auto-chunk
 197                 $chunked = $alive = 2;
 198                 $h .= "Transfer-Encoding: chunked\r\n";
 199                 # no need for "Connection: keep-alive" with HTTP/1.1
 200         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 201                 $alive = 1;
 202                 $h .= "Connection: keep-alive\r\n";
 203         } else {
 204                 $alive = 0;
 205                 $h .= "Connection: close\r\n";
 206         }
 207         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 208
 209         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 210                 msg_more($self, $h);
 211         } else {
 212                 $self->write(\$h);
 213         }
 214         $alive;
 215 }
 216
 217 # middlewares such as Deflater may write empty strings
 218 sub chunked_wcb ($) {
 219         my ($self) = @_;
 220         sub {
 221                 return if $_[0] eq '';
 222                 msg_more($self, sprintf("%x\r\n", bytes::length($_[0])));
 223                 msg_more($self, $_[0]);
 224
 225                 # use $self->write(\"\n\n") if you care about real-time
 226                 # streaming responses, public-inbox WWW does not.
 227                 msg_more($self, "\r\n");
 228         }
 229 }
 230
 231 sub identity_wcb ($) {
 232         my ($self) = @_;
 233         sub { $self->write(\($_[0])) if $_[0] ne '' }
 234 }
 235
 236 sub next_request ($) {
 237         my ($self) = @_;
 238         if ($self->{rbuf} eq '') { # wait for next request
 239                 $self->watch_in1;
 240         } else { # avoid recursion for pipelined requests
 241                 push @$pipelineq, $self;
 242                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 243         }
 244 }
 245
 246 sub response_done_cb ($$) {
 247         my ($self, $alive) = @_;
 248         sub {
 249                 my $env = delete $self->{env};
 250                 $self->write(\"0\r\n\r\n") if $alive == 2;
 251                 $self->write($alive ? \&next_request : \&close);
 252         }
 253 }
 254
 255 sub getline_cb ($$$) {
 256         my ($self, $write, $close) = @_;
 257         local $/ = \8192;
 258         my $forward = $self->{forward};
 259         # limit our own running time for fairness with other
 260         # clients and to avoid buffering too much:
 261         if ($forward) {
 262                 my $buf = eval { $forward->getline };
 263                 if (defined $buf) {
 264                         $write->($buf); # may close in PublicInbox::DS::write
 265                         if ($self->{sock}) {
 266                                 my $next = $self->{pull};
 267                                 if ($self->{wbuf}) {
 268                                         $self->write($next);
 269                                 } else {
 270                                         PublicInbox::EvCleanup::asap($next);
 271                                 }
 272                                 return;
 273                         }
 274                 } elsif ($@) {
 275                         err($self, "response ->getline error: $@");
 276                         $forward = undef;
 277                         $self->close;
 278                 }
 279         }
 280
 281         delete @$self{qw(forward pull)};
 282         # avoid recursion
 283         if ($forward) {
 284                 eval { $forward->close };
 285                 if ($@) {
 286                         err($self, "response ->close error: $@");
 287                         $self->close; # idempotent
 288                 }
 289         }
 290         $close->();
 291 }
 292
 293 sub getline_response ($$$) {
 294         my ($self, $write, $close) = @_;
 295         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 296         $pull->();
 297 }
 298
 299 sub response_write {
 300         my ($self, $env, $res) = @_;
 301         my $alive = response_header_write($self, $env, $res);
 302         my $close = response_done_cb($self, $alive);
 303         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 304         if (defined(my $body = $res->[2])) {
 305                 if (ref $body eq 'ARRAY') {
 306                         $write->($_) foreach @$body;
 307                         $close->();
 308                 } else {
 309                         $self->{forward} = $body;
 310                         getline_response($self, $write, $close);
 311                 }
 312         } else {
 313                 # this is returned to the calling application:
 314                 Plack::Util::inline_object(write => $write, close => $close);
 315         }
 316 }
 317
 318 sub input_tmpfile ($) {
 319         open($_[0], '+>', undef);
 320         $_[0]->autoflush(1);
 321 }
 322
 323 sub input_prepare {
 324         my ($self, $env) = @_;
 325         my $input;
 326         my $len = $env->{CONTENT_LENGTH};
 327         if ($len) {
 328                 if ($len > $MAX_REQUEST_BUFFER) {
 329                         quit($self, 413);
 330                         return;
 331                 }
 332                 input_tmpfile($input);
 333         } elsif (env_chunked($env)) {
 334                 $len = CHUNK_START;
 335                 input_tmpfile($input);
 336         } else {
 337                 $input = $null_io;
 338         }
 339
 340         # TODO: expire idle clients on ENFILE / EMFILE
 341         return unless $input;
 342
 343         $env->{'psgi.input'} = $input;
 344         $self->{env} = $env;
 345         $self->{input_left} = $len || 0;
 346 }
 347
 348 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 349
 350 sub err ($$) {
 351         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 352 }
 353
 354 sub write_err {
 355         my ($self, $len) = @_;
 356         my $msg = $! || '(zero write)';
 357         $msg .= " ($len bytes remaining)" if defined $len;
 358         err($self, "error buffering to input: $msg");
 359         quit($self, 500);
 360 }
 361
 362 sub recv_err {
 363         my ($self, $r, $len) = @_;
 364         return $self->close if (defined $r && $r == 0);
 365         if ($! == EAGAIN) {
 366                 $self->{input_left} = $len;
 367                 return $self->watch_in1;
 368         }
 369         err($self, "error reading for input: $! ($len bytes remaining)");
 370         quit($self, 500);
 371 }
 372
 373 sub read_input_chunked { # unlikely...
 374         my ($self) = @_;
 375         my $input = $self->{env}->{'psgi.input'};
 376         my $sock = $self->{sock};
 377         my $len = delete $self->{input_left};
 378         my $rbuf = \($self->{rbuf});
 379
 380         while (1) { # chunk start
 381                 if ($len == CHUNK_ZEND) {
 382                         $$rbuf =~ s/\A\r\n//s and
 383                                 return app_dispatch($self, $input);
 384                         return quit($self, 400) if bytes::length($$rbuf) > 2;
 385                 }
 386                 if ($len == CHUNK_END) {
 387                         if ($$rbuf =~ s/\A\r\n//s) {
 388                                 $len = CHUNK_START;
 389                         } elsif (bytes::length($$rbuf) > 2) {
 390                                 return quit($self, 400);
 391                         }
 392                 }
 393                 if ($len == CHUNK_START) {
 394                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 395                                 $len = hex $1;
 396                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 397                                         return quit($self, 413);
 398                                 }
 399                         } elsif (bytes::length($$rbuf) > CHUNK_MAX_HDR) {
 400                                 return quit($self, 400);
 401                         }
 402                         # will break from loop since $len >= 0
 403                 }
 404
 405                 if ($len < 0) { # chunk header is trickled, read more
 406                         my $off = bytes::length($$rbuf);
 407                         my $r = sysread($sock, $$rbuf, 8192, $off);
 408                         return recv_err($self, $r, $len) unless $r;
 409                         # (implicit) goto chunk_start if $r > 0;
 410                 }
 411                 $len = CHUNK_ZEND if $len == 0;
 412
 413                 # drain the current chunk
 414                 until ($len <= 0) {
 415                         if ($$rbuf ne '') {
 416                                 my $w = xwrite($input, $rbuf, $len);
 417                                 return write_err($self, "$len chunk") if !$w;
 418                                 $len -= $w;
 419                                 if ($len == 0) {
 420                                         # we may have leftover data to parse
 421                                         # in chunk
 422                                         $$rbuf = substr($$rbuf, $w);
 423                                         $len = CHUNK_END;
 424                                 } elsif ($len < 0) {
 425                                         die "BUG: len < 0: $len";
 426                                 } else {
 427                                         $$rbuf = '';
 428                                 }
 429                         }
 430                         if ($$rbuf eq '') {
 431                                 # read more of current chunk
 432                                 my $r = sysread($sock, $$rbuf, 8192);
 433                                 return recv_err($self, $r, $len) unless $r;
 434                         }
 435                 }
 436         }
 437 }
 438
 439 sub quit {
 440         my ($self, $status) = @_;
 441         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 442         $self->write(\$h);
 443         $self->close;
 444 }
 445
 446 sub close {
 447         my $self = $_[0];
 448         if (my $env = delete $self->{env}) {
 449                 delete $env->{'psgix.io'}; # prevent circular references
 450         }
 451         delete $self->{pull};
 452         if (my $forward = delete $self->{forward}) {
 453                 eval { $forward->close };
 454                 err($self, "forward ->close error: $@") if $@;
 455         }
 456         $self->SUPER::close; # PublicInbox::DS::close
 457 }
 458
 459 # for graceful shutdown in PublicInbox::Daemon:
 460 sub busy () {
 461         my ($self) = @_;
 462         ($self->{rbuf} ne '' || $self->{env} || $self->{wbuf});
 463 }
 464
 465 # fires after pending writes are complete:
 466 sub restart_pass ($) {
 467         $_[0]->{forward}->restart_read; # see PublicInbox::HTTPD::Async
 468 }
 469
 470 sub enqueue_restart_pass ($) { $_[0]->write(\&restart_pass) }
 471
 472 1;