lib/PublicInbox/Hval.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # represents a header value in various forms.  Used for HTML generation
   5 # in our web interface(s)
   6 package PublicInbox::Hval;
   7 use strict;
   8 use warnings;
   9 use Encode qw(find_encoding);
  10 use URI::Escape qw(uri_escape_utf8);
  11 use PublicInbox::MID qw/mid_clean/;
  12 use base qw/Exporter/;
  13 our @EXPORT_OK = qw/ascii_html/;
  14
  15 # for user-generated content (UGC) which may have excessively long lines
  16 # and screw up rendering on some browsers.  This is the only CSS style
  17 # feature we use.
  18 use constant STYLE => '<style>pre{white-space:pre-wrap}</style>';
  19
  20 my $enc_ascii = find_encoding('us-ascii');
  21
  22 sub new {
  23         my ($class, $raw, $href) = @_;
  24
  25         # we never care about trailing whitespace
  26         $raw =~ s/\s*\z//;
  27         bless {
  28                 raw => $raw,
  29                 href => defined $href ? $href : $raw,
  30         }, $class;
  31 }
  32
  33 sub new_msgid {
  34         my ($class, $msgid, $no_compress) = @_;
  35         $msgid = mid_clean($msgid);
  36         $class->new($msgid, $msgid);
  37 }
  38
  39 sub new_oneline {
  40         my ($class, $raw) = @_;
  41         $raw = '' unless defined $raw;
  42         $raw =~ tr/\t\n / /s; # squeeze spaces
  43         $raw =~ tr/\r//d; # kill CR
  44         $class->new($raw);
  45 }
  46
  47 my %xhtml_map = (
  48         '"' => '&#34;',
  49         '&' => '&#38;',
  50         "'" => '&#39;',
  51         '<' => '&lt;',
  52         '>' => '&gt;',
  53 );
  54
  55 sub ascii_html {
  56         my ($s) = @_;
  57         $s =~ s/\r\n/\n/sg; # fixup bad line endings
  58         $s =~ s/([<>&'"])/$xhtml_map{$1}/ge;
  59         $enc_ascii->encode($s, Encode::HTMLCREF);
  60 }
  61
  62 sub as_html { ascii_html($_[0]->{raw}) }
  63 sub as_href { ascii_html(uri_escape_utf8($_[0]->{href})) }
  64
  65 sub raw {
  66         if (defined $_[1]) {
  67                 $_[0]->{raw} = $_[1];
  68         } else {
  69                 $_[0]->{raw};
  70         }
  71 }
  72
  73 sub prurl {
  74         my ($env, $u) = @_;
  75         index($u, '//') == 0 ? "$env->{'psgi.url_scheme'}:$u" : $u;
  76 }
  77
  78 1;