lib/PublicInbox/Hval.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # represents a header value in various forms
   5 package PublicInbox::Hval;
   6 use strict;
   7 use warnings;
   8 use Encode qw(find_encoding);
   9 use URI::Escape qw(uri_escape_utf8);
  10 use PublicInbox::MID qw/mid_clean/;
  11
  12 my $enc_ascii = find_encoding('us-ascii');
  13
  14 sub new {
  15         my ($class, $raw, $href) = @_;
  16
  17         # we never care about leading/trailing whitespace
  18         $raw =~ s/\A\s*//;
  19         $raw =~ s/\s*\z//;
  20         bless {
  21                 raw => $raw,
  22                 href => defined $href ? $href : $raw,
  23         }, $class;
  24 }
  25
  26 sub new_msgid {
  27         my ($class, $msgid, $no_compress) = @_;
  28         $msgid = mid_clean($msgid);
  29         $class->new($msgid, $msgid);
  30 }
  31
  32 sub new_oneline {
  33         my ($class, $raw) = @_;
  34         $raw = '' unless defined $raw;
  35         $raw =~ tr/\t\n / /s; # squeeze spaces
  36         $raw =~ tr/\r//d; # kill CR
  37         $class->new($raw);
  38 }
  39
  40 my %xhtml_map = (
  41         '"' => '&#34;',
  42         '&' => '&#38;',
  43         "'" => '&#39;',
  44         '<' => '&lt;',
  45         '>' => '&gt;',
  46 );
  47
  48 sub ascii_html {
  49         my ($s) = @_;
  50         $s =~ s/\r\n/\n/sg; # fixup bad line endings
  51         $s =~ s/([<>&'"])/$xhtml_map{$1}/ge;
  52         $enc_ascii->encode($s, Encode::HTMLCREF);
  53 }
  54
  55 sub as_html { ascii_html($_[0]->{raw}) }
  56 sub as_href { ascii_html(uri_escape_utf8($_[0]->{href})) }
  57
  58 sub raw {
  59         if (defined $_[1]) {
  60                 $_[0]->{raw} = $_[1];
  61         } else {
  62                 $_[0]->{raw};
  63         }
  64 }
  65
  66 1;