lib/PublicInbox/IMAP.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents an IMAP client connected to
   5 # public-inbox-imapd.  Much of this was taken from NNTP, but
   6 # further refined while experimenting on future ideas to handle
   7 # slow storage.
   8 #
   9 # data notes:
  10 # * NNTP article numbers are UIDs
  11
  12 package PublicInbox::IMAP;
  13 use strict;
  14 use base qw(PublicInbox::DS);
  15 use fields qw(imapd ibx long_cb -login_tag
  16         uid_base -idle_tag -idle_max);
  17 use PublicInbox::Eml;
  18 use PublicInbox::EmlContentFoo qw(parse_content_disposition);
  19 use PublicInbox::DS qw(now);
  20 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  21 use PublicInbox::GitAsyncCat;
  22 use Text::ParseWords qw(parse_line);
  23 use Errno qw(EAGAIN);
  24 use Time::Local qw(timegm);
  25 use POSIX qw(strftime);
  26 use Hash::Util qw(unlock_hash); # dependency of fields for perl 5.10+, anyways
  27 use PublicInbox::Search;
  28 *mdocid = \&PublicInbox::Search::mdocid;
  29
  30 my $Address;
  31 for my $mod (qw(Email::Address::XS Mail::Address)) {
  32         eval "require $mod" or next;
  33         $Address = $mod and last;
  34 }
  35 die "neither Email::Address::XS nor Mail::Address loaded: $@" if !$Address;
  36
  37 sub LINE_MAX () { 8000 } # RFC 2683 3.2.1.5
  38
  39 # changing this will cause grief for clients which cache
  40 sub UID_BLOCK () { 50_000 }
  41
  42 # these values area also used for sorting
  43 sub NEED_SMSG () { 1 }
  44 sub NEED_BLOB () { NEED_SMSG|2 }
  45 sub CRLF_BREF () { 4 }
  46 sub EML_HDR () { 8 }
  47 sub CRLF_HDR () { 16 }
  48 sub EML_BDY () { 32 }
  49 sub CRLF_BDY () { 64 }
  50 my $OP_EML_NEW = [ EML_HDR - 1, \&op_eml_new ];
  51 my $OP_CRLF_BREF = [ CRLF_BREF, \&op_crlf_bref ];
  52 my $OP_CRLF_HDR = [ CRLF_HDR, \&op_crlf_hdr ];
  53 my $OP_CRLF_BDY = [ CRLF_BDY, \&op_crlf_bdy ];
  54
  55 my %FETCH_NEED = (
  56         'BODY[HEADER]' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  57         'BODY[TEXT]' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  58         'BODY[]' => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  59         'RFC822.HEADER' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  60         'RFC822.TEXT' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  61         'RFC822.SIZE' => [ NEED_SMSG, \&emit_rfc822_size ],
  62         RFC822 => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  63         BODY => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_body ],
  64         BODYSTRUCTURE => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_bodystructure ],
  65         ENVELOPE => [ NEED_BLOB|EML_HDR, \&emit_envelope ],
  66         FLAGS => [ 0, \&emit_flags ],
  67         INTERNALDATE => [ NEED_SMSG, \&emit_internaldate ],
  68 );
  69 my %FETCH_ATT = map { $_ => [ $_ ] } keys %FETCH_NEED;
  70
  71 # aliases (RFC 3501 section 6.4.5)
  72 $FETCH_ATT{FAST} = [ qw(FLAGS INTERNALDATE RFC822.SIZE) ];
  73 $FETCH_ATT{ALL} = [ @{$FETCH_ATT{FAST}}, 'ENVELOPE' ];
  74 $FETCH_ATT{FULL} = [ @{$FETCH_ATT{ALL}}, 'BODY' ];
  75
  76 for my $att (keys %FETCH_ATT) {
  77         my %h = map { $_ => $FETCH_NEED{$_} } @{$FETCH_ATT{$att}};
  78         $FETCH_ATT{$att} = \%h;
  79 }
  80 undef %FETCH_NEED;
  81
  82 my $valid_range = '[0-9]+|[0-9]+:[0-9]+|[0-9]+:\*';
  83 $valid_range = qr/\A(?:$valid_range)(?:,(?:$valid_range))*\z/;
  84
  85 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  86 my %MoY;
  87 @MoY{@MoY} = (0..11);
  88
  89 # RFC 3501 5.4. Autologout Timer needs to be >= 30min
  90 $PublicInbox::DS::EXPTIME = 60 * 30;
  91
  92 sub greet ($) {
  93         my ($self) = @_;
  94         my $capa = capa($self);
  95         $self->write(\"* OK [$capa] public-inbox-imapd ready\r\n");
  96 }
  97
  98 sub new ($$$) {
  99         my ($class, $sock, $imapd) = @_;
 100         my $self = fields::new('PublicInbox::IMAP_preauth');
 101         unlock_hash(%$self);
 102         my $ev = EPOLLIN;
 103         my $wbuf;
 104         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
 105                 return CORE::close($sock) if $! != EAGAIN;
 106                 $ev = PublicInbox::TLS::epollbit();
 107                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
 108         }
 109         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
 110         $self->{imapd} = $imapd;
 111         if ($wbuf) {
 112                 $self->{wbuf} = $wbuf;
 113         } else {
 114                 greet($self);
 115         }
 116         $self->update_idle_time;
 117         $self;
 118 }
 119
 120 sub logged_in { 1 }
 121
 122 sub capa ($) {
 123         my ($self) = @_;
 124
 125         # dovecot advertises IDLE pre-login; perhaps because some clients
 126         # depend on it, so we'll do the same
 127         my $capa = 'CAPABILITY IMAP4rev1 IDLE';
 128         if ($self->logged_in) {
 129                 $capa .= ' COMPRESS=DEFLATE';
 130         } else {
 131                 if (!($self->{sock} // $self)->can('accept_SSL') &&
 132                         $self->{imapd}->{accept_tls}) {
 133                         $capa .= ' STARTTLS';
 134                 }
 135                 $capa .= ' AUTH=ANONYMOUS';
 136         }
 137 }
 138
 139 sub login_success ($$) {
 140         my ($self, $tag) = @_;
 141         bless $self, 'PublicInbox::IMAP';
 142         my $capa = capa($self);
 143         "$tag OK [$capa] Logged in\r\n";
 144 }
 145
 146 sub auth_challenge_ok ($) {
 147         my ($self) = @_;
 148         my $tag = delete($self->{-login_tag}) or return;
 149         login_success($self, $tag);
 150 }
 151
 152 sub cmd_login ($$$$) {
 153         my ($self, $tag) = @_; # ignore ($user, $password) = ($_[2], $_[3])
 154         login_success($self, $tag);
 155 }
 156
 157 sub cmd_close ($$) {
 158         my ($self, $tag) = @_;
 159         delete $self->{uid_base};
 160         delete $self->{ibx} ? "$tag OK Close done\r\n"
 161                                 : "$tag BAD No mailbox\r\n";
 162 }
 163
 164 sub cmd_logout ($$) {
 165         my ($self, $tag) = @_;
 166         delete $self->{-idle_tag};
 167         $self->write(\"* BYE logging out\r\n$tag OK Logout done\r\n");
 168         $self->shutdn; # PublicInbox::DS::shutdn
 169         undef;
 170 }
 171
 172 sub cmd_authenticate ($$$) {
 173         my ($self, $tag) = @_; # $method = $_[2], should be "ANONYMOUS"
 174         $self->{-login_tag} = $tag;
 175         "+\r\n"; # challenge
 176 }
 177
 178 sub cmd_capability ($$) {
 179         my ($self, $tag) = @_;
 180         '* '.capa($self)."\r\n$tag OK Capability done\r\n";
 181 }
 182
 183 sub cmd_noop ($$) { "$_[1] OK Noop done\r\n" }
 184
 185 # called by PublicInbox::InboxIdle
 186 sub on_inbox_unlock {
 187         my ($self, $ibx) = @_;
 188         my $new = $ibx->over->max;
 189         my $uid_base = $self->{uid_base} // 0;
 190         my $uid_end = $uid_base + UID_BLOCK;
 191         defined(my $old = $self->{-idle_max}) or die 'BUG: -idle_max unset';
 192         $new = $uid_end if $new > $uid_end;
 193         if ($new > $old) {
 194                 $self->{-idle_max} = $new;
 195                 $new -= $uid_base;
 196                 $old -= $uid_base;
 197                 $self->msg_more("* $_ EXISTS\r\n") for (($old + 1)..($new - 1));
 198                 $self->write(\"* $new EXISTS\r\n");
 199         } elsif ($new == $uid_end) { # max exceeded $uid_end
 200                 # continue idling w/o inotify
 201                 delete $self->{-idle_max};
 202                 my $sock = $self->{sock} or return;
 203                 $ibx->unsubscribe_unlock(fileno($sock));
 204         }
 205 }
 206
 207 # called every X minute(s) or so by PublicInbox::DS::later
 208 my $IDLERS = {};
 209 my $idle_timer;
 210 sub idle_tick_all {
 211         my $old = $IDLERS;
 212         $IDLERS = {};
 213         for my $i (values %$old) {
 214                 next if ($i->{wbuf} || !exists($i->{-idle_tag}));
 215                 $i->update_idle_time or next;
 216                 $IDLERS->{fileno($i->{sock})} = $i;
 217                 $i->write(\"* OK Still here\r\n");
 218         }
 219         $idle_timer = scalar keys %$IDLERS ?
 220                         PublicInbox::DS::later(\&idle_tick_all) : undef;
 221 }
 222
 223 sub cmd_idle ($$) {
 224         my ($self, $tag) = @_;
 225         # IDLE seems allowed by dovecot w/o a mailbox selected *shrug*
 226         my $ibx = $self->{ibx} or return "$tag BAD no mailbox selected\r\n";
 227         $self->{-idle_tag} = $tag;
 228         my $max = $ibx->over->max;
 229         my $uid_end = $self->{uid_base} + UID_BLOCK;
 230         my $sock = $self->{sock} or return;
 231         my $fd = fileno($sock);
 232         # only do inotify on most recent slice
 233         if ($max < $uid_end) {
 234                 $ibx->subscribe_unlock($fd, $self);
 235                 $self->{imapd}->idler_start;
 236                 $self->{-idle_max} = $max;
 237         }
 238         $idle_timer //= PublicInbox::DS::later(\&idle_tick_all);
 239         $IDLERS->{$fd} = $self;
 240         \"+ idling\r\n"
 241 }
 242
 243 sub stop_idle ($$) {
 244         my ($self, $ibx);
 245         my $sock = $self->{sock} or return;
 246         my $fd = fileno($sock);
 247         delete $IDLERS->{$fd};
 248         $ibx->unsubscribe_unlock($fd);
 249 }
 250
 251 sub cmd_done ($$) {
 252         my ($self, $tag) = @_; # $tag is "DONE" (case-insensitive)
 253         defined(my $idle_tag = delete $self->{-idle_tag}) or
 254                 return "$tag BAD not idle\r\n";
 255         my $ibx = $self->{ibx} or do {
 256                 warn "BUG: idle_tag set w/o inbox";
 257                 return "$tag BAD internal bug\r\n";
 258         };
 259         stop_idle($self, $ibx);
 260         "$idle_tag OK Idle done\r\n";
 261 }
 262
 263 sub ensure_ranges_exist ($$$) {
 264         my ($imapd, $ibx, $max) = @_;
 265         defined(my $mb_top = $ibx->{newsgroup}) or return;
 266         my $mailboxes = $imapd->{mailboxes};
 267         my @created;
 268         for (my $i = int($max/UID_BLOCK); $i >= 0; --$i) {
 269                 my $sub_mailbox = "$mb_top.$i";
 270                 last if exists $mailboxes->{$sub_mailbox};
 271                 $mailboxes->{$sub_mailbox} = $ibx;
 272                 $sub_mailbox =~ s/\Ainbox\./INBOX./i; # more familiar to users
 273                 push @created, $sub_mailbox;
 274         }
 275         return unless @created;
 276         my $l = $imapd->{inboxlist} or return;
 277         push @$l, map { qq[* LIST (\\HasNoChildren) "." $_\r\n] } @created;
 278 }
 279
 280 sub inbox_lookup ($$) {
 281         my ($self, $mailbox) = @_;
 282         my ($ibx, $exists, $uidnext, $uid_base);
 283         if ($mailbox =~ /\A(.+)\.([0-9]+)\z/) {
 284                 # old mail: inbox.comp.foo.$uid_block_idx
 285                 my $mb_top = $1;
 286                 $uid_base = $2 * UID_BLOCK;
 287                 $ibx = $self->{imapd}->{mailboxes}->{lc $mailbox} or return;
 288                 my $max;
 289                 ($exists, $uidnext, $max) = $ibx->over->imap_status($uid_base,
 290                                                         $uid_base + UID_BLOCK);
 291                 ensure_ranges_exist($self->{imapd}, $ibx, $max);
 292         } else { # check for dummy inboxes
 293                 $mailbox = lc $mailbox;
 294                 $ibx = $self->{imapd}->{mailboxes}->{$mailbox} or return;
 295
 296                 # if "INBOX.foo.bar" is selected and "INBOX.foo.bar.0",
 297                 # check for new UID ranges (e.g. "INBOX.foo.bar.1")
 298                 if (my $z = $self->{imapd}->{mailboxes}->{"$mailbox.0"}) {
 299                         ensure_ranges_exist($self->{imapd}, $z, $z->over->max);
 300                 }
 301
 302                 $uid_base = $exists = 0;
 303                 $uidnext = 1;
 304         }
 305         ($ibx, $exists, $uidnext, $uid_base);
 306 }
 307
 308 sub cmd_examine ($$$) {
 309         my ($self, $tag, $mailbox) = @_;
 310         my ($ibx, $exists, $uidnext, $base) = inbox_lookup($self, $mailbox);
 311         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 312         $self->{uid_base} = $base;
 313
 314         # XXX: do we need this? RFC 5162/7162
 315         my $ret = $self->{ibx} ? "* OK [CLOSED] previous closed\r\n" : '';
 316         $self->{ibx} = $ibx;
 317         $ret .= <<EOF;
 318 * $exists EXISTS\r
 319 * $exists RECENT\r
 320 * FLAGS (\\Seen)\r
 321 * OK [PERMANENTFLAGS ()] Read-only mailbox\r
 322 * OK [UNSEEN $exists]\r
 323 * OK [UIDNEXT $uidnext]\r
 324 * OK [UIDVALIDITY $ibx->{uidvalidity}]\r
 325 $tag OK [READ-ONLY] EXAMINE/SELECT done\r
 326 EOF
 327 }
 328
 329 sub _esc ($) {
 330         my ($v) = @_;
 331         if (!defined($v)) {
 332                 'NIL';
 333         } elsif ($v =~ /[{"\r\n%*\\\[]/) { # literal string
 334                 '{' . length($v) . "}\r\n" . $v;
 335         } else { # quoted string
 336                 qq{"$v"}
 337         }
 338 }
 339
 340 sub addr_envelope ($$;$) {
 341         my ($eml, $x, $y) = @_;
 342         my $v = $eml->header_raw($x) //
 343                 ($y ? $eml->header_raw($y) : undef) // return 'NIL';
 344
 345         my @x = $Address->parse($v) or return 'NIL';
 346         '(' . join('',
 347                 map { '(' . join(' ',
 348                                 _esc($_->name), 'NIL',
 349                                 _esc($_->user), _esc($_->host)
 350                         ) . ')'
 351                 } @x) .
 352         ')';
 353 }
 354
 355 sub eml_envelope ($) {
 356         my ($eml) = @_;
 357         '(' . join(' ',
 358                 _esc($eml->header_raw('Date')),
 359                 _esc($eml->header_raw('Subject')),
 360                 addr_envelope($eml, 'From'),
 361                 addr_envelope($eml, 'Sender', 'From'),
 362                 addr_envelope($eml, 'Reply-To', 'From'),
 363                 addr_envelope($eml, 'To'),
 364                 addr_envelope($eml, 'Cc'),
 365                 addr_envelope($eml, 'Bcc'),
 366                 _esc($eml->header_raw('In-Reply-To')),
 367                 _esc($eml->header_raw('Message-ID')),
 368         ) . ')';
 369 }
 370
 371 sub _esc_hash ($) {
 372         my ($hash) = @_;
 373         if ($hash && scalar keys %$hash) {
 374                 $hash = [ %$hash ]; # flatten hash into 1-dimensional array
 375                 '(' . join(' ', map { _esc($_) } @$hash) . ')';
 376         } else {
 377                 'NIL';
 378         }
 379 }
 380
 381 sub body_disposition ($) {
 382         my ($eml) = @_;
 383         my $cd = $eml->header_raw('Content-Disposition') or return 'NIL';
 384         $cd = parse_content_disposition($cd);
 385         my $buf = '('._esc($cd->{type});
 386         $buf .= ' ' . _esc_hash(delete $cd->{attributes});
 387         $buf .= ')';
 388 }
 389
 390 sub body_leaf ($$;$) {
 391         my ($eml, $structure, $hold) = @_;
 392         my $buf = '';
 393         $eml->{is_submsg} and # parent was a message/(rfc822|news|global)
 394                 $buf .= eml_envelope($eml). ' ';
 395         my $ct = $eml->ct;
 396         $buf .= '('._esc($ct->{type}).' ';
 397         $buf .= _esc($ct->{subtype});
 398         $buf .= ' ' . _esc_hash(delete $ct->{attributes});
 399         $buf .= ' ' . _esc($eml->header_raw('Content-ID'));
 400         $buf .= ' ' . _esc($eml->header_raw('Content-Description'));
 401         my $cte = $eml->header_raw('Content-Transfer-Encoding') // '7bit';
 402         $buf .= ' ' . _esc($cte);
 403         $buf .= ' ' . $eml->{imap_body_len};
 404         $buf .= ' '.($eml->body_raw =~ tr/\n/\n/) if lc($ct->{type}) eq 'text';
 405
 406         # for message/(rfc822|global|news), $hold[0] should have envelope
 407         $buf .= ' ' . (@$hold ? join('', @$hold) : 'NIL') if $hold;
 408
 409         if ($structure) {
 410                 $buf .= ' '._esc($eml->header_raw('Content-MD5'));
 411                 $buf .= ' '. body_disposition($eml);
 412                 $buf .= ' '._esc($eml->header_raw('Content-Language'));
 413                 $buf .= ' '._esc($eml->header_raw('Content-Location'));
 414         }
 415         $buf .= ')';
 416 }
 417
 418 sub body_parent ($$$) {
 419         my ($eml, $structure, $hold) = @_;
 420         my $ct = $eml->ct;
 421         my $type = lc($ct->{type});
 422         if ($type eq 'multipart') {
 423                 my $buf = '(';
 424                 $buf .= @$hold ? join('', @$hold) : 'NIL';
 425                 $buf .= ' '._esc($ct->{subtype});
 426                 if ($structure) {
 427                         $buf .= ' '._esc_hash(delete $ct->{attributes});
 428                         $buf .= ' '.body_disposition($eml);
 429                         $buf .= ' '._esc($eml->header_raw('Content-Language'));
 430                         $buf .= ' '._esc($eml->header_raw('Content-Location'));
 431                 }
 432                 $buf .= ')';
 433                 @$hold = ($buf);
 434         } else { # message/(rfc822|global|news)
 435                 @$hold = (body_leaf($eml, $structure, $hold));
 436         }
 437 }
 438
 439 # this is gross, but we need to process the parent part AFTER
 440 # the child parts are done
 441 sub bodystructure_prep {
 442         my ($p, $q) = @_;
 443         my ($eml, $depth) = @$p; # ignore idx
 444         # set length here, as $eml->{bdy} gets deleted for message/rfc822
 445         $eml->{imap_body_len} = length($eml->body_raw);
 446         push @$q, $eml, $depth;
 447 }
 448
 449 # for FETCH BODY and FETCH BODYSTRUCTURE
 450 sub fetch_body ($;$) {
 451         my ($eml, $structure) = @_;
 452         my @q;
 453         $eml->each_part(\&bodystructure_prep, \@q, 0, 1);
 454         my $cur_depth = 0;
 455         my @hold;
 456         do {
 457                 my ($part, $depth) = splice(@q, -2);
 458                 my $is_mp_parent = $depth == ($cur_depth - 1);
 459                 $cur_depth = $depth;
 460
 461                 if ($is_mp_parent) {
 462                         body_parent($part, $structure, \@hold);
 463                 } else {
 464                         unshift @hold, body_leaf($part, $structure);
 465                 }
 466         } while (@q);
 467         join('', @hold);
 468 }
 469
 470 sub requeue_once ($) {
 471         my ($self) = @_;
 472         # COMPRESS users all share the same DEFLATE context.
 473         # Flush it here to ensure clients don't see
 474         # each other's data
 475         $self->zflush;
 476
 477         # no recursion, schedule another call ASAP,
 478         # but only after all pending writes are done.
 479         # autovivify wbuf:
 480         my $new_size = push(@{$self->{wbuf}}, \&long_step);
 481
 482         # wbuf may be populated by $cb, no need to rearm if so:
 483         $self->requeue if $new_size == 1;
 484 }
 485
 486 # my ($msn, $UID) = @_;
 487 sub fetch_msn_uid ($$) { '* '.(${$_[0]}++).' FETCH (UID '.$_[1] }
 488
 489 sub fetch_run_ops {
 490         my ($self, $msn, $smsg, $bref, $ops, $partial) = @_;
 491         $self->msg_more(fetch_msn_uid($msn, $smsg->{num}));
 492         my ($eml, $k);
 493         for (my $i = 0; $i < @$ops;) {
 494                 $k = $ops->[$i++];
 495                 $ops->[$i++]->($self, $k, $smsg, $bref, $eml);
 496         }
 497         partial_emit($self, $partial, $eml) if $partial;
 498         $self->msg_more(")\r\n");
 499 }
 500
 501 sub fetch_blob_cb { # called by git->cat_async via git_async_cat
 502         my ($bref, $oid, $type, $size, $fetch_arg) = @_;
 503         my ($self, undef, $msgs, $range_info, $ops, $partial) = @$fetch_arg;
 504         my $smsg = shift @$msgs or die 'BUG: no smsg';
 505         if (!defined($oid)) {
 506                 # it's possible to have TOCTOU if an admin runs
 507                 # public-inbox-(edit|purge), just move onto the next message
 508                 return requeue_once($self);
 509         } else {
 510                 $smsg->{blob} eq $oid or die "BUG: $smsg->{blob} != $oid";
 511         }
 512         fetch_run_ops($self, $range_info->[3], $smsg, $bref, $ops, $partial);
 513         requeue_once($self);
 514 }
 515
 516 sub emit_rfc822 {
 517         my ($self, $k, undef, $bref) = @_;
 518         $self->msg_more(" $k {" . length($$bref)."}\r\n");
 519         $self->msg_more($$bref);
 520 }
 521
 522 # Mail::IMAPClient::message_string cares about this by default,
 523 # (->Ignoresizeerrors attribute).  Admins are encouraged to
 524 # --reindex for IMAP support, anyways.
 525 sub emit_rfc822_size {
 526         my ($self, $k, $smsg) = @_;
 527         $self->msg_more(' RFC822.SIZE ' . $smsg->{bytes});
 528 }
 529
 530 sub emit_internaldate {
 531         my ($self, undef, $smsg) = @_;
 532         $self->msg_more(' INTERNALDATE "'.$smsg->internaldate.'"');
 533 }
 534
 535 sub emit_flags { $_[0]->msg_more(' FLAGS ()') }
 536
 537 sub emit_envelope {
 538         my ($self, undef, undef, undef, $eml) = @_;
 539         $self->msg_more(' ENVELOPE '.eml_envelope($eml));
 540 }
 541
 542 sub emit_rfc822_header {
 543         my ($self, $k, undef, undef, $eml) = @_;
 544         $self->msg_more(" $k {".length(${$eml->{hdr}})."}\r\n");
 545         $self->msg_more(${$eml->{hdr}});
 546 }
 547
 548 # n.b. this is sorted to be after any emit_eml_new ops
 549 sub emit_rfc822_text {
 550         my ($self, $k, undef, $bref) = @_;
 551         $self->msg_more(" $k {".length($$bref)."}\r\n");
 552         $self->msg_more($$bref);
 553 }
 554
 555 sub emit_bodystructure {
 556         my ($self, undef, undef, undef, $eml) = @_;
 557         $self->msg_more(' BODYSTRUCTURE '.fetch_body($eml, 1));
 558 }
 559
 560 sub emit_body {
 561         my ($self, undef, undef, undef, $eml) = @_;
 562         $self->msg_more(' BODY '.fetch_body($eml));
 563 }
 564
 565 # set $eml once ($_[4] == $eml, $_[3] == $bref)
 566 sub op_eml_new { $_[4] = PublicInbox::Eml->new($_[3]) }
 567
 568 # s/From / fixes old bug from import (pre-a0c07cba0e5d8b6a)
 569 sub to_crlf_full {
 570         ${$_[0]} =~ s/(?<!\r)\n/\r\n/sg;
 571         ${$_[0]} =~ s/\A[\r\n]*From [^\r\n]*\r\n//s;
 572 }
 573
 574 sub op_crlf_bref { to_crlf_full($_[3]) }
 575
 576 sub op_crlf_hdr { to_crlf_full($_[4]->{hdr}) }
 577
 578 sub op_crlf_bdy { ${$_[4]->{bdy}} =~ s/(?<!\r)\n/\r\n/sg if $_[4]->{bdy} }
 579
 580 sub uid_clamp ($$$) {
 581         my ($self, $beg, $end) = @_;
 582         my $uid_min = $self->{uid_base} + 1;
 583         my $uid_end = $uid_min + UID_BLOCK - 1;
 584         $$beg = $uid_min if $$beg < $uid_min;
 585         $$end = $uid_end if $$end > $uid_end;
 586 }
 587
 588 sub range_step ($$) {
 589         my ($self, $range_csv) = @_;
 590         my ($beg, $end, $range);
 591         if ($$range_csv =~ s/\A([^,]+),//) {
 592                 $range = $1;
 593         } else {
 594                 $range = $$range_csv;
 595                 $$range_csv = undef;
 596         }
 597         my $uid_base = $self->{uid_base};
 598         my $uid_end = $uid_base + UID_BLOCK;
 599         if ($range =~ /\A([0-9]+):([0-9]+)\z/) {
 600                 ($beg, $end) = ($1 + 0, $2 + 0);
 601                 uid_clamp($self, \$beg, \$end);
 602         } elsif ($range =~ /\A([0-9]+):\*\z/) {
 603                 $beg = $1 + 0;
 604                 $end = $self->{ibx}->over->max;
 605                 $end = $uid_end if $end > $uid_end;
 606                 $beg = $end if $beg > $end;
 607                 uid_clamp($self, \$beg, \$end);
 608         } elsif ($range =~ /\A[0-9]+\z/) {
 609                 $beg = $end = $range + 0;
 610                 # just let the caller do an out-of-range query if a single
 611                 # UID is out-of-range
 612                 ++$beg if ($beg <= $uid_base || $end > $uid_end);
 613         } else {
 614                 return 'BAD fetch range';
 615         }
 616         my $msn = $beg - $uid_base;
 617         [ $beg, $end, $$range_csv, \$msn ];
 618 }
 619
 620 sub refill_range ($$$) {
 621         my ($self, $msgs, $range_info) = @_;
 622         my ($beg, $end, $range_csv) = @$range_info;
 623         if (scalar(@$msgs = @{$self->{ibx}->over->query_xover($beg, $end)})) {
 624                 $range_info->[0] = $msgs->[-1]->{num} + 1;
 625                 return;
 626         }
 627         return 'OK Fetch done' if !$range_csv;
 628         my $next_range = range_step($self, \$range_csv);
 629         return $next_range if !ref($next_range); # error
 630         @$range_info = @$next_range;
 631         undef; # keep looping
 632 }
 633
 634 sub fetch_blob { # long_response
 635         my ($self, $tag, $msgs, $range_info, $ops, $partial) = @_;
 636         while (!@$msgs) { # rare
 637                 if (my $end = refill_range($self, $msgs, $range_info)) {
 638                         $self->write(\"$tag $end\r\n");
 639                         return;
 640                 }
 641         }
 642         git_async_cat($self->{ibx}->git, $msgs->[0]->{blob},
 643                         \&fetch_blob_cb, \@_);
 644 }
 645
 646 sub fetch_smsg { # long_response
 647         my ($self, $tag, $msgs, $range_info, $ops) = @_;
 648         while (!@$msgs) { # rare
 649                 if (my $end = refill_range($self, $msgs, $range_info)) {
 650                         $self->write(\"$tag $end\r\n");
 651                         return;
 652                 }
 653         }
 654         fetch_run_ops($self, $range_info->[3], $_, undef, $ops) for @$msgs;
 655         @$msgs = ();
 656         1; # more
 657 }
 658
 659 sub refill_uids ($$$;$) {
 660         my ($self, $uids, $range_info, $sql) = @_;
 661         my ($beg, $end, $range_csv) = @$range_info;
 662         my $over = $self->{ibx}->over;
 663         while (1) {
 664                 if (scalar(@$uids = @{$over->uid_range($beg, $end, $sql)})) {
 665                         $range_info->[0] = $uids->[-1] + 1; # update $beg
 666                         return;
 667                 } elsif (!$range_csv) {
 668                         return 0;
 669                 } else {
 670                         my $next_range = range_step($self, \$range_csv);
 671                         return $next_range if !ref($next_range); # error
 672                         ($beg, $end, $range_csv) = @$range_info = @$next_range;
 673                         # continue looping
 674                 }
 675         }
 676 }
 677
 678 sub fetch_uid { # long_response
 679         my ($self, $tag, $uids, $range_info, $ops) = @_;
 680         if (defined(my $err = refill_uids($self, $uids, $range_info))) {
 681                 $err ||= 'OK Fetch done';
 682                 $self->write("$tag $err\r\n");
 683                 return;
 684         }
 685         my ($i, $k);
 686         my $msn = $range_info->[3];
 687         for (@$uids) {
 688                 $self->msg_more(fetch_msn_uid($msn, $_));
 689                 for ($i = 0; $i < @$ops;) {
 690                         $k = $ops->[$i++];
 691                         $ops->[$i++]->($self, $k);
 692                 }
 693                 $self->msg_more(")\r\n");
 694         }
 695         @$uids = ();
 696         1; # more
 697 }
 698
 699 sub cmd_status ($$$;@) {
 700         my ($self, $tag, $mailbox, @items) = @_;
 701         return "$tag BAD no items\r\n" if !scalar(@items);
 702         ($items[0] !~ s/\A\(//s || $items[-1] !~ s/\)\z//s) and
 703                 return "$tag BAD invalid args\r\n";
 704         my ($ibx, $exists, $uidnext) = inbox_lookup($self, $mailbox);
 705         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 706         my @it;
 707         for my $it (@items) {
 708                 $it = uc($it);
 709                 push @it, $it;
 710                 if ($it =~ /\A(?:MESSAGES|UNSEEN|RECENT)\z/) {
 711                         push @it, $exists;
 712                 } elsif ($it eq 'UIDNEXT') {
 713                         push @it, $uidnext;
 714                 } elsif ($it eq 'UIDVALIDITY') {
 715                         push @it, $ibx->{uidvalidity};
 716                 } else {
 717                         return "$tag BAD invalid item\r\n";
 718                 }
 719         }
 720         return "$tag BAD no items\r\n" if !@it;
 721         "* STATUS $mailbox (".join(' ', @it).")\r\n" .
 722         "$tag OK Status done\r\n";
 723 }
 724
 725 my %patmap = ('*' => '.*', '%' => '[^\.]*');
 726 sub cmd_list ($$$$) {
 727         my ($self, $tag, $refname, $wildcard) = @_;
 728         my $l = $self->{imapd}->{inboxlist};
 729         if ($refname eq '' && $wildcard eq '') {
 730                 # request for hierarchy delimiter
 731                 $l = [ qq[* LIST (\\Noselect) "." ""\r\n] ];
 732         } elsif ($refname ne '' || $wildcard ne '*') {
 733                 $wildcard =~ s!([^a-z0-9_])!$patmap{$1} // "\Q$1"!egi;
 734                 $l = [ grep(/ \Q$refname\E$wildcard\r\n\z/is, @$l) ];
 735         }
 736         \(join('', @$l, "$tag OK List done\r\n"));
 737 }
 738
 739 sub cmd_lsub ($$$$) {
 740         my (undef, $tag) = @_; # same args as cmd_list
 741         "$tag OK Lsub done\r\n";
 742 }
 743
 744 sub eml_index_offs_i { # PublicInbox::Eml::each_part callback
 745         my ($p, $all) = @_;
 746         my ($eml, undef, $idx) = @$p;
 747         if ($idx && lc($eml->ct->{type}) eq 'multipart') {
 748                 $eml->{imap_bdy} = $eml->{bdy} // \'';
 749         }
 750         $all->{$idx} = $eml; # $idx => Eml
 751 }
 752
 753 # prepares an index for BODY[$SECTION_IDX] fetches
 754 sub eml_body_idx ($$) {
 755         my ($eml, $section_idx) = @_;
 756         my $idx = $eml->{imap_all_parts} //= do {
 757                 my $all = {};
 758                 $eml->each_part(\&eml_index_offs_i, $all, 0, 1);
 759                 # top-level of multipart, BODY[0] not allowed (nz-number)
 760                 delete $all->{0};
 761                 $all;
 762         };
 763         $idx->{$section_idx};
 764 }
 765
 766 # BODY[($SECTION_IDX)?(.$SECTION_NAME)?]<$offset.$bytes>
 767 sub partial_body {
 768         my ($eml, $section_idx, $section_name) = @_;
 769         if (defined $section_idx) {
 770                 $eml = eml_body_idx($eml, $section_idx) or return;
 771         }
 772         if (defined $section_name) {
 773                 if ($section_name eq 'MIME') {
 774                         # RFC 3501 6.4.5 states:
 775                         #       The MIME part specifier MUST be prefixed
 776                         #       by one or more numeric part specifiers
 777                         return unless defined $section_idx;
 778                         return $eml->header_obj->as_string . "\r\n";
 779                 }
 780                 my $bdy = $eml->{bdy} // $eml->{imap_bdy} // \'';
 781                 $eml = PublicInbox::Eml->new($$bdy);
 782                 if ($section_name eq 'TEXT') {
 783                         return $eml->body_raw;
 784                 } elsif ($section_name eq 'HEADER') {
 785                         return $eml->header_obj->as_string . "\r\n";
 786                 } else {
 787                         die "BUG: bad section_name=$section_name";
 788                 }
 789         }
 790         ${$eml->{bdy} // $eml->{imap_bdy} // \''};
 791 }
 792
 793 # similar to what's in PublicInbox::Eml::re_memo, but doesn't memoize
 794 # to avoid OOM with malicious users
 795 sub hdrs_regexp ($) {
 796         my ($hdrs) = @_;
 797         my $names = join('|', map { "\Q$_" } split(/[ \t]+/, $hdrs));
 798         qr/^(?:$names):[ \t]*[^\n]*\r?\n # 1st line
 799                 # continuation lines:
 800                 (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*
 801                 /ismx;
 802 }
 803
 804 # BODY[($SECTION_IDX.)?HEADER.FIELDS.NOT ($HDRS)]<$offset.$bytes>
 805 sub partial_hdr_not {
 806         my ($eml, $section_idx, $hdrs_re) = @_;
 807         if (defined $section_idx) {
 808                 $eml = eml_body_idx($eml, $section_idx) or return;
 809         }
 810         my $str = $eml->header_obj->as_string;
 811         $str =~ s/$hdrs_re//g;
 812         $str =~ s/(?<!\r)\n/\r\n/sg;
 813         $str .= "\r\n";
 814 }
 815
 816 # BODY[($SECTION_IDX.)?HEADER.FIELDS ($HDRS)]<$offset.$bytes>
 817 sub partial_hdr_get {
 818         my ($eml, $section_idx, $hdrs_re) = @_;
 819         if (defined $section_idx) {
 820                 $eml = eml_body_idx($eml, $section_idx) or return;
 821         }
 822         my $str = $eml->header_obj->as_string;
 823         $str = join('', ($str =~ m/($hdrs_re)/g));
 824         $str =~ s/(?<!\r)\n/\r\n/sg;
 825         $str .= "\r\n";
 826 }
 827
 828 sub partial_prepare ($$$$) {
 829         my ($need, $partial, $want, $att) = @_;
 830
 831         # recombine [ "BODY[1.HEADER.FIELDS", "(foo", "bar)]" ]
 832         # back to: "BODY[1.HEADER.FIELDS (foo bar)]"
 833         return unless $att =~ /\ABODY\[/s;
 834         until (rindex($att, ']') >= 0) {
 835                 my $next = shift @$want or return;
 836                 $att .= ' ' . uc($next);
 837         }
 838         if ($att =~ /\ABODY\[([0-9]+(?:\.[0-9]+)*)? # 1 - section_idx
 839                         (?:\.(HEADER|MIME|TEXT))? # 2 - section_name
 840                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 3, 4
 841                 $partial->{$att} = [ \&partial_body, $1, $2, $3, $4 ];
 842                 $$need |= CRLF_BREF|EML_HDR|EML_BDY;
 843         } elsif ($att =~ /\ABODY\[(?:([0-9]+(?:\.[0-9]+)*)\.)? # 1 - section_idx
 844                                 (?:HEADER\.FIELDS(\.NOT)?)\x20 # 2
 845                                 \(([A-Z0-9\-\x20]+)\) # 3 - hdrs
 846                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 4 5
 847                 my $tmp = $partial->{$att} = [ $2 ? \&partial_hdr_not
 848                                                 : \&partial_hdr_get,
 849                                                 $1, undef, $4, $5 ];
 850                 $tmp->[2] = hdrs_regexp($3);
 851
 852                 # don't emit CRLF_HDR instruction, here, partial_hdr_*
 853                 # will do CRLF conversion with only the extracted result
 854                 # and not waste time converting lines we don't care about.
 855                 $$need |= EML_HDR;
 856         } else {
 857                 undef;
 858         }
 859 }
 860
 861 sub partial_emit ($$$) {
 862         my ($self, $partial, $eml) = @_;
 863         for (@$partial) {
 864                 my ($k, $cb, @args) = @$_;
 865                 my ($offset, $len) = splice(@args, -2);
 866                 # $cb is partial_body|partial_hdr_get|partial_hdr_not
 867                 my $str = $cb->($eml, @args) // '';
 868                 if (defined $offset) {
 869                         if (defined $len) {
 870                                 $str = substr($str, $offset, $len);
 871                                 $k =~ s/\.$len>\z/>/ or warn
 872 "BUG: unable to remove `.$len>' from `$k'";
 873                         } else {
 874                                 $str = substr($str, $offset);
 875                                 $len = length($str);
 876                         }
 877                 } else {
 878                         $len = length($str);
 879                 }
 880                 $self->msg_more(" $k {$len}\r\n");
 881                 $self->msg_more($str);
 882         }
 883 }
 884
 885 sub fetch_compile ($) {
 886         my ($want) = @_;
 887         if ($want->[0] =~ s/\A\(//s) {
 888                 $want->[-1] =~ s/\)\z//s or return 'BAD no rparen';
 889         }
 890         my (%partial, %seen, @op);
 891         my $need = 0;
 892         while (defined(my $att = shift @$want)) {
 893                 $att = uc($att);
 894                 next if $att eq 'UID'; # always returned
 895                 $att =~ s/\ABODY\.PEEK\[/BODY\[/; # we're read-only
 896                 my $x = $FETCH_ATT{$att};
 897                 if ($x) {
 898                         while (my ($k, $fl_cb) = each %$x) {
 899                                 next if $seen{$k}++;
 900                                 $need |= $fl_cb->[0];
 901                                 push @op, [ @$fl_cb, $k ];
 902                         }
 903                 } elsif (!partial_prepare(\$need, \%partial, $want, $att)) {
 904                         return "BAD param: $att";
 905                 }
 906         }
 907         my @r;
 908
 909         # stabilize partial order for consistency and ease-of-debugging:
 910         if (scalar keys %partial) {
 911                 $need |= NEED_BLOB;
 912                 $r[2] = [ map { [ $_, @{$partial{$_}} ] } sort keys %partial ];
 913         }
 914
 915         push @op, $OP_EML_NEW if ($need & (EML_HDR|EML_BDY));
 916
 917         # do we need CRLF conversion?
 918         if ($need & CRLF_BREF) {
 919                 push @op, $OP_CRLF_BREF;
 920         } elsif (my $crlf = ($need & (CRLF_HDR|CRLF_BDY))) {
 921                 if ($crlf == (CRLF_HDR|CRLF_BDY)) {
 922                         push @op, $OP_CRLF_BREF;
 923                 } elsif ($need & CRLF_HDR) {
 924                         push @op, $OP_CRLF_HDR;
 925                 } else {
 926                         push @op, $OP_CRLF_BDY;
 927                 }
 928         }
 929
 930         $r[0] = $need & NEED_BLOB ? \&fetch_blob :
 931                 ($need & NEED_SMSG ? \&fetch_smsg : \&fetch_uid);
 932
 933         # r[1] = [ $key1, $cb1, $key2, $cb2, ... ]
 934         use sort 'stable'; # makes output more consistent
 935         $r[1] = [ map { ($_->[2], $_->[1]) } sort { $a->[0] <=> $b->[0] } @op ];
 936         @r;
 937 }
 938
 939 sub cmd_uid_fetch ($$$$;@) {
 940         my ($self, $tag, $range_csv, @want) = @_;
 941         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 942         my ($cb, $ops, $partial) = fetch_compile(\@want);
 943         return "$tag $cb\r\n" unless $ops;
 944
 945         $range_csv = 'bad' if $range_csv !~ $valid_range;
 946         my $range_info = range_step($self, \$range_csv);
 947         return "$tag $range_info\r\n" if !ref($range_info);
 948         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 949 }
 950
 951 sub msn_to_uid_range ($$) {
 952         my $uid_base = $_[0]->{uid_base};
 953         $_[1] =~ s/([0-9]+)/$uid_base + $1/sge;
 954 }
 955
 956 sub cmd_fetch ($$$$;@) {
 957         my ($self, $tag, $range_csv, @want) = @_;
 958         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 959         my ($cb, $ops, $partial) = fetch_compile(\@want);
 960         return "$tag $cb\r\n" unless $ops;
 961
 962         # cb is one of fetch_blob, fetch_smsg, fetch_uid
 963         $range_csv = 'bad' if $range_csv !~ $valid_range;
 964         msn_to_uid_range($self, $range_csv);
 965         my $range_info = range_step($self, \$range_csv);
 966         return "$tag $range_info\r\n" if !ref($range_info);
 967         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 968 }
 969
 970 sub parse_date ($) { # 02-Oct-1993
 971         my ($date_text) = @_;
 972         my ($dd, $mon, $yyyy) = split(/-/, $_[0], 3);
 973         defined($yyyy) or return;
 974         my $mm = $MoY{$mon} // return;
 975         $dd =~ /\A[0123]?[0-9]\z/ or return;
 976         $yyyy =~ /\A[0-9]{4,}\z/ or return; # Y10K-compatible!
 977         timegm(0, 0, 0, $dd, $mm, $yyyy);
 978 }
 979
 980 sub msn_convert ($$) {
 981         my ($self, $uids) = @_;
 982         my $adj = $self->{uid_base};
 983         $_ -= $adj for @$uids;
 984 }
 985
 986 sub search_uid_range { # long_response
 987         my ($self, $tag, $sql, $range_info, $want_msn) = @_;
 988         my $uids = [];
 989         if (defined(my $err = refill_uids($self, $uids, $range_info, $sql))) {
 990                 $err ||= 'OK Search done';
 991                 $self->write("\r\n$tag $err\r\n");
 992                 return;
 993         }
 994         msn_convert($self, $uids) if $want_msn;
 995         $self->msg_more(join(' ', '', @$uids));
 996         1; # more
 997 }
 998
 999 sub date_search {
1000         my ($q, $k, $d) = @_;
1001         my $sql = $q->{sql};
1002
1003         # Date: header
1004         if ($k eq 'SENTON') {
1005                 my $end = $d + 86399; # no leap day...
1006                 my $da = strftime('%Y%m%d%H%M%S', gmtime($d));
1007                 my $db = strftime('%Y%m%d%H%M%S', gmtime($end));
1008                 $q->{xap} .= " dt:$da..$db";
1009                 $$sql .= " AND ds >= $d AND ds <= $end" if defined($sql);
1010         } elsif ($k eq 'SENTBEFORE') {
1011                 $q->{xap} .= ' d:..'.strftime('%Y%m%d', gmtime($d));
1012                 $$sql .= " AND ds <= $d" if defined($sql);
1013         } elsif ($k eq 'SENTSINCE') {
1014                 $q->{xap} .= ' d:'.strftime('%Y%m%d', gmtime($d)).'..';
1015                 $$sql .= " AND ds >= $d" if defined($sql);
1016
1017         # INTERNALDATE (Received)
1018         } elsif ($k eq 'ON') {
1019                 my $end = $d + 86399; # no leap day...
1020                 $q->{xap} .= " ts:$d..$end";
1021                 $$sql .= " AND ts >= $d AND ts <= $end" if defined($sql);
1022         } elsif ($k eq 'BEFORE') {
1023                 $q->{xap} .= " ts:..$d";
1024                 $$sql .= " AND ts <= $d" if defined($sql);
1025         } elsif ($k eq 'SINCE') {
1026                 $q->{xap} .= " ts:$d..";
1027                 $$sql .= " AND ts >= $d" if defined($sql);
1028         } else {
1029                 die "BUG: $k not recognized";
1030         }
1031 }
1032
1033 # IMAP to Xapian search key mapping
1034 my %I2X = (
1035         SUBJECT => 's:',
1036         BODY => 'b:',
1037         FROM => 'f:',
1038         TEXT => '', # n.b. does not include all headers
1039         TO => 't:',
1040         CC => 'c:',
1041         # BCC => 'bcc:', # TODO
1042         # KEYWORD # TODO ? dfpre,dfpost,...
1043 );
1044
1045 # IMAP allows searching arbitrary headers via "HEADER $HDR_NAME $HDR_VAL"
1046 # which gets silly expensive.  We only allow the headers we already index.
1047 my %H2X = (%I2X, 'MESSAGE-ID' => 'm:', 'LIST-ID' => 'l:');
1048
1049 sub xap_append ($$$$) {
1050         my ($q, $rest, $k, $xk) = @_;
1051         delete $q->{sql}; # can't use over.sqlite3
1052         defined(my $arg = shift @$rest) or return "BAD $k no arg";
1053
1054         # AFAIK Xapian can't handle [*"] in probabilistic terms
1055         $arg =~ tr/*"//d;
1056         ${$q->{xap}} .= qq[ $xk"$arg"];
1057         undef;
1058 }
1059
1060 sub parse_query {
1061         my ($self, $rest) = @_;
1062         if (uc($rest->[0]) eq 'CHARSET') {
1063                 shift @$rest;
1064                 defined(my $c = shift @$rest) or return 'BAD missing charset';
1065                 $c =~ /\A(?:UTF-8|US-ASCII)\z/ or return 'NO [BADCHARSET]';
1066         }
1067
1068         my $sql = ''; # date conditions, {sql} deleted if Xapian is needed
1069         my $xap = '';
1070         my $q = { sql => \$sql, xap => \$xap };
1071         while (@$rest) {
1072                 my $k = uc(shift @$rest);
1073                 # default criteria
1074                 next if $k =~ /\A(?:ALL|RECENT|UNSEEN|NEW)\z/;
1075                 next if $k eq 'AND'; # the default, until we support OR
1076                 if ($k =~ $valid_range) { # convert sequence numbers to UIDs
1077                         msn_to_uid_range($self, $k);
1078                         push @{$q->{uid}}, $k;
1079                 } elsif ($k eq 'UID') {
1080                         $k = shift(@$rest) // '';
1081                         $k =~ $valid_range or return 'BAD UID range';
1082                         push @{$q->{uid}}, $k;
1083                 } elsif ($k =~ /\A(?:SENT)?(?:SINCE|ON|BEFORE)\z/) {
1084                         my $d = parse_date(shift(@$rest) // '');
1085                         defined $d or return "BAD $k date format";
1086                         date_search($q, $k, $d);
1087                 } elsif ($k =~ /\A(?:SMALLER|LARGER)\z/) {
1088                         delete $q->{sql}; # can't use over.sqlite3
1089                         my $bytes = shift(@$rest) // '';
1090                         $bytes =~ /\A[0-9]+\z/ or return "BAD $k not a number";
1091                         $xap .= ' bytes:' . ($k eq 'SMALLER' ?
1092                                                         '..'.(--$bytes) :
1093                                                         (++$bytes).'..');
1094                 } elsif ($k eq 'HEADER') {
1095                         $k = uc(shift(@$rest) // '');
1096                         my $xk = $H2X{$k} or
1097                                 return "BAD HEADER $k not supported";
1098                         my $err = xap_append($q, $rest, $k, $xk);
1099                         return $err if $err;
1100                 } elsif (defined(my $xk = $I2X{$k})) {
1101                         my $err = xap_append($q, $rest, $k, $xk);
1102                         return $err if $err;
1103                 } else {
1104                         # TODO: parentheses, OR, NOT ...
1105                         return "BAD $k not supported (yet?)";
1106                 }
1107         }
1108
1109         # favor using over.sqlite3 if possible, since Xapian is optional
1110         if (exists $q->{sql}) {
1111                 delete($q->{xap});
1112                 delete($q->{sql}) if $sql eq '';
1113         } elsif (!$self->{ibx}->search) {
1114                 return 'BAD Xapian not configured for mailbox';
1115         }
1116         my $max = $self->{ibx}->over->max;
1117         if (my $uid = delete $q->{uid}) {
1118                 my $range_csv = join(',', @$uid);
1119                 do {
1120                         my $nxt = range_step($self, \$range_csv);
1121                         my ($beg, $end) = @$nxt;
1122                         if ($xap) {
1123                                 $xap .= " uid:$beg..$end";
1124                         } elsif ($beg == $end) {
1125                                 $sql .= " AND num = $beg";
1126                         } else {
1127                                 $sql .= " AND num >= $beg AND num <= $end";
1128                         }
1129                 } while ($range_csv);
1130         }
1131         my $beg = 1;
1132         uid_clamp($self, \$beg, \$max);
1133         $q->{range_info} = [ $beg, $max ];
1134         $q;
1135 }
1136
1137 sub refill_xap ($$$$) {
1138         my ($self, $uids, $range_info, $q) = @_;
1139         my ($beg, $end) = @$range_info;
1140         my $srch = $self->{ibx}->search;
1141         my $opt = { mset => 2, limit => 1000 };
1142         my $nshard = $srch->{nshard} // 1;
1143         while (1) {
1144                 my $mset = $srch->query("$$q uid:$beg..$end", $opt);
1145                 @$uids = map { mdocid($nshard, $_) } $mset->items;
1146                 if (@$uids) {
1147                         $range_info->[0] = $uids->[-1] + 1; # update $beg
1148                         return;
1149                 } else { # all done
1150                         return 0;
1151                 }
1152         }
1153 }
1154
1155 sub search_xap_range { # long_response
1156         my ($self, $tag, $q, $range_info, $want_msn) = @_;
1157         my $uids = [];
1158         if (defined(my $err = refill_xap($self, $uids, $range_info, $q))) {
1159                 $err ||= 'OK Search done';
1160                 $self->write("\r\n$tag $err\r\n");
1161                 return;
1162         }
1163         msn_convert($self, $uids) if $want_msn;
1164         $self->msg_more(join(' ', '', @$uids));
1165         1; # more
1166 }
1167
1168 sub search_common {
1169         my ($self, $tag, $rest, $want_msn) = @_;
1170         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
1171         my $q = parse_query($self, $rest);
1172         return "$tag $q\r\n" if !ref($q);
1173         my ($sql, $range_info) = delete @$q{qw(sql range_info)};
1174         if (!scalar(keys %$q)) { # overview.sqlite3
1175                 $self->msg_more('* SEARCH');
1176                 long_response($self, \&search_uid_range,
1177                                 $tag, $sql, $range_info, $want_msn);
1178         } elsif ($q = $q->{xap}) {
1179                 $self->msg_more('* SEARCH');
1180                 long_response($self, \&search_xap_range,
1181                                 $tag, $q, $range_info, $want_msn);
1182         } else {
1183                 "$tag BAD Error\r\n";
1184         }
1185 }
1186
1187 sub cmd_uid_search ($$$;) {
1188         my ($self, $tag) = splice(@_, 0, 2);
1189         search_common($self, $tag, \@_);
1190 }
1191
1192 sub cmd_search ($$$;) {
1193         my ($self, $tag) = splice(@_, 0, 2);
1194         search_common($self, $tag, \@_, 1);
1195 }
1196
1197 sub args_ok ($$) { # duplicated from PublicInbox::NNTP
1198         my ($cb, $argc) = @_;
1199         my $tot = prototype $cb;
1200         my ($nreq, undef) = split(';', $tot);
1201         $nreq = ($nreq =~ tr/$//) - 1;
1202         $tot = ($tot =~ tr/$//) - 1;
1203         ($argc <= $tot && $argc >= $nreq);
1204 }
1205
1206 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
1207 sub process_line ($$) {
1208         my ($self, $l) = @_;
1209         my ($tag, $req, @args) = parse_line('[ \t]+', 0, $l);
1210         pop(@args) if (@args && !defined($args[-1]));
1211         if (@args && uc($req) eq 'UID') {
1212                 $req .= "_".(shift @args);
1213         }
1214         my $res = eval {
1215                 if (my $cmd = $self->can('cmd_'.lc($req // ''))) {
1216                         defined($self->{-idle_tag}) ?
1217                                 "$self->{-idle_tag} BAD expected DONE\r\n" :
1218                                 $cmd->($self, $tag, @args);
1219                 } elsif (uc($tag // '') eq 'DONE' && !defined($req)) {
1220                         cmd_done($self, $tag);
1221                 } else { # this is weird
1222                         auth_challenge_ok($self) //
1223                                         ($tag // '*') .
1224                                         ' BAD Error in IMAP command '.
1225                                         ($req // '(???)').
1226                                         ": Unknown command\r\n";
1227                 }
1228         };
1229         my $err = $@;
1230         if ($err && $self->{sock}) {
1231                 $l =~ s/\r?\n//s;
1232                 err($self, 'error from: %s (%s)', $l, $err);
1233                 $tag //= '*';
1234                 $res = "$tag BAD program fault - command not performed\r\n";
1235         }
1236         return 0 unless defined $res;
1237         $self->write($res);
1238 }
1239
1240 sub long_step {
1241         my ($self) = @_;
1242         # wbuf is unset or empty, here; {long} may add to it
1243         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
1244         my $more = eval { $cb->($self, @args) };
1245         if ($@ || !$self->{sock}) { # something bad happened...
1246                 delete $self->{long_cb};
1247                 my $elapsed = now() - $t0;
1248                 if ($@) {
1249                         err($self,
1250                             "%s during long response[$fd] - %0.6f",
1251                             $@, $elapsed);
1252                 }
1253                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
1254                 $self->close;
1255         } elsif ($more) { # $self->{wbuf}:
1256                 $self->update_idle_time;
1257
1258                 # control passed to $more may be a GitAsyncCat object
1259                 requeue_once($self) if !ref($more);
1260         } else { # all done!
1261                 delete $self->{long_cb};
1262                 my $elapsed = now() - $t0;
1263                 my $fd = fileno($self->{sock});
1264                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
1265                 my $wbuf = $self->{wbuf}; # do NOT autovivify
1266
1267                 $self->requeue unless $wbuf && @$wbuf;
1268         }
1269 }
1270
1271 sub err ($$;@) {
1272         my ($self, $fmt, @args) = @_;
1273         printf { $self->{imapd}->{err} } $fmt."\n", @args;
1274 }
1275
1276 sub out ($$;@) {
1277         my ($self, $fmt, @args) = @_;
1278         printf { $self->{imapd}->{out} } $fmt."\n", @args;
1279 }
1280
1281 sub long_response ($$;@) {
1282         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
1283
1284         my $sock = $self->{sock} or return;
1285         # make sure we disable reading during a long response,
1286         # clients should not be sending us stuff and making us do more
1287         # work while we are stream a response to them
1288         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
1289         long_step($self); # kick off!
1290         undef;
1291 }
1292
1293 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1294 sub event_step {
1295         my ($self) = @_;
1296
1297         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1298
1299         $self->update_idle_time;
1300         # only read more requests if we've drained the write buffer,
1301         # otherwise we can be buffering infinitely w/o backpressure
1302
1303         my $rbuf = $self->{rbuf} // \(my $x = '');
1304         my $line = index($$rbuf, "\n");
1305         while ($line < 0) {
1306                 if (length($$rbuf) >= LINE_MAX) {
1307                         $self->write(\"\* BAD request too long\r\n");
1308                         return $self->close;
1309                 }
1310                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1311                 $line = index($$rbuf, "\n");
1312         }
1313         $line = substr($$rbuf, 0, $line + 1, '');
1314         $line =~ s/\r?\n\z//s;
1315         return $self->close if $line =~ /[[:cntrl:]]/s;
1316         my $t0 = now();
1317         my $fd = fileno($self->{sock});
1318         my $r = eval { process_line($self, $line) };
1319         my $pending = $self->{wbuf} ? ' pending' : '';
1320         out($self, "[$fd] %s - %0.6f$pending - $r", $line, now() - $t0);
1321
1322         return $self->close if $r < 0;
1323         $self->rbuf_idle($rbuf);
1324         $self->update_idle_time;
1325
1326         # maybe there's more pipelined data, or we'll have
1327         # to register it for socket-readiness notifications
1328         $self->requeue unless $pending;
1329 }
1330
1331 sub compressed { undef }
1332
1333 sub zflush {} # overridden by IMAPdeflate
1334
1335 # RFC 4978
1336 sub cmd_compress ($$$) {
1337         my ($self, $tag, $alg) = @_;
1338         return "$tag BAD DEFLATE only\r\n" if uc($alg) ne "DEFLATE";
1339         return "$tag BAD COMPRESS active\r\n" if $self->compressed;
1340
1341         # CRIME made TLS compression obsolete
1342         # return "$tag NO [COMPRESSIONACTIVE]\r\n" if $self->tls_compressed;
1343
1344         PublicInbox::IMAPdeflate->enable($self, $tag);
1345         $self->requeue;
1346         undef
1347 }
1348
1349 sub cmd_starttls ($$) {
1350         my ($self, $tag) = @_;
1351         my $sock = $self->{sock} or return;
1352         if ($sock->can('stop_SSL') || $self->compressed) {
1353                 return "$tag BAD TLS or compression already enabled\r\n";
1354         }
1355         my $opt = $self->{imapd}->{accept_tls} or
1356                 return "$tag BAD can not initiate TLS negotiation\r\n";
1357         $self->write(\"$tag OK begin TLS negotiation now\r\n");
1358         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
1359         $self->requeue if PublicInbox::DS::accept_tls_step($self);
1360         undef;
1361 }
1362
1363 # for graceful shutdown in PublicInbox::Daemon:
1364 sub busy {
1365         my ($self, $now) = @_;
1366         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1367 }
1368
1369 sub close {
1370         my ($self) = @_;
1371         if (my $ibx = delete $self->{ibx}) {
1372                 stop_idle($self, $ibx);
1373         }
1374         $self->SUPER::close; # PublicInbox::DS::close
1375 }
1376
1377 # we're read-only, so SELECT and EXAMINE do the same thing
1378 no warnings 'once';
1379 *cmd_select = \&cmd_examine;
1380
1381 package PublicInbox::IMAP_preauth;
1382 our @ISA = qw(PublicInbox::IMAP);
1383
1384 sub logged_in { 0 }
1385
1386 1;