lib/PublicInbox/HTTPD/Async.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # XXX This is a totally unstable API for public-inbox internal use only
   5 # This is exposed via the 'pi-httpd.async' key in the PSGI env hash.
   6 # The name of this key is not even stable!
   7 # Currently intended for use with read-only pipes with expensive
   8 # processes such as git-http-backend(1), cgit(1)
   9 package PublicInbox::HTTPD::Async;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::DS);
  13 use fields qw(cb arg end end_arg);
  14 use Errno qw(EAGAIN);
  15 use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
  16
  17 # This is called via: $env->{'pi-httpd.async'}->()
  18 # $io is a read-only pipe ($rpipe) for now, but may be a
  19 # bidirectional socket in the future.
  20 sub new {
  21         my ($class, $io, $cb, $arg, $end, $end_arg) = @_;
  22
  23         # no $io? call $cb at the top of the next event loop to
  24         # avoid recursion:
  25         unless (defined($io)) {
  26                 PublicInbox::DS::requeue($cb ? $cb : $arg);
  27                 die '$end unsupported w/o $io' if $end;
  28                 return;
  29         }
  30
  31         my $self = fields::new($class);
  32         IO::Handle::blocking($io, 0);
  33         $self->SUPER::new($io, EPOLLIN | EPOLLET);
  34         $self->{cb} = $cb; # initial read callback, later replaced by main_cb
  35         $self->{arg} = $arg; # arg for $cb
  36         $self->{end} = $end; # like END {}, but only for this object
  37         $self->{end_arg} = $end_arg; # arg for $end
  38         $self;
  39 }
  40
  41 sub main_cb ($$) {
  42         my ($http, $fh) = @_;
  43         sub {
  44                 my ($self) = @_;
  45                 # $self->{sock} is a read pipe for git-http-backend or cgit
  46                 # and 65536 is the default Linux pipe size
  47                 my $r = sysread($self->{sock}, my $buf, 65536);
  48                 if ($r) {
  49                         $fh->write($buf); # may call $http->close
  50                         if ($http->{sock}) { # !closed
  51                                 $self->requeue;
  52                                 # let other clients get some work done, too
  53                                 return;
  54                         }
  55
  56                         # else: fall through to close below...
  57                 } elsif (!defined $r && $! == EAGAIN) {
  58                         return; # EPOLLET means we'll be notified
  59                 }
  60
  61                 # Done! Error handling will happen in $fh->close
  62                 # called by the {end} handler
  63                 delete $http->{forward};
  64                 $self->close; # queues ->{end} to be called
  65         }
  66 }
  67
  68 # once this is called, all data we read is passed to the
  69 # to the PublicInbox::HTTP instance ($http) via $fh->write
  70 sub async_pass {
  71         my ($self, $http, $fh, $bref) = @_;
  72         # In case the client HTTP connection ($http) dies, it
  73         # will automatically close this ($self) object.
  74         $http->{forward} = $self;
  75
  76         # write anything we overread when we were reading headers
  77         $fh->write($$bref); # PublicInbox:HTTP::{chunked,identity}_wcb
  78
  79         # we're done with this, free this memory up ASAP since the
  80         # calls after this may use much memory:
  81         $$bref = undef;
  82
  83         # replace the header read callback with the main one
  84         my $cb = $self->{cb} = main_cb($http, $fh);
  85         $cb->($self); # either hit EAGAIN or ->requeue to keep EPOLLET happy
  86 }
  87
  88 sub event_step {
  89         # {cb} may be undef after ->requeue due to $http->close happening
  90         my $cb = $_[0]->{cb} or return;
  91         $cb->(@_);
  92 }
  93
  94 # may be called as $forward->close in PublicInbox::HTTP or EOF (main_cb)
  95 sub close {
  96         my $self = $_[0];
  97         delete $self->{cb};
  98         $self->SUPER::close; # DS::close
  99
 100         # we defer this to the next timer loop since close is deferred
 101         if (my $end = delete $self->{end}) {
 102                 PublicInbox::DS::requeue($end);
 103         }
 104 }
 105
 106 1;