lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port);
  15 use Fcntl qw(:seek);
  16 use HTTP::Parser::XS qw(parse_http_request); # supports pure Perl fallback
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 my $null_io = IO::File->new('/dev/null', '<');
  28 my $http_date;
  29 my $prev = 0;
  30 sub http_date () {
  31         my $now = time;
  32         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  33 }
  34
  35 sub new ($$$) {
  36         my ($class, $sock, $addr, $httpd) = @_;
  37         my $self = fields::new($class);
  38         $self->SUPER::new($sock);
  39         $self->{httpd} = $httpd;
  40         $self->{rbuf} = '';
  41         ($self->{remote_addr}, $self->{remote_port}) =
  42                 PublicInbox::Daemon::host_with_port($addr);
  43         $self->watch_read(1);
  44         $self;
  45 }
  46
  47 sub event_read { # called by Danga::Socket
  48         my ($self) = @_;
  49
  50         return event_read_input($self) if defined $self->{env};
  51
  52         my $off = length($self->{rbuf});
  53         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  54         if (defined $r) {
  55                 return $self->close if $r == 0;
  56                 return rbuf_process($self);
  57         }
  58         return if $!{EAGAIN}; # no need to call watch_read(1) again
  59
  60         # common for clients to break connections without warning,
  61         # would be too noisy to log here:
  62         return $self->close;
  63 }
  64
  65 sub rbuf_process {
  66         my ($self) = @_;
  67
  68         my %env = %{$self->{httpd}->{env}}; # full hash copy
  69         my $r = parse_http_request($self->{rbuf}, \%env);
  70
  71         # We do not support Trailers in chunked requests, for now
  72         # (they are rarely-used and git (as of 2.7.2) does not use them)
  73         return quit($self, 400) if $r == -1 || $env{HTTP_TRAILER};
  74         return $self->watch_read(1) if $r < 0; # incomplete
  75         $self->{rbuf} = substr($self->{rbuf}, $r);
  76
  77         my $len = input_prepare($self, \%env);
  78         defined $len or return write_err($self); # EMFILE/ENFILE
  79
  80         $len ? event_read_input($self) : app_dispatch($self);
  81 }
  82
  83 sub event_read_input ($) {
  84         my ($self) = @_;
  85         my $env = $self->{env};
  86         return event_read_input_chunked($self) if env_chunked($env);
  87
  88         # env->{CONTENT_LENGTH} (identity)
  89         my $sock = $self->{sock};
  90         my $len = $self->{input_left};
  91         $self->{input_left} = undef;
  92         my $rbuf = \($self->{rbuf});
  93         my $input = $env->{'psgi.input'};
  94
  95         while ($len > 0) {
  96                 if ($$rbuf ne '') {
  97                         my $w = write_in_full($input, $rbuf, $len);
  98                         return write_err($self) unless $w;
  99                         $len -= $w;
 100                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 101                         if ($len == 0) { # next request may be pipelined
 102                                 $$rbuf = substr($$rbuf, $w);
 103                                 last;
 104                         }
 105                         $$rbuf = '';
 106                 }
 107                 my $r = sysread($sock, $$rbuf, 8192);
 108                 return recv_err($self, $r, $len) unless $r;
 109                 # continue looping if $r > 0;
 110         }
 111         app_dispatch($self);
 112 }
 113
 114 sub app_dispatch ($) {
 115         my ($self) = @_;
 116         $self->watch_read(0);
 117         my $env = $self->{env};
 118         $env->{REMOTE_ADDR} = $self->{remote_addr};
 119         $env->{REMOTE_PORT} = $self->{remote_port};
 120         if (my $host = $env->{HTTP_HOST}) {
 121                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 122                 $env->{SERVER_NAME} = $host;
 123         }
 124
 125         sysseek($env->{'psgi.input'}, 0, SEEK_SET) or
 126                         die "BUG: psgi.input seek failed: $!";
 127
 128         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 129         eval {
 130                 if (ref($res) eq 'CODE') {
 131                         $res->(sub { response_write($self, $env, $_[0]) });
 132                 } else {
 133                         response_write($self, $env, $res);
 134                 }
 135         };
 136         $self->close if $@;
 137 }
 138
 139 sub response_header_write {
 140         my ($self, $env, $res) = @_;
 141         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 142         my $status = $res->[0];
 143         my $h = "$proto $status " . status_message($status) . "\r\n";
 144         my ($len, $chunked);
 145         my $headers = $res->[1];
 146
 147         for (my $i = 0; $i < @$headers; $i += 2) {
 148                 my $k = $headers->[$i];
 149                 my $v = $headers->[$i + 1];
 150                 next if $k =~ /\A(?:Connection|Date)\z/i;
 151
 152                 $len = $v if $k =~ /\AContent-Length\z/i;
 153                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 154                         $chunked = 1;
 155                 }
 156
 157                 $h .= "$k: $v\r\n";
 158         }
 159
 160         my $conn = $env->{HTTP_CONNECTION} || '';
 161         my $alive = (defined($len) || $chunked) &&
 162                         ($proto eq 'HTTP/1.1' && $conn !~ /\bclose\b/i) ||
 163                         ($conn =~ /\bkeep-alive\b/i);
 164
 165         $h .= 'Connection: ' . ($alive ? 'keep-alive' : 'close');
 166         $h .= "\r\nDate: " . http_date() . "\r\n\r\n";
 167
 168         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 169                 more($self, $h);
 170         } else {
 171                 $self->write($h);
 172         }
 173         ($alive, $chunked);
 174 }
 175
 176 sub response_write {
 177         my ($self, $env, $res) = @_;
 178         my ($alive, $chunked) = response_header_write($self, $env, $res);
 179         my $write = sub { $self->write($_[0]) };
 180         my $close = sub {
 181                 if ($alive) {
 182                         $self->event_write; # watch for readability if done
 183                 } else {
 184                         $self->write(sub { $self->close });
 185                 }
 186                 $self->{env} = undef;
 187         };
 188
 189         if (defined $res->[2]) {
 190                 Plack::Util::foreach($res->[2], $write);
 191                 $close->();
 192         } else {
 193                 # this is returned to the calling application:
 194                 Plack::Util::inline_object(write => $write, close => $close);
 195         }
 196 }
 197
 198 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 199 sub more ($$) {
 200         my $self = $_[0];
 201         if (MSG_MORE && !$self->{write_buf_size}) {
 202                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 203                 if (defined $n) {
 204                         my $dlen = length($_[1]);
 205                         return 1 if $n == $dlen; # all done!
 206                         $_[1] = substr($_[1], $n, $dlen - $n);
 207                         # fall through to normal write:
 208                 }
 209         }
 210         $self->write($_[1]);
 211 }
 212
 213 # overrides existing Danga::Socket method
 214 sub event_write {
 215         my ($self) = @_;
 216         # only continue watching for readability when we are done writing:
 217         return if $self->write(undef) != 1;
 218
 219         if ($self->{rbuf} eq '') { # wait for next request
 220                 $self->watch_read(1);
 221         } else { # avoid recursion for pipelined requests
 222                 Danga::Socket->AddTimer(0, sub { rbuf_process($self) });
 223         }
 224 }
 225
 226 sub input_prepare {
 227         my ($self, $env) = @_;
 228         my $input = $null_io;
 229         my $len = $env->{CONTENT_LENGTH};
 230         if ($len) {
 231                 $input = IO::File->new_tmpfile;
 232         } elsif (env_chunked($env)) {
 233                 $len = CHUNK_START;
 234                 $input = IO::File->new_tmpfile;
 235         }
 236
 237         # TODO: expire idle clients on ENFILE / EMFILE
 238         return unless $input;
 239
 240         binmode $input;
 241         $env->{'psgi.input'} = $input;
 242         $self->{env} = $env;
 243         $self->{input_left} = $len || 0;
 244 }
 245
 246 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 247
 248 sub write_err {
 249         my ($self) = @_;
 250         my $err = $self->{env}->{'psgi.errors'};
 251         my $msg = $! || '(zero write)';
 252         $err->print("error buffering to input: $msg\n");
 253         quit($self, 500);
 254 }
 255
 256 sub recv_err {
 257         my ($self, $r, $len) = @_;
 258         return $self->close if (defined $r && $r == 0);
 259         if ($!{EAGAIN}) {
 260                 $self->{input_left} = $len;
 261                 return;
 262         }
 263         my $err = $self->{env}->{'psgi.errors'};
 264         $err->print("error reading for input: $! ($len bytes remaining)\n");
 265         quit($self, 500);
 266 }
 267
 268 sub write_in_full {
 269         my ($fh, $rbuf, $len) = @_;
 270         my $rv = 0;
 271         my $off = 0;
 272         while ($len > 0) {
 273                 my $w = syswrite($fh, $$rbuf, $len, $off);
 274                 return ($rv ? $rv : $w) unless $w; # undef or 0
 275                 $rv += $w;
 276                 $off += $w;
 277                 $len -= $w;
 278         }
 279         $rv
 280 }
 281
 282 sub event_read_input_chunked { # unlikely...
 283         my ($self) = @_;
 284         my $input = $self->{env}->{'psgi.input'};
 285         my $sock = $self->{sock};
 286         my $len = $self->{input_left};
 287         $self->{input_left} = undef;
 288         my $rbuf = \($self->{rbuf});
 289
 290         while (1) { # chunk start
 291                 if ($len == CHUNK_ZEND) {
 292                         return app_dispatch($self) if $$rbuf =~ s/\A\r\n//s;
 293                         return quit($self, 400) if length($$rbuf) > 2;
 294                 }
 295                 if ($len == CHUNK_END) {
 296                         if ($$rbuf =~ s/\A\r\n//s) {
 297                                 $len = CHUNK_START;
 298                         } elsif (length($$rbuf) > 2) {
 299                                 return quit($self, 400);
 300                         }
 301                 }
 302                 if ($len == CHUNK_START) {
 303                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 304                                 $len = hex $1;
 305                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 306                                 return quit($self, 400);
 307                         }
 308                         # will break from loop since $len >= 0
 309                 }
 310
 311                 if ($len < 0) { # chunk header is trickled, read more
 312                         my $off = length($$rbuf);
 313                         my $r = sysread($sock, $$rbuf, 8192, $off);
 314                         return recv_err($self, $r, $len) unless $r;
 315                         # (implicit) goto chunk_start if $r > 0;
 316                 }
 317                 $len = CHUNK_ZEND if $len == 0;
 318
 319                 # drain the current chunk
 320                 until ($len <= 0) {
 321                         if ($$rbuf ne '') {
 322                                 my $w = write_in_full($input, $rbuf, $len);
 323                                 return write_err($self) unless $w;
 324                                 $len -= $w;
 325                                 if ($len == 0) {
 326                                         # we may have leftover data to parse
 327                                         # in chunk
 328                                         $$rbuf = substr($$rbuf, $w);
 329                                         $len = CHUNK_END;
 330                                 } elsif ($len < 0) {
 331                                         die "BUG: len < 0: $len";
 332                                 } else {
 333                                         $$rbuf = '';
 334                                 }
 335                         }
 336                         if ($$rbuf eq '') {
 337                                 # read more of current chunk
 338                                 my $r = sysread($sock, $$rbuf, 8192);
 339                                 return recv_err($self, $r, $len) unless $r;
 340                         }
 341                 }
 342         }
 343 }
 344
 345 sub quit {
 346         my ($self, $status) = @_;
 347         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 348         $self->write($h);
 349         $self->close;
 350 }
 351
 352 # callbacks for Danga::Socket
 353
 354 sub event_hup { $_[0]->close }
 355 sub event_err { $_[0]->close }
 356
 357 # for graceful shutdown in PublicInbox::Daemon:
 358 sub busy () {
 359         my ($self) = @_;
 360         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 361 }
 362
 363 1;