lib/PublicInbox/Hval.pm

   1 # Copyright (C) 2014-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # represents a header value in various forms.  Used for HTML generation
   5 # in our web interface(s)
   6 package PublicInbox::Hval;
   7 use strict;
   8 use warnings;
   9 use Encode qw(find_encoding);
  10 use PublicInbox::MID qw/mid_clean mid_escape/;
  11 use base qw/Exporter/;
  12 our @EXPORT_OK = qw/ascii_html obfuscate_addrs to_filename src_escape
  13                 to_attr from_attr/;
  14 my $enc_ascii = find_encoding('us-ascii');
  15
  16 # safe-ish acceptable filename pattern for portability
  17 our $FN = '[a-zA-Z0-9][a-zA-Z0-9_\-\.]+[a-zA-Z0-9]'; # needs \z anchor
  18
  19 sub new {
  20         my ($class, $raw, $href) = @_;
  21
  22         # we never care about trailing whitespace
  23         $raw =~ s/\s*\z//;
  24         bless {
  25                 raw => $raw,
  26                 href => defined $href ? $href : $raw,
  27         }, $class;
  28 }
  29
  30 sub new_msgid {
  31         my ($class, $msgid) = @_;
  32         $class->new($msgid, mid_escape($msgid));
  33 }
  34
  35 # some of these overrides are standard C escapes so they're
  36 # easy-to-understand when rendered.
  37 my %escape_sequence = (
  38         "\x00" => '\\0', # NUL
  39         "\x07" => '\\a', # bell
  40         "\x08" => '\\b', # backspace
  41         "\x09" => "\t", # obvious to show as-is
  42         "\x0a" => "\n", # obvious to show as-is
  43         "\x0b" => '\\v', # vertical tab
  44         "\x0c" => '\\f', # form feed
  45         "\x0d" => '\\r', # carriage ret (not preceding \n)
  46         "\x1b" => '^[', # ASCII escape (mutt seems to escape this way)
  47         "\x7f" => '\\x7f', # DEL
  48 );
  49
  50 my %xhtml_map = (
  51         '"' => '&#34;',
  52         '&' => '&#38;',
  53         "'" => '&#39;',
  54         '<' => '&lt;',
  55         '>' => '&gt;',
  56 );
  57
  58 $xhtml_map{chr($_)} = sprintf('\\x%02x', $_) for (0..31);
  59 %xhtml_map = (%xhtml_map, %escape_sequence);
  60
  61 sub src_escape ($) {
  62         $_[0] =~ s/\r\n/\n/sg;
  63         $_[0] =~ s/([\x7f\x00-\x1f])/$xhtml_map{$1}/sge;
  64         $_[0] = $enc_ascii->encode($_[0], Encode::HTMLCREF);
  65 }
  66
  67 sub ascii_html {
  68         my ($s) = @_;
  69         $s =~ s/\r\n/\n/sg; # fixup bad line endings
  70         $s =~ s/([<>&'"\x7f\x00-\x1f])/$xhtml_map{$1}/sge;
  71         $enc_ascii->encode($s, Encode::HTMLCREF);
  72 }
  73
  74 sub as_html { ascii_html($_[0]->{raw}) }
  75
  76 sub raw {
  77         if (defined $_[1]) {
  78                 $_[0]->{raw} = $_[1];
  79         } else {
  80                 $_[0]->{raw};
  81         }
  82 }
  83
  84 sub prurl {
  85         my ($env, $u) = @_;
  86         index($u, '//') == 0 ? "$env->{'psgi.url_scheme'}:$u" : $u;
  87 }
  88
  89 # for misguided people who believe in this stuff, give them a
  90 # substitution for '.'
  91 # &#8228; &#183; and &#890; were also candidates:
  92 #   https://public-inbox.org/meta/20170615015250.GA6484@starla/
  93 # However, &#8226; was chosen to make copy+paste errors more obvious
  94 sub obfuscate_addrs ($$;$) {
  95         my $ibx = $_[0];
  96         my $repl = $_[2] || '&#8226;';
  97         my $re = $ibx->{-no_obfuscate_re}; # regex of domains
  98         my $addrs = $ibx->{-no_obfuscate}; # { adddress => 1 }
  99         $_[1] =~ s/(([\w\.\+=\-]+)\@([\w\-]+\.[\w\.\-]+))/
 100                 my ($addr, $user, $domain) = ($1, $2, $3);
 101                 if ($addrs->{$addr} || ((defined $re && $domain =~ $re))) {
 102                         $addr;
 103                 } else {
 104                         $domain =~ s!([^\.]+)\.!$1$repl!;
 105                         $user . '@' . $domain
 106                 }
 107                 /sge;
 108 }
 109
 110 # like format_sanitized_subject in git.git pretty.c with '%f' format string
 111 sub to_filename ($) {
 112         my ($s, undef) = split(/\n/, $_[0]);
 113         $s =~ s/[^A-Za-z0-9_\.]+/-/g;
 114         $s =~ tr/././s;
 115         $s =~ s/[\.\-]+\z//;
 116         $s =~ s/\A[\.\-]+//;
 117         $s
 118 }
 119
 120 # convert a filename (or any string) to HTML attribute
 121
 122 my %ESCAPES = map { chr($_) => sprintf('::%02x', $_) } (0..255);
 123 $ESCAPES{'/'} = ':'; # common
 124
 125 sub to_attr ($) {
 126         my ($str) = @_;
 127
 128         # git would never do this to us:
 129         return if index($str, '//') >= 0;
 130
 131         my $first = '';
 132         if ($str =~ s/\A([^A-Ya-z])//ms) { # start with a letter
 133                   $first = sprintf('Z%02x', ord($1));
 134         }
 135         $str =~ s/([^A-Za-z0-9_\.\-])/$ESCAPES{$1}/egms;
 136         $first . $str;
 137 }
 138
 139 # reverse the result of to_attr
 140 sub from_attr ($) {
 141         my ($str) = @_;
 142         my $first = '';
 143         if ($str =~ s/\AZ([a-f0-9]{2})//ms) {
 144                 $first = chr(hex($1));
 145         }
 146         $str =~ s!::([a-f0-9]{2})!chr(hex($1))!egms;
 147         $str =~ tr!:!/!;
 148         $first . $str;
 149 }
 150
 151 1;