lib/PublicInbox/Hval.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # represents a header value in various forms.  Used for HTML generation
   5 # in our web interface(s)
   6 package PublicInbox::Hval;
   7 use strict;
   8 use warnings;
   9 use Encode qw(find_encoding);
  10 use PublicInbox::MID qw/mid_clean mid_escape/;
  11 use base qw/Exporter/;
  12 our @EXPORT_OK = qw/ascii_html/;
  13
  14 # for user-generated content (UGC) which may have excessively long lines
  15 # and screw up rendering on some browsers.  This is the only CSS style
  16 # feature we use.
  17 use constant STYLE => '<style>pre{white-space:pre-wrap}</style>';
  18
  19 my $enc_ascii = find_encoding('us-ascii');
  20
  21 sub new {
  22         my ($class, $raw, $href) = @_;
  23
  24         # we never care about trailing whitespace
  25         $raw =~ s/\s*\z//;
  26         bless {
  27                 raw => $raw,
  28                 href => defined $href ? $href : $raw,
  29         }, $class;
  30 }
  31
  32 sub new_msgid {
  33         my ($class, $msgid) = @_;
  34         $msgid = mid_clean($msgid);
  35         $class->new($msgid, mid_escape($msgid));
  36 }
  37
  38 sub new_oneline {
  39         my ($class, $raw) = @_;
  40         $raw = '' unless defined $raw;
  41         $raw =~ tr/\t\n / /s; # squeeze spaces
  42         $raw =~ tr/\r//d; # kill CR
  43         $class->new($raw);
  44 }
  45
  46 my %xhtml_map = (
  47         '"' => '&#34;',
  48         '&' => '&#38;',
  49         "'" => '&#39;',
  50         '<' => '&lt;',
  51         '>' => '&gt;',
  52 );
  53
  54 $xhtml_map{chr($_)} = sprintf('\\x%02x', $_) for (0..31);
  55 # some of these overrides are standard C escapes so they're
  56 # easy-to-understand when rendered.
  57 $xhtml_map{"\x00"} = '\\0'; # NUL
  58 $xhtml_map{"\x07"} = '\\a'; # bell
  59 $xhtml_map{"\x08"} = '\\b'; # backspace
  60 $xhtml_map{"\x09"} = "\t"; # obvious to show as-is
  61 $xhtml_map{"\x0a"} = "\n"; # obvious to show as-is
  62 $xhtml_map{"\x0b"} = '\\v'; # vertical tab
  63 $xhtml_map{"\x0c"} = '\\f'; # form feed
  64 $xhtml_map{"\x0d"} = '\\r'; # carriage ret (not preceding \n)
  65 $xhtml_map{"\x1b"} = '^['; # ASCII escape (mutt seems to escape this way)
  66 $xhtml_map{"\x7f"} = '\\x7f'; # DEL
  67
  68 sub ascii_html {
  69         my ($s) = @_;
  70         $s =~ s/\r\n/\n/sg; # fixup bad line endings
  71         $s =~ s/([<>&'"\x7f\x00-\x1f])/$xhtml_map{$1}/sge;
  72         $enc_ascii->encode($s, Encode::HTMLCREF);
  73 }
  74
  75 sub as_html { ascii_html($_[0]->{raw}) }
  76
  77 sub raw {
  78         if (defined $_[1]) {
  79                 $_[0]->{raw} = $_[1];
  80         } else {
  81                 $_[0]->{raw};
  82         }
  83 }
  84
  85 sub prurl {
  86         my ($env, $u) = @_;
  87         index($u, '//') == 0 ? "$env->{'psgi.url_scheme'}:$u" : $u;
  88 }
  89
  90 1;