lib/PublicInbox/Hval.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # represents a header value in various forms.  Used for HTML generation
   5 # in our web interface(s)
   6 package PublicInbox::Hval;
   7 use strict;
   8 use warnings;
   9 use Encode qw(find_encoding);
  10 use PublicInbox::MID qw/mid_clean mid_escape/;
  11 use base qw/Exporter/;
  12 our @EXPORT_OK = qw/ascii_html obfuscate_addrs to_filename/;
  13
  14 # for user-generated content (UGC) which may have excessively long lines
  15 # and screw up rendering on some browsers.  This is the only CSS style
  16 # feature we use.
  17 use constant STYLE => '<style>pre{white-space:pre-wrap}</style>';
  18
  19 my $enc_ascii = find_encoding('us-ascii');
  20
  21 sub new {
  22         my ($class, $raw, $href) = @_;
  23
  24         # we never care about trailing whitespace
  25         $raw =~ s/\s*\z//;
  26         bless {
  27                 raw => $raw,
  28                 href => defined $href ? $href : $raw,
  29         }, $class;
  30 }
  31
  32 sub new_msgid {
  33         my ($class, $msgid) = @_;
  34         $class->new($msgid, mid_escape($msgid));
  35 }
  36
  37 sub new_oneline {
  38         my ($class, $raw) = @_;
  39         $raw = '' unless defined $raw;
  40         $raw =~ tr/\t\n / /s; # squeeze spaces
  41         $raw =~ tr/\r//d; # kill CR
  42         $class->new($raw);
  43 }
  44
  45 my %xhtml_map = (
  46         '"' => '&#34;',
  47         '&' => '&#38;',
  48         "'" => '&#39;',
  49         '<' => '&lt;',
  50         '>' => '&gt;',
  51 );
  52
  53 $xhtml_map{chr($_)} = sprintf('\\x%02x', $_) for (0..31);
  54 # some of these overrides are standard C escapes so they're
  55 # easy-to-understand when rendered.
  56 $xhtml_map{"\x00"} = '\\0'; # NUL
  57 $xhtml_map{"\x07"} = '\\a'; # bell
  58 $xhtml_map{"\x08"} = '\\b'; # backspace
  59 $xhtml_map{"\x09"} = "\t"; # obvious to show as-is
  60 $xhtml_map{"\x0a"} = "\n"; # obvious to show as-is
  61 $xhtml_map{"\x0b"} = '\\v'; # vertical tab
  62 $xhtml_map{"\x0c"} = '\\f'; # form feed
  63 $xhtml_map{"\x0d"} = '\\r'; # carriage ret (not preceding \n)
  64 $xhtml_map{"\x1b"} = '^['; # ASCII escape (mutt seems to escape this way)
  65 $xhtml_map{"\x7f"} = '\\x7f'; # DEL
  66
  67 sub ascii_html {
  68         my ($s) = @_;
  69         $s =~ s/\r\n/\n/sg; # fixup bad line endings
  70         $s =~ s/([<>&'"\x7f\x00-\x1f])/$xhtml_map{$1}/sge;
  71         $enc_ascii->encode($s, Encode::HTMLCREF);
  72 }
  73
  74 sub as_html { ascii_html($_[0]->{raw}) }
  75
  76 sub raw {
  77         if (defined $_[1]) {
  78                 $_[0]->{raw} = $_[1];
  79         } else {
  80                 $_[0]->{raw};
  81         }
  82 }
  83
  84 sub prurl {
  85         my ($env, $u) = @_;
  86         index($u, '//') == 0 ? "$env->{'psgi.url_scheme'}:$u" : $u;
  87 }
  88
  89 # for misguided people who believe in this stuff, give them a
  90 # substitution for '.'
  91 # &#8228; &#183; and &#890; were also candidates:
  92 #   https://public-inbox.org/meta/20170615015250.GA6484@starla/
  93 # However, &#8226; was chosen to make copy+paste errors more obvious
  94 sub obfuscate_addrs ($$;$) {
  95         my $ibx = $_[0];
  96         my $repl = $_[2] || '&#8226;';
  97         my $re = $ibx->{-no_obfuscate_re}; # regex of domains
  98         my $addrs = $ibx->{-no_obfuscate}; # { adddress => 1 }
  99         $_[1] =~ s/(([\w\.\+=\-]+)\@([\w\-]+\.[\w\.\-]+))/
 100                 my ($addr, $user, $domain) = ($1, $2, $3);
 101                 if ($addrs->{$addr} || ((defined $re && $domain =~ $re))) {
 102                         $addr;
 103                 } else {
 104                         $domain =~ s!([^\.]+)\.!$1$repl!;
 105                         $user . '@' . $domain
 106                 }
 107                 /sge;
 108 }
 109
 110 # like format_sanitized_subject in git.git pretty.c with '%f' format string
 111 sub to_filename ($) {
 112         my ($s, undef) = split(/\n/, $_[0]);
 113         $s =~ s/[^A-Za-z0-9_\.]+/-/g;
 114         $s =~ tr/././s;
 115         $s =~ s/[\.\-]+\z//;
 116         $s =~ s/\A[\.\-]+//;
 117         $s
 118 }
 119
 120 1;