lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 # Use the same configuration parameter as git since this is primarily
  28 # a slow-client sponge for git-http-backend
  29 # TODO: support per-respository http.maxRequestBuffer somehow...
  30 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  31                         (10 * 1024 * 1024);
  32
  33 my $null_io = IO::File->new('/dev/null', '<');
  34 my $http_date;
  35 my $prev = 0;
  36 sub http_date () {
  37         my $now = time;
  38         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  39 }
  40
  41 sub new ($$$) {
  42         my ($class, $sock, $addr, $httpd) = @_;
  43         my $self = fields::new($class);
  44         $self->SUPER::new($sock);
  45         $self->{httpd} = $httpd;
  46         $self->{rbuf} = '';
  47         ($self->{remote_addr}, $self->{remote_port}) =
  48                 PublicInbox::Daemon::host_with_port($addr);
  49         $self->watch_read(1);
  50         $self;
  51 }
  52
  53 sub event_read { # called by Danga::Socket
  54         my ($self) = @_;
  55
  56         return event_read_input($self) if defined $self->{env};
  57
  58         my $off = length($self->{rbuf});
  59         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  60         if (defined $r) {
  61                 return $self->close if $r == 0;
  62                 return rbuf_process($self);
  63         }
  64         return if $!{EAGAIN}; # no need to call watch_read(1) again
  65
  66         # common for clients to break connections without warning,
  67         # would be too noisy to log here:
  68         return $self->close;
  69 }
  70
  71 sub rbuf_process {
  72         my ($self) = @_;
  73
  74         my %env = %{$self->{httpd}->{env}}; # full hash copy
  75         my $r = parse_http_request($self->{rbuf}, \%env);
  76
  77         # We do not support Trailers in chunked requests, for now
  78         # (they are rarely-used and git (as of 2.7.2) does not use them)
  79         if ($r == -1 || $env{HTTP_TRAILER} ||
  80                         # this length-check is necessary for PURE_PERL=1:
  81                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  82                 return quit($self, 400);
  83         }
  84         return $self->watch_read(1) if $r < 0; # incomplete
  85         $self->{rbuf} = substr($self->{rbuf}, $r);
  86
  87         my $len = input_prepare($self, \%env);
  88         defined $len or return write_err($self); # EMFILE/ENFILE
  89
  90         $len ? event_read_input($self) : app_dispatch($self);
  91 }
  92
  93 sub event_read_input ($) {
  94         my ($self) = @_;
  95         my $env = $self->{env};
  96         return event_read_input_chunked($self) if env_chunked($env);
  97
  98         # env->{CONTENT_LENGTH} (identity)
  99         my $sock = $self->{sock};
 100         my $len = $self->{input_left};
 101         $self->{input_left} = undef;
 102         my $rbuf = \($self->{rbuf});
 103         my $input = $env->{'psgi.input'};
 104
 105         while ($len > 0) {
 106                 if ($$rbuf ne '') {
 107                         my $w = write_in_full($input, $rbuf, $len);
 108                         return write_err($self) unless $w;
 109                         $len -= $w;
 110                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 111                         if ($len == 0) { # next request may be pipelined
 112                                 $$rbuf = substr($$rbuf, $w);
 113                                 last;
 114                         }
 115                         $$rbuf = '';
 116                 }
 117                 my $r = sysread($sock, $$rbuf, 8192);
 118                 return recv_err($self, $r, $len) unless $r;
 119                 # continue looping if $r > 0;
 120         }
 121         app_dispatch($self);
 122 }
 123
 124 sub app_dispatch ($) {
 125         my ($self) = @_;
 126         $self->watch_read(0);
 127         my $env = $self->{env};
 128         $env->{REMOTE_ADDR} = $self->{remote_addr};
 129         $env->{REMOTE_PORT} = $self->{remote_port};
 130         if (my $host = $env->{HTTP_HOST}) {
 131                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 132                 $env->{SERVER_NAME} = $host;
 133         }
 134
 135         sysseek($env->{'psgi.input'}, 0, SEEK_SET) or
 136                         die "BUG: psgi.input seek failed: $!";
 137
 138         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 139         eval {
 140                 if (ref($res) eq 'CODE') {
 141                         $res->(sub { response_write($self, $env, $_[0]) });
 142                 } else {
 143                         response_write($self, $env, $res);
 144                 }
 145         };
 146         $self->close if $@;
 147 }
 148
 149 sub response_header_write {
 150         my ($self, $env, $res) = @_;
 151         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 152         my $status = $res->[0];
 153         my $h = "$proto $status " . status_message($status) . "\r\n";
 154         my $term;
 155         my $headers = $res->[1];
 156
 157         for (my $i = 0; $i < @$headers; $i += 2) {
 158                 my $k = $headers->[$i];
 159                 my $v = $headers->[$i + 1];
 160                 next if $k =~ /\A(?:Connection|Date)\z/i;
 161
 162                 if ($k =~ /\AContent-Length\z/ ||
 163                     ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i)) {
 164                         $term = 1;
 165                 }
 166                 $h .= "$k: $v\r\n";
 167         }
 168
 169         my $conn = $env->{HTTP_CONNECTION} || '';
 170         my $alive = $term &&
 171                         (($proto eq 'HTTP/1.1' && $conn !~ /\bclose\b/i) ||
 172                          ($conn =~ /\bkeep-alive\b/i));
 173
 174         $h .= 'Connection: ' . ($alive ? 'keep-alive' : 'close');
 175         $h .= "\r\nDate: " . http_date() . "\r\n\r\n";
 176
 177         if ($term && $env->{REQUEST_METHOD} ne 'HEAD') {
 178                 more($self, $h);
 179         } else {
 180                 $self->write($h);
 181         }
 182         $alive;
 183 }
 184
 185 sub response_write {
 186         my ($self, $env, $res) = @_;
 187         my $alive = response_header_write($self, $env, $res);
 188         my $write = sub { $self->write($_[0]) };
 189         my $close = sub {
 190                 if ($alive) {
 191                         $self->event_write; # watch for readability if done
 192                 } else {
 193                         $self->write(sub { $self->close });
 194                 }
 195                 $self->{env} = undef;
 196         };
 197
 198         if (defined $res->[2]) {
 199                 Plack::Util::foreach($res->[2], $write);
 200                 $close->();
 201         } else {
 202                 # this is returned to the calling application:
 203                 Plack::Util::inline_object(write => $write, close => $close);
 204         }
 205 }
 206
 207 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 208 sub more ($$) {
 209         my $self = $_[0];
 210         if (MSG_MORE && !$self->{write_buf_size}) {
 211                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 212                 if (defined $n) {
 213                         my $dlen = length($_[1]);
 214                         return 1 if $n == $dlen; # all done!
 215                         $_[1] = substr($_[1], $n, $dlen - $n);
 216                         # fall through to normal write:
 217                 }
 218         }
 219         $self->write($_[1]);
 220 }
 221
 222 # overrides existing Danga::Socket method
 223 sub event_write {
 224         my ($self) = @_;
 225         # only continue watching for readability when we are done writing:
 226         return if $self->write(undef) != 1;
 227
 228         if ($self->{rbuf} eq '') { # wait for next request
 229                 $self->watch_read(1);
 230         } else { # avoid recursion for pipelined requests
 231                 Danga::Socket->AddTimer(0, sub { rbuf_process($self) });
 232         }
 233 }
 234
 235 sub input_prepare {
 236         my ($self, $env) = @_;
 237         my $input = $null_io;
 238         my $len = $env->{CONTENT_LENGTH};
 239         if ($len) {
 240                 if ($len > $MAX_REQUEST_BUFFER) {
 241                         quit($self, 413);
 242                         return;
 243                 }
 244                 $input = IO::File->new_tmpfile;
 245         } elsif (env_chunked($env)) {
 246                 $len = CHUNK_START;
 247                 $input = IO::File->new_tmpfile;
 248         }
 249
 250         # TODO: expire idle clients on ENFILE / EMFILE
 251         return unless $input;
 252
 253         binmode $input;
 254         $env->{'psgi.input'} = $input;
 255         $self->{env} = $env;
 256         $self->{input_left} = $len || 0;
 257 }
 258
 259 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 260
 261 sub write_err {
 262         my ($self) = @_;
 263         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 264         my $msg = $! || '(zero write)';
 265         $err->print("error buffering to input: $msg\n");
 266         quit($self, 500);
 267 }
 268
 269 sub recv_err {
 270         my ($self, $r, $len) = @_;
 271         return $self->close if (defined $r && $r == 0);
 272         if ($!{EAGAIN}) {
 273                 $self->{input_left} = $len;
 274                 return;
 275         }
 276         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 277         $err->print("error reading for input: $! ($len bytes remaining)\n");
 278         quit($self, 500);
 279 }
 280
 281 sub write_in_full {
 282         my ($fh, $rbuf, $len) = @_;
 283         my $rv = 0;
 284         my $off = 0;
 285         while ($len > 0) {
 286                 my $w = syswrite($fh, $$rbuf, $len, $off);
 287                 return ($rv ? $rv : $w) unless $w; # undef or 0
 288                 $rv += $w;
 289                 $off += $w;
 290                 $len -= $w;
 291         }
 292         $rv
 293 }
 294
 295 sub event_read_input_chunked { # unlikely...
 296         my ($self) = @_;
 297         my $input = $self->{env}->{'psgi.input'};
 298         my $sock = $self->{sock};
 299         my $len = $self->{input_left};
 300         $self->{input_left} = undef;
 301         my $rbuf = \($self->{rbuf});
 302
 303         while (1) { # chunk start
 304                 if ($len == CHUNK_ZEND) {
 305                         return app_dispatch($self) if $$rbuf =~ s/\A\r\n//s;
 306                         return quit($self, 400) if length($$rbuf) > 2;
 307                 }
 308                 if ($len == CHUNK_END) {
 309                         if ($$rbuf =~ s/\A\r\n//s) {
 310                                 $len = CHUNK_START;
 311                         } elsif (length($$rbuf) > 2) {
 312                                 return quit($self, 400);
 313                         }
 314                 }
 315                 if ($len == CHUNK_START) {
 316                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 317                                 $len = hex $1;
 318                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 319                                         return quit($self, 413);
 320                                 }
 321                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 322                                 return quit($self, 400);
 323                         }
 324                         # will break from loop since $len >= 0
 325                 }
 326
 327                 if ($len < 0) { # chunk header is trickled, read more
 328                         my $off = length($$rbuf);
 329                         my $r = sysread($sock, $$rbuf, 8192, $off);
 330                         return recv_err($self, $r, $len) unless $r;
 331                         # (implicit) goto chunk_start if $r > 0;
 332                 }
 333                 $len = CHUNK_ZEND if $len == 0;
 334
 335                 # drain the current chunk
 336                 until ($len <= 0) {
 337                         if ($$rbuf ne '') {
 338                                 my $w = write_in_full($input, $rbuf, $len);
 339                                 return write_err($self) unless $w;
 340                                 $len -= $w;
 341                                 if ($len == 0) {
 342                                         # we may have leftover data to parse
 343                                         # in chunk
 344                                         $$rbuf = substr($$rbuf, $w);
 345                                         $len = CHUNK_END;
 346                                 } elsif ($len < 0) {
 347                                         die "BUG: len < 0: $len";
 348                                 } else {
 349                                         $$rbuf = '';
 350                                 }
 351                         }
 352                         if ($$rbuf eq '') {
 353                                 # read more of current chunk
 354                                 my $r = sysread($sock, $$rbuf, 8192);
 355                                 return recv_err($self, $r, $len) unless $r;
 356                         }
 357                 }
 358         }
 359 }
 360
 361 sub quit {
 362         my ($self, $status) = @_;
 363         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 364         $self->write($h);
 365         $self->close;
 366 }
 367
 368 # callbacks for Danga::Socket
 369
 370 sub event_hup { $_[0]->close }
 371 sub event_err { $_[0]->close }
 372
 373 sub write ($$) : method {
 374         my PublicInbox::HTTP $self = $_[0];
 375         return 1 if (defined($_[1]) && ref($_[1]) eq '' && $_[1] eq '');
 376
 377         $self->SUPER::write($_[1]);
 378 }
 379
 380 # for graceful shutdown in PublicInbox::Daemon:
 381 sub busy () {
 382         my ($self) = @_;
 383         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 384 }
 385
 386 1;