lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 # Use the same configuration parameter as git since this is primarily
  28 # a slow-client sponge for git-http-backend
  29 # TODO: support per-respository http.maxRequestBuffer somehow...
  30 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  31                         (10 * 1024 * 1024);
  32
  33 my $null_io = IO::File->new('/dev/null', '<');
  34 my $http_date;
  35 my $prev = 0;
  36 sub http_date () {
  37         my $now = time;
  38         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  39 }
  40
  41 sub new ($$$) {
  42         my ($class, $sock, $addr, $httpd) = @_;
  43         my $self = fields::new($class);
  44         $self->SUPER::new($sock);
  45         $self->{httpd} = $httpd;
  46         $self->{rbuf} = '';
  47         ($self->{remote_addr}, $self->{remote_port}) =
  48                 PublicInbox::Daemon::host_with_port($addr);
  49         $self->watch_read(1);
  50         $self;
  51 }
  52
  53 sub event_read { # called by Danga::Socket
  54         my ($self) = @_;
  55
  56         return event_read_input($self) if defined $self->{env};
  57
  58         my $off = length($self->{rbuf});
  59         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  60         if (defined $r) {
  61                 return $self->close if $r == 0;
  62                 return rbuf_process($self);
  63         }
  64         return if $!{EAGAIN}; # no need to call watch_read(1) again
  65
  66         # common for clients to break connections without warning,
  67         # would be too noisy to log here:
  68         return $self->close;
  69 }
  70
  71 sub rbuf_process {
  72         my ($self) = @_;
  73
  74         my %env = %{$self->{httpd}->{env}}; # full hash copy
  75         my $r = parse_http_request($self->{rbuf}, \%env);
  76
  77         # We do not support Trailers in chunked requests, for now
  78         # (they are rarely-used and git (as of 2.7.2) does not use them)
  79         if ($r == -1 || $env{HTTP_TRAILER} ||
  80                         # this length-check is necessary for PURE_PERL=1:
  81                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  82                 return quit($self, 400);
  83         }
  84         return $self->watch_read(1) if $r < 0; # incomplete
  85         $self->{rbuf} = substr($self->{rbuf}, $r);
  86
  87         my $len = input_prepare($self, \%env);
  88         defined $len or return write_err($self); # EMFILE/ENFILE
  89
  90         $len ? event_read_input($self) : app_dispatch($self);
  91 }
  92
  93 sub event_read_input ($) {
  94         my ($self) = @_;
  95         my $env = $self->{env};
  96         return event_read_input_chunked($self) if env_chunked($env);
  97
  98         # env->{CONTENT_LENGTH} (identity)
  99         my $sock = $self->{sock};
 100         my $len = $self->{input_left};
 101         $self->{input_left} = undef;
 102         my $rbuf = \($self->{rbuf});
 103         my $input = $env->{'psgi.input'};
 104
 105         while ($len > 0) {
 106                 if ($$rbuf ne '') {
 107                         my $w = write_in_full($input, $rbuf, $len);
 108                         return write_err($self) unless $w;
 109                         $len -= $w;
 110                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 111                         if ($len == 0) { # next request may be pipelined
 112                                 $$rbuf = substr($$rbuf, $w);
 113                                 last;
 114                         }
 115                         $$rbuf = '';
 116                 }
 117                 my $r = sysread($sock, $$rbuf, 8192);
 118                 return recv_err($self, $r, $len) unless $r;
 119                 # continue looping if $r > 0;
 120         }
 121         app_dispatch($self, $input);
 122 }
 123
 124 sub app_dispatch {
 125         my ($self, $input) = @_;
 126         $self->watch_read(0);
 127         my $env = $self->{env};
 128         $env->{REMOTE_ADDR} = $self->{remote_addr};
 129         $env->{REMOTE_PORT} = $self->{remote_port};
 130         if (my $host = $env->{HTTP_HOST}) {
 131                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 132                 $env->{SERVER_NAME} = $host;
 133         }
 134         if (defined $input) {
 135                 sysseek($input, 0, SEEK_SET) or
 136                         die "BUG: psgi.input seek failed: $!";
 137         }
 138         # note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
 139         # to do proper cleanup:
 140         $env->{'psgix.io'} = $self; # only for ->close
 141         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 142         eval {
 143                 if (ref($res) eq 'CODE') {
 144                         $res->(sub { response_write($self, $env, $_[0]) });
 145                 } else {
 146                         response_write($self, $env, $res);
 147                 }
 148         };
 149         $self->close if $@;
 150 }
 151
 152 sub response_header_write {
 153         my ($self, $env, $res) = @_;
 154         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 155         my $status = $res->[0];
 156         my $h = "$proto $status " . status_message($status) . "\r\n";
 157         my ($len, $chunked);
 158         my $headers = $res->[1];
 159
 160         for (my $i = 0; $i < @$headers; $i += 2) {
 161                 my $k = $headers->[$i];
 162                 my $v = $headers->[$i + 1];
 163                 next if $k =~ /\A(?:Connection|Date)\z/i;
 164
 165                 $len = $v if $k =~ /\AContent-Length\z/i;
 166                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 167                         $chunked = 1;
 168                 }
 169                 $h .= "$k: $v\r\n";
 170         }
 171
 172         my $conn = $env->{HTTP_CONNECTION} || '';
 173         my $term = defined($len) || $chunked;
 174         my $alive = $term &&
 175                         (($proto eq 'HTTP/1.1' && $conn !~ /\bclose\b/i) ||
 176                          ($conn =~ /\bkeep-alive\b/i));
 177
 178         $h .= 'Connection: ' . ($alive ? 'keep-alive' : 'close');
 179         $h .= "\r\nDate: " . http_date() . "\r\n\r\n";
 180
 181         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 182                 more($self, $h);
 183         } else {
 184                 $self->write($h);
 185         }
 186         $alive;
 187 }
 188
 189 sub response_write {
 190         my ($self, $env, $res) = @_;
 191         my $alive = response_header_write($self, $env, $res);
 192         my $write = sub { $self->write($_[0]) };
 193         my $close = sub {
 194                 if ($alive) {
 195                         $self->event_write; # watch for readability if done
 196                 } else {
 197                         $self->write(sub { $self->close });
 198                 }
 199                 $self->{env} = undef;
 200         };
 201
 202         if (defined $res->[2]) {
 203                 Plack::Util::foreach($res->[2], $write);
 204                 $close->();
 205         } else {
 206                 # this is returned to the calling application:
 207                 Plack::Util::inline_object(write => $write, close => $close);
 208         }
 209 }
 210
 211 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 212 sub more ($$) {
 213         my $self = $_[0];
 214         if (MSG_MORE && !$self->{write_buf_size}) {
 215                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 216                 if (defined $n) {
 217                         my $dlen = length($_[1]);
 218                         return 1 if $n == $dlen; # all done!
 219                         $_[1] = substr($_[1], $n, $dlen - $n);
 220                         # fall through to normal write:
 221                 }
 222         }
 223         $self->write($_[1]);
 224 }
 225
 226 my $pipelineq = [];
 227 my $next_tick;
 228 sub process_pipelineq () {
 229         $next_tick = undef;
 230         my $q = $pipelineq;
 231         $pipelineq = [];
 232         rbuf_process($_) foreach @$q;
 233 }
 234
 235 # overrides existing Danga::Socket method
 236 sub event_write {
 237         my ($self) = @_;
 238         # only continue watching for readability when we are done writing:
 239         return if $self->write(undef) != 1;
 240
 241         if ($self->{rbuf} eq '') { # wait for next request
 242                 $self->watch_read(1);
 243         } else { # avoid recursion for pipelined requests
 244                 push @$pipelineq, $self;
 245                 $next_tick ||= Danga::Socket->AddTimer(0, *process_pipelineq);
 246         }
 247 }
 248
 249 sub input_prepare {
 250         my ($self, $env) = @_;
 251         my $input = $null_io;
 252         my $len = $env->{CONTENT_LENGTH};
 253         if ($len) {
 254                 if ($len > $MAX_REQUEST_BUFFER) {
 255                         quit($self, 413);
 256                         return;
 257                 }
 258                 $input = IO::File->new_tmpfile;
 259         } elsif (env_chunked($env)) {
 260                 $len = CHUNK_START;
 261                 $input = IO::File->new_tmpfile;
 262         }
 263
 264         # TODO: expire idle clients on ENFILE / EMFILE
 265         return unless $input;
 266
 267         binmode $input;
 268         $env->{'psgi.input'} = $input;
 269         $self->{env} = $env;
 270         $self->{input_left} = $len || 0;
 271 }
 272
 273 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 274
 275 sub write_err {
 276         my ($self) = @_;
 277         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 278         my $msg = $! || '(zero write)';
 279         $err->print("error buffering to input: $msg\n");
 280         quit($self, 500);
 281 }
 282
 283 sub recv_err {
 284         my ($self, $r, $len) = @_;
 285         return $self->close if (defined $r && $r == 0);
 286         if ($!{EAGAIN}) {
 287                 $self->{input_left} = $len;
 288                 return;
 289         }
 290         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 291         $err->print("error reading for input: $! ($len bytes remaining)\n");
 292         quit($self, 500);
 293 }
 294
 295 sub write_in_full {
 296         my ($fh, $rbuf, $len) = @_;
 297         my $rv = 0;
 298         my $off = 0;
 299         while ($len > 0) {
 300                 my $w = syswrite($fh, $$rbuf, $len, $off);
 301                 return ($rv ? $rv : $w) unless $w; # undef or 0
 302                 $rv += $w;
 303                 $off += $w;
 304                 $len -= $w;
 305         }
 306         $rv
 307 }
 308
 309 sub event_read_input_chunked { # unlikely...
 310         my ($self) = @_;
 311         my $input = $self->{env}->{'psgi.input'};
 312         my $sock = $self->{sock};
 313         my $len = $self->{input_left};
 314         $self->{input_left} = undef;
 315         my $rbuf = \($self->{rbuf});
 316
 317         while (1) { # chunk start
 318                 if ($len == CHUNK_ZEND) {
 319                         $$rbuf =~ s/\A\r\n//s and
 320                                 return app_dispatch($self, $input);
 321                         return quit($self, 400) if length($$rbuf) > 2;
 322                 }
 323                 if ($len == CHUNK_END) {
 324                         if ($$rbuf =~ s/\A\r\n//s) {
 325                                 $len = CHUNK_START;
 326                         } elsif (length($$rbuf) > 2) {
 327                                 return quit($self, 400);
 328                         }
 329                 }
 330                 if ($len == CHUNK_START) {
 331                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 332                                 $len = hex $1;
 333                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 334                                         return quit($self, 413);
 335                                 }
 336                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 337                                 return quit($self, 400);
 338                         }
 339                         # will break from loop since $len >= 0
 340                 }
 341
 342                 if ($len < 0) { # chunk header is trickled, read more
 343                         my $off = length($$rbuf);
 344                         my $r = sysread($sock, $$rbuf, 8192, $off);
 345                         return recv_err($self, $r, $len) unless $r;
 346                         # (implicit) goto chunk_start if $r > 0;
 347                 }
 348                 $len = CHUNK_ZEND if $len == 0;
 349
 350                 # drain the current chunk
 351                 until ($len <= 0) {
 352                         if ($$rbuf ne '') {
 353                                 my $w = write_in_full($input, $rbuf, $len);
 354                                 return write_err($self) unless $w;
 355                                 $len -= $w;
 356                                 if ($len == 0) {
 357                                         # we may have leftover data to parse
 358                                         # in chunk
 359                                         $$rbuf = substr($$rbuf, $w);
 360                                         $len = CHUNK_END;
 361                                 } elsif ($len < 0) {
 362                                         die "BUG: len < 0: $len";
 363                                 } else {
 364                                         $$rbuf = '';
 365                                 }
 366                         }
 367                         if ($$rbuf eq '') {
 368                                 # read more of current chunk
 369                                 my $r = sysread($sock, $$rbuf, 8192);
 370                                 return recv_err($self, $r, $len) unless $r;
 371                         }
 372                 }
 373         }
 374 }
 375
 376 sub quit {
 377         my ($self, $status) = @_;
 378         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 379         $self->write($h);
 380         $self->close;
 381 }
 382
 383 # callbacks for Danga::Socket
 384
 385 sub event_hup { $_[0]->close }
 386 sub event_err { $_[0]->close }
 387
 388 sub close {
 389         my $self = shift;
 390         $self->{env} = undef;
 391         $self->SUPER::close(@_);
 392 }
 393
 394 sub write ($$) : method {
 395         my PublicInbox::HTTP $self = $_[0];
 396         return 1 if (defined($_[1]) && ref($_[1]) eq '' && $_[1] eq '');
 397
 398         $self->SUPER::write($_[1]);
 399 }
 400
 401 # for graceful shutdown in PublicInbox::Daemon:
 402 sub busy () {
 403         my ($self) = @_;
 404         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 405 }
 406
 407 1;