lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port);
  15 use Fcntl qw(:seek);
  16 use HTTP::Parser::XS qw(parse_http_request); # supports pure Perl fallback
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 # Use the same configuration parameter as git since this is primarily
  28 # a slow-client sponge for git-http-backend
  29 # TODO: support per-respository http.maxRequestBuffer somehow...
  30 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  31                         (10 * 1024 * 1024);
  32
  33 my $null_io = IO::File->new('/dev/null', '<');
  34 my $http_date;
  35 my $prev = 0;
  36 sub http_date () {
  37         my $now = time;
  38         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  39 }
  40
  41 sub new ($$$) {
  42         my ($class, $sock, $addr, $httpd) = @_;
  43         my $self = fields::new($class);
  44         $self->SUPER::new($sock);
  45         $self->{httpd} = $httpd;
  46         $self->{rbuf} = '';
  47         ($self->{remote_addr}, $self->{remote_port}) =
  48                 PublicInbox::Daemon::host_with_port($addr);
  49         $self->watch_read(1);
  50         $self;
  51 }
  52
  53 sub event_read { # called by Danga::Socket
  54         my ($self) = @_;
  55
  56         return event_read_input($self) if defined $self->{env};
  57
  58         my $off = length($self->{rbuf});
  59         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  60         if (defined $r) {
  61                 return $self->close if $r == 0;
  62                 return rbuf_process($self);
  63         }
  64         return if $!{EAGAIN}; # no need to call watch_read(1) again
  65
  66         # common for clients to break connections without warning,
  67         # would be too noisy to log here:
  68         return $self->close;
  69 }
  70
  71 sub rbuf_process {
  72         my ($self) = @_;
  73
  74         my %env = %{$self->{httpd}->{env}}; # full hash copy
  75         my $r = parse_http_request($self->{rbuf}, \%env);
  76
  77         # We do not support Trailers in chunked requests, for now
  78         # (they are rarely-used and git (as of 2.7.2) does not use them)
  79         if ($r == -1 || $env{HTTP_TRAILER} ||
  80                         # this length-check is necessary for PURE_PERL=1:
  81                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  82                 return quit($self, 400);
  83         }
  84         return $self->watch_read(1) if $r < 0; # incomplete
  85         $self->{rbuf} = substr($self->{rbuf}, $r);
  86
  87         my $len = input_prepare($self, \%env);
  88         defined $len or return write_err($self); # EMFILE/ENFILE
  89
  90         $len ? event_read_input($self) : app_dispatch($self);
  91 }
  92
  93 sub event_read_input ($) {
  94         my ($self) = @_;
  95         my $env = $self->{env};
  96         return event_read_input_chunked($self) if env_chunked($env);
  97
  98         # env->{CONTENT_LENGTH} (identity)
  99         my $sock = $self->{sock};
 100         my $len = $self->{input_left};
 101         $self->{input_left} = undef;
 102         my $rbuf = \($self->{rbuf});
 103         my $input = $env->{'psgi.input'};
 104
 105         while ($len > 0) {
 106                 if ($$rbuf ne '') {
 107                         my $w = write_in_full($input, $rbuf, $len);
 108                         return write_err($self) unless $w;
 109                         $len -= $w;
 110                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 111                         if ($len == 0) { # next request may be pipelined
 112                                 $$rbuf = substr($$rbuf, $w);
 113                                 last;
 114                         }
 115                         $$rbuf = '';
 116                 }
 117                 my $r = sysread($sock, $$rbuf, 8192);
 118                 return recv_err($self, $r, $len) unless $r;
 119                 # continue looping if $r > 0;
 120         }
 121         app_dispatch($self);
 122 }
 123
 124 sub app_dispatch ($) {
 125         my ($self) = @_;
 126         $self->watch_read(0);
 127         my $env = $self->{env};
 128         $env->{REMOTE_ADDR} = $self->{remote_addr};
 129         $env->{REMOTE_PORT} = $self->{remote_port};
 130         if (my $host = $env->{HTTP_HOST}) {
 131                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 132                 $env->{SERVER_NAME} = $host;
 133         }
 134
 135         sysseek($env->{'psgi.input'}, 0, SEEK_SET) or
 136                         die "BUG: psgi.input seek failed: $!";
 137
 138         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 139         eval {
 140                 if (ref($res) eq 'CODE') {
 141                         $res->(sub { response_write($self, $env, $_[0]) });
 142                 } else {
 143                         response_write($self, $env, $res);
 144                 }
 145         };
 146         $self->close if $@;
 147 }
 148
 149 sub response_header_write {
 150         my ($self, $env, $res) = @_;
 151         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 152         my $status = $res->[0];
 153         my $h = "$proto $status " . status_message($status) . "\r\n";
 154         my ($len, $chunked);
 155         my $headers = $res->[1];
 156
 157         for (my $i = 0; $i < @$headers; $i += 2) {
 158                 my $k = $headers->[$i];
 159                 my $v = $headers->[$i + 1];
 160                 next if $k =~ /\A(?:Connection|Date)\z/i;
 161
 162                 $len = $v if $k =~ /\AContent-Length\z/i;
 163                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 164                         $chunked = 1;
 165                 }
 166
 167                 $h .= "$k: $v\r\n";
 168         }
 169
 170         my $conn = $env->{HTTP_CONNECTION} || '';
 171         my $alive = (defined($len) || $chunked) &&
 172                         ($proto eq 'HTTP/1.1' && $conn !~ /\bclose\b/i) ||
 173                         ($conn =~ /\bkeep-alive\b/i);
 174
 175         $h .= 'Connection: ' . ($alive ? 'keep-alive' : 'close');
 176         $h .= "\r\nDate: " . http_date() . "\r\n\r\n";
 177
 178         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 179                 more($self, $h);
 180         } else {
 181                 $self->write($h);
 182         }
 183         ($alive, $chunked);
 184 }
 185
 186 sub response_write {
 187         my ($self, $env, $res) = @_;
 188         my ($alive, $chunked) = response_header_write($self, $env, $res);
 189         my $write = sub { $self->write($_[0]) };
 190         my $close = sub {
 191                 if ($alive) {
 192                         $self->event_write; # watch for readability if done
 193                 } else {
 194                         $self->write(sub { $self->close });
 195                 }
 196                 $self->{env} = undef;
 197         };
 198
 199         if (defined $res->[2]) {
 200                 Plack::Util::foreach($res->[2], $write);
 201                 $close->();
 202         } else {
 203                 # this is returned to the calling application:
 204                 Plack::Util::inline_object(write => $write, close => $close);
 205         }
 206 }
 207
 208 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 209 sub more ($$) {
 210         my $self = $_[0];
 211         if (MSG_MORE && !$self->{write_buf_size}) {
 212                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 213                 if (defined $n) {
 214                         my $dlen = length($_[1]);
 215                         return 1 if $n == $dlen; # all done!
 216                         $_[1] = substr($_[1], $n, $dlen - $n);
 217                         # fall through to normal write:
 218                 }
 219         }
 220         $self->write($_[1]);
 221 }
 222
 223 # overrides existing Danga::Socket method
 224 sub event_write {
 225         my ($self) = @_;
 226         # only continue watching for readability when we are done writing:
 227         return if $self->write(undef) != 1;
 228
 229         if ($self->{rbuf} eq '') { # wait for next request
 230                 $self->watch_read(1);
 231         } else { # avoid recursion for pipelined requests
 232                 Danga::Socket->AddTimer(0, sub { rbuf_process($self) });
 233         }
 234 }
 235
 236 sub input_prepare {
 237         my ($self, $env) = @_;
 238         my $input = $null_io;
 239         my $len = $env->{CONTENT_LENGTH};
 240         if ($len) {
 241                 if ($len > $MAX_REQUEST_BUFFER) {
 242                         quit($self, 413);
 243                         return;
 244                 }
 245                 $input = IO::File->new_tmpfile;
 246         } elsif (env_chunked($env)) {
 247                 $len = CHUNK_START;
 248                 $input = IO::File->new_tmpfile;
 249         }
 250
 251         # TODO: expire idle clients on ENFILE / EMFILE
 252         return unless $input;
 253
 254         binmode $input;
 255         $env->{'psgi.input'} = $input;
 256         $self->{env} = $env;
 257         $self->{input_left} = $len || 0;
 258 }
 259
 260 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 261
 262 sub write_err {
 263         my ($self) = @_;
 264         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 265         my $msg = $! || '(zero write)';
 266         $err->print("error buffering to input: $msg\n");
 267         quit($self, 500);
 268 }
 269
 270 sub recv_err {
 271         my ($self, $r, $len) = @_;
 272         return $self->close if (defined $r && $r == 0);
 273         if ($!{EAGAIN}) {
 274                 $self->{input_left} = $len;
 275                 return;
 276         }
 277         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 278         $err->print("error reading for input: $! ($len bytes remaining)\n");
 279         quit($self, 500);
 280 }
 281
 282 sub write_in_full {
 283         my ($fh, $rbuf, $len) = @_;
 284         my $rv = 0;
 285         my $off = 0;
 286         while ($len > 0) {
 287                 my $w = syswrite($fh, $$rbuf, $len, $off);
 288                 return ($rv ? $rv : $w) unless $w; # undef or 0
 289                 $rv += $w;
 290                 $off += $w;
 291                 $len -= $w;
 292         }
 293         $rv
 294 }
 295
 296 sub event_read_input_chunked { # unlikely...
 297         my ($self) = @_;
 298         my $input = $self->{env}->{'psgi.input'};
 299         my $sock = $self->{sock};
 300         my $len = $self->{input_left};
 301         $self->{input_left} = undef;
 302         my $rbuf = \($self->{rbuf});
 303
 304         while (1) { # chunk start
 305                 if ($len == CHUNK_ZEND) {
 306                         return app_dispatch($self) if $$rbuf =~ s/\A\r\n//s;
 307                         return quit($self, 400) if length($$rbuf) > 2;
 308                 }
 309                 if ($len == CHUNK_END) {
 310                         if ($$rbuf =~ s/\A\r\n//s) {
 311                                 $len = CHUNK_START;
 312                         } elsif (length($$rbuf) > 2) {
 313                                 return quit($self, 400);
 314                         }
 315                 }
 316                 if ($len == CHUNK_START) {
 317                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 318                                 $len = hex $1;
 319                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 320                                         return quit($self, 413);
 321                                 }
 322                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 323                                 return quit($self, 400);
 324                         }
 325                         # will break from loop since $len >= 0
 326                 }
 327
 328                 if ($len < 0) { # chunk header is trickled, read more
 329                         my $off = length($$rbuf);
 330                         my $r = sysread($sock, $$rbuf, 8192, $off);
 331                         return recv_err($self, $r, $len) unless $r;
 332                         # (implicit) goto chunk_start if $r > 0;
 333                 }
 334                 $len = CHUNK_ZEND if $len == 0;
 335
 336                 # drain the current chunk
 337                 until ($len <= 0) {
 338                         if ($$rbuf ne '') {
 339                                 my $w = write_in_full($input, $rbuf, $len);
 340                                 return write_err($self) unless $w;
 341                                 $len -= $w;
 342                                 if ($len == 0) {
 343                                         # we may have leftover data to parse
 344                                         # in chunk
 345                                         $$rbuf = substr($$rbuf, $w);
 346                                         $len = CHUNK_END;
 347                                 } elsif ($len < 0) {
 348                                         die "BUG: len < 0: $len";
 349                                 } else {
 350                                         $$rbuf = '';
 351                                 }
 352                         }
 353                         if ($$rbuf eq '') {
 354                                 # read more of current chunk
 355                                 my $r = sysread($sock, $$rbuf, 8192);
 356                                 return recv_err($self, $r, $len) unless $r;
 357                         }
 358                 }
 359         }
 360 }
 361
 362 sub quit {
 363         my ($self, $status) = @_;
 364         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 365         $self->write($h);
 366         $self->close;
 367 }
 368
 369 # callbacks for Danga::Socket
 370
 371 sub event_hup { $_[0]->close }
 372 sub event_err { $_[0]->close }
 373
 374 sub write ($$) : method {
 375         my PublicInbox::HTTP $self = $_[0];
 376         return 1 if (defined($_[1]) && ref($_[1]) eq '' && $_[1] eq '');
 377
 378         $self->SUPER::write($_[1]);
 379 }
 380
 381 # for graceful shutdown in PublicInbox::Daemon:
 382 sub busy () {
 383         my ($self) = @_;
 384         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 385 }
 386
 387 1;