lib/PublicInbox/IMAP.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents an IMAP client connected to
   5 # public-inbox-imapd.  Much of this was taken from NNTP, but
   6 # further refined while experimenting on future ideas to handle
   7 # slow storage.
   8 #
   9 # data notes:
  10 #
  11 # * NNTP article numbers are UIDs, mm->created_at is UIDVALIDITY
  12 #
  13 # * public-inboxes are sliced into mailboxes of 50K messages
  14 #   to not overload MUAs: $NEWSGROUP_NAME.$SLICE_INDEX
  15 #   Slices are similar in concept to v2 "epochs".  Epochs
  16 #   are for the limitations of git clients, while slices are
  17 #   for the limitations of IMAP clients.
  18 #
  19 # * We also take advantage of slices being only 50K to store
  20 #   "UID offset" to message sequence number (MSN) mapping
  21 #   as a 50K uint16_t array (via pack("S*", ...)).  "UID offset"
  22 #   is the offset from {uid_base} which determines the start of
  23 #   the mailbox slice.
  24 #
  25 # fields:
  26 # imapd: PublicInbox::IMAPD ref
  27 # ibx: PublicInbox::Inbox ref
  28 # long_cb: long_response private data
  29 # uid_base: base UID for mailbox slice (0-based)
  30 # -login_tag: IMAP TAG for LOGIN
  31 # -idle_tag: IMAP response tag for IDLE
  32 # uo2m: UID-to-MSN mapping
  33 package PublicInbox::IMAP;
  34 use strict;
  35 use parent qw(PublicInbox::DS);
  36 use PublicInbox::Eml;
  37 use PublicInbox::EmlContentFoo qw(parse_content_disposition);
  38 use PublicInbox::DS qw(now);
  39 use PublicInbox::GitAsyncCat;
  40 use Text::ParseWords qw(parse_line);
  41 use Errno qw(EAGAIN);
  42 use PublicInbox::IMAPsearchqp;
  43
  44 my $Address;
  45 for my $mod (qw(Email::Address::XS Mail::Address)) {
  46         eval "require $mod" or next;
  47         $Address = $mod and last;
  48 }
  49 die "neither Email::Address::XS nor Mail::Address loaded: $@" if !$Address;
  50
  51 sub LINE_MAX () { 8000 } # RFC 2683 3.2.1.5
  52
  53 # Changing UID_SLICE will cause grief for clients which cache.
  54 # This also needs to be <64K: we pack it into a uint16_t
  55 # for long_response UID (offset) => MSN mappings
  56 sub UID_SLICE () { 50_000 }
  57
  58 # these values area also used for sorting
  59 sub NEED_SMSG () { 1 }
  60 sub NEED_BLOB () { NEED_SMSG|2 }
  61 sub CRLF_BREF () { 4 }
  62 sub EML_HDR () { 8 }
  63 sub CRLF_HDR () { 16 }
  64 sub EML_BDY () { 32 }
  65 sub CRLF_BDY () { 64 }
  66 my $OP_EML_NEW = [ EML_HDR - 1, \&op_eml_new ];
  67 my $OP_CRLF_BREF = [ CRLF_BREF, \&op_crlf_bref ];
  68 my $OP_CRLF_HDR = [ CRLF_HDR, \&op_crlf_hdr ];
  69 my $OP_CRLF_BDY = [ CRLF_BDY, \&op_crlf_bdy ];
  70
  71 my %FETCH_NEED = (
  72         'BODY[HEADER]' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  73         'BODY[TEXT]' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  74         'BODY[]' => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  75         'RFC822.HEADER' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  76         'RFC822.TEXT' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  77         'RFC822.SIZE' => [ NEED_SMSG, \&emit_rfc822_size ],
  78         RFC822 => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  79         BODY => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_body ],
  80         BODYSTRUCTURE => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_bodystructure ],
  81         ENVELOPE => [ NEED_BLOB|EML_HDR, \&emit_envelope ],
  82         FLAGS => [ 0, \&emit_flags ],
  83         INTERNALDATE => [ NEED_SMSG, \&emit_internaldate ],
  84 );
  85 my %FETCH_ATT = map { $_ => [ $_ ] } keys %FETCH_NEED;
  86
  87 # aliases (RFC 3501 section 6.4.5)
  88 $FETCH_ATT{FAST} = [ qw(FLAGS INTERNALDATE RFC822.SIZE) ];
  89 $FETCH_ATT{ALL} = [ @{$FETCH_ATT{FAST}}, 'ENVELOPE' ];
  90 $FETCH_ATT{FULL} = [ @{$FETCH_ATT{ALL}}, 'BODY' ];
  91
  92 for my $att (keys %FETCH_ATT) {
  93         my %h = map { $_ => $FETCH_NEED{$_} } @{$FETCH_ATT{$att}};
  94         $FETCH_ATT{$att} = \%h;
  95 }
  96 undef %FETCH_NEED;
  97
  98 my $valid_range = '[0-9]+|[0-9]+:[0-9]+|[0-9]+:\*';
  99 $valid_range = qr/\A(?:$valid_range)(?:,(?:$valid_range))*\z/;
 100
 101 sub do_greet {
 102         my ($self) = @_;
 103         my $capa = capa($self);
 104         $self->write(\"* OK [$capa] public-inbox-imapd ready\r\n");
 105 }
 106
 107 sub new {
 108         my (undef, $sock, $imapd) = @_;
 109         (bless { imapd => $imapd }, 'PublicInbox::IMAP_preauth')->greet($sock)
 110 }
 111
 112 sub logged_in { 1 }
 113
 114 sub capa ($) {
 115         my ($self) = @_;
 116
 117         # dovecot advertises IDLE pre-login; perhaps because some clients
 118         # depend on it, so we'll do the same
 119         my $capa = 'CAPABILITY IMAP4rev1 IDLE';
 120         if ($self->logged_in) {
 121                 $capa .= ' COMPRESS=DEFLATE';
 122         } else {
 123                 if (!($self->{sock} // $self)->can('accept_SSL') &&
 124                         $self->{imapd}->{accept_tls}) {
 125                         $capa .= ' STARTTLS';
 126                 }
 127                 $capa .= ' AUTH=ANONYMOUS';
 128         }
 129 }
 130
 131 sub login_success ($$) {
 132         my ($self, $tag) = @_;
 133         bless $self, 'PublicInbox::IMAP';
 134         my $capa = capa($self);
 135         "$tag OK [$capa] Logged in\r\n";
 136 }
 137
 138 sub auth_challenge_ok ($) {
 139         my ($self) = @_;
 140         my $tag = delete($self->{-login_tag}) or return;
 141         login_success($self, $tag);
 142 }
 143
 144 sub cmd_login ($$$$) {
 145         my ($self, $tag) = @_; # ignore ($user, $password) = ($_[2], $_[3])
 146         login_success($self, $tag);
 147 }
 148
 149 sub cmd_close ($$) {
 150         my ($self, $tag) = @_;
 151         delete @$self{qw(uid_base uo2m)};
 152         delete $self->{ibx} ? "$tag OK Close done\r\n"
 153                                 : "$tag BAD No mailbox\r\n";
 154 }
 155
 156 sub cmd_logout ($$) {
 157         my ($self, $tag) = @_;
 158         delete $self->{-idle_tag};
 159         $self->write(\"* BYE logging out\r\n$tag OK Logout done\r\n");
 160         $self->shutdn; # PublicInbox::DS::shutdn
 161         undef;
 162 }
 163
 164 sub cmd_authenticate ($$$) {
 165         my ($self, $tag) = @_; # $method = $_[2], should be "ANONYMOUS"
 166         $self->{-login_tag} = $tag;
 167         "+\r\n"; # challenge
 168 }
 169
 170 sub cmd_capability ($$) {
 171         my ($self, $tag) = @_;
 172         '* '.capa($self)."\r\n$tag OK Capability done\r\n";
 173 }
 174
 175 # uo2m: UID Offset to MSN, this is an arrayref by default,
 176 # but uo2m_hibernate can compact and deduplicate it
 177 sub uo2m_ary_new ($;$) {
 178         my ($self, $exists) = @_;
 179         my $ub = $self->{uid_base};
 180         my $uids = $self->{ibx}->over(1)->uid_range($ub + 1, $ub + UID_SLICE);
 181
 182         # convert UIDs to offsets from {base}
 183         my @tmp; # [$UID_OFFSET] => $MSN
 184         my $msn = 0;
 185         ++$ub;
 186         $tmp[$_ - $ub] = ++$msn for @$uids;
 187         $$exists = $msn if $exists;
 188         \@tmp;
 189 }
 190
 191 # changes UID-offset-to-MSN mapping into a deduplicated scalar:
 192 # uint16_t uo2m[UID_SLICE].
 193 # May be swapped out for idle clients if THP is disabled.
 194 sub uo2m_hibernate ($) {
 195         my ($self) = @_;
 196         ref(my $uo2m = $self->{uo2m}) or return;
 197         my %dedupe = ( uo2m_pack($uo2m) => undef );
 198         $self->{uo2m} = (keys(%dedupe))[0];
 199         undef;
 200 }
 201
 202 sub uo2m_last_uid ($) {
 203         my ($self) = @_;
 204         defined(my $uo2m = $self->{uo2m}) or die 'BUG: uo2m_last_uid w/o {uo2m}';
 205         (ref($uo2m) ? @$uo2m : (length($uo2m) >> 1)) + $self->{uid_base};
 206 }
 207
 208 sub uo2m_pack ($) {
 209         # $_[0] is an arrayref of MSNs, it may have undef gaps if there
 210         # are gaps in the corresponding UIDs: [ msn1, msn2, undef, msn3 ]
 211         no warnings 'uninitialized';
 212         pack('S*', @{$_[0]});
 213 }
 214
 215 # extend {uo2m} to account for new messages which arrived since
 216 # {uo2m} was created.
 217 sub uo2m_extend ($$;$) {
 218         my ($self, $new_uid_max) = @_;
 219         defined(my $uo2m = $self->{uo2m}) or
 220                 return($self->{uo2m} = uo2m_ary_new($self));
 221         my $beg = uo2m_last_uid($self); # last UID we've learned
 222         return $uo2m if $beg >= $new_uid_max; # fast path
 223
 224         # need to extend the current range:
 225         my $base = $self->{uid_base};
 226         ++$beg;
 227         my $uids = $self->{ibx}->over(1)->uid_range($beg, $base + UID_SLICE);
 228         return $uo2m if !scalar(@$uids);
 229         my @tmp; # [$UID_OFFSET] => $MSN
 230         my $write_method = $_[2] // 'msg_more';
 231         if (ref($uo2m)) {
 232                 my $msn = $uo2m->[-1];
 233                 $tmp[$_ - $beg] = ++$msn for @$uids;
 234                 $self->$write_method("* $msn EXISTS\r\n");
 235                 push @$uo2m, @tmp;
 236                 $uo2m;
 237         } else {
 238                 my $msn = unpack('S', substr($uo2m, -2, 2));
 239                 $tmp[$_ - $beg] = ++$msn for @$uids;
 240                 $self->$write_method("* $msn EXISTS\r\n");
 241                 $uo2m .= uo2m_pack(\@tmp);
 242                 my %dedupe = ($uo2m => undef);
 243                 $self->{uo2m} = (keys %dedupe)[0];
 244         }
 245 }
 246
 247 sub cmd_noop ($$) {
 248         my ($self, $tag) = @_;
 249         defined($self->{uid_base}) and
 250                 uo2m_extend($self, $self->{uid_base} + UID_SLICE);
 251         \"$tag OK Noop done\r\n";
 252 }
 253
 254 # the flexible version which works on scalars and array refs.
 255 # Must call uo2m_extend before this
 256 sub uid2msn ($$) {
 257         my ($self, $uid) = @_;
 258         my $uo2m = $self->{uo2m};
 259         my $off = $uid - $self->{uid_base} - 1;
 260         ref($uo2m) ? $uo2m->[$off] : unpack('S', substr($uo2m, $off << 1, 2));
 261 }
 262
 263 # returns an arrayref of UIDs, so MSNs can be translated to UIDs via:
 264 # $msn2uid->[$MSN-1] => $UID.  The result of this is always ephemeral
 265 # and does not live beyond the event loop.
 266 sub msn2uid ($) {
 267         my ($self) = @_;
 268         my $base = $self->{uid_base};
 269         my $uo2m = uo2m_extend($self, $base + UID_SLICE);
 270         $uo2m = [ unpack('S*', $uo2m) ] if !ref($uo2m);
 271
 272         my $uo = 0;
 273         my @msn2uid;
 274         for my $msn (@$uo2m) {
 275                 ++$uo;
 276                 $msn2uid[$msn - 1] = $uo + $base if $msn;
 277         }
 278         \@msn2uid;
 279 }
 280
 281 # converts a set of message sequence numbers in requests to UIDs:
 282 sub msn_to_uid_range ($$) {
 283         my $msn2uid = $_[0];
 284         $_[1] =~ s!([0-9]+)!$msn2uid->[$1 - 1] // ($msn2uid->[-1] // 0 + 1)!sge;
 285 }
 286
 287 # called by PublicInbox::InboxIdle
 288 sub on_inbox_unlock {
 289         my ($self, $ibx) = @_;
 290         my $uid_end = $self->{uid_base} + UID_SLICE;
 291         uo2m_extend($self, $uid_end, 'write');
 292         my $new = uo2m_last_uid($self);
 293         if ($new == $uid_end) { # max exceeded $uid_end
 294                 # continue idling w/o inotify
 295                 my $sock = $self->{sock} or return;
 296                 $ibx->unsubscribe_unlock(fileno($sock));
 297         }
 298 }
 299
 300 # called every minute or so by PublicInbox::DS::later
 301 my $IDLERS; # fileno($obj->{sock}) => PublicInbox::IMAP
 302 sub idle_tick_all {
 303         my $old = $IDLERS;
 304         $IDLERS = undef;
 305         for my $i (values %$old) {
 306                 next if ($i->{wbuf} || !exists($i->{-idle_tag}));
 307                 $IDLERS->{fileno($i->{sock})} = $i;
 308                 $i->write(\"* OK Still here\r\n");
 309         }
 310         $IDLERS and
 311                 PublicInbox::DS::add_uniq_timer('idle', 60, \&idle_tick_all);
 312 }
 313
 314 sub cmd_idle ($$) {
 315         my ($self, $tag) = @_;
 316         # IDLE seems allowed by dovecot w/o a mailbox selected *shrug*
 317         my $ibx = $self->{ibx} or return "$tag BAD no mailbox selected\r\n";
 318         my $uid_end = $self->{uid_base} + UID_SLICE;
 319         uo2m_extend($self, $uid_end);
 320         my $sock = $self->{sock} or return;
 321         my $fd = fileno($sock);
 322         $self->{-idle_tag} = $tag;
 323         # only do inotify on most recent slice
 324         if ($ibx->over(1)->max < $uid_end) {
 325                 $ibx->subscribe_unlock($fd, $self);
 326                 $self->{imapd}->idler_start;
 327         }
 328         PublicInbox::DS::add_uniq_timer('idle', 60, \&idle_tick_all);
 329         $IDLERS->{$fd} = $self;
 330         \"+ idling\r\n"
 331 }
 332
 333 sub stop_idle ($$) {
 334         my ($self, $ibx) = @_;
 335         my $sock = $self->{sock} or return;
 336         my $fd = fileno($sock);
 337         delete $IDLERS->{$fd};
 338         $ibx->unsubscribe_unlock($fd);
 339 }
 340
 341 sub idle_done ($$) {
 342         my ($self, $tag) = @_; # $tag is "DONE" (case-insensitive)
 343         defined(my $idle_tag = delete $self->{-idle_tag}) or
 344                 return "$tag BAD not idle\r\n";
 345         my $ibx = $self->{ibx} or do {
 346                 warn "BUG: idle_tag set w/o inbox";
 347                 return "$tag BAD internal bug\r\n";
 348         };
 349         stop_idle($self, $ibx);
 350         "$idle_tag OK Idle done\r\n";
 351 }
 352
 353 sub ensure_slices_exist ($$$) {
 354         my ($imapd, $ibx, $max) = @_;
 355         defined(my $mb_top = $ibx->{newsgroup}) or return;
 356         my $mailboxes = $imapd->{mailboxes};
 357         my @created;
 358         for (my $i = int($max/UID_SLICE); $i >= 0; --$i) {
 359                 my $sub_mailbox = "$mb_top.$i";
 360                 last if exists $mailboxes->{$sub_mailbox};
 361                 $mailboxes->{$sub_mailbox} = $ibx;
 362                 $sub_mailbox =~ s/\Ainbox\./INBOX./i; # more familiar to users
 363                 push @created, $sub_mailbox;
 364         }
 365         return unless @created;
 366         my $l = $imapd->{mailboxlist} or return;
 367         push @$l, map { qq[* LIST (\\HasNoChildren) "." $_\r\n] } @created;
 368 }
 369
 370 sub inbox_lookup ($$;$) {
 371         my ($self, $mailbox, $examine) = @_;
 372         my ($ibx, $exists, $uidmax, $uid_base) = (undef, 0, 0, 0);
 373         $mailbox = lc $mailbox;
 374         $ibx = $self->{imapd}->{mailboxes}->{$mailbox} or return;
 375         my $over = $ibx->over(1);
 376         if ($over != $ibx) { # not a dummy
 377                 $mailbox =~ /\.([0-9]+)\z/ or
 378                                 die "BUG: unexpected dummy mailbox: $mailbox\n";
 379                 $uid_base = $1 * UID_SLICE;
 380
 381                 $uidmax = $ibx->mm->num_highwater // 0;
 382                 if ($examine) {
 383                         $self->{uid_base} = $uid_base;
 384                         $self->{ibx} = $ibx;
 385                         $self->{uo2m} = uo2m_ary_new($self, \$exists);
 386                 } else {
 387                         my $uid_end = $uid_base + UID_SLICE;
 388                         $exists = $over->imap_exists($uid_base, $uid_end);
 389                 }
 390                 ensure_slices_exist($self->{imapd}, $ibx, $over->max);
 391         } else {
 392                 if ($examine) {
 393                         $self->{uid_base} = $uid_base;
 394                         $self->{ibx} = $ibx;
 395                         delete $self->{uo2m};
 396                 }
 397                 # if "INBOX.foo.bar" is selected and "INBOX.foo.bar.0",
 398                 # check for new UID ranges (e.g. "INBOX.foo.bar.1")
 399                 if (my $z = $self->{imapd}->{mailboxes}->{"$mailbox.0"}) {
 400                         ensure_slices_exist($self->{imapd}, $z,
 401                                                 $z->over(1)->max);
 402                 }
 403         }
 404         ($ibx, $exists, $uidmax + 1, $uid_base);
 405 }
 406
 407 sub cmd_examine ($$$) {
 408         my ($self, $tag, $mailbox) = @_;
 409         # XXX: do we need this? RFC 5162/7162
 410         my $ret = $self->{ibx} ? "* OK [CLOSED] previous closed\r\n" : '';
 411         my ($ibx, $exists, $uidnext, $base) = inbox_lookup($self, $mailbox, 1);
 412         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 413         $ret .= <<EOF;
 414 * $exists EXISTS\r
 415 * $exists RECENT\r
 416 * FLAGS (\\Seen)\r
 417 * OK [PERMANENTFLAGS ()] Read-only mailbox\r
 418 * OK [UNSEEN $exists]\r
 419 * OK [UIDNEXT $uidnext]\r
 420 * OK [UIDVALIDITY $ibx->{uidvalidity}]\r
 421 $tag OK [READ-ONLY] EXAMINE/SELECT done\r
 422 EOF
 423 }
 424
 425 sub _esc ($) {
 426         my ($v) = @_;
 427         if (!defined($v)) {
 428                 'NIL';
 429         } elsif ($v =~ /[{"\r\n%*\\\[]/) { # literal string
 430                 '{' . length($v) . "}\r\n" . $v;
 431         } else { # quoted string
 432                 qq{"$v"}
 433         }
 434 }
 435
 436 sub addr_envelope ($$;$) {
 437         my ($eml, $x, $y) = @_;
 438         my $v = $eml->header_raw($x) //
 439                 ($y ? $eml->header_raw($y) : undef) // return 'NIL';
 440
 441         my @x = $Address->parse($v) or return 'NIL';
 442         '(' . join('',
 443                 map { '(' . join(' ',
 444                                 _esc($_->name), 'NIL',
 445                                 _esc($_->user), _esc($_->host)
 446                         ) . ')'
 447                 } @x) .
 448         ')';
 449 }
 450
 451 sub eml_envelope ($) {
 452         my ($eml) = @_;
 453         '(' . join(' ',
 454                 _esc($eml->header_raw('Date')),
 455                 _esc($eml->header_raw('Subject')),
 456                 addr_envelope($eml, 'From'),
 457                 addr_envelope($eml, 'Sender', 'From'),
 458                 addr_envelope($eml, 'Reply-To', 'From'),
 459                 addr_envelope($eml, 'To'),
 460                 addr_envelope($eml, 'Cc'),
 461                 addr_envelope($eml, 'Bcc'),
 462                 _esc($eml->header_raw('In-Reply-To')),
 463                 _esc($eml->header_raw('Message-ID')),
 464         ) . ')';
 465 }
 466
 467 sub _esc_hash ($) {
 468         my ($hash) = @_;
 469         if ($hash && scalar keys %$hash) {
 470                 $hash = [ %$hash ]; # flatten hash into 1-dimensional array
 471                 '(' . join(' ', map { _esc($_) } @$hash) . ')';
 472         } else {
 473                 'NIL';
 474         }
 475 }
 476
 477 sub body_disposition ($) {
 478         my ($eml) = @_;
 479         my $cd = $eml->header_raw('Content-Disposition') or return 'NIL';
 480         $cd = parse_content_disposition($cd);
 481         my $buf = '('._esc($cd->{type});
 482         $buf .= ' ' . _esc_hash($cd->{attributes});
 483         $buf .= ')';
 484 }
 485
 486 sub body_leaf ($$;$) {
 487         my ($eml, $structure, $hold) = @_;
 488         my $buf = '';
 489         $eml->{is_submsg} and # parent was a message/(rfc822|news|global)
 490                 $buf .= eml_envelope($eml). ' ';
 491         my $ct = $eml->ct;
 492         $buf .= '('._esc($ct->{type}).' ';
 493         $buf .= _esc($ct->{subtype});
 494         $buf .= ' ' . _esc_hash($ct->{attributes});
 495         $buf .= ' ' . _esc($eml->header_raw('Content-ID'));
 496         $buf .= ' ' . _esc($eml->header_raw('Content-Description'));
 497         my $cte = $eml->header_raw('Content-Transfer-Encoding') // '7bit';
 498         $buf .= ' ' . _esc($cte);
 499         $buf .= ' ' . $eml->{imap_body_len};
 500         $buf .= ' '.($eml->body_raw =~ tr/\n/\n/) if lc($ct->{type}) eq 'text';
 501
 502         # for message/(rfc822|global|news), $hold[0] should have envelope
 503         $buf .= ' ' . (@$hold ? join('', @$hold) : 'NIL') if $hold;
 504
 505         if ($structure) {
 506                 $buf .= ' '._esc($eml->header_raw('Content-MD5'));
 507                 $buf .= ' '. body_disposition($eml);
 508                 $buf .= ' '._esc($eml->header_raw('Content-Language'));
 509                 $buf .= ' '._esc($eml->header_raw('Content-Location'));
 510         }
 511         $buf .= ')';
 512 }
 513
 514 sub body_parent ($$$) {
 515         my ($eml, $structure, $hold) = @_;
 516         my $ct = $eml->ct;
 517         my $type = lc($ct->{type});
 518         if ($type eq 'multipart') {
 519                 my $buf = '(';
 520                 $buf .= @$hold ? join('', @$hold) : 'NIL';
 521                 $buf .= ' '._esc($ct->{subtype});
 522                 if ($structure) {
 523                         $buf .= ' '._esc_hash($ct->{attributes});
 524                         $buf .= ' '.body_disposition($eml);
 525                         $buf .= ' '._esc($eml->header_raw('Content-Language'));
 526                         $buf .= ' '._esc($eml->header_raw('Content-Location'));
 527                 }
 528                 $buf .= ')';
 529                 @$hold = ($buf);
 530         } else { # message/(rfc822|global|news)
 531                 @$hold = (body_leaf($eml, $structure, $hold));
 532         }
 533 }
 534
 535 # this is gross, but we need to process the parent part AFTER
 536 # the child parts are done
 537 sub bodystructure_prep {
 538         my ($p, $q) = @_;
 539         my ($eml, $depth) = @$p; # ignore idx
 540         # set length here, as $eml->{bdy} gets deleted for message/rfc822
 541         $eml->{imap_body_len} = length($eml->body_raw);
 542         push @$q, $eml, $depth;
 543 }
 544
 545 # for FETCH BODY and FETCH BODYSTRUCTURE
 546 sub fetch_body ($;$) {
 547         my ($eml, $structure) = @_;
 548         my @q;
 549         $eml->each_part(\&bodystructure_prep, \@q, 0, 1);
 550         my $cur_depth = 0;
 551         my @hold;
 552         do {
 553                 my ($part, $depth) = splice(@q, -2);
 554                 my $is_mp_parent = $depth == ($cur_depth - 1);
 555                 $cur_depth = $depth;
 556
 557                 if ($is_mp_parent) {
 558                         body_parent($part, $structure, \@hold);
 559                 } else {
 560                         unshift @hold, body_leaf($part, $structure);
 561                 }
 562         } while (@q);
 563         join('', @hold);
 564 }
 565
 566 sub fetch_run_ops {
 567         my ($self, $smsg, $bref, $ops, $partial) = @_;
 568         my $uid = $smsg->{num};
 569         $self->msg_more('* '.uid2msn($self, $uid)." FETCH (UID $uid");
 570         my ($eml, $k);
 571         for (my $i = 0; $i < @$ops;) {
 572                 $k = $ops->[$i++];
 573                 $ops->[$i++]->($self, $k, $smsg, $bref, $eml);
 574         }
 575         partial_emit($self, $partial, $eml) if $partial;
 576         $self->msg_more(")\r\n");
 577 }
 578
 579 sub fetch_blob_cb { # called by git->cat_async via ibx_async_cat
 580         my ($bref, $oid, $type, $size, $fetch_arg) = @_;
 581         my ($self, undef, $msgs, $range_info, $ops, $partial) = @$fetch_arg;
 582         my $ibx = $self->{ibx} or return $self->close; # client disconnected
 583         my $smsg = shift @$msgs or die 'BUG: no smsg';
 584         if (!defined($oid)) {
 585                 # it's possible to have TOCTOU if an admin runs
 586                 # public-inbox-(edit|purge), just move onto the next message
 587                 warn "E: $smsg->{blob} missing in $ibx->{inboxdir}\n";
 588                 return $self->requeue_once;
 589         } else {
 590                 $smsg->{blob} eq $oid or die "BUG: $smsg->{blob} != $oid";
 591         }
 592         my $pre;
 593         if (!$self->{wbuf} && (my $nxt = $msgs->[0])) {
 594                 $pre = ibx_async_prefetch($ibx, $nxt->{blob},
 595                                         \&fetch_blob_cb, $fetch_arg);
 596         }
 597         fetch_run_ops($self, $smsg, $bref, $ops, $partial);
 598         $pre ? $self->zflush : $self->requeue_once;
 599 }
 600
 601 sub emit_rfc822 {
 602         my ($self, $k, undef, $bref) = @_;
 603         $self->msg_more(" $k {" . length($$bref)."}\r\n");
 604         $self->msg_more($$bref);
 605 }
 606
 607 # Mail::IMAPClient::message_string cares about this by default,
 608 # (->Ignoresizeerrors attribute).  Admins are encouraged to
 609 # --reindex for IMAP support, anyways.
 610 sub emit_rfc822_size {
 611         my ($self, $k, $smsg) = @_;
 612         $self->msg_more(' RFC822.SIZE ' . $smsg->{bytes});
 613 }
 614
 615 sub emit_internaldate {
 616         my ($self, undef, $smsg) = @_;
 617         $self->msg_more(' INTERNALDATE "'.$smsg->internaldate.'"');
 618 }
 619
 620 sub emit_flags { $_[0]->msg_more(' FLAGS ()') }
 621
 622 sub emit_envelope {
 623         my ($self, undef, undef, undef, $eml) = @_;
 624         $self->msg_more(' ENVELOPE '.eml_envelope($eml));
 625 }
 626
 627 sub emit_rfc822_header {
 628         my ($self, $k, undef, undef, $eml) = @_;
 629         $self->msg_more(" $k {".length(${$eml->{hdr}})."}\r\n");
 630         $self->msg_more(${$eml->{hdr}});
 631 }
 632
 633 # n.b. this is sorted to be after any emit_eml_new ops
 634 sub emit_rfc822_text {
 635         my ($self, $k, undef, $bref) = @_;
 636         $self->msg_more(" $k {".length($$bref)."}\r\n");
 637         $self->msg_more($$bref);
 638 }
 639
 640 sub emit_bodystructure {
 641         my ($self, undef, undef, undef, $eml) = @_;
 642         $self->msg_more(' BODYSTRUCTURE '.fetch_body($eml, 1));
 643 }
 644
 645 sub emit_body {
 646         my ($self, undef, undef, undef, $eml) = @_;
 647         $self->msg_more(' BODY '.fetch_body($eml));
 648 }
 649
 650 # set $eml once ($_[4] == $eml, $_[3] == $bref)
 651 sub op_eml_new { $_[4] = PublicInbox::Eml->new($_[3]) }
 652
 653 # s/From / fixes old bug from import (pre-a0c07cba0e5d8b6a)
 654 sub to_crlf_full {
 655         ${$_[0]} =~ s/(?<!\r)\n/\r\n/sg;
 656         ${$_[0]} =~ s/\A[\r\n]*From [^\r\n]*\r\n//s;
 657 }
 658
 659 sub op_crlf_bref { to_crlf_full($_[3]) }
 660
 661 sub op_crlf_hdr { to_crlf_full($_[4]->{hdr}) }
 662
 663 sub op_crlf_bdy { ${$_[4]->{bdy}} =~ s/(?<!\r)\n/\r\n/sg if $_[4]->{bdy} }
 664
 665 sub uid_clamp ($$$) {
 666         my ($self, $beg, $end) = @_;
 667         my $uid_min = $self->{uid_base} + 1;
 668         my $uid_end = $uid_min + UID_SLICE - 1;
 669         $$beg = $uid_min if $$beg < $uid_min;
 670         $$end = $uid_end if $$end > $uid_end;
 671 }
 672
 673 sub range_step ($$) {
 674         my ($self, $range_csv) = @_;
 675         my ($beg, $end, $range);
 676         if ($$range_csv =~ s/\A([^,]+),//) {
 677                 $range = $1;
 678         } else {
 679                 $range = $$range_csv;
 680                 $$range_csv = undef;
 681         }
 682         my $uid_base = $self->{uid_base};
 683         my $uid_end = $uid_base + UID_SLICE;
 684         if ($range =~ /\A([0-9]+):([0-9]+)\z/) {
 685                 ($beg, $end) = ($1 + 0, $2 + 0);
 686                 uid_clamp($self, \$beg, \$end);
 687         } elsif ($range =~ /\A([0-9]+):\*\z/) {
 688                 $beg = $1 + 0;
 689                 $end = $self->{ibx}->over(1)->max;
 690                 $end = $uid_end if $end > $uid_end;
 691                 $beg = $end if $beg > $end;
 692                 uid_clamp($self, \$beg, \$end);
 693         } elsif ($range =~ /\A[0-9]+\z/) {
 694                 $beg = $end = $range + 0;
 695                 # just let the caller do an out-of-range query if a single
 696                 # UID is out-of-range
 697                 ++$beg if ($beg <= $uid_base || $end > $uid_end);
 698         } else {
 699                 return 'BAD fetch range';
 700         }
 701         [ $beg, $end, $$range_csv ];
 702 }
 703
 704 sub refill_range ($$$) {
 705         my ($self, $msgs, $range_info) = @_;
 706         my ($beg, $end, $range_csv) = @$range_info;
 707         if (scalar(@$msgs = @{$self->{ibx}->over(1)->query_xover($beg, $end)})){
 708                 $range_info->[0] = $msgs->[-1]->{num} + 1;
 709                 return;
 710         }
 711         return 'OK Fetch done' if !$range_csv;
 712         my $next_range = range_step($self, \$range_csv);
 713         return $next_range if !ref($next_range); # error
 714         @$range_info = @$next_range;
 715         undef; # keep looping
 716 }
 717
 718 sub fetch_blob { # long_response
 719         my ($self, $tag, $msgs, $range_info, $ops, $partial) = @_;
 720         while (!@$msgs) { # rare
 721                 if (my $end = refill_range($self, $msgs, $range_info)) {
 722                         $self->write(\"$tag $end\r\n");
 723                         return;
 724                 }
 725         }
 726         uo2m_extend($self, $msgs->[-1]->{num});
 727         ibx_async_cat($self->{ibx}, $msgs->[0]->{blob},
 728                         \&fetch_blob_cb, \@_);
 729 }
 730
 731 sub fetch_smsg { # long_response
 732         my ($self, $tag, $msgs, $range_info, $ops) = @_;
 733         while (!@$msgs) { # rare
 734                 if (my $end = refill_range($self, $msgs, $range_info)) {
 735                         $self->write(\"$tag $end\r\n");
 736                         return;
 737                 }
 738         }
 739         uo2m_extend($self, $msgs->[-1]->{num});
 740         fetch_run_ops($self, $_, undef, $ops) for @$msgs;
 741         @$msgs = ();
 742         1; # more
 743 }
 744
 745 sub refill_uids ($$$;$) {
 746         my ($self, $uids, $range_info, $sql) = @_;
 747         my ($beg, $end, $range_csv) = @$range_info;
 748         my $over = $self->{ibx}->over(1);
 749         while (1) {
 750                 if (scalar(@$uids = @{$over->uid_range($beg, $end, $sql)})) {
 751                         $range_info->[0] = $uids->[-1] + 1; # update $beg
 752                         return;
 753                 } elsif (!$range_csv) {
 754                         return 0;
 755                 } else {
 756                         my $next_range = range_step($self, \$range_csv);
 757                         return $next_range if !ref($next_range); # error
 758                         ($beg, $end, $range_csv) = @$range_info = @$next_range;
 759                         # continue looping
 760                 }
 761         }
 762 }
 763
 764 sub fetch_uid { # long_response
 765         my ($self, $tag, $uids, $range_info, $ops) = @_;
 766         if (defined(my $err = refill_uids($self, $uids, $range_info))) {
 767                 $err ||= 'OK Fetch done';
 768                 $self->write("$tag $err\r\n");
 769                 return;
 770         }
 771         my $adj = $self->{uid_base} + 1;
 772         my $uo2m = uo2m_extend($self, $uids->[-1]);
 773         $uo2m = [ unpack('S*', $uo2m) ] if !ref($uo2m);
 774         my ($i, $k);
 775         for (@$uids) {
 776                 $self->msg_more("* $uo2m->[$_ - $adj] FETCH (UID $_");
 777                 for ($i = 0; $i < @$ops;) {
 778                         $k = $ops->[$i++];
 779                         $ops->[$i++]->($self, $k);
 780                 }
 781                 $self->msg_more(")\r\n");
 782         }
 783         @$uids = ();
 784         1; # more
 785 }
 786
 787 sub cmd_status ($$$;@) {
 788         my ($self, $tag, $mailbox, @items) = @_;
 789         return "$tag BAD no items\r\n" if !scalar(@items);
 790         ($items[0] !~ s/\A\(//s || $items[-1] !~ s/\)\z//s) and
 791                 return "$tag BAD invalid args\r\n";
 792         my ($ibx, $exists, $uidnext) = inbox_lookup($self, $mailbox);
 793         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 794         my @it;
 795         for my $it (@items) {
 796                 $it = uc($it);
 797                 push @it, $it;
 798                 if ($it =~ /\A(?:MESSAGES|UNSEEN|RECENT)\z/) {
 799                         push @it, $exists;
 800                 } elsif ($it eq 'UIDNEXT') {
 801                         push @it, $uidnext;
 802                 } elsif ($it eq 'UIDVALIDITY') {
 803                         push @it, $ibx->{uidvalidity};
 804                 } else {
 805                         return "$tag BAD invalid item\r\n";
 806                 }
 807         }
 808         return "$tag BAD no items\r\n" if !@it;
 809         "* STATUS $mailbox (".join(' ', @it).")\r\n" .
 810         "$tag OK Status done\r\n";
 811 }
 812
 813 my %patmap = ('*' => '.*', '%' => '[^\.]*');
 814 sub cmd_list ($$$$) {
 815         my ($self, $tag, $refname, $wildcard) = @_;
 816         my $l = $self->{imapd}->{mailboxlist};
 817         if ($refname eq '' && $wildcard eq '') {
 818                 # request for hierarchy delimiter
 819                 $l = [ qq[* LIST (\\Noselect) "." ""\r\n] ];
 820         } elsif ($refname ne '' || $wildcard ne '*') {
 821                 $wildcard =~ s!([^a-z0-9_])!$patmap{$1} // "\Q$1"!egi;
 822                 $l = [ grep(/ \Q$refname\E$wildcard\r\n\z/is, @$l) ];
 823         }
 824         \(join('', @$l, "$tag OK List done\r\n"));
 825 }
 826
 827 sub cmd_lsub ($$$$) {
 828         my (undef, $tag) = @_; # same args as cmd_list
 829         "$tag OK Lsub done\r\n";
 830 }
 831
 832 sub eml_index_offs_i { # PublicInbox::Eml::each_part callback
 833         my ($p, $all) = @_;
 834         my ($eml, undef, $idx) = @$p;
 835         if ($idx && lc($eml->ct->{type}) eq 'multipart') {
 836                 $eml->{imap_bdy} = $eml->{bdy} // \'';
 837         }
 838         $all->{$idx} = $eml; # $idx => Eml
 839 }
 840
 841 # prepares an index for BODY[$SECTION_IDX] fetches
 842 sub eml_body_idx ($$) {
 843         my ($eml, $section_idx) = @_;
 844         my $idx = $eml->{imap_all_parts} // do {
 845                 my $all = {};
 846                 $eml->each_part(\&eml_index_offs_i, $all, 0, 1);
 847                 # top-level of multipart, BODY[0] not allowed (nz-number)
 848                 delete $all->{0};
 849                 $eml->{imap_all_parts} = $all;
 850         };
 851         $idx->{$section_idx};
 852 }
 853
 854 # BODY[($SECTION_IDX)?(.$SECTION_NAME)?]<$offset.$bytes>
 855 sub partial_body {
 856         my ($eml, $section_idx, $section_name) = @_;
 857         if (defined $section_idx) {
 858                 $eml = eml_body_idx($eml, $section_idx) or return;
 859         }
 860         if (defined $section_name) {
 861                 if ($section_name eq 'MIME') {
 862                         # RFC 3501 6.4.5 states:
 863                         #       The MIME part specifier MUST be prefixed
 864                         #       by one or more numeric part specifiers
 865                         return unless defined $section_idx;
 866                         return $eml->header_obj->as_string . "\r\n";
 867                 }
 868                 my $bdy = $eml->{bdy} // $eml->{imap_bdy} // \'';
 869                 $eml = PublicInbox::Eml->new($$bdy);
 870                 if ($section_name eq 'TEXT') {
 871                         return $eml->body_raw;
 872                 } elsif ($section_name eq 'HEADER') {
 873                         return $eml->header_obj->as_string . "\r\n";
 874                 } else {
 875                         die "BUG: bad section_name=$section_name";
 876                 }
 877         }
 878         ${$eml->{bdy} // $eml->{imap_bdy} // \''};
 879 }
 880
 881 # similar to what's in PublicInbox::Eml::re_memo, but doesn't memoize
 882 # to avoid OOM with malicious users
 883 sub hdrs_regexp ($) {
 884         my ($hdrs) = @_;
 885         my $names = join('|', map { "\Q$_" } split(/[ \t]+/, $hdrs));
 886         qr/^(?:$names):[ \t]*[^\n]*\r?\n # 1st line
 887                 # continuation lines:
 888                 (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*
 889                 /ismx;
 890 }
 891
 892 # BODY[($SECTION_IDX.)?HEADER.FIELDS.NOT ($HDRS)]<$offset.$bytes>
 893 sub partial_hdr_not {
 894         my ($eml, $section_idx, $hdrs_re) = @_;
 895         if (defined $section_idx) {
 896                 $eml = eml_body_idx($eml, $section_idx) or return;
 897         }
 898         my $str = $eml->header_obj->as_string;
 899         $str =~ s/$hdrs_re//g;
 900         $str =~ s/(?<!\r)\n/\r\n/sg;
 901         $str .= "\r\n";
 902 }
 903
 904 # BODY[($SECTION_IDX.)?HEADER.FIELDS ($HDRS)]<$offset.$bytes>
 905 sub partial_hdr_get {
 906         my ($eml, $section_idx, $hdrs_re) = @_;
 907         if (defined $section_idx) {
 908                 $eml = eml_body_idx($eml, $section_idx) or return;
 909         }
 910         my $str = $eml->header_obj->as_string;
 911         $str = join('', ($str =~ m/($hdrs_re)/g));
 912         $str =~ s/(?<!\r)\n/\r\n/sg;
 913         $str .= "\r\n";
 914 }
 915
 916 sub partial_prepare ($$$$) {
 917         my ($need, $partial, $want, $att) = @_;
 918
 919         # recombine [ "BODY[1.HEADER.FIELDS", "(foo", "bar)]" ]
 920         # back to: "BODY[1.HEADER.FIELDS (foo bar)]"
 921         return unless $att =~ /\ABODY\[/s;
 922         until (rindex($att, ']') >= 0) {
 923                 my $next = shift @$want or return;
 924                 $att .= ' ' . uc($next);
 925         }
 926         if ($att =~ /\ABODY\[([0-9]+(?:\.[0-9]+)*)? # 1 - section_idx
 927                         (?:\.(HEADER|MIME|TEXT))? # 2 - section_name
 928                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 3, 4
 929                 $partial->{$att} = [ \&partial_body, $1, $2, $3, $4 ];
 930                 $$need |= CRLF_BREF|EML_HDR|EML_BDY;
 931         } elsif ($att =~ /\ABODY\[(?:([0-9]+(?:\.[0-9]+)*)\.)? # 1 - section_idx
 932                                 (?:HEADER\.FIELDS(\.NOT)?)\x20 # 2
 933                                 \(([A-Z0-9\-\x20]+)\) # 3 - hdrs
 934                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 4 5
 935                 my $tmp = $partial->{$att} = [ $2 ? \&partial_hdr_not
 936                                                 : \&partial_hdr_get,
 937                                                 $1, undef, $4, $5 ];
 938                 $tmp->[2] = hdrs_regexp($3);
 939
 940                 # don't emit CRLF_HDR instruction, here, partial_hdr_*
 941                 # will do CRLF conversion with only the extracted result
 942                 # and not waste time converting lines we don't care about.
 943                 $$need |= EML_HDR;
 944         } else {
 945                 undef;
 946         }
 947 }
 948
 949 sub partial_emit ($$$) {
 950         my ($self, $partial, $eml) = @_;
 951         for (@$partial) {
 952                 my ($k, $cb, @args) = @$_;
 953                 my ($offset, $len) = splice(@args, -2);
 954                 # $cb is partial_body|partial_hdr_get|partial_hdr_not
 955                 my $str = $cb->($eml, @args) // '';
 956                 if (defined $offset) {
 957                         if (defined $len) {
 958                                 $str = substr($str, $offset, $len);
 959                                 $k =~ s/\.$len>\z/>/ or warn
 960 "BUG: unable to remove `.$len>' from `$k'";
 961                         } else {
 962                                 $str = substr($str, $offset);
 963                                 $len = length($str);
 964                         }
 965                 } else {
 966                         $len = length($str);
 967                 }
 968                 $self->msg_more(" $k {$len}\r\n");
 969                 $self->msg_more($str);
 970         }
 971 }
 972
 973 sub fetch_compile ($) {
 974         my ($want) = @_;
 975         if ($want->[0] =~ s/\A\(//s) {
 976                 $want->[-1] =~ s/\)\z//s or return 'BAD no rparen';
 977         }
 978         my (%partial, %seen, @op);
 979         my $need = 0;
 980         while (defined(my $att = shift @$want)) {
 981                 $att = uc($att);
 982                 next if $att eq 'UID'; # always returned
 983                 $att =~ s/\ABODY\.PEEK\[/BODY\[/; # we're read-only
 984                 my $x = $FETCH_ATT{$att};
 985                 if ($x) {
 986                         while (my ($k, $fl_cb) = each %$x) {
 987                                 next if $seen{$k}++;
 988                                 $need |= $fl_cb->[0];
 989                                 push @op, [ @$fl_cb, $k ];
 990                         }
 991                 } elsif (!partial_prepare(\$need, \%partial, $want, $att)) {
 992                         return "BAD param: $att";
 993                 }
 994         }
 995         my @r;
 996
 997         # stabilize partial order for consistency and ease-of-debugging:
 998         if (scalar keys %partial) {
 999                 $need |= NEED_BLOB;
1000                 $r[2] = [ map { [ $_, @{$partial{$_}} ] } sort keys %partial ];
1001         }
1002
1003         push @op, $OP_EML_NEW if ($need & (EML_HDR|EML_BDY));
1004
1005         # do we need CRLF conversion?
1006         if ($need & CRLF_BREF) {
1007                 push @op, $OP_CRLF_BREF;
1008         } elsif (my $crlf = ($need & (CRLF_HDR|CRLF_BDY))) {
1009                 if ($crlf == (CRLF_HDR|CRLF_BDY)) {
1010                         push @op, $OP_CRLF_BREF;
1011                 } elsif ($need & CRLF_HDR) {
1012                         push @op, $OP_CRLF_HDR;
1013                 } else {
1014                         push @op, $OP_CRLF_BDY;
1015                 }
1016         }
1017
1018         $r[0] = $need & NEED_BLOB ? \&fetch_blob :
1019                 ($need & NEED_SMSG ? \&fetch_smsg : \&fetch_uid);
1020
1021         # r[1] = [ $key1, $cb1, $key2, $cb2, ... ]
1022         use sort 'stable'; # makes output more consistent
1023         $r[1] = [ map { ($_->[2], $_->[1]) } sort { $a->[0] <=> $b->[0] } @op ];
1024         @r;
1025 }
1026
1027 sub cmd_uid_fetch ($$$$;@) {
1028         my ($self, $tag, $range_csv, @want) = @_;
1029         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
1030         my ($cb, $ops, $partial) = fetch_compile(\@want);
1031         return "$tag $cb\r\n" unless $ops;
1032
1033         # cb is one of fetch_blob, fetch_smsg, fetch_uid
1034         $range_csv = 'bad' if $range_csv !~ $valid_range;
1035         my $range_info = range_step($self, \$range_csv);
1036         return "$tag $range_info\r\n" if !ref($range_info);
1037         uo2m_hibernate($self) if $cb == \&fetch_blob; # slow, save RAM
1038         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
1039 }
1040
1041 sub cmd_fetch ($$$$;@) {
1042         my ($self, $tag, $range_csv, @want) = @_;
1043         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
1044         my ($cb, $ops, $partial) = fetch_compile(\@want);
1045         return "$tag $cb\r\n" unless $ops;
1046
1047         # cb is one of fetch_blob, fetch_smsg, fetch_uid
1048         $range_csv = 'bad' if $range_csv !~ $valid_range;
1049         msn_to_uid_range(msn2uid($self), $range_csv);
1050         my $range_info = range_step($self, \$range_csv);
1051         return "$tag $range_info\r\n" if !ref($range_info);
1052         uo2m_hibernate($self) if $cb == \&fetch_blob; # slow, save RAM
1053         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
1054 }
1055
1056 sub msn_convert ($$) {
1057         my ($self, $uids) = @_;
1058         my $adj = $self->{uid_base} + 1;
1059         my $uo2m = uo2m_extend($self, $uids->[-1]);
1060         $uo2m = [ unpack('S*', $uo2m) ] if !ref($uo2m);
1061         $_ = $uo2m->[$_ - $adj] for @$uids;
1062 }
1063
1064 sub search_uid_range { # long_response
1065         my ($self, $tag, $sql, $range_info, $want_msn) = @_;
1066         my $uids = [];
1067         if (defined(my $err = refill_uids($self, $uids, $range_info, $sql))) {
1068                 $err ||= 'OK Search done';
1069                 $self->write("\r\n$tag $err\r\n");
1070                 return;
1071         }
1072         msn_convert($self, $uids) if $want_msn;
1073         $self->msg_more(join(' ', '', @$uids));
1074         1; # more
1075 }
1076
1077 sub parse_imap_query ($$) {
1078         my ($self, $query) = @_;
1079         my $q = PublicInbox::IMAPsearchqp::parse($self, $query);
1080         if (ref($q)) {
1081                 my $max = $self->{ibx}->over(1)->max;
1082                 my $beg = 1;
1083                 uid_clamp($self, \$beg, \$max);
1084                 $q->{range_info} = [ $beg, $max ];
1085         }
1086         $q;
1087 }
1088
1089 sub search_common {
1090         my ($self, $tag, $query, $want_msn) = @_;
1091         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
1092         my $q = parse_imap_query($self, $query);
1093         return "$tag $q\r\n" if !ref($q);
1094         my ($sql, $range_info) = delete @$q{qw(sql range_info)};
1095         if (!scalar(keys %$q)) { # overview.sqlite3
1096                 $self->msg_more('* SEARCH');
1097                 long_response($self, \&search_uid_range,
1098                                 $tag, $sql, $range_info, $want_msn);
1099         } elsif ($q = $q->{xap}) {
1100                 my $srch = $self->{ibx}->isrch or
1101                         return "$tag BAD search not available for mailbox\r\n";
1102                 my $opt = {
1103                         relevance => -1,
1104                         limit => UID_SLICE,
1105                         uid_range => $range_info
1106                 };
1107                 my $mset = $srch->mset($q, $opt);
1108                 my $uids = $srch->mset_to_artnums($mset, $opt);
1109                 msn_convert($self, $uids) if scalar(@$uids) && $want_msn;
1110                 "* SEARCH @$uids\r\n$tag OK Search done\r\n";
1111         } else {
1112                 "$tag BAD Error\r\n";
1113         }
1114 }
1115
1116 sub cmd_uid_search ($$$) {
1117         my ($self, $tag, $query) = @_;
1118         search_common($self, $tag, $query);
1119 }
1120
1121 sub cmd_search ($$$;) {
1122         my ($self, $tag, $query) = @_;
1123         search_common($self, $tag, $query, 1);
1124 }
1125
1126 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
1127 sub process_line ($$) {
1128         my ($self, $l) = @_;
1129
1130         # TODO: IMAP allows literals for big requests to upload messages
1131         # (which we don't support) but maybe some big search queries use it.
1132         # RFC 3501 9 (2) doesn't permit TAB or multiple SP
1133         my ($tag, $req, @args) = parse_line('[ \t]+', 0, $l);
1134         pop(@args) if (@args && !defined($args[-1]));
1135         if (@args && uc($req) eq 'UID') {
1136                 $req .= "_".(shift @args);
1137         }
1138         my $res = eval {
1139                 if (defined(my $idle_tag = $self->{-idle_tag})) {
1140                         (uc($tag // '') eq 'DONE' && !defined($req)) ?
1141                                 idle_done($self, $tag) :
1142                                 "$idle_tag BAD expected DONE\r\n";
1143                 } elsif (my $cmd = $self->can('cmd_'.lc($req // ''))) {
1144                         if ($cmd == \&cmd_uid_search || $cmd == \&cmd_search) {
1145                                 # preserve user-supplied quotes for search
1146                                 (undef, @args) = split(/ search /i, $l, 2);
1147                         }
1148                         $cmd->($self, $tag, @args);
1149                 } else { # this is weird
1150                         auth_challenge_ok($self) //
1151                                         ($tag // '*') .
1152                                         ' BAD Error in IMAP command '.
1153                                         ($req // '(???)').
1154                                         ": Unknown command\r\n";
1155                 }
1156         };
1157         my $err = $@;
1158         if ($err && $self->{sock}) {
1159                 $l =~ s/\r?\n//s;
1160                 err($self, 'error from: %s (%s)', $l, $err);
1161                 $tag //= '*';
1162                 $res = "$tag BAD program fault - command not performed\r\n";
1163         }
1164         return 0 unless defined $res;
1165         $self->write($res);
1166 }
1167
1168 sub long_step {
1169         my ($self) = @_;
1170         # wbuf is unset or empty, here; {long} may add to it
1171         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
1172         my $more = eval { $cb->($self, @args) };
1173         if ($@ || !$self->{sock}) { # something bad happened...
1174                 delete $self->{long_cb};
1175                 my $elapsed = now() - $t0;
1176                 if ($@) {
1177                         err($self,
1178                             "%s during long response[$fd] - %0.6f",
1179                             $@, $elapsed);
1180                 }
1181                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
1182                 $self->close;
1183         } elsif ($more) { # $self->{wbuf}:
1184                 # control passed to ibx_async_cat if $more == \undef
1185                 $self->requeue_once($self) if !ref($more);
1186         } else { # all done!
1187                 delete $self->{long_cb};
1188                 my $elapsed = now() - $t0;
1189                 my $fd = fileno($self->{sock});
1190                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
1191                 my $wbuf = $self->{wbuf}; # do NOT autovivify
1192
1193                 $self->requeue unless $wbuf && @$wbuf;
1194         }
1195 }
1196
1197 sub err ($$;@) {
1198         my ($self, $fmt, @args) = @_;
1199         printf { $self->{imapd}->{err} } $fmt."\n", @args;
1200 }
1201
1202 sub out ($$;@) {
1203         my ($self, $fmt, @args) = @_;
1204         printf { $self->{imapd}->{out} } $fmt."\n", @args;
1205 }
1206
1207 sub long_response ($$;@) {
1208         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
1209
1210         my $sock = $self->{sock} or return;
1211         # make sure we disable reading during a long response,
1212         # clients should not be sending us stuff and making us do more
1213         # work while we are stream a response to them
1214         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
1215         long_step($self); # kick off!
1216         undef;
1217 }
1218
1219 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1220 sub event_step {
1221         my ($self) = @_;
1222
1223         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1224
1225         # only read more requests if we've drained the write buffer,
1226         # otherwise we can be buffering infinitely w/o backpressure
1227
1228         my $rbuf = $self->{rbuf} // \(my $x = '');
1229         my $line = index($$rbuf, "\n");
1230         while ($line < 0) {
1231                 if (length($$rbuf) >= LINE_MAX) {
1232                         $self->write(\"\* BAD request too long\r\n");
1233                         return $self->close;
1234                 }
1235                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or
1236                                 return uo2m_hibernate($self);
1237                 $line = index($$rbuf, "\n");
1238         }
1239         $line = substr($$rbuf, 0, $line + 1, '');
1240         $line =~ s/\r?\n\z//s;
1241         return $self->close if $line =~ /[[:cntrl:]]/s;
1242         my $t0 = now();
1243         my $fd = fileno($self->{sock});
1244         my $r = eval { process_line($self, $line) };
1245         my $pending = $self->{wbuf} ? ' pending' : '';
1246         out($self, "[$fd] %s - %0.6f$pending - $r", $line, now() - $t0);
1247
1248         return $self->close if $r < 0;
1249         $self->rbuf_idle($rbuf);
1250
1251         # maybe there's more pipelined data, or we'll have
1252         # to register it for socket-readiness notifications
1253         $self->requeue unless $pending;
1254 }
1255
1256 sub compressed { undef }
1257
1258 # RFC 4978
1259 sub cmd_compress ($$$) {
1260         my ($self, $tag, $alg) = @_;
1261         return "$tag BAD DEFLATE only\r\n" if uc($alg) ne "DEFLATE";
1262         return "$tag BAD COMPRESS active\r\n" if $self->compressed;
1263
1264         # CRIME made TLS compression obsolete
1265         # return "$tag NO [COMPRESSIONACTIVE]\r\n" if $self->tls_compressed;
1266
1267         PublicInbox::IMAPdeflate->enable($self, $tag);
1268         $self->requeue;
1269         undef
1270 }
1271
1272 sub cmd_starttls ($$) {
1273         my ($self, $tag) = @_;
1274         my $sock = $self->{sock} or return;
1275         if ($sock->can('stop_SSL') || $self->compressed) {
1276                 return "$tag BAD TLS or compression already enabled\r\n";
1277         }
1278         my $opt = $self->{imapd}->{accept_tls} or
1279                 return "$tag BAD can not initiate TLS negotiation\r\n";
1280         $self->write(\"$tag OK begin TLS negotiation now\r\n");
1281         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
1282         $self->requeue if PublicInbox::DS::accept_tls_step($self);
1283         undef;
1284 }
1285
1286 sub busy { # for graceful shutdown in PublicInbox::Daemon:
1287         my ($self) = @_;
1288         if (defined($self->{-idle_tag})) {
1289                 $self->write(\"* BYE server shutting down\r\n");
1290                 return; # not busy anymore
1291         }
1292         defined($self->{rbuf}) || defined($self->{wbuf}) ||
1293                 !$self->write(\"* BYE server shutting down\r\n");
1294 }
1295
1296 sub close {
1297         my ($self) = @_;
1298         if (my $ibx = delete $self->{ibx}) {
1299                 stop_idle($self, $ibx);
1300         }
1301         $self->SUPER::close; # PublicInbox::DS::close
1302 }
1303
1304 # we're read-only, so SELECT and EXAMINE do the same thing
1305 no warnings 'once';
1306 *cmd_select = \&cmd_examine;
1307
1308 package PublicInbox::IMAP_preauth;
1309 our @ISA = qw(PublicInbox::IMAP);
1310
1311 sub logged_in { 0 }
1312
1313 1;