lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use Scalar::Util qw(weaken);
  20 use IO::File;
  21 use constant {
  22         CHUNK_START => -1,   # [a-f0-9]+\r\n
  23         CHUNK_END => -2,     # \r\n
  24         CHUNK_ZEND => -3,    # \r\n
  25         CHUNK_MAX_HDR => 256,
  26 };
  27
  28 my $pipelineq = [];
  29 my $pipet;
  30 sub process_pipelineq () {
  31         my $q = $pipelineq;
  32         $pipet = undef;
  33         $pipelineq = [];
  34         foreach (@$q) {
  35                 next if $_->{closed};
  36                 rbuf_process($_);
  37         }
  38 }
  39
  40 # Use the same configuration parameter as git since this is primarily
  41 # a slow-client sponge for git-http-backend
  42 # TODO: support per-respository http.maxRequestBuffer somehow...
  43 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  44                         (10 * 1024 * 1024);
  45
  46 my $null_io = IO::File->new('/dev/null', '<');
  47 my $http_date;
  48 my $prev = 0;
  49 sub http_date () {
  50         my $now = time;
  51         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  52 }
  53
  54 sub new ($$$) {
  55         my ($class, $sock, $addr, $httpd) = @_;
  56         my $self = fields::new($class);
  57         $self->SUPER::new($sock);
  58         $self->{httpd} = $httpd;
  59         $self->{rbuf} = '';
  60         ($self->{remote_addr}, $self->{remote_port}) =
  61                 PublicInbox::Daemon::host_with_port($addr);
  62         $self->watch_read(1);
  63         $self;
  64 }
  65
  66 sub event_read { # called by Danga::Socket
  67         my ($self) = @_;
  68
  69         return event_read_input($self) if defined $self->{env};
  70
  71         my $off = length($self->{rbuf});
  72         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  73         if (defined $r) {
  74                 return $self->close if $r == 0;
  75                 return rbuf_process($self);
  76         }
  77         return if $!{EAGAIN}; # no need to call watch_read(1) again
  78
  79         # common for clients to break connections without warning,
  80         # would be too noisy to log here:
  81         return $self->close;
  82 }
  83
  84 sub rbuf_process {
  85         my ($self) = @_;
  86
  87         my %env = %{$self->{httpd}->{env}}; # full hash copy
  88         my $r = parse_http_request($self->{rbuf}, \%env);
  89
  90         # We do not support Trailers in chunked requests, for now
  91         # (they are rarely-used and git (as of 2.7.2) does not use them)
  92         if ($r == -1 || $env{HTTP_TRAILER} ||
  93                         # this length-check is necessary for PURE_PERL=1:
  94                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  95                 return quit($self, 400);
  96         }
  97         return $self->watch_read(1) if $r < 0; # incomplete
  98         $self->{rbuf} = substr($self->{rbuf}, $r);
  99
 100         my $len = input_prepare($self, \%env);
 101         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 102
 103         $len ? event_read_input($self) : app_dispatch($self);
 104 }
 105
 106 sub event_read_input ($) {
 107         my ($self) = @_;
 108         my $env = $self->{env};
 109         return event_read_input_chunked($self) if env_chunked($env);
 110
 111         # env->{CONTENT_LENGTH} (identity)
 112         my $sock = $self->{sock};
 113         my $len = $self->{input_left};
 114         $self->{input_left} = undef;
 115         my $rbuf = \($self->{rbuf});
 116         my $input = $env->{'psgi.input'};
 117
 118         while ($len > 0) {
 119                 if ($$rbuf ne '') {
 120                         my $w = write_in_full($input, $rbuf, $len);
 121                         return write_err($self, $len) unless $w;
 122                         $len -= $w;
 123                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 124                         if ($len == 0) { # next request may be pipelined
 125                                 $$rbuf = substr($$rbuf, $w);
 126                                 last;
 127                         }
 128                         $$rbuf = '';
 129                 }
 130                 my $r = sysread($sock, $$rbuf, 8192);
 131                 return recv_err($self, $r, $len) unless $r;
 132                 # continue looping if $r > 0;
 133         }
 134         app_dispatch($self, $input);
 135 }
 136
 137 sub app_dispatch {
 138         my ($self, $input) = @_;
 139         $self->watch_read(0);
 140         my $env = $self->{env};
 141         $env->{REMOTE_ADDR} = $self->{remote_addr};
 142         $env->{REMOTE_PORT} = $self->{remote_port};
 143         if (my $host = $env->{HTTP_HOST}) {
 144                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 145                 $env->{SERVER_NAME} = $host;
 146         }
 147         if (defined $input) {
 148                 sysseek($input, 0, SEEK_SET) or
 149                         die "BUG: psgi.input seek failed: $!";
 150         }
 151         # note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
 152         # to do proper cleanup:
 153         $env->{'psgix.io'} = $self; # only for ->close
 154         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 155         eval {
 156                 if (ref($res) eq 'CODE') {
 157                         $res->(sub { response_write($self, $env, $_[0]) });
 158                 } else {
 159                         response_write($self, $env, $res);
 160                 }
 161         };
 162         $self->close if $@;
 163 }
 164
 165 sub response_header_write {
 166         my ($self, $env, $res) = @_;
 167         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 168         my $status = $res->[0];
 169         my $h = "$proto $status " . status_message($status) . "\r\n";
 170         my ($len, $chunked);
 171         my $headers = $res->[1];
 172
 173         for (my $i = 0; $i < @$headers; $i += 2) {
 174                 my $k = $headers->[$i];
 175                 my $v = $headers->[$i + 1];
 176                 next if $k =~ /\A(?:Connection|Date)\z/i;
 177
 178                 $len = $v if $k =~ /\AContent-Length\z/i;
 179                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 180                         $chunked = 1;
 181                 }
 182                 $h .= "$k: $v\r\n";
 183         }
 184
 185         my $conn = $env->{HTTP_CONNECTION} || '';
 186         my $term = defined($len) || $chunked;
 187         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 188         my $alive;
 189         if (!$term && $prot_persist) { # auto-chunk
 190                 $chunked = $alive = 2;
 191                 $h .= "Transfer-Encoding: chunked\r\n";
 192                 # no need for "Connection: keep-alive" with HTTP/1.1
 193         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 194                 $alive = 1;
 195                 $h .= "Connection: keep-alive\r\n";
 196         } else {
 197                 $alive = 0;
 198                 $h .= "Connection: close\r\n";
 199         }
 200         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 201
 202         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 203                 more($self, $h);
 204         } else {
 205                 $self->write($h);
 206         }
 207         $alive;
 208 }
 209
 210 # middlewares such as Deflater may write empty strings
 211 sub chunked_wcb ($) {
 212         my ($self) = @_;
 213         sub {
 214                 return if $_[0] eq '';
 215                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 216                 more($self, $_[0]);
 217
 218                 # use $self->write("\n\n") if you care about real-time
 219                 # streaming responses, public-inbox WWW does not.
 220                 more($self, "\r\n");
 221         }
 222 }
 223
 224 sub identity_wcb ($) {
 225         my ($self) = @_;
 226         sub { $self->write(\($_[0])) if $_[0] ne '' }
 227 }
 228
 229 sub next_request ($) {
 230         my ($self) = @_;
 231         $self->watch_write(0);
 232         if ($self->{rbuf} eq '') { # wait for next request
 233                 $self->watch_read(1);
 234         } else { # avoid recursion for pipelined requests
 235                 push @$pipelineq, $self;
 236                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 237         }
 238 }
 239
 240 sub response_done ($$) {
 241         my ($self, $alive) = @_;
 242         my $env = $self->{env};
 243         $self->{env} = undef;
 244         $self->write("0\r\n\r\n") if $alive == 2;
 245         $self->write(sub { $alive ? next_request($self) : $self->close });
 246 }
 247
 248 sub getline_response {
 249         my ($self, $body, $write, $close) = @_;
 250         $self->{forward} = $body;
 251         weaken($self);
 252         my $pull = $self->{pull} = sub {
 253                 local $/ = \8192;
 254                 my $forward = $self->{forward};
 255                 # limit our own running time for fairness with other
 256                 # clients and to avoid buffering too much:
 257                 while ($forward && defined(my $buf = $forward->getline)) {
 258                         $write->($buf);
 259                         last if $self->{closed};
 260                         if ($self->{write_buf_size}) {
 261                                 $self->write($self->{pull});
 262                         } else {
 263                                 PublicInbox::EvCleanup::asap($self->{pull});
 264                         }
 265                         return;
 266                 }
 267                 $self->{forward} = $self->{pull} = undef;
 268                 $forward->close if $forward; # avoid recursion
 269                 $close->();
 270         };
 271         $pull->();
 272 }
 273
 274 sub response_write {
 275         my ($self, $env, $res) = @_;
 276         my $alive = response_header_write($self, $env, $res);
 277
 278         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 279         my $close = sub { response_done($self, $alive) };
 280         if (defined(my $body = $res->[2])) {
 281                 if (ref $body eq 'ARRAY') {
 282                         $write->($_) foreach @$body;
 283                         $close->();
 284                 } else {
 285                         getline_response($self, $body, $write, $close);
 286                 }
 287         } else {
 288                 # this is returned to the calling application:
 289                 Plack::Util::inline_object(write => $write, close => $close);
 290         }
 291 }
 292
 293 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 294 sub more ($$) {
 295         my $self = $_[0];
 296         return if $self->{closed};
 297         if (MSG_MORE && !$self->{write_buf_size}) {
 298                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 299                 if (defined $n) {
 300                         my $dlen = length($_[1]);
 301                         return 1 if $n == $dlen; # all done!
 302                         $_[1] = substr($_[1], $n, $dlen - $n);
 303                         # fall through to normal write:
 304                 }
 305         }
 306         $self->write($_[1]);
 307 }
 308
 309 sub input_prepare {
 310         my ($self, $env) = @_;
 311         my $input = $null_io;
 312         my $len = $env->{CONTENT_LENGTH};
 313         if ($len) {
 314                 if ($len > $MAX_REQUEST_BUFFER) {
 315                         quit($self, 413);
 316                         return;
 317                 }
 318                 $input = IO::File->new_tmpfile;
 319         } elsif (env_chunked($env)) {
 320                 $len = CHUNK_START;
 321                 $input = IO::File->new_tmpfile;
 322         }
 323
 324         # TODO: expire idle clients on ENFILE / EMFILE
 325         return unless $input;
 326
 327         $env->{'psgi.input'} = $input;
 328         $self->{env} = $env;
 329         $self->{input_left} = $len || 0;
 330 }
 331
 332 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 333
 334 sub write_err {
 335         my ($self, $len) = @_;
 336         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 337         my $msg = $! || '(zero write)';
 338         $msg .= " ($len bytes remaining)\n" if defined $len;
 339         $err->print("error buffering to input: $msg\n");
 340         quit($self, 500);
 341 }
 342
 343 sub recv_err {
 344         my ($self, $r, $len) = @_;
 345         return $self->close if (defined $r && $r == 0);
 346         if ($!{EAGAIN}) {
 347                 $self->{input_left} = $len;
 348                 return;
 349         }
 350         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 351         $err->print("error reading for input: $! ($len bytes remaining)\n");
 352         quit($self, 500);
 353 }
 354
 355 sub write_in_full {
 356         my ($fh, $rbuf, $len) = @_;
 357         my $rv = 0;
 358         my $off = 0;
 359         while ($len > 0) {
 360                 my $w = syswrite($fh, $$rbuf, $len, $off);
 361                 return ($rv ? $rv : $w) unless $w; # undef or 0
 362                 $rv += $w;
 363                 $off += $w;
 364                 $len -= $w;
 365         }
 366         $rv
 367 }
 368
 369 sub event_read_input_chunked { # unlikely...
 370         my ($self) = @_;
 371         my $input = $self->{env}->{'psgi.input'};
 372         my $sock = $self->{sock};
 373         my $len = $self->{input_left};
 374         $self->{input_left} = undef;
 375         my $rbuf = \($self->{rbuf});
 376
 377         while (1) { # chunk start
 378                 if ($len == CHUNK_ZEND) {
 379                         $$rbuf =~ s/\A\r\n//s and
 380                                 return app_dispatch($self, $input);
 381                         return quit($self, 400) if length($$rbuf) > 2;
 382                 }
 383                 if ($len == CHUNK_END) {
 384                         if ($$rbuf =~ s/\A\r\n//s) {
 385                                 $len = CHUNK_START;
 386                         } elsif (length($$rbuf) > 2) {
 387                                 return quit($self, 400);
 388                         }
 389                 }
 390                 if ($len == CHUNK_START) {
 391                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 392                                 $len = hex $1;
 393                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 394                                         return quit($self, 413);
 395                                 }
 396                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 397                                 return quit($self, 400);
 398                         }
 399                         # will break from loop since $len >= 0
 400                 }
 401
 402                 if ($len < 0) { # chunk header is trickled, read more
 403                         my $off = length($$rbuf);
 404                         my $r = sysread($sock, $$rbuf, 8192, $off);
 405                         return recv_err($self, $r, $len) unless $r;
 406                         # (implicit) goto chunk_start if $r > 0;
 407                 }
 408                 $len = CHUNK_ZEND if $len == 0;
 409
 410                 # drain the current chunk
 411                 until ($len <= 0) {
 412                         if ($$rbuf ne '') {
 413                                 my $w = write_in_full($input, $rbuf, $len);
 414                                 return write_err($self, "$len chunk") if !$w;
 415                                 $len -= $w;
 416                                 if ($len == 0) {
 417                                         # we may have leftover data to parse
 418                                         # in chunk
 419                                         $$rbuf = substr($$rbuf, $w);
 420                                         $len = CHUNK_END;
 421                                 } elsif ($len < 0) {
 422                                         die "BUG: len < 0: $len";
 423                                 } else {
 424                                         $$rbuf = '';
 425                                 }
 426                         }
 427                         if ($$rbuf eq '') {
 428                                 # read more of current chunk
 429                                 my $r = sysread($sock, $$rbuf, 8192);
 430                                 return recv_err($self, $r, $len) unless $r;
 431                         }
 432                 }
 433         }
 434 }
 435
 436 sub quit {
 437         my ($self, $status) = @_;
 438         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 439         $self->write($h);
 440         $self->close;
 441 }
 442
 443 # callbacks for Danga::Socket
 444
 445 sub event_hup { $_[0]->close }
 446 sub event_err { $_[0]->close }
 447
 448 sub close {
 449         my $self = shift;
 450         my $forward = $self->{forward};
 451         my $env = $self->{env};
 452         delete $env->{'psgix.io'} if $env; # prevent circular referernces
 453         $self->{pull} = $self->{forward} = $self->{env} = undef;
 454         $forward->close if $forward;
 455         $self->SUPER::close(@_);
 456 }
 457
 458 # for graceful shutdown in PublicInbox::Daemon:
 459 sub busy () {
 460         my ($self) = @_;
 461         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 462 }
 463
 464 1;