lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 PublicInbox::DS->import(qw(msg_more write_in_full));
  23 use constant {
  24         CHUNK_START => -1,   # [a-f0-9]+\r\n
  25         CHUNK_END => -2,     # \r\n
  26         CHUNK_ZEND => -3,    # \r\n
  27         CHUNK_MAX_HDR => 256,
  28 };
  29
  30 my $pipelineq = [];
  31 my $pipet;
  32 sub process_pipelineq () {
  33         my $q = $pipelineq;
  34         $pipet = undef;
  35         $pipelineq = [];
  36         foreach (@$q) {
  37                 next unless $_->{sock};
  38                 rbuf_process($_);
  39         }
  40 }
  41
  42 # Use the same configuration parameter as git since this is primarily
  43 # a slow-client sponge for git-http-backend
  44 # TODO: support per-respository http.maxRequestBuffer somehow...
  45 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  46                         (10 * 1024 * 1024);
  47
  48 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  49 my $http_date;
  50 my $prev = 0;
  51 sub http_date () {
  52         my $now = time;
  53         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  54 }
  55
  56 sub new ($$$) {
  57         my ($class, $sock, $addr, $httpd) = @_;
  58         my $self = fields::new($class);
  59         $self->SUPER::new($sock, PublicInbox::DS::EPOLLIN());
  60         $self->{httpd} = $httpd;
  61         $self->{rbuf} = '';
  62         ($self->{remote_addr}, $self->{remote_port}) =
  63                 PublicInbox::Daemon::host_with_port($addr);
  64         $self;
  65 }
  66
  67 sub event_step { # called by PublicInbox::DS
  68         my ($self) = @_;
  69
  70         return unless $self->flush_write && $self->{sock};
  71
  72         # only read more requests if we've drained the write buffer,
  73         # otherwise we can be buffering infinitely w/o backpressure
  74
  75         return read_input($self) if defined $self->{env};
  76
  77         my $off = length($self->{rbuf});
  78         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  79         if (defined $r) {
  80                 return $self->close if $r == 0;
  81                 return rbuf_process($self);
  82         }
  83         return if $!{EAGAIN}; # no need to call watch_read(1) again
  84
  85         # common for clients to break connections without warning,
  86         # would be too noisy to log here:
  87         return $self->close;
  88 }
  89
  90 sub rbuf_process {
  91         my ($self) = @_;
  92
  93         my %env = %{$self->{httpd}->{env}}; # full hash copy
  94         my $r = parse_http_request($self->{rbuf}, \%env);
  95
  96         # We do not support Trailers in chunked requests, for now
  97         # (they are rarely-used and git (as of 2.7.2) does not use them)
  98         if ($r == -1 || $env{HTTP_TRAILER} ||
  99                         # this length-check is necessary for PURE_PERL=1:
 100                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
 101                 return quit($self, 400);
 102         }
 103         return $self->watch_read(1) if $r < 0; # incomplete
 104         $self->{rbuf} = substr($self->{rbuf}, $r);
 105
 106         my $len = input_prepare($self, \%env);
 107         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 108
 109         $len ? read_input($self) : app_dispatch($self);
 110 }
 111
 112 sub read_input ($) {
 113         my ($self) = @_;
 114         my $env = $self->{env};
 115         return if $env->{REMOTE_ADDR}; # in app dispatch
 116         return read_input_chunked($self) if env_chunked($env);
 117
 118         # env->{CONTENT_LENGTH} (identity)
 119         my $sock = $self->{sock};
 120         my $len = $self->{input_left};
 121         $self->{input_left} = undef;
 122         my $rbuf = \($self->{rbuf});
 123         my $input = $env->{'psgi.input'};
 124
 125         while ($len > 0) {
 126                 if ($$rbuf ne '') {
 127                         my $w = write_in_full($input, $rbuf, $len, 0);
 128                         return write_err($self, $len) unless $w;
 129                         $len -= $w;
 130                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 131                         if ($len == 0) { # next request may be pipelined
 132                                 $$rbuf = substr($$rbuf, $w);
 133                                 last;
 134                         }
 135                         $$rbuf = '';
 136                 }
 137                 my $r = sysread($sock, $$rbuf, 8192);
 138                 return recv_err($self, $r, $len) unless $r;
 139                 # continue looping if $r > 0;
 140         }
 141         app_dispatch($self, $input);
 142 }
 143
 144 sub app_dispatch {
 145         my ($self, $input) = @_;
 146         $self->watch_read(0);
 147         my $env = $self->{env};
 148         $env->{REMOTE_ADDR} = $self->{remote_addr};
 149         $env->{REMOTE_PORT} = $self->{remote_port};
 150         if (my $host = $env->{HTTP_HOST}) {
 151                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 152                 $env->{SERVER_NAME} = $host;
 153         }
 154         if (defined $input) {
 155                 sysseek($input, 0, SEEK_SET) or
 156                         die "BUG: psgi.input seek failed: $!";
 157         }
 158         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 159         # to do proper cleanup:
 160         $env->{'psgix.io'} = $self; # only for ->close
 161         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 162         eval {
 163                 if (ref($res) eq 'CODE') {
 164                         $res->(sub { response_write($self, $env, $_[0]) });
 165                 } else {
 166                         response_write($self, $env, $res);
 167                 }
 168         };
 169         $self->close if $@;
 170 }
 171
 172 sub response_header_write {
 173         my ($self, $env, $res) = @_;
 174         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 175         my $status = $res->[0];
 176         my $h = "$proto $status " . status_message($status) . "\r\n";
 177         my ($len, $chunked);
 178         my $headers = $res->[1];
 179
 180         for (my $i = 0; $i < @$headers; $i += 2) {
 181                 my $k = $headers->[$i];
 182                 my $v = $headers->[$i + 1];
 183                 next if $k =~ /\A(?:Connection|Date)\z/i;
 184
 185                 $len = $v if $k =~ /\AContent-Length\z/i;
 186                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 187                         $chunked = 1;
 188                 }
 189                 $h .= "$k: $v\r\n";
 190         }
 191
 192         my $conn = $env->{HTTP_CONNECTION} || '';
 193         my $term = defined($len) || $chunked;
 194         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 195         my $alive;
 196         if (!$term && $prot_persist) { # auto-chunk
 197                 $chunked = $alive = 2;
 198                 $h .= "Transfer-Encoding: chunked\r\n";
 199                 # no need for "Connection: keep-alive" with HTTP/1.1
 200         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 201                 $alive = 1;
 202                 $h .= "Connection: keep-alive\r\n";
 203         } else {
 204                 $alive = 0;
 205                 $h .= "Connection: close\r\n";
 206         }
 207         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 208
 209         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 210                 msg_more($self, $h);
 211         } else {
 212                 $self->write(\$h);
 213         }
 214         $alive;
 215 }
 216
 217 # middlewares such as Deflater may write empty strings
 218 sub chunked_wcb ($) {
 219         my ($self) = @_;
 220         sub {
 221                 return if $_[0] eq '';
 222                 msg_more($self, sprintf("%x\r\n", bytes::length($_[0])));
 223                 msg_more($self, $_[0]);
 224
 225                 # use $self->write(\"\n\n") if you care about real-time
 226                 # streaming responses, public-inbox WWW does not.
 227                 msg_more($self, "\r\n");
 228         }
 229 }
 230
 231 sub identity_wcb ($) {
 232         my ($self) = @_;
 233         sub { $self->write(\($_[0])) if $_[0] ne '' }
 234 }
 235
 236 sub next_request ($) {
 237         my ($self) = @_;
 238         if ($self->{rbuf} eq '') { # wait for next request
 239                 $self->watch_read(1);
 240         } else { # avoid recursion for pipelined requests
 241                 push @$pipelineq, $self;
 242                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 243         }
 244 }
 245
 246 sub response_done_cb ($$) {
 247         my ($self, $alive) = @_;
 248         sub {
 249                 my $env = $self->{env};
 250                 $self->{env} = undef;
 251                 $self->write(\"0\r\n\r\n") if $alive == 2;
 252                 $self->write(sub{$alive ? next_request($self) : $self->close});
 253         }
 254 }
 255
 256 sub getline_cb ($$$) {
 257         my ($self, $write, $close) = @_;
 258         local $/ = \8192;
 259         my $forward = $self->{forward};
 260         # limit our own running time for fairness with other
 261         # clients and to avoid buffering too much:
 262         if ($forward) {
 263                 my $buf = eval { $forward->getline };
 264                 if (defined $buf) {
 265                         $write->($buf); # may close in PublicInbox::DS::write
 266                         if ($self->{sock}) {
 267                                 my $next = $self->{pull};
 268                                 if ($self->{wbuf}) {
 269                                         $self->write($next);
 270                                 } else {
 271                                         PublicInbox::EvCleanup::asap($next);
 272                                 }
 273                                 return;
 274                         }
 275                 } elsif ($@) {
 276                         err($self, "response ->getline error: $@");
 277                         $forward = undef;
 278                         $self->close;
 279                 }
 280         }
 281
 282         $self->{forward} = $self->{pull} = undef;
 283         # avoid recursion
 284         if ($forward) {
 285                 eval { $forward->close };
 286                 if ($@) {
 287                         err($self, "response ->close error: $@");
 288                         $self->close; # idempotent
 289                 }
 290         }
 291         $close->();
 292 }
 293
 294 sub getline_response ($$$) {
 295         my ($self, $write, $close) = @_;
 296         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 297         $pull->();
 298 }
 299
 300 sub response_write {
 301         my ($self, $env, $res) = @_;
 302         my $alive = response_header_write($self, $env, $res);
 303         my $close = response_done_cb($self, $alive);
 304         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 305         if (defined(my $body = $res->[2])) {
 306                 if (ref $body eq 'ARRAY') {
 307                         $write->($_) foreach @$body;
 308                         $close->();
 309                 } else {
 310                         $self->{forward} = $body;
 311                         getline_response($self, $write, $close);
 312                 }
 313         } else {
 314                 # this is returned to the calling application:
 315                 Plack::Util::inline_object(write => $write, close => $close);
 316         }
 317 }
 318
 319 sub input_prepare {
 320         my ($self, $env) = @_;
 321         my $input;
 322         my $len = $env->{CONTENT_LENGTH};
 323         if ($len) {
 324                 if ($len > $MAX_REQUEST_BUFFER) {
 325                         quit($self, 413);
 326                         return;
 327                 }
 328                 open($input, '+>', undef);
 329         } elsif (env_chunked($env)) {
 330                 $len = CHUNK_START;
 331                 open($input, '+>', undef);
 332         } else {
 333                 $input = $null_io;
 334         }
 335
 336         # TODO: expire idle clients on ENFILE / EMFILE
 337         return unless $input;
 338
 339         $env->{'psgi.input'} = $input;
 340         $self->{env} = $env;
 341         $self->{input_left} = $len || 0;
 342 }
 343
 344 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 345
 346 sub err ($$) {
 347         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 348 }
 349
 350 sub write_err {
 351         my ($self, $len) = @_;
 352         my $msg = $! || '(zero write)';
 353         $msg .= " ($len bytes remaining)" if defined $len;
 354         err($self, "error buffering to input: $msg");
 355         quit($self, 500);
 356 }
 357
 358 sub recv_err {
 359         my ($self, $r, $len) = @_;
 360         return $self->close if (defined $r && $r == 0);
 361         if ($!{EAGAIN}) {
 362                 $self->{input_left} = $len;
 363                 return;
 364         }
 365         err($self, "error reading for input: $! ($len bytes remaining)");
 366         quit($self, 500);
 367 }
 368
 369 sub read_input_chunked { # unlikely...
 370         my ($self) = @_;
 371         my $input = $self->{env}->{'psgi.input'};
 372         my $sock = $self->{sock};
 373         my $len = $self->{input_left};
 374         $self->{input_left} = undef;
 375         my $rbuf = \($self->{rbuf});
 376
 377         while (1) { # chunk start
 378                 if ($len == CHUNK_ZEND) {
 379                         $$rbuf =~ s/\A\r\n//s and
 380                                 return app_dispatch($self, $input);
 381                         return quit($self, 400) if length($$rbuf) > 2;
 382                 }
 383                 if ($len == CHUNK_END) {
 384                         if ($$rbuf =~ s/\A\r\n//s) {
 385                                 $len = CHUNK_START;
 386                         } elsif (length($$rbuf) > 2) {
 387                                 return quit($self, 400);
 388                         }
 389                 }
 390                 if ($len == CHUNK_START) {
 391                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 392                                 $len = hex $1;
 393                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 394                                         return quit($self, 413);
 395                                 }
 396                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 397                                 return quit($self, 400);
 398                         }
 399                         # will break from loop since $len >= 0
 400                 }
 401
 402                 if ($len < 0) { # chunk header is trickled, read more
 403                         my $off = length($$rbuf);
 404                         my $r = sysread($sock, $$rbuf, 8192, $off);
 405                         return recv_err($self, $r, $len) unless $r;
 406                         # (implicit) goto chunk_start if $r > 0;
 407                 }
 408                 $len = CHUNK_ZEND if $len == 0;
 409
 410                 # drain the current chunk
 411                 until ($len <= 0) {
 412                         if ($$rbuf ne '') {
 413                                 my $w = write_in_full($input, $rbuf, $len, 0);
 414                                 return write_err($self, "$len chunk") if !$w;
 415                                 $len -= $w;
 416                                 if ($len == 0) {
 417                                         # we may have leftover data to parse
 418                                         # in chunk
 419                                         $$rbuf = substr($$rbuf, $w);
 420                                         $len = CHUNK_END;
 421                                 } elsif ($len < 0) {
 422                                         die "BUG: len < 0: $len";
 423                                 } else {
 424                                         $$rbuf = '';
 425                                 }
 426                         }
 427                         if ($$rbuf eq '') {
 428                                 # read more of current chunk
 429                                 my $r = sysread($sock, $$rbuf, 8192);
 430                                 return recv_err($self, $r, $len) unless $r;
 431                         }
 432                 }
 433         }
 434 }
 435
 436 sub quit {
 437         my ($self, $status) = @_;
 438         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 439         $self->write(\$h);
 440         $self->close;
 441 }
 442
 443 sub close {
 444         my $self = shift;
 445         my $forward = $self->{forward};
 446         my $env = $self->{env};
 447         delete $env->{'psgix.io'} if $env; # prevent circular references
 448         $self->{pull} = $self->{forward} = $self->{env} = undef;
 449         if ($forward) {
 450                 eval { $forward->close };
 451                 err($self, "forward ->close error: $@") if $@;
 452         }
 453         $self->SUPER::close(@_);
 454 }
 455
 456 # for graceful shutdown in PublicInbox::Daemon:
 457 sub busy () {
 458         my ($self) = @_;
 459         ($self->{rbuf} ne '' || $self->{env} || $self->{wbuf});
 460 }
 461
 462 1;