lib/PublicInbox/Hval.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # represents a header value in various forms
   5 package PublicInbox::Hval;
   6 use strict;
   7 use warnings;
   8 use fields qw(raw);
   9 use Encode qw(find_encoding);
  10 use URI::Escape qw(uri_escape_utf8);
  11
  12 my $enc_ascii = find_encoding('us-ascii');
  13
  14 sub new {
  15         my ($class, $raw) = @_;
  16         my $self = fields::new($class);
  17
  18         # we never care about leading/trailing whitespace
  19         $raw =~ s/\A\s*//;
  20         $raw =~ s/\s*\z//;
  21         $self->{raw} = $raw;
  22         $self;
  23 }
  24
  25 sub new_msgid {
  26         my ($class, $raw) = @_;
  27         $raw =~ s/\A<//;
  28         $raw =~ s/>\z//;
  29         $class->new($raw);
  30 }
  31
  32 sub new_oneline {
  33         my ($class, $raw) = @_;
  34         $raw = '' unless defined $raw;
  35         $raw =~ tr/\t\n / /s; # squeeze spaces
  36         $raw =~ tr/\r//d; # kill CR
  37         $class->new($raw);
  38 }
  39
  40 my %xhtml_map = (
  41         '"' => '&#34;',
  42         '&' => '&#38;',
  43         "'" => '&#39;',
  44         '<' => '&lt;',
  45         '>' => '&gt;',
  46 );
  47
  48 sub ascii_html {
  49         my ($s) = @_;
  50         $s =~ s/([<>&'"])/$xhtml_map{$1}/ge;
  51         $enc_ascii->encode($s, Encode::HTMLCREF);
  52 }
  53
  54 sub as_html { ascii_html($_[0]->{raw}) }
  55 sub as_href { ascii_html(uri_escape_utf8($_[0]->{raw})) }
  56
  57 sub raw {
  58         if (defined $_[1]) {
  59                 $_[0]->{raw} = $_[1];
  60         } else {
  61                 $_[0]->{raw};
  62         }
  63 }
  64
  65 1;