lib/PublicInbox/IMAP.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents an IMAP client connected to
   5 # public-inbox-imapd.  Much of this was taken from NNTP, but
   6 # further refined while experimenting on future ideas to handle
   7 # slow storage.
   8 #
   9 # data notes:
  10 # * NNTP article numbers are UIDs
  11
  12 package PublicInbox::IMAP;
  13 use strict;
  14 use base qw(PublicInbox::DS);
  15 use fields qw(imapd ibx long_cb -login_tag
  16         uid_base -idle_tag -idle_max);
  17 use PublicInbox::Eml;
  18 use PublicInbox::EmlContentFoo qw(parse_content_disposition);
  19 use PublicInbox::DS qw(now);
  20 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  21 use PublicInbox::GitAsyncCat;
  22 use Text::ParseWords qw(parse_line);
  23 use Errno qw(EAGAIN);
  24 use Time::Local qw(timegm);
  25 use POSIX qw(strftime);
  26 use Hash::Util qw(unlock_hash); # dependency of fields for perl 5.10+, anyways
  27
  28 my $Address;
  29 for my $mod (qw(Email::Address::XS Mail::Address)) {
  30         eval "require $mod" or next;
  31         $Address = $mod and last;
  32 }
  33 die "neither Email::Address::XS nor Mail::Address loaded: $@" if !$Address;
  34
  35 sub LINE_MAX () { 8000 } # RFC 2683 3.2.1.5
  36
  37 # changing this will cause grief for clients which cache
  38 sub UID_BLOCK () { 50_000 }
  39
  40 # these values area also used for sorting
  41 sub NEED_SMSG () { 1 }
  42 sub NEED_BLOB () { NEED_SMSG|2 }
  43 sub NEED_EML () { NEED_BLOB|4 }
  44 my $OP_EML_NEW = [ NEED_EML - 1, \&op_eml_new ];
  45
  46 my %FETCH_NEED = (
  47         'BODY[HEADER]' => [ NEED_EML, \&emit_rfc822_header ],
  48         'BODY[TEXT]' => [ NEED_EML, \&emit_rfc822_text ],
  49         'BODY[]' => [ NEED_BLOB, \&emit_rfc822 ],
  50         'RFC822.HEADER' => [ NEED_EML, \&emit_rfc822_header ],
  51         'RFC822.TEXT' => [ NEED_EML, \&emit_rfc822_text ],
  52         'RFC822.SIZE' => [ NEED_SMSG, \&emit_rfc822_size ],
  53         RFC822 => [ NEED_BLOB, \&emit_rfc822 ],
  54         BODY => [ NEED_EML, \&emit_body ],
  55         BODYSTRUCTURE => [ NEED_EML, \&emit_bodystructure ],
  56         ENVELOPE => [ NEED_EML, \&emit_envelope ],
  57         FLAGS => [ 0, \&emit_flags ],
  58         INTERNALDATE => [ NEED_SMSG, \&emit_internaldate ],
  59 );
  60 my %FETCH_ATT = map { $_ => [ $_ ] } keys %FETCH_NEED;
  61
  62 # aliases (RFC 3501 section 6.4.5)
  63 $FETCH_ATT{FAST} = [ qw(FLAGS INTERNALDATE RFC822.SIZE) ];
  64 $FETCH_ATT{ALL} = [ @{$FETCH_ATT{FAST}}, 'ENVELOPE' ];
  65 $FETCH_ATT{FULL} = [ @{$FETCH_ATT{ALL}}, 'BODY' ];
  66
  67 for my $att (keys %FETCH_ATT) {
  68         my %h = map { $_ => $FETCH_NEED{$_} } @{$FETCH_ATT{$att}};
  69         $FETCH_ATT{$att} = \%h;
  70 }
  71 undef %FETCH_NEED;
  72
  73 my $valid_range = '[0-9]+|[0-9]+:[0-9]+|[0-9]+:\*';
  74 $valid_range = qr/\A(?:$valid_range)(?:,(?:$valid_range))*\z/;
  75
  76 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  77 my %MoY;
  78 @MoY{@MoY} = (0..11);
  79
  80 # RFC 3501 5.4. Autologout Timer needs to be >= 30min
  81 $PublicInbox::DS::EXPTIME = 60 * 30;
  82
  83 sub greet ($) {
  84         my ($self) = @_;
  85         my $capa = capa($self);
  86         $self->write(\"* OK [$capa] public-inbox-imapd ready\r\n");
  87 }
  88
  89 sub new ($$$) {
  90         my ($class, $sock, $imapd) = @_;
  91         my $self = fields::new('PublicInbox::IMAP_preauth');
  92         unlock_hash(%$self);
  93         my $ev = EPOLLIN;
  94         my $wbuf;
  95         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  96                 return CORE::close($sock) if $! != EAGAIN;
  97                 $ev = PublicInbox::TLS::epollbit();
  98                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  99         }
 100         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
 101         $self->{imapd} = $imapd;
 102         if ($wbuf) {
 103                 $self->{wbuf} = $wbuf;
 104         } else {
 105                 greet($self);
 106         }
 107         $self->update_idle_time;
 108         $self;
 109 }
 110
 111 sub logged_in { 1 }
 112
 113 sub capa ($) {
 114         my ($self) = @_;
 115
 116         # dovecot advertises IDLE pre-login; perhaps because some clients
 117         # depend on it, so we'll do the same
 118         my $capa = 'CAPABILITY IMAP4rev1 IDLE';
 119         if ($self->logged_in) {
 120                 $capa .= ' COMPRESS=DEFLATE';
 121         } else {
 122                 if (!($self->{sock} // $self)->can('accept_SSL') &&
 123                         $self->{imapd}->{accept_tls}) {
 124                         $capa .= ' STARTTLS';
 125                 }
 126                 $capa .= ' AUTH=ANONYMOUS';
 127         }
 128 }
 129
 130 sub login_success ($$) {
 131         my ($self, $tag) = @_;
 132         bless $self, 'PublicInbox::IMAP';
 133         my $capa = capa($self);
 134         "$tag OK [$capa] Logged in\r\n";
 135 }
 136
 137 sub auth_challenge_ok ($) {
 138         my ($self) = @_;
 139         my $tag = delete($self->{-login_tag}) or return;
 140         login_success($self, $tag);
 141 }
 142
 143 sub cmd_login ($$$$) {
 144         my ($self, $tag) = @_; # ignore ($user, $password) = ($_[2], $_[3])
 145         login_success($self, $tag);
 146 }
 147
 148 sub cmd_close ($$) {
 149         my ($self, $tag) = @_;
 150         delete $self->{uid_base};
 151         delete $self->{ibx} ? "$tag OK Close done\r\n"
 152                                 : "$tag BAD No mailbox\r\n";
 153 }
 154
 155 sub cmd_logout ($$) {
 156         my ($self, $tag) = @_;
 157         delete $self->{-idle_tag};
 158         $self->write(\"* BYE logging out\r\n$tag OK Logout done\r\n");
 159         $self->shutdn; # PublicInbox::DS::shutdn
 160         undef;
 161 }
 162
 163 sub cmd_authenticate ($$$) {
 164         my ($self, $tag) = @_; # $method = $_[2], should be "ANONYMOUS"
 165         $self->{-login_tag} = $tag;
 166         "+\r\n"; # challenge
 167 }
 168
 169 sub cmd_capability ($$) {
 170         my ($self, $tag) = @_;
 171         '* '.capa($self)."\r\n$tag OK Capability done\r\n";
 172 }
 173
 174 sub cmd_noop ($$) { "$_[1] OK Noop done\r\n" }
 175
 176 # called by PublicInbox::InboxIdle
 177 sub on_inbox_unlock {
 178         my ($self, $ibx) = @_;
 179         my $new = $ibx->mm->max;
 180         my $uid_base = $self->{uid_base} // 0;
 181         my $uid_end = $uid_base + UID_BLOCK;
 182         defined(my $old = $self->{-idle_max}) or die 'BUG: -idle_max unset';
 183         $new = $uid_end if $new > $uid_end;
 184         if ($new > $old) {
 185                 $self->{-idle_max} = $new;
 186                 $new -= $uid_base;
 187                 $old -= $uid_base;
 188                 $self->msg_more("* $_ EXISTS\r\n") for (($old + 1)..($new - 1));
 189                 $self->write(\"* $new EXISTS\r\n");
 190         } elsif ($new == $uid_end) { # max exceeded $uid_end
 191                 # continue idling w/o inotify
 192                 delete $self->{-idle_max};
 193                 my $sock = $self->{sock} or return;
 194                 $ibx->unsubscribe_unlock(fileno($sock));
 195         }
 196 }
 197
 198 # called every X minute(s) or so by PublicInbox::DS::later
 199 my $IDLERS = {};
 200 my $idle_timer;
 201 sub idle_tick_all {
 202         my $old = $IDLERS;
 203         $IDLERS = {};
 204         for my $i (values %$old) {
 205                 next if ($i->{wbuf} || !exists($i->{-idle_tag}));
 206                 $i->update_idle_time or next;
 207                 $IDLERS->{fileno($i->{sock})} = $i;
 208                 $i->write(\"* OK Still here\r\n");
 209         }
 210         $idle_timer = scalar keys %$IDLERS ?
 211                         PublicInbox::DS::later(\&idle_tick_all) : undef;
 212 }
 213
 214 sub cmd_idle ($$) {
 215         my ($self, $tag) = @_;
 216         # IDLE seems allowed by dovecot w/o a mailbox selected *shrug*
 217         my $ibx = $self->{ibx} or return "$tag BAD no mailbox selected\r\n";
 218         $self->{-idle_tag} = $tag;
 219         my $max = $ibx->mm->max // 0;
 220         my $uid_end = ($self->{uid_base} // 0) + UID_BLOCK;
 221         my $sock = $self->{sock} or return;
 222         my $fd = fileno($sock);
 223         # only do inotify on most recent slice
 224         if ($max < $uid_end) {
 225                 $ibx->subscribe_unlock($fd, $self);
 226                 $self->{imapd}->idler_start;
 227                 $self->{-idle_max} = $max;
 228         }
 229         $idle_timer //= PublicInbox::DS::later(\&idle_tick_all);
 230         $IDLERS->{$fd} = $self;
 231         \"+ idling\r\n"
 232 }
 233
 234 sub stop_idle ($$) {
 235         my ($self, $ibx);
 236         my $sock = $self->{sock} or return;
 237         my $fd = fileno($sock);
 238         delete $IDLERS->{$fd};
 239         $ibx->unsubscribe_unlock($fd);
 240 }
 241
 242 sub cmd_done ($$) {
 243         my ($self, $tag) = @_; # $tag is "DONE" (case-insensitive)
 244         defined(my $idle_tag = delete $self->{-idle_tag}) or
 245                 return "$tag BAD not idle\r\n";
 246         my $ibx = $self->{ibx} or do {
 247                 warn "BUG: idle_tag set w/o inbox";
 248                 return "$tag BAD internal bug\r\n";
 249         };
 250         stop_idle($self, $ibx);
 251         "$idle_tag OK Idle done\r\n";
 252 }
 253
 254 sub ensure_ranges_exist ($$$) {
 255         my ($imapd, $ibx, $max) = @_;
 256         defined(my $mb_top = $ibx->{newsgroup}) or return;
 257         my $mailboxes = $imapd->{mailboxes};
 258         my @created;
 259         for (my $i = int($max/UID_BLOCK); $i >= 0; --$i) {
 260                 my $sub_mailbox = "$mb_top.$i";
 261                 last if exists $mailboxes->{$sub_mailbox};
 262                 $mailboxes->{$sub_mailbox} = $ibx;
 263                 $sub_mailbox =~ s/\Ainbox\./INBOX./i; # more familiar to users
 264                 push @created, $sub_mailbox;
 265         }
 266         return unless @created;
 267         my $l = $imapd->{inboxlist} or return;
 268         push @$l, map { qq[* LIST (\\HasNoChildren) "." $_\r\n] } @created;
 269 }
 270
 271 sub inbox_lookup ($$) {
 272         my ($self, $mailbox) = @_;
 273         my ($ibx, $exists, $uidnext);
 274         if ($mailbox =~ /\A(.+)\.([0-9]+)\z/) {
 275                 # old mail: inbox.comp.foo.$uid_block_idx
 276                 my ($mb_top, $uid_base) = ($1, $2 * UID_BLOCK);
 277
 278                 $ibx = $self->{imapd}->{mailboxes}->{lc $mailbox} or return;
 279                 $exists = $ibx->mm->max // 0;
 280                 $self->{uid_base} = $uid_base;
 281                 ensure_ranges_exist($self->{imapd}, $ibx, $exists);
 282                 my $uid_end = $uid_base + UID_BLOCK;
 283                 $exists = $uid_end if $exists > $uid_end;
 284                 $uidnext = $exists + 1;
 285                 $exists -= $uid_base;
 286         } else { # check for dummy inboxes
 287                 $ibx = $self->{imapd}->{mailboxes}->{lc $mailbox} or return;
 288                 delete $self->{uid_base};
 289                 $exists = 0;
 290                 $uidnext = 1;
 291         }
 292         ($ibx, $exists, $uidnext);
 293 }
 294
 295 sub cmd_examine ($$$) {
 296         my ($self, $tag, $mailbox) = @_;
 297         my ($ibx, $exists, $uidnext) = inbox_lookup($self, $mailbox);
 298         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 299
 300         # XXX: do we need this? RFC 5162/7162
 301         my $ret = $self->{ibx} ? "* OK [CLOSED] previous closed\r\n" : '';
 302         $self->{ibx} = $ibx;
 303         $ret .= <<EOF;
 304 * $exists EXISTS\r
 305 * $exists RECENT\r
 306 * FLAGS (\\Seen)\r
 307 * OK [PERMANENTFLAGS ()] Read-only mailbox\r
 308 * OK [UNSEEN $exists]\r
 309 * OK [UIDNEXT $uidnext]\r
 310 * OK [UIDVALIDITY $ibx->{uidvalidity}]\r
 311 $tag OK [READ-ONLY] EXAMINE/SELECT done\r
 312 EOF
 313 }
 314
 315 sub _esc ($) {
 316         my ($v) = @_;
 317         if (!defined($v)) {
 318                 'NIL';
 319         } elsif ($v =~ /[{"\r\n%*\\\[]/) { # literal string
 320                 '{' . length($v) . "}\r\n" . $v;
 321         } else { # quoted string
 322                 qq{"$v"}
 323         }
 324 }
 325
 326 sub addr_envelope ($$;$) {
 327         my ($eml, $x, $y) = @_;
 328         my $v = $eml->header_raw($x) //
 329                 ($y ? $eml->header_raw($y) : undef) // return 'NIL';
 330
 331         my @x = $Address->parse($v) or return 'NIL';
 332         '(' . join('',
 333                 map { '(' . join(' ',
 334                                 _esc($_->name), 'NIL',
 335                                 _esc($_->user), _esc($_->host)
 336                         ) . ')'
 337                 } @x) .
 338         ')';
 339 }
 340
 341 sub eml_envelope ($) {
 342         my ($eml) = @_;
 343         '(' . join(' ',
 344                 _esc($eml->header_raw('Date')),
 345                 _esc($eml->header_raw('Subject')),
 346                 addr_envelope($eml, 'From'),
 347                 addr_envelope($eml, 'Sender', 'From'),
 348                 addr_envelope($eml, 'Reply-To', 'From'),
 349                 addr_envelope($eml, 'To'),
 350                 addr_envelope($eml, 'Cc'),
 351                 addr_envelope($eml, 'Bcc'),
 352                 _esc($eml->header_raw('In-Reply-To')),
 353                 _esc($eml->header_raw('Message-ID')),
 354         ) . ')';
 355 }
 356
 357 sub _esc_hash ($) {
 358         my ($hash) = @_;
 359         if ($hash && scalar keys %$hash) {
 360                 $hash = [ %$hash ]; # flatten hash into 1-dimensional array
 361                 '(' . join(' ', map { _esc($_) } @$hash) . ')';
 362         } else {
 363                 'NIL';
 364         }
 365 }
 366
 367 sub body_disposition ($) {
 368         my ($eml) = @_;
 369         my $cd = $eml->header_raw('Content-Disposition') or return 'NIL';
 370         $cd = parse_content_disposition($cd);
 371         my $buf = '('._esc($cd->{type});
 372         $buf .= ' ' . _esc_hash(delete $cd->{attributes});
 373         $buf .= ')';
 374 }
 375
 376 sub body_leaf ($$;$) {
 377         my ($eml, $structure, $hold) = @_;
 378         my $buf = '';
 379         $eml->{is_submsg} and # parent was a message/(rfc822|news|global)
 380                 $buf .= eml_envelope($eml). ' ';
 381         my $ct = $eml->ct;
 382         $buf .= '('._esc($ct->{type}).' ';
 383         $buf .= _esc($ct->{subtype});
 384         $buf .= ' ' . _esc_hash(delete $ct->{attributes});
 385         $buf .= ' ' . _esc($eml->header_raw('Content-ID'));
 386         $buf .= ' ' . _esc($eml->header_raw('Content-Description'));
 387         my $cte = $eml->header_raw('Content-Transfer-Encoding') // '7bit';
 388         $buf .= ' ' . _esc($cte);
 389         $buf .= ' ' . $eml->{imap_body_len};
 390         $buf .= ' '.($eml->body_raw =~ tr/\n/\n/) if lc($ct->{type}) eq 'text';
 391
 392         # for message/(rfc822|global|news), $hold[0] should have envelope
 393         $buf .= ' ' . (@$hold ? join('', @$hold) : 'NIL') if $hold;
 394
 395         if ($structure) {
 396                 $buf .= ' '._esc($eml->header_raw('Content-MD5'));
 397                 $buf .= ' '. body_disposition($eml);
 398                 $buf .= ' '._esc($eml->header_raw('Content-Language'));
 399                 $buf .= ' '._esc($eml->header_raw('Content-Location'));
 400         }
 401         $buf .= ')';
 402 }
 403
 404 sub body_parent ($$$) {
 405         my ($eml, $structure, $hold) = @_;
 406         my $ct = $eml->ct;
 407         my $type = lc($ct->{type});
 408         if ($type eq 'multipart') {
 409                 my $buf = '(';
 410                 $buf .= @$hold ? join('', @$hold) : 'NIL';
 411                 $buf .= ' '._esc($ct->{subtype});
 412                 if ($structure) {
 413                         $buf .= ' '._esc_hash(delete $ct->{attributes});
 414                         $buf .= ' '.body_disposition($eml);
 415                         $buf .= ' '._esc($eml->header_raw('Content-Language'));
 416                         $buf .= ' '._esc($eml->header_raw('Content-Location'));
 417                 }
 418                 $buf .= ')';
 419                 @$hold = ($buf);
 420         } else { # message/(rfc822|global|news)
 421                 @$hold = (body_leaf($eml, $structure, $hold));
 422         }
 423 }
 424
 425 # this is gross, but we need to process the parent part AFTER
 426 # the child parts are done
 427 sub bodystructure_prep {
 428         my ($p, $q) = @_;
 429         my ($eml, $depth) = @$p; # ignore idx
 430         # set length here, as $eml->{bdy} gets deleted for message/rfc822
 431         $eml->{imap_body_len} = length($eml->body_raw);
 432         push @$q, $eml, $depth;
 433 }
 434
 435 # for FETCH BODY and FETCH BODYSTRUCTURE
 436 sub fetch_body ($;$) {
 437         my ($eml, $structure) = @_;
 438         my @q;
 439         $eml->each_part(\&bodystructure_prep, \@q, 0, 1);
 440         my $cur_depth = 0;
 441         my @hold;
 442         do {
 443                 my ($part, $depth) = splice(@q, -2);
 444                 my $is_mp_parent = $depth == ($cur_depth - 1);
 445                 $cur_depth = $depth;
 446
 447                 if ($is_mp_parent) {
 448                         body_parent($part, $structure, \@hold);
 449                 } else {
 450                         unshift @hold, body_leaf($part, $structure);
 451                 }
 452         } while (@q);
 453         join('', @hold);
 454 }
 455
 456 sub requeue_once ($) {
 457         my ($self) = @_;
 458         # COMPRESS users all share the same DEFLATE context.
 459         # Flush it here to ensure clients don't see
 460         # each other's data
 461         $self->zflush;
 462
 463         # no recursion, schedule another call ASAP,
 464         # but only after all pending writes are done.
 465         # autovivify wbuf:
 466         my $new_size = push(@{$self->{wbuf}}, \&long_step);
 467
 468         # wbuf may be populated by $cb, no need to rearm if so:
 469         $self->requeue if $new_size == 1;
 470 }
 471
 472 # my ($uid_base, $UID) = @_;
 473 sub fetch_msn_uid ($$) { '* '.($_[1] - $_[0]).' FETCH (UID '.$_[1] }
 474
 475 sub fetch_run_ops {
 476         my ($self, $uid_base, $smsg, $bref, $ops, $partial) = @_;
 477         $self->msg_more(fetch_msn_uid($uid_base, $smsg->{num}));
 478         my ($eml, $k);
 479         for (my $i = 0; $i < @$ops;) {
 480                 $k = $ops->[$i++];
 481                 $ops->[$i++]->($self, $k, $smsg, $bref, $eml);
 482         }
 483         partial_emit($self, $partial, $eml) if $partial;
 484         $self->msg_more(")\r\n");
 485 }
 486
 487 sub fetch_blob_cb { # called by git->cat_async via git_async_cat
 488         my ($bref, $oid, $type, $size, $fetch_arg) = @_;
 489         my ($self, undef, $msgs, undef, $ops, $partial) = @$fetch_arg;
 490         my $smsg = shift @$msgs or die 'BUG: no smsg';
 491         if (!defined($oid)) {
 492                 # it's possible to have TOCTOU if an admin runs
 493                 # public-inbox-(edit|purge), just move onto the next message
 494                 return requeue_once($self);
 495         } else {
 496                 $smsg->{blob} eq $oid or die "BUG: $smsg->{blob} != $oid";
 497         }
 498         $$bref =~ s/(?<!\r)\n/\r\n/sg; # make strict clients happy
 499
 500         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 501         $$bref =~ s/\A[\r\n]*From [^\r\n]*\r\n//s;
 502         fetch_run_ops($self, $self->{uid_base} // 0,
 503                         $smsg, $bref, $ops, $partial);
 504         requeue_once($self);
 505 }
 506
 507 sub emit_rfc822 {
 508         my ($self, $k, undef, $bref) = @_;
 509         $self->msg_more(" $k {" . length($$bref)."}\r\n");
 510         $self->msg_more($$bref);
 511 }
 512
 513 # Mail::IMAPClient::message_string cares about this by default,
 514 # (->Ignoresizeerrors attribute).  Admins are encouraged to
 515 # --reindex for IMAP support, anyways.
 516 sub emit_rfc822_size {
 517         my ($self, $k, $smsg) = @_;
 518         $self->msg_more(' RFC822.SIZE ' . $smsg->{bytes});
 519 }
 520
 521 sub emit_internaldate {
 522         my ($self, undef, $smsg) = @_;
 523         $self->msg_more(' INTERNALDATE "'.$smsg->internaldate.'"');
 524 }
 525
 526 sub emit_flags { $_[0]->msg_more(' FLAGS ()') }
 527
 528 sub emit_envelope {
 529         my ($self, undef, undef, undef, $eml) = @_;
 530         $self->msg_more(' ENVELOPE '.eml_envelope($eml));
 531 }
 532
 533 sub emit_rfc822_header {
 534         my ($self, $k, undef, undef, $eml) = @_;
 535         $self->msg_more(" $k {".length(${$eml->{hdr}})."}\r\n");
 536         $self->msg_more(${$eml->{hdr}});
 537 }
 538
 539 # n.b. this is sorted to be after any emit_eml_new ops
 540 sub emit_rfc822_text {
 541         my ($self, $k, undef, $bref) = @_;
 542         $self->msg_more(" $k {".length($$bref)."}\r\n");
 543         $self->msg_more($$bref);
 544 }
 545
 546 sub emit_bodystructure {
 547         my ($self, undef, undef, undef, $eml) = @_;
 548         $self->msg_more(' BODYSTRUCTURE '.fetch_body($eml, 1));
 549 }
 550
 551 sub emit_body {
 552         my ($self, undef, undef, undef, $eml) = @_;
 553         $self->msg_more(' BODY '.fetch_body($eml));
 554 }
 555
 556 # set $eml once ($_[4] == $eml, $_[3] == $bref)
 557 sub op_eml_new { $_[4] = PublicInbox::Eml->new($_[3]) }
 558
 559 sub uid_clamp ($$$) {
 560         my ($self, $beg, $end) = @_;
 561         my $uid_min = ($self->{uid_base} // 0) + 1;
 562         my $uid_end = $uid_min + UID_BLOCK - 1;
 563         $$beg = $uid_min if $$beg < $uid_min;
 564         $$end = $uid_end if $$end > $uid_end;
 565 }
 566
 567 sub range_step ($$) {
 568         my ($self, $range_csv) = @_;
 569         my ($beg, $end, $range);
 570         if ($$range_csv =~ s/\A([^,]+),//) {
 571                 $range = $1;
 572         } else {
 573                 $range = $$range_csv;
 574                 $$range_csv = undef;
 575         }
 576         if ($range =~ /\A([0-9]+):([0-9]+)\z/) {
 577                 ($beg, $end) = ($1 + 0, $2 + 0);
 578         } elsif ($range =~ /\A([0-9]+):\*\z/) {
 579                 $beg = $1 + 0;
 580                 $end = $self->{ibx}->mm->max // 0;
 581                 my $uid_end = $self->{uid_base} + UID_BLOCK;
 582                 $end = $uid_end if $end > $uid_end;
 583                 $beg = $end if $beg > $end;
 584         } elsif ($range =~ /\A[0-9]+\z/) {
 585                 $beg = $end = $range + 0;
 586                 undef $range;
 587         } else {
 588                 return 'BAD fetch range';
 589         }
 590         uid_clamp($self, \$beg, \$end) if defined($range);
 591         [ $beg, $end, $$range_csv ];
 592 }
 593
 594 sub refill_range ($$$) {
 595         my ($self, $msgs, $range_info) = @_;
 596         my ($beg, $end, $range_csv) = @$range_info;
 597         if (scalar(@$msgs = @{$self->{ibx}->over->query_xover($beg, $end)})) {
 598                 $range_info->[0] = $msgs->[-1]->{num} + 1;
 599                 return;
 600         }
 601         return 'OK Fetch done' if !$range_csv;
 602         my $next_range = range_step($self, \$range_csv);
 603         return $next_range if !ref($next_range); # error
 604         @$range_info = @$next_range;
 605         undef; # keep looping
 606 }
 607
 608 sub fetch_blob { # long_response
 609         my ($self, $tag, $msgs, $range_info, $ops, $partial) = @_;
 610         while (!@$msgs) { # rare
 611                 if (my $end = refill_range($self, $msgs, $range_info)) {
 612                         $self->write(\"$tag $end\r\n");
 613                         return;
 614                 }
 615         }
 616         git_async_cat($self->{ibx}->git, $msgs->[0]->{blob},
 617                         \&fetch_blob_cb, \@_);
 618 }
 619
 620 sub fetch_smsg { # long_response
 621         my ($self, $tag, $msgs, $range_info, $ops) = @_;
 622         while (!@$msgs) { # rare
 623                 if (my $end = refill_range($self, $msgs, $range_info)) {
 624                         $self->write(\"$tag $end\r\n");
 625                         return;
 626                 }
 627         }
 628         my $uid_base = $self->{uid_base} // 0;
 629         fetch_run_ops($self, $uid_base, $_, undef, $ops) for @$msgs;
 630         @$msgs = ();
 631         1; # more
 632 }
 633
 634 sub fetch_uid { # long_response
 635         my ($self, $tag, $uids, $range_info, $ops) = @_;
 636
 637         while (!@$uids) { # rare
 638                 my ($beg, $end, $range_csv) = @$range_info;
 639                 if (scalar(@$uids = @{$self->{ibx}->over->
 640                                         uid_range($beg, $end)})) {
 641                         $range_info->[0] = $uids->[-1] + 1;
 642                 } elsif (!$range_csv) {
 643                         $self->write(\"$tag OK Fetch done\r\n");
 644                         return;
 645                 } else {
 646                         my $next_range = range_step($self, \$range_csv);
 647                         if (!ref($next_range)) { # error
 648                                 $self->write(\"$tag $next_range\r\n");
 649                                 return;
 650                         }
 651                         @$range_info = @$next_range;
 652                 }
 653                 # continue looping
 654         }
 655         my $uid_base = $self->{uid_base} // 0;
 656         my ($i, $k);
 657         for (@$uids) {
 658                 $self->msg_more(fetch_msn_uid($uid_base, $_));
 659                 for ($i = 0; $i < @$ops;) {
 660                         $k = $ops->[$i++];
 661                         $ops->[$i++]->($self, $k);
 662                 }
 663                 $self->msg_more(")\r\n");
 664         }
 665         @$uids = ();
 666         1; # more
 667 }
 668
 669 sub cmd_status ($$$;@) {
 670         my ($self, $tag, $mailbox, @items) = @_;
 671         return "$tag BAD no items\r\n" if !scalar(@items);
 672         ($items[0] !~ s/\A\(//s || $items[-1] !~ s/\)\z//s) and
 673                 return "$tag BAD invalid args\r\n";
 674         my ($ibx, $exists, $uidnext) = inbox_lookup($self, $mailbox);
 675         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 676         my @it;
 677         for my $it (@items) {
 678                 $it = uc($it);
 679                 push @it, $it;
 680                 if ($it =~ /\A(?:MESSAGES|UNSEEN|RECENT)\z/) {
 681                         push @it, $exists;
 682                 } elsif ($it eq 'UIDNEXT') {
 683                         push @it, $uidnext;
 684                 } elsif ($it eq 'UIDVALIDITY') {
 685                         push @it, $ibx->{uidvalidity};
 686                 } else {
 687                         return "$tag BAD invalid item\r\n";
 688                 }
 689         }
 690         return "$tag BAD no items\r\n" if !@it;
 691         "* STATUS $mailbox (".join(' ', @it).")\r\n" .
 692         "$tag OK Status done\r\n";
 693 }
 694
 695 my %patmap = ('*' => '.*', '%' => '[^\.]*');
 696 sub cmd_list ($$$$) {
 697         my ($self, $tag, $refname, $wildcard) = @_;
 698         my $l = $self->{imapd}->{inboxlist};
 699         if ($refname eq '' && $wildcard eq '') {
 700                 # request for hierarchy delimiter
 701                 $l = [ qq[* LIST (\\Noselect) "." ""\r\n] ];
 702         } elsif ($refname ne '' || $wildcard ne '*') {
 703                 $wildcard =~ s!([^a-z0-9_])!$patmap{$1} // "\Q$1"!egi;
 704                 $l = [ grep(/ \Q$refname\E$wildcard\r\n\z/is, @$l) ];
 705         }
 706         \(join('', @$l, "$tag OK List done\r\n"));
 707 }
 708
 709 sub cmd_lsub ($$$$) {
 710         my (undef, $tag) = @_; # same args as cmd_list
 711         "$tag OK Lsub done\r\n";
 712 }
 713
 714 sub eml_index_offs_i { # PublicInbox::Eml::each_part callback
 715         my ($p, $all) = @_;
 716         my ($eml, undef, $idx) = @$p;
 717         if ($idx && lc($eml->ct->{type}) eq 'multipart') {
 718                 $eml->{imap_bdy} = $eml->{bdy} // \'';
 719         }
 720         $all->{$idx} = $eml; # $idx => Eml
 721 }
 722
 723 # prepares an index for BODY[$SECTION_IDX] fetches
 724 sub eml_body_idx ($$) {
 725         my ($eml, $section_idx) = @_;
 726         my $idx = $eml->{imap_all_parts} //= do {
 727                 my $all = {};
 728                 $eml->each_part(\&eml_index_offs_i, $all, 0, 1);
 729                 # top-level of multipart, BODY[0] not allowed (nz-number)
 730                 delete $all->{0};
 731                 $all;
 732         };
 733         $idx->{$section_idx};
 734 }
 735
 736 # BODY[($SECTION_IDX)?(.$SECTION_NAME)?]<$offset.$bytes>
 737 sub partial_body {
 738         my ($eml, $section_idx, $section_name) = @_;
 739         if (defined $section_idx) {
 740                 $eml = eml_body_idx($eml, $section_idx) or return;
 741         }
 742         if (defined $section_name) {
 743                 if ($section_name eq 'MIME') {
 744                         # RFC 3501 6.4.5 states:
 745                         #       The MIME part specifier MUST be prefixed
 746                         #       by one or more numeric part specifiers
 747                         return unless defined $section_idx;
 748                         return $eml->header_obj->as_string . "\r\n";
 749                 }
 750                 my $bdy = $eml->{bdy} // $eml->{imap_bdy} // \'';
 751                 $eml = PublicInbox::Eml->new($$bdy);
 752                 if ($section_name eq 'TEXT') {
 753                         return $eml->body_raw;
 754                 } elsif ($section_name eq 'HEADER') {
 755                         return $eml->header_obj->as_string . "\r\n";
 756                 } else {
 757                         die "BUG: bad section_name=$section_name";
 758                 }
 759         }
 760         ${$eml->{bdy} // $eml->{imap_bdy} // \''};
 761 }
 762
 763 # similar to what's in PublicInbox::Eml::re_memo, but doesn't memoize
 764 # to avoid OOM with malicious users
 765 sub hdrs_regexp ($) {
 766         my ($hdrs) = @_;
 767         my $names = join('|', map { "\Q$_" } split(/[ \t]+/, $hdrs));
 768         qr/^(?:$names):[ \t]*[^\n]*\r?\n # 1st line
 769                 # continuation lines:
 770                 (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*
 771                 /ismx;
 772 }
 773
 774 # BODY[($SECTION_IDX.)?HEADER.FIELDS.NOT ($HDRS)]<$offset.$bytes>
 775 sub partial_hdr_not {
 776         my ($eml, $section_idx, $hdrs_re) = @_;
 777         if (defined $section_idx) {
 778                 $eml = eml_body_idx($eml, $section_idx) or return;
 779         }
 780         my $str = $eml->header_obj->as_string;
 781         $str =~ s/$hdrs_re//g;
 782         $str .= "\r\n";
 783 }
 784
 785 # BODY[($SECTION_IDX.)?HEADER.FIELDS ($HDRS)]<$offset.$bytes>
 786 sub partial_hdr_get {
 787         my ($eml, $section_idx, $hdrs_re) = @_;
 788         if (defined $section_idx) {
 789                 $eml = eml_body_idx($eml, $section_idx) or return;
 790         }
 791         my $str = $eml->header_obj->as_string;
 792         join('', ($str =~ m/($hdrs_re)/g), "\r\n");
 793 }
 794
 795 sub partial_prepare ($$$) {
 796         my ($partial, $want, $att) = @_;
 797
 798         # recombine [ "BODY[1.HEADER.FIELDS", "(foo", "bar)]" ]
 799         # back to: "BODY[1.HEADER.FIELDS (foo bar)]"
 800         return unless $att =~ /\ABODY\[/s;
 801         until (rindex($att, ']') >= 0) {
 802                 my $next = shift @$want or return;
 803                 $att .= ' ' . uc($next);
 804         }
 805         if ($att =~ /\ABODY\[([0-9]+(?:\.[0-9]+)*)? # 1 - section_idx
 806                         (?:\.(HEADER|MIME|TEXT))? # 2 - section_name
 807                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 3, 4
 808                 $partial->{$att} = [ \&partial_body, $1, $2, $3, $4 ];
 809         } elsif ($att =~ /\ABODY\[(?:([0-9]+(?:\.[0-9]+)*)\.)? # 1 - section_idx
 810                                 (?:HEADER\.FIELDS(\.NOT)?)\x20 # 2
 811                                 \(([A-Z0-9\-\x20]+)\) # 3 - hdrs
 812                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 4 5
 813                 my $tmp = $partial->{$att} = [ $2 ? \&partial_hdr_not
 814                                                 : \&partial_hdr_get,
 815                                                 $1, undef, $4, $5 ];
 816                 $tmp->[2] = hdrs_regexp($3);
 817         } else {
 818                 undef;
 819         }
 820 }
 821
 822 sub partial_emit ($$$) {
 823         my ($self, $partial, $eml) = @_;
 824         for (@$partial) {
 825                 my ($k, $cb, @args) = @$_;
 826                 my ($offset, $len) = splice(@args, -2);
 827                 # $cb is partial_body|partial_hdr_get|partial_hdr_not
 828                 my $str = $cb->($eml, @args) // '';
 829                 if (defined $offset) {
 830                         if (defined $len) {
 831                                 $str = substr($str, $offset, $len);
 832                                 $k =~ s/\.$len>\z/>/ or warn
 833 "BUG: unable to remove `.$len>' from `$k'";
 834                         } else {
 835                                 $str = substr($str, $offset);
 836                                 $len = length($str);
 837                         }
 838                 } else {
 839                         $len = length($str);
 840                 }
 841                 $self->msg_more(" $k {$len}\r\n");
 842                 $self->msg_more($str);
 843         }
 844 }
 845
 846 sub fetch_compile ($) {
 847         my ($want) = @_;
 848         if ($want->[0] =~ s/\A\(//s) {
 849                 $want->[-1] =~ s/\)\z//s or return 'BAD no rparen';
 850         }
 851         my (%partial, %seen, @op);
 852         my $need = 0;
 853         while (defined(my $att = shift @$want)) {
 854                 $att = uc($att);
 855                 next if $att eq 'UID'; # always returned
 856                 $att =~ s/\ABODY\.PEEK\[/BODY\[/; # we're read-only
 857                 my $x = $FETCH_ATT{$att};
 858                 if ($x) {
 859                         while (my ($k, $fl_cb) = each %$x) {
 860                                 next if $seen{$k}++;
 861                                 $need |= $fl_cb->[0];
 862
 863                                 # insert a special op to convert $bref to $eml
 864                                 # the first time we need it
 865                                 if ($need == NEED_EML && !$seen{$need}++) {
 866                                         push @op, $OP_EML_NEW;
 867                                 }
 868                                 # $fl_cb = [ flags, \&emit_foo ]
 869                                 push @op, [ @$fl_cb , $k ];
 870                         }
 871                 } elsif (!partial_prepare(\%partial, $want, $att)) {
 872                         return "BAD param: $att";
 873                 }
 874         }
 875         my @r;
 876
 877         # stabilize partial order for consistency and ease-of-debugging:
 878         if (scalar keys %partial) {
 879                 $need = NEED_EML;
 880                 push @op, $OP_EML_NEW if !$seen{$need}++;
 881                 $r[2] = [ map { [ $_, @{$partial{$_}} ] } sort keys %partial ];
 882         }
 883
 884         $r[0] = $need & NEED_BLOB ? \&fetch_blob :
 885                 ($need & NEED_SMSG ? \&fetch_smsg : \&fetch_uid);
 886
 887         # r[1] = [ $key1, $cb1, $key2, $cb2, ... ]
 888         use sort 'stable'; # makes output more consistent
 889         $r[1] = [ map { ($_->[2], $_->[1]) } sort { $a->[0] <=> $b->[0] } @op ];
 890         @r;
 891 }
 892
 893 sub cmd_uid_fetch ($$$$;@) {
 894         my ($self, $tag, $range_csv, @want) = @_;
 895         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 896         my ($cb, $ops, $partial) = fetch_compile(\@want);
 897         return "$tag $cb\r\n" unless $ops;
 898
 899         $range_csv = 'bad' if $range_csv !~ $valid_range;
 900         my $range_info = range_step($self, \$range_csv);
 901         return "$tag $range_info\r\n" if !ref($range_info);
 902         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 903 }
 904
 905 sub msn_to_uid_range ($$) {
 906         my $uid_base = $_[0]->{uid_base} // 0;
 907         $_[1] =~ s/([0-9]+)/$uid_base + $1/sge;
 908 }
 909
 910 sub cmd_fetch ($$$$;@) {
 911         my ($self, $tag, $range_csv, @want) = @_;
 912         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 913         my ($cb, $ops, $partial) = fetch_compile(\@want);
 914         return "$tag $cb\r\n" unless $ops;
 915
 916         # cb is one of fetch_blob, fetch_smsg, fetch_uid
 917         $range_csv = 'bad' if $range_csv !~ $valid_range;
 918         msn_to_uid_range($self, $range_csv);
 919         my $range_info = range_step($self, \$range_csv);
 920         return "$tag $range_info\r\n" if !ref($range_info);
 921         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 922 }
 923
 924 sub parse_date ($) { # 02-Oct-1993
 925         my ($date_text) = @_;
 926         my ($dd, $mon, $yyyy) = split(/-/, $_[0], 3);
 927         defined($yyyy) or return;
 928         my $mm = $MoY{$mon} // return;
 929         $dd =~ /\A[0123]?[0-9]\z/ or return;
 930         $yyyy =~ /\A[0-9]{4,}\z/ or return; # Y10K-compatible!
 931         timegm(0, 0, 0, $dd, $mm, $yyyy);
 932 }
 933
 934 sub uid_search_uid_range { # long_response
 935         my ($self, $tag, $beg, $end, $sql) = @_;
 936         my $uids = $self->{ibx}->over->uid_range($$beg, $end, $sql);
 937         if (@$uids) {
 938                 $$beg = $uids->[-1] + 1;
 939                 $self->msg_more(join(' ', '', @$uids));
 940         } else {
 941                 $self->write(\"\r\n$tag OK Search done\r\n");
 942                 undef;
 943         }
 944 }
 945
 946 sub date_search {
 947         my ($q, $k, $d) = @_;
 948         my $sql = $q->{sql};
 949
 950         # Date: header
 951         if ($k eq 'SENTON') {
 952                 my $end = $d + 86399; # no leap day...
 953                 my $da = strftime('%Y%m%d%H%M%S', gmtime($d));
 954                 my $db = strftime('%Y%m%d%H%M%S', gmtime($end));
 955                 $q->{xap} .= " dt:$da..$db";
 956                 $$sql .= " AND ds >= $d AND ds <= $end" if defined($sql);
 957         } elsif ($k eq 'SENTBEFORE') {
 958                 $q->{xap} .= ' d:..'.strftime('%Y%m%d', gmtime($d));
 959                 $$sql .= " AND ds <= $d" if defined($sql);
 960         } elsif ($k eq 'SENTSINCE') {
 961                 $q->{xap} .= ' d:'.strftime('%Y%m%d', gmtime($d)).'..';
 962                 $$sql .= " AND ds >= $d" if defined($sql);
 963
 964         # INTERNALDATE (Received)
 965         } elsif ($k eq 'ON') {
 966                 my $end = $d + 86399; # no leap day...
 967                 $q->{xap} .= " ts:$d..$end";
 968                 $$sql .= " AND ts >= $d AND ts <= $end" if defined($sql);
 969         } elsif ($k eq 'BEFORE') {
 970                 $q->{xap} .= " ts:..$d";
 971                 $$sql .= " AND ts <= $d" if defined($sql);
 972         } elsif ($k eq 'SINCE') {
 973                 $q->{xap} .= " ts:$d..";
 974                 $$sql .= " AND ts >= $d" if defined($sql);
 975         } else {
 976                 die "BUG: $k not recognized";
 977         }
 978 }
 979
 980 # IMAP to Xapian search key mapping
 981 my %I2X = (
 982         SUBJECT => 's:',
 983         BODY => 'b:',
 984         FROM => 'f:',
 985         TEXT => '', # n.b. does not include all headers
 986         TO => 't:',
 987         CC => 'c:',
 988         # BCC => 'bcc:', # TODO
 989         # KEYWORD # TODO ? dfpre,dfpost,...
 990 );
 991
 992 sub parse_query {
 993         my ($self, $rest) = @_;
 994         if (uc($rest->[0]) eq 'CHARSET') {
 995                 shift @$rest;
 996                 defined(my $c = shift @$rest) or return 'BAD missing charset';
 997                 $c =~ /\A(?:UTF-8|US-ASCII)\z/ or return 'NO [BADCHARSET]';
 998         }
 999
1000         my $sql = ''; # date conditions, {sql} deleted if Xapian is needed
1001         my $q = { xap => '', sql => \$sql };
1002         while (@$rest) {
1003                 my $k = uc(shift @$rest);
1004                 # default criteria
1005                 next if $k =~ /\A(?:ALL|RECENT|UNSEEN|NEW)\z/;
1006                 next if $k eq 'AND'; # the default, until we support OR
1007                 if ($k =~ $valid_range) { # convert sequence numbers to UIDs
1008                         msn_to_uid_range($self, $k);
1009                         push @{$q->{uid}}, $k;
1010                 } elsif ($k eq 'UID') {
1011                         $k = shift(@$rest) // '';
1012                         $k =~ $valid_range or return 'BAD UID range';
1013                         push @{$q->{uid}}, $k;
1014                 } elsif ($k =~ /\A(?:SENT)?(?:SINCE|ON|BEFORE)\z/) {
1015                         my $d = parse_date(shift(@$rest) // '');
1016                         defined $d or return "BAD $k date format";
1017                         date_search($q, $k, $d);
1018                 } elsif ($k =~ /\A(?:SMALLER|LARGER)\z/) {
1019                         delete $q->{sql}; # can't use over.sqlite3
1020                         my $bytes = shift(@$rest) // '';
1021                         $bytes =~ /\A[0-9]+\z/ or return "BAD $k not a number";
1022                         $q->{xap} .= ' bytes:' . ($k eq 'SMALLER' ?
1023                                                         '..'.(--$bytes) :
1024                                                         (++$bytes).'..');
1025                 } elsif (defined(my $xk = $I2X{$k})) {
1026                         delete $q->{sql}; # can't use over.sqlite3
1027                         my $arg = shift @$rest;
1028                         defined($arg) or return "BAD $k no arg";
1029
1030                         # Xapian can't handle [*"] in probabilistic terms
1031                         $arg =~ tr/*"//d;
1032                         $q->{xap} .= qq[ $xk:"$arg"];
1033                 } else {
1034                         # TODO: parentheses, OR, NOT ...
1035                         return "BAD $k not supported (yet?)";
1036                 }
1037         }
1038
1039         # favor using over.sqlite3 if possible, since Xapian is optional
1040         if (exists $q->{sql}) {
1041                 delete($q->{xap});
1042                 delete($q->{sql}) if $sql eq '';
1043         } elsif (!$self->{ibx}->search) {
1044                 return 'BAD Xapian not configured for mailbox';
1045         }
1046
1047         if (my $uid = $q->{uid}) {
1048                 ((@$uid > 1) || $uid->[0] =~ /,/) and
1049                         return 'BAD multiple ranges not supported, yet';
1050                 ($q->{sql} // $q->{xap}) and
1051                         return 'BAD ranges and queries do not mix, yet';
1052                 $q->{uid} = join(',', @$uid); # TODO: multiple ranges
1053         }
1054         $q;
1055 }
1056
1057 sub cmd_uid_search ($$$;) {
1058         my ($self, $tag) = splice(@_, 0, 2);
1059         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
1060         my $q = parse_query($self, \@_);
1061         return "$tag $q\r\n" if !ref($q);
1062         my $sql = delete $q->{sql};
1063
1064         if (!scalar(keys %$q)) {
1065                 $self->msg_more('* SEARCH');
1066                 my $beg = 1;
1067                 my $end = $ibx->mm->max // 0;
1068                 uid_clamp($self, \$beg, \$end);
1069                 long_response($self, \&uid_search_uid_range,
1070                                 $tag, \$beg, $end, $sql);
1071         } elsif (my $uid = $q->{uid}) {
1072                 if ($uid =~ /\A([0-9]+):([0-9]+|\*)\z/s) {
1073                         my ($beg, $end) = ($1, $2);
1074                         $end = $ibx->mm->max if $end eq '*';
1075                         uid_clamp($self, \$beg, \$end);
1076                         $self->msg_more('* SEARCH');
1077                         long_response($self, \&uid_search_uid_range,
1078                                         $tag, \$beg, $end, $sql);
1079                 } elsif ($uid =~ /\A[0-9]+\z/s) {
1080                         $uid = $ibx->over->get_art($uid) ? " $uid" : '';
1081                         "* SEARCH$uid\r\n$tag OK Search done\r\n";
1082                 } else {
1083                         "$tag BAD Error\r\n";
1084                 }
1085         } else {
1086                 "$tag BAD Error\r\n";
1087         }
1088 }
1089
1090 sub args_ok ($$) { # duplicated from PublicInbox::NNTP
1091         my ($cb, $argc) = @_;
1092         my $tot = prototype $cb;
1093         my ($nreq, undef) = split(';', $tot);
1094         $nreq = ($nreq =~ tr/$//) - 1;
1095         $tot = ($tot =~ tr/$//) - 1;
1096         ($argc <= $tot && $argc >= $nreq);
1097 }
1098
1099 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
1100 sub process_line ($$) {
1101         my ($self, $l) = @_;
1102         my ($tag, $req, @args) = parse_line('[ \t]+', 0, $l);
1103         pop(@args) if (@args && !defined($args[-1]));
1104         if (@args && uc($req) eq 'UID') {
1105                 $req .= "_".(shift @args);
1106         }
1107         my $res = eval {
1108                 if (my $cmd = $self->can('cmd_'.lc($req // ''))) {
1109                         defined($self->{-idle_tag}) ?
1110                                 "$self->{-idle_tag} BAD expected DONE\r\n" :
1111                                 $cmd->($self, $tag, @args);
1112                 } elsif (uc($tag // '') eq 'DONE' && !defined($req)) {
1113                         cmd_done($self, $tag);
1114                 } else { # this is weird
1115                         auth_challenge_ok($self) //
1116                                         ($tag // '*') .
1117                                         ' BAD Error in IMAP command '.
1118                                         ($req // '(???)').
1119                                         ": Unknown command\r\n";
1120                 }
1121         };
1122         my $err = $@;
1123         if ($err && $self->{sock}) {
1124                 $l =~ s/\r?\n//s;
1125                 err($self, 'error from: %s (%s)', $l, $err);
1126                 $tag //= '*';
1127                 $res = "$tag BAD program fault - command not performed\r\n";
1128         }
1129         return 0 unless defined $res;
1130         $self->write($res);
1131 }
1132
1133 sub long_step {
1134         my ($self) = @_;
1135         # wbuf is unset or empty, here; {long} may add to it
1136         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
1137         my $more = eval { $cb->($self, @args) };
1138         if ($@ || !$self->{sock}) { # something bad happened...
1139                 delete $self->{long_cb};
1140                 my $elapsed = now() - $t0;
1141                 if ($@) {
1142                         err($self,
1143                             "%s during long response[$fd] - %0.6f",
1144                             $@, $elapsed);
1145                 }
1146                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
1147                 $self->close;
1148         } elsif ($more) { # $self->{wbuf}:
1149                 $self->update_idle_time;
1150
1151                 # control passed to $more may be a GitAsyncCat object
1152                 requeue_once($self) if !ref($more);
1153         } else { # all done!
1154                 delete $self->{long_cb};
1155                 my $elapsed = now() - $t0;
1156                 my $fd = fileno($self->{sock});
1157                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
1158                 my $wbuf = $self->{wbuf}; # do NOT autovivify
1159
1160                 $self->requeue unless $wbuf && @$wbuf;
1161         }
1162 }
1163
1164 sub err ($$;@) {
1165         my ($self, $fmt, @args) = @_;
1166         printf { $self->{imapd}->{err} } $fmt."\n", @args;
1167 }
1168
1169 sub out ($$;@) {
1170         my ($self, $fmt, @args) = @_;
1171         printf { $self->{imapd}->{out} } $fmt."\n", @args;
1172 }
1173
1174 sub long_response ($$;@) {
1175         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
1176
1177         my $sock = $self->{sock} or return;
1178         # make sure we disable reading during a long response,
1179         # clients should not be sending us stuff and making us do more
1180         # work while we are stream a response to them
1181         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
1182         long_step($self); # kick off!
1183         undef;
1184 }
1185
1186 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1187 sub event_step {
1188         my ($self) = @_;
1189
1190         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1191
1192         $self->update_idle_time;
1193         # only read more requests if we've drained the write buffer,
1194         # otherwise we can be buffering infinitely w/o backpressure
1195
1196         my $rbuf = $self->{rbuf} // \(my $x = '');
1197         my $line = index($$rbuf, "\n");
1198         while ($line < 0) {
1199                 if (length($$rbuf) >= LINE_MAX) {
1200                         $self->write(\"\* BAD request too long\r\n");
1201                         return $self->close;
1202                 }
1203                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1204                 $line = index($$rbuf, "\n");
1205         }
1206         $line = substr($$rbuf, 0, $line + 1, '');
1207         $line =~ s/\r?\n\z//s;
1208         return $self->close if $line =~ /[[:cntrl:]]/s;
1209         my $t0 = now();
1210         my $fd = fileno($self->{sock});
1211         my $r = eval { process_line($self, $line) };
1212         my $pending = $self->{wbuf} ? ' pending' : '';
1213         out($self, "[$fd] %s - %0.6f$pending - $r", $line, now() - $t0);
1214
1215         return $self->close if $r < 0;
1216         $self->rbuf_idle($rbuf);
1217         $self->update_idle_time;
1218
1219         # maybe there's more pipelined data, or we'll have
1220         # to register it for socket-readiness notifications
1221         $self->requeue unless $pending;
1222 }
1223
1224 sub compressed { undef }
1225
1226 sub zflush {} # overridden by IMAPdeflate
1227
1228 # RFC 4978
1229 sub cmd_compress ($$$) {
1230         my ($self, $tag, $alg) = @_;
1231         return "$tag BAD DEFLATE only\r\n" if uc($alg) ne "DEFLATE";
1232         return "$tag BAD COMPRESS active\r\n" if $self->compressed;
1233
1234         # CRIME made TLS compression obsolete
1235         # return "$tag NO [COMPRESSIONACTIVE]\r\n" if $self->tls_compressed;
1236
1237         PublicInbox::IMAPdeflate->enable($self, $tag);
1238         $self->requeue;
1239         undef
1240 }
1241
1242 sub cmd_starttls ($$) {
1243         my ($self, $tag) = @_;
1244         my $sock = $self->{sock} or return;
1245         if ($sock->can('stop_SSL') || $self->compressed) {
1246                 return "$tag BAD TLS or compression already enabled\r\n";
1247         }
1248         my $opt = $self->{imapd}->{accept_tls} or
1249                 return "$tag BAD can not initiate TLS negotiation\r\n";
1250         $self->write(\"$tag OK begin TLS negotiation now\r\n");
1251         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
1252         $self->requeue if PublicInbox::DS::accept_tls_step($self);
1253         undef;
1254 }
1255
1256 # for graceful shutdown in PublicInbox::Daemon:
1257 sub busy {
1258         my ($self, $now) = @_;
1259         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1260 }
1261
1262 sub close {
1263         my ($self) = @_;
1264         if (my $ibx = delete $self->{ibx}) {
1265                 stop_idle($self, $ibx);
1266         }
1267         $self->SUPER::close; # PublicInbox::DS::close
1268 }
1269
1270 # we're read-only, so SELECT and EXAMINE do the same thing
1271 no warnings 'once';
1272 *cmd_select = \&cmd_examine;
1273
1274 package PublicInbox::IMAP_preauth;
1275 our @ISA = qw(PublicInbox::IMAP);
1276
1277 sub logged_in { 0 }
1278
1279 1;