lib/PublicInbox/HTTPD/Async.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # XXX This is a totally unstable API for public-inbox internal use only
   5 # This is exposed via the 'pi-httpd.async' key in the PSGI env hash.
   6 # The name of this key is not even stable!
   7 # Currently intended for use with read-only pipes with expensive
   8 # processes such as git-http-backend(1), cgit(1)
   9 #
  10 # fields:
  11 # http: PublicInbox::HTTP ref
  12 # fh: PublicInbox::HTTP::{Identity,Chunked} ref (can ->write + ->close)
  13 # cb: initial read callback
  14 # arg: arg for {cb}
  15 # end_obj: CODE or object which responds to ->event_step when ->close is called
  16 package PublicInbox::HTTPD::Async;
  17 use strict;
  18 use parent qw(PublicInbox::DS);
  19 use Errno qw(EAGAIN);
  20 use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
  21
  22 # This is called via: $env->{'pi-httpd.async'}->()
  23 # $io is a read-only pipe ($rpipe) for now, but may be a
  24 # bidirectional socket in the future.
  25 sub new {
  26         my ($class, $io, $cb, $arg, $end_obj) = @_;
  27
  28         # no $io? call $cb at the top of the next event loop to
  29         # avoid recursion:
  30         unless (defined($io)) {
  31                 PublicInbox::DS::requeue($cb ? $cb : $arg);
  32                 die '$end_obj unsupported w/o $io' if $end_obj;
  33                 return;
  34         }
  35         my $self = bless {
  36                 cb => $cb, # initial read callback
  37                 arg => $arg, # arg for $cb
  38                 end_obj => $end_obj, # like END{}, can ->event_step
  39         }, $class;
  40         IO::Handle::blocking($io, 0);
  41         $self->SUPER::new($io, EPOLLIN | EPOLLET);
  42 }
  43
  44 sub event_step {
  45         my ($self) = @_;
  46         if (my $cb = delete $self->{cb}) {
  47                 # this may call async_pass when headers are done
  48                 $cb->(delete $self->{arg});
  49         } elsif (my $sock = $self->{sock}) {
  50                 my $http = $self->{http};
  51                 # $self->{sock} is a read pipe for git-http-backend or cgit
  52                 # and 65536 is the default Linux pipe size
  53                 my $r = sysread($sock, my $buf, 65536);
  54                 if ($r) {
  55                         $self->{fh}->write($buf); # may call $http->close
  56                         if ($http->{sock}) { # !closed
  57                                 $self->requeue;
  58                                 # let other clients get some work done, too
  59                                 return;
  60                         }
  61
  62                         # else: fall through to close below...
  63                 } elsif (!defined $r && $! == EAGAIN) {
  64                         return; # EPOLLET means we'll be notified
  65                 }
  66
  67                 # Done! Error handling will happen in $self->{fh}->close
  68                 # called by end_obj->event_step handler
  69                 delete $http->{forward};
  70                 $self->close; # queues end_obj->event_step to be called
  71         } # else { # we may've been requeued but closed by $http
  72 }
  73
  74 # once this is called, all data we read is passed to the
  75 # to the PublicInbox::HTTP instance ($http) via $fh->write
  76 sub async_pass {
  77         my ($self, $http, $fh, $bref) = @_;
  78         # In case the client HTTP connection ($http) dies, it
  79         # will automatically close this ($self) object.
  80         $http->{forward} = $self;
  81
  82         # write anything we overread when we were reading headers
  83         $fh->write($$bref); # PublicInbox:HTTP::{chunked,identity}_wcb
  84
  85         # we're done with this, free this memory up ASAP since the
  86         # calls after this may use much memory:
  87         $$bref = undef;
  88
  89         $self->{http} = $http;
  90         $self->{fh} = $fh;
  91
  92         # either hit EAGAIN or ->requeue to keep EPOLLET happy
  93         event_step($self);
  94 }
  95
  96 # may be called as $forward->close in PublicInbox::HTTP or EOF (event_step)
  97 sub close {
  98         my $self = $_[0];
  99         $self->SUPER::close; # DS::close
 100
 101         # we defer this to the next timer loop since close is deferred
 102         if (my $end_obj = delete $self->{end_obj}) {
 103                 # this calls $end_obj->event_step
 104                 # (likely PublicInbox::Qspawn::event_step,
 105                 #  NOT PublicInbox::HTTPD::Async::event_step)
 106                 PublicInbox::DS::requeue($end_obj);
 107         }
 108 }
 109
 110 1;