lib/PublicInbox/HTTPD/Async.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # XXX This is a totally unstable API for public-inbox internal use only
   5 # This is exposed via the 'pi-httpd.async' key in the PSGI env hash.
   6 # The name of this key is not even stable!
   7 # Currently is is intended for use with read-only pipes.
   8 package PublicInbox::HTTPD::Async;
   9 use strict;
  10 use warnings;
  11 use base qw(PublicInbox::DS);
  12 use fields qw(cb cleanup);
  13 require PublicInbox::EvCleanup;
  14 use Errno qw(EAGAIN);
  15
  16 sub new {
  17         my ($class, $io, $cb, $cleanup) = @_;
  18
  19         # no $io? call $cb at the top of the next event loop to
  20         # avoid recursion:
  21         unless (defined($io)) {
  22                 PublicInbox::DS::requeue($cb);
  23                 die 'cleanup unsupported w/o $io' if $cleanup;
  24                 return;
  25         }
  26
  27         my $self = fields::new($class);
  28         IO::Handle::blocking($io, 0);
  29         $self->SUPER::new($io, PublicInbox::DS::EPOLLIN());
  30         $self->{cb} = $cb;
  31         $self->{cleanup} = $cleanup;
  32         $self;
  33 }
  34
  35 sub restart_read ($) { $_[0]->watch(PublicInbox::DS::EPOLLIN()) }
  36
  37 sub main_cb ($$$) {
  38         my ($http, $fh, $bref) = @_;
  39         sub {
  40                 my ($self) = @_;
  41                 my $r = sysread($self->{sock}, $$bref, 8192);
  42                 if ($r) {
  43                         $fh->write($$bref); # may call $http->close
  44
  45                         if ($http->{sock}) { # !closed
  46                                 if ($http->{wbuf}) {
  47                                         # HTTP client could not keep up, so
  48                                         # stop reading and buffering.
  49                                         $self->watch(0);
  50
  51                                         # Tell the HTTP socket to restart us
  52                                         # when HTTP client is done draining
  53                                         # $http->{wbuf}:
  54                                         $http->enqueue_restart_pass;
  55                                 }
  56                                 # stay in EPOLLIN, but let other clients
  57                                 # get some work done, too.
  58                                 return;
  59                         }
  60                         # fall through to close below...
  61                 } elsif (!defined $r) {
  62                         return restart_read($self) if $! == EAGAIN;
  63                 }
  64
  65                 # Done! Error handling will happen in $fh->close
  66                 # called by the {cleanup} handler
  67                 delete $http->{forward};
  68                 $self->close;
  69         }
  70 }
  71
  72 sub async_pass {
  73         my ($self, $http, $fh, $bref) = @_;
  74         # In case the client HTTP connection ($http) dies, it
  75         # will automatically close this ($self) object.
  76         $http->{forward} = $self;
  77         $fh->write($$bref); # PublicInbox:HTTP::{chunked,identity}_wcb
  78         $self->{cb} = main_cb($http, $fh, $bref);
  79 }
  80
  81 sub event_step { $_[0]->{cb}->(@_) }
  82
  83 sub close {
  84         my $self = $_[0];
  85         delete $self->{cb};
  86         $self->SUPER::close;
  87
  88         # we defer this to the next timer loop since close is deferred
  89         if (my $cleanup = delete $self->{cleanup}) {
  90                 PublicInbox::DS::requeue($cleanup);
  91         }
  92 }
  93
  94 1;