lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left);
  15 use Fcntl qw(:seek);
  16 use HTTP::Parser::XS qw(parse_http_request); # supports pure Perl fallback
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 my $null_io = IO::File->new('/dev/null', '<');
  28 my $http_date;
  29 my $prev = 0;
  30 sub http_date () {
  31         my $now = time;
  32         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  33 }
  34
  35 sub new ($$$) {
  36         my ($class, $sock, $addr, $httpd) = @_;
  37         my $self = fields::new($class);
  38         $self->SUPER::new($sock);
  39         $self->{httpd} = $httpd;
  40         $self->{rbuf} = '';
  41         $self->watch_read(1);
  42         $self;
  43 }
  44
  45 sub event_read { # called by Danga::Socket
  46         my ($self) = @_;
  47
  48         return event_read_input($self) if defined $self->{env};
  49
  50         my $off = length($self->{rbuf});
  51         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  52         if (defined $r) {
  53                 return $self->close if $r == 0;
  54                 return rbuf_process($self);
  55         }
  56         return if $!{EAGAIN}; # no need to call watch_read(1) again
  57
  58         # common for clients to break connections without warning,
  59         # would be too noisy to log here:
  60         return $self->close;
  61 }
  62
  63 sub rbuf_process {
  64         my ($self) = @_;
  65
  66         my %env = %{$self->{httpd}->{env}}; # full hash copy
  67         my $r = parse_http_request($self->{rbuf}, \%env);
  68
  69         # We do not support Trailers in chunked requests, for now
  70         # (they are rarely-used and git (as of 2.7.2) does not use them)
  71         return $self->quit(400) if $r == -1 || $env{HTTP_TRAILER};
  72         return $self->watch_read(1) if $r < 0; # incomplete
  73         $self->{rbuf} = substr($self->{rbuf}, $r);
  74         my $len = input_prepare($self, \%env);
  75         $len ? event_read_input($self) : app_dispatch($self);
  76 }
  77
  78 sub event_read_input ($) {
  79         my ($self) = @_;
  80         my $env = $self->{env};
  81         return event_read_input_chunked($self) if env_chunked($env);
  82
  83         # env->{CONTENT_LENGTH} (identity)
  84         my $sock = $self->{sock};
  85         my $len = $self->{input_left};
  86         $self->{input_left} = undef;
  87         my $rbuf = \($self->{rbuf});
  88         my $input = $env->{'psgi.input'};
  89
  90         while ($len > 0) {
  91                 if ($$rbuf ne '') {
  92                         my $w = write_in_full($input, $rbuf, $len);
  93                         return $self->write_err unless $w;
  94                         $len -= $w;
  95                         die "BUG: $len < 0 (w=$w)" if $len < 0;
  96                         if ($len == 0) { # next request may be pipelined
  97                                 $$rbuf = substr($$rbuf, $w);
  98                                 last;
  99                         }
 100                         $$rbuf = '';
 101                 }
 102                 my $r = sysread($sock, $$rbuf, 8192);
 103                 return $self->recv_err($r, $len) unless $r;
 104                 # continue looping if $r > 0;
 105         }
 106         app_dispatch($self);
 107 }
 108
 109 sub app_dispatch ($) {
 110         my ($self) = @_;
 111         $self->watch_read(0);
 112         my $env = $self->{env};
 113         $env->{REMOTE_ADDR} = $self->peer_ip_string; # Danga::Socket
 114         $env->{REMOTE_PORT} = $self->{peer_port}; # set by peer_ip_string
 115         if (my $host = $env->{HTTP_HOST}) {
 116                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 117                 $env->{SERVER_NAME} = $host;
 118         }
 119         sysseek($env->{'psgi.input'}, 0, SEEK_SET) or die "input seek failed: $!";
 120         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 121         eval {
 122                 if (ref($res) eq 'CODE') {
 123                         $res->(sub { response_write($self, $env, $_[0]) });
 124                 } else {
 125                         response_write($self, $env, $res);
 126                 }
 127         };
 128         $self->close if $@;
 129 }
 130
 131 sub response_header_write {
 132         my ($self, $env, $res) = @_;
 133         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 134         my $status = $res->[0];
 135         my $h = "$proto $status " . status_message($status) . "\r\n";
 136         my ($len, $chunked);
 137         my $headers = $res->[1];
 138
 139         for (my $i = 0; $i < @$headers; $i += 2) {
 140                 my $k = $headers->[$i];
 141                 my $v = $headers->[$i + 1];
 142                 next if $k =~ /\A(?:Connection|Date)\z/i;
 143
 144                 $len = $v if $k =~ /\AContent-Length\z/i;
 145                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 146                         $chunked = 1;
 147                 }
 148
 149                 $h .= "$k: $v\r\n";
 150         }
 151
 152         my $conn = $env->{HTTP_CONNECTION} || '';
 153         my $alive = (defined($len) || $chunked) &&
 154                         ($proto eq 'HTTP/1.1' && $conn !~ /\bclose\b/i) ||
 155                         ($conn =~ /\bkeep-alive\b/i);
 156
 157         $h .= 'Connection: ' . ($alive ? 'keep-alive' : 'close');
 158         $h .= "\r\nDate: " . http_date() . "\r\n\r\n";
 159
 160         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 161                 more($self, $h);
 162         } else {
 163                 $self->write($h);
 164         }
 165         ($alive, $chunked);
 166 }
 167
 168 sub response_write {
 169         my ($self, $env, $res) = @_;
 170         my ($alive, $chunked) = response_header_write($self, $env, $res);
 171         my $write = sub { $self->write($_[0]) };
 172         my $close = sub {
 173                 if ($alive) {
 174                         $self->event_write; # watch for readability if done
 175                 } else {
 176                         $self->write(sub { $self->close });
 177                 }
 178                 $self->{env} = undef;
 179         };
 180
 181         if (defined $res->[2]) {
 182                 Plack::Util::foreach($res->[2], $write);
 183                 $close->();
 184         } else {
 185                 # this is returned to the calling application:
 186                 Plack::Util::inline_object(write => $write, close => $close);
 187         }
 188 }
 189
 190 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 191 sub more ($$) {
 192         my $self = $_[0];
 193         if (MSG_MORE && !$self->{write_buf_size}) {
 194                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 195                 if (defined $n) {
 196                         my $dlen = length($_[1]);
 197                         return 1 if $n == $dlen; # all done!
 198                         $_[1] = substr($_[1], $n, $dlen - $n);
 199                         # fall through to normal write:
 200                 }
 201         }
 202         $self->write($_[1]);
 203 }
 204
 205 # overrides existing Danga::Socket method
 206 sub event_write {
 207         my ($self) = @_;
 208         # only continue watching for readability when we are done writing:
 209         return if $self->write(undef) != 1;
 210
 211         if ($self->{rbuf} eq '') { # wait for next request
 212                 $self->watch_read(1);
 213         } else { # avoid recursion for pipelined requests
 214                 Danga::Socket->AddTimer(0, sub { rbuf_process($self) });
 215         }
 216 }
 217
 218 sub input_prepare {
 219         my ($self, $env) = @_;
 220         my $input = $null_io;
 221         my $len = $env->{CONTENT_LENGTH};
 222         if ($len) {
 223                 $input = IO::File->new_tmpfile;
 224         } elsif (env_chunked($env)) {
 225                 $input = IO::File->new_tmpfile;
 226                 $len = CHUNK_START;
 227         }
 228         binmode $input;
 229         $env->{'psgi.input'} = $input;
 230         $self->{env} = $env;
 231         $self->{input_left} = $len;
 232 }
 233
 234 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 235
 236 sub write_err {
 237         my ($self) = @_;
 238         my $err = $self->{env}->{'psgi.errors'};
 239         my $msg = $! || '(zero write)';
 240         $err->print("error buffering to input: $msg\n");
 241         $self->quit(500);
 242 }
 243
 244 sub recv_err {
 245         my ($self, $r, $len) = @_;
 246         return $self->close if (defined $r && $r == 0);
 247         if ($!{EAGAIN}) {
 248                 $self->{input_left} = $len;
 249                 return;
 250         }
 251         my $err = $self->{env}->{'psgi.errors'};
 252         $err->print("error reading for input: $! ($len bytes remaining)\n");
 253         $self->quit(500);
 254 }
 255
 256 sub write_in_full {
 257         my ($fh, $rbuf, $len) = @_;
 258         my $rv = 0;
 259         my $off = 0;
 260         while ($len > 0) {
 261                 my $w = syswrite($fh, $$rbuf, $len, $off);
 262                 return ($rv ? $rv : $w) unless $w; # undef or 0
 263                 $rv += $w;
 264                 $off += $w;
 265                 $len -= $w;
 266         }
 267         $rv
 268 }
 269
 270 sub event_read_input_chunked { # unlikely...
 271         my ($self) = @_;
 272         my $input = $self->{env}->{'psgi.input'};
 273         my $sock = $self->{sock};
 274         my $len = $self->{input_left};
 275         $self->{input_left} = undef;
 276         my $rbuf = \($self->{rbuf});
 277
 278         while (1) { # chunk start
 279                 if ($len == CHUNK_ZEND) {
 280                         return app_dispatch($self) if $$rbuf =~ s/\A\r\n//s;
 281                         return $self->quit(400) if length($$rbuf) > 2;
 282                 }
 283                 if ($len == CHUNK_END) {
 284                         if ($$rbuf =~ s/\A\r\n//s) {
 285                                 $len = CHUNK_START;
 286                         } elsif (length($$rbuf) > 2) {
 287                                 return $self->quit(400);
 288                         }
 289                 }
 290                 if ($len == CHUNK_START) {
 291                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 292                                 $len = hex $1;
 293                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 294                                 return $self->quit(400);
 295                         }
 296                         # will break from loop since $len >= 0
 297                 }
 298
 299                 if ($len < 0) { # chunk header is trickled, read more
 300                         my $off = length($$rbuf);
 301                         my $r = sysread($sock, $$rbuf, 8192, $off);
 302                         return $self->recv_err($r, $len) unless $r;
 303                         # (implicit) goto chunk_start if $r > 0;
 304                 }
 305                 $len = CHUNK_ZEND if $len == 0;
 306
 307                 # drain the current chunk
 308                 until ($len <= 0) {
 309                         if ($$rbuf ne '') {
 310                                 my $w = write_in_full($input, $rbuf, $len);
 311                                 return $self->write_err unless $w;
 312                                 $len -= $w;
 313                                 if ($len == 0) {
 314                                         # we may have leftover data to parse
 315                                         # in chunk
 316                                         $$rbuf = substr($$rbuf, $w);
 317                                         $len = CHUNK_END;
 318                                 } elsif ($len < 0) {
 319                                         die "BUG: len < 0: $len";
 320                                 } else {
 321                                         $$rbuf = '';
 322                                 }
 323                         }
 324                         if ($$rbuf eq '') {
 325                                 # read more of current chunk
 326                                 my $r = sysread($sock, $$rbuf, 8192);
 327                                 return $self->recv_err($r, $len) unless $r;
 328                         }
 329                 }
 330         }
 331 }
 332
 333 sub quit {
 334         my ($self, $status) = @_;
 335         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 336         $self->write($h);
 337         $self->close;
 338 }
 339
 340 # callbacks for Danga::Socket
 341
 342 sub event_hup { $_[0]->close }
 343 sub event_err { $_[0]->close }
 344
 345 # for graceful shutdown in PublicInbox::Daemon:
 346 sub busy () {
 347         my ($self) = @_;
 348         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 349 }
 350
 351 1;