lib/PublicInbox/IMAP.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents an IMAP client connected to
   5 # public-inbox-imapd.  Much of this was taken from NNTP, but
   6 # further refined while experimenting on future ideas to handle
   7 # slow storage.
   8 #
   9 # data notes:
  10 #
  11 # * NNTP article numbers are UIDs, mm->created_at is UIDVALIDITY
  12 #
  13 # * public-inboxes are sliced into mailboxes of 50K messages
  14 #   to not overload MUAs: $NEWSGROUP_NAME.$SLICE_INDEX
  15 #   Slices are similar in concept to v2 "epochs".  Epochs
  16 #   are for the limitations of git clients, while slices are
  17 #   for the limitations of IMAP clients.
  18 #
  19 # * sequence numbers are estimated based on slice.  If they
  20 #   wrong, they're higher than than the corresponding UID
  21 #   because UIDs have gaps due to spam removals.
  22 #   We only support an ephemeral mapping non-UID "FETCH"
  23 #   because mutt header caching relies on it; mutt uses
  24 #   UID requests everywhere else.
  25
  26 package PublicInbox::IMAP;
  27 use strict;
  28 use base qw(PublicInbox::DS);
  29 use fields qw(imapd ibx long_cb -login_tag
  30         uid_base -idle_tag -idle_max);
  31 use PublicInbox::Eml;
  32 use PublicInbox::EmlContentFoo qw(parse_content_disposition);
  33 use PublicInbox::DS qw(now);
  34 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  35 use PublicInbox::GitAsyncCat;
  36 use Text::ParseWords qw(parse_line);
  37 use Errno qw(EAGAIN);
  38 use Time::Local qw(timegm);
  39 use POSIX qw(strftime);
  40 use Hash::Util qw(unlock_hash); # dependency of fields for perl 5.10+, anyways
  41 use PublicInbox::Search;
  42 *mdocid = \&PublicInbox::Search::mdocid;
  43
  44 my $Address;
  45 for my $mod (qw(Email::Address::XS Mail::Address)) {
  46         eval "require $mod" or next;
  47         $Address = $mod and last;
  48 }
  49 die "neither Email::Address::XS nor Mail::Address loaded: $@" if !$Address;
  50
  51 sub LINE_MAX () { 8000 } # RFC 2683 3.2.1.5
  52
  53 # changing this will cause grief for clients which cache
  54 sub UID_SLICE () { 50_000 }
  55
  56 # these values area also used for sorting
  57 sub NEED_SMSG () { 1 }
  58 sub NEED_BLOB () { NEED_SMSG|2 }
  59 sub CRLF_BREF () { 4 }
  60 sub EML_HDR () { 8 }
  61 sub CRLF_HDR () { 16 }
  62 sub EML_BDY () { 32 }
  63 sub CRLF_BDY () { 64 }
  64 my $OP_EML_NEW = [ EML_HDR - 1, \&op_eml_new ];
  65 my $OP_CRLF_BREF = [ CRLF_BREF, \&op_crlf_bref ];
  66 my $OP_CRLF_HDR = [ CRLF_HDR, \&op_crlf_hdr ];
  67 my $OP_CRLF_BDY = [ CRLF_BDY, \&op_crlf_bdy ];
  68
  69 my %FETCH_NEED = (
  70         'BODY[HEADER]' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  71         'BODY[TEXT]' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  72         'BODY[]' => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  73         'RFC822.HEADER' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  74         'RFC822.TEXT' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  75         'RFC822.SIZE' => [ NEED_SMSG, \&emit_rfc822_size ],
  76         RFC822 => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  77         BODY => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_body ],
  78         BODYSTRUCTURE => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_bodystructure ],
  79         ENVELOPE => [ NEED_BLOB|EML_HDR, \&emit_envelope ],
  80         FLAGS => [ 0, \&emit_flags ],
  81         INTERNALDATE => [ NEED_SMSG, \&emit_internaldate ],
  82 );
  83 my %FETCH_ATT = map { $_ => [ $_ ] } keys %FETCH_NEED;
  84
  85 # aliases (RFC 3501 section 6.4.5)
  86 $FETCH_ATT{FAST} = [ qw(FLAGS INTERNALDATE RFC822.SIZE) ];
  87 $FETCH_ATT{ALL} = [ @{$FETCH_ATT{FAST}}, 'ENVELOPE' ];
  88 $FETCH_ATT{FULL} = [ @{$FETCH_ATT{ALL}}, 'BODY' ];
  89
  90 for my $att (keys %FETCH_ATT) {
  91         my %h = map { $_ => $FETCH_NEED{$_} } @{$FETCH_ATT{$att}};
  92         $FETCH_ATT{$att} = \%h;
  93 }
  94 undef %FETCH_NEED;
  95
  96 my $valid_range = '[0-9]+|[0-9]+:[0-9]+|[0-9]+:\*';
  97 $valid_range = qr/\A(?:$valid_range)(?:,(?:$valid_range))*\z/;
  98
  99 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 100 my %MoY;
 101 @MoY{@MoY} = (0..11);
 102
 103 # RFC 3501 5.4. Autologout Timer needs to be >= 30min
 104 $PublicInbox::DS::EXPTIME = 60 * 30;
 105
 106 sub greet ($) {
 107         my ($self) = @_;
 108         my $capa = capa($self);
 109         $self->write(\"* OK [$capa] public-inbox-imapd ready\r\n");
 110 }
 111
 112 sub new ($$$) {
 113         my ($class, $sock, $imapd) = @_;
 114         my $self = fields::new('PublicInbox::IMAP_preauth');
 115         unlock_hash(%$self);
 116         my $ev = EPOLLIN;
 117         my $wbuf;
 118         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
 119                 return CORE::close($sock) if $! != EAGAIN;
 120                 $ev = PublicInbox::TLS::epollbit();
 121                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
 122         }
 123         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
 124         $self->{imapd} = $imapd;
 125         if ($wbuf) {
 126                 $self->{wbuf} = $wbuf;
 127         } else {
 128                 greet($self);
 129         }
 130         $self->update_idle_time;
 131         $self;
 132 }
 133
 134 sub logged_in { 1 }
 135
 136 sub capa ($) {
 137         my ($self) = @_;
 138
 139         # dovecot advertises IDLE pre-login; perhaps because some clients
 140         # depend on it, so we'll do the same
 141         my $capa = 'CAPABILITY IMAP4rev1 IDLE';
 142         if ($self->logged_in) {
 143                 $capa .= ' COMPRESS=DEFLATE';
 144         } else {
 145                 if (!($self->{sock} // $self)->can('accept_SSL') &&
 146                         $self->{imapd}->{accept_tls}) {
 147                         $capa .= ' STARTTLS';
 148                 }
 149                 $capa .= ' AUTH=ANONYMOUS';
 150         }
 151 }
 152
 153 sub login_success ($$) {
 154         my ($self, $tag) = @_;
 155         bless $self, 'PublicInbox::IMAP';
 156         my $capa = capa($self);
 157         "$tag OK [$capa] Logged in\r\n";
 158 }
 159
 160 sub auth_challenge_ok ($) {
 161         my ($self) = @_;
 162         my $tag = delete($self->{-login_tag}) or return;
 163         login_success($self, $tag);
 164 }
 165
 166 sub cmd_login ($$$$) {
 167         my ($self, $tag) = @_; # ignore ($user, $password) = ($_[2], $_[3])
 168         login_success($self, $tag);
 169 }
 170
 171 sub cmd_close ($$) {
 172         my ($self, $tag) = @_;
 173         delete $self->{uid_base};
 174         delete $self->{ibx} ? "$tag OK Close done\r\n"
 175                                 : "$tag BAD No mailbox\r\n";
 176 }
 177
 178 sub cmd_logout ($$) {
 179         my ($self, $tag) = @_;
 180         delete $self->{-idle_tag};
 181         $self->write(\"* BYE logging out\r\n$tag OK Logout done\r\n");
 182         $self->shutdn; # PublicInbox::DS::shutdn
 183         undef;
 184 }
 185
 186 sub cmd_authenticate ($$$) {
 187         my ($self, $tag) = @_; # $method = $_[2], should be "ANONYMOUS"
 188         $self->{-login_tag} = $tag;
 189         "+\r\n"; # challenge
 190 }
 191
 192 sub cmd_capability ($$) {
 193         my ($self, $tag) = @_;
 194         '* '.capa($self)."\r\n$tag OK Capability done\r\n";
 195 }
 196
 197 sub cmd_noop ($$) { "$_[1] OK Noop done\r\n" }
 198
 199 # called by PublicInbox::InboxIdle
 200 sub on_inbox_unlock {
 201         my ($self, $ibx) = @_;
 202         my $new = $ibx->over->max;
 203         my $uid_base = $self->{uid_base} // 0;
 204         my $uid_end = $uid_base + UID_SLICE;
 205         defined(my $old = $self->{-idle_max}) or die 'BUG: -idle_max unset';
 206         $new = $uid_end if $new > $uid_end;
 207         if ($new > $old) {
 208                 $self->{-idle_max} = $new;
 209                 $new -= $uid_base;
 210                 $old -= $uid_base;
 211                 $self->msg_more("* $_ EXISTS\r\n") for (($old + 1)..($new - 1));
 212                 $self->write(\"* $new EXISTS\r\n");
 213         } elsif ($new == $uid_end) { # max exceeded $uid_end
 214                 # continue idling w/o inotify
 215                 delete $self->{-idle_max};
 216                 my $sock = $self->{sock} or return;
 217                 $ibx->unsubscribe_unlock(fileno($sock));
 218         }
 219 }
 220
 221 # called every X minute(s) or so by PublicInbox::DS::later
 222 my $IDLERS = {};
 223 my $idle_timer;
 224 sub idle_tick_all {
 225         my $old = $IDLERS;
 226         $IDLERS = {};
 227         for my $i (values %$old) {
 228                 next if ($i->{wbuf} || !exists($i->{-idle_tag}));
 229                 $i->update_idle_time or next;
 230                 $IDLERS->{fileno($i->{sock})} = $i;
 231                 $i->write(\"* OK Still here\r\n");
 232         }
 233         $idle_timer = scalar keys %$IDLERS ?
 234                         PublicInbox::DS::later(\&idle_tick_all) : undef;
 235 }
 236
 237 sub cmd_idle ($$) {
 238         my ($self, $tag) = @_;
 239         # IDLE seems allowed by dovecot w/o a mailbox selected *shrug*
 240         my $ibx = $self->{ibx} or return "$tag BAD no mailbox selected\r\n";
 241         $self->{-idle_tag} = $tag;
 242         my $max = $ibx->over->max;
 243         my $uid_end = $self->{uid_base} + UID_SLICE;
 244         my $sock = $self->{sock} or return;
 245         my $fd = fileno($sock);
 246         # only do inotify on most recent slice
 247         if ($max < $uid_end) {
 248                 $ibx->subscribe_unlock($fd, $self);
 249                 $self->{imapd}->idler_start;
 250                 $self->{-idle_max} = $max;
 251         }
 252         $idle_timer //= PublicInbox::DS::later(\&idle_tick_all);
 253         $IDLERS->{$fd} = $self;
 254         \"+ idling\r\n"
 255 }
 256
 257 sub stop_idle ($$) {
 258         my ($self, $ibx);
 259         my $sock = $self->{sock} or return;
 260         my $fd = fileno($sock);
 261         delete $IDLERS->{$fd};
 262         $ibx->unsubscribe_unlock($fd);
 263 }
 264
 265 sub cmd_done ($$) {
 266         my ($self, $tag) = @_; # $tag is "DONE" (case-insensitive)
 267         defined(my $idle_tag = delete $self->{-idle_tag}) or
 268                 return "$tag BAD not idle\r\n";
 269         my $ibx = $self->{ibx} or do {
 270                 warn "BUG: idle_tag set w/o inbox";
 271                 return "$tag BAD internal bug\r\n";
 272         };
 273         stop_idle($self, $ibx);
 274         "$idle_tag OK Idle done\r\n";
 275 }
 276
 277 sub ensure_slices_exist ($$$) {
 278         my ($imapd, $ibx, $max) = @_;
 279         defined(my $mb_top = $ibx->{newsgroup}) or return;
 280         my $mailboxes = $imapd->{mailboxes};
 281         my @created;
 282         for (my $i = int($max/UID_SLICE); $i >= 0; --$i) {
 283                 my $sub_mailbox = "$mb_top.$i";
 284                 last if exists $mailboxes->{$sub_mailbox};
 285                 $mailboxes->{$sub_mailbox} = $ibx;
 286                 $sub_mailbox =~ s/\Ainbox\./INBOX./i; # more familiar to users
 287                 push @created, $sub_mailbox;
 288         }
 289         return unless @created;
 290         my $l = $imapd->{inboxlist} or return;
 291         push @$l, map { qq[* LIST (\\HasNoChildren) "." $_\r\n] } @created;
 292 }
 293
 294 sub inbox_lookup ($$) {
 295         my ($self, $mailbox) = @_;
 296         my ($ibx, $exists, $uidnext, $uid_base);
 297         if ($mailbox =~ /\A(.+)\.([0-9]+)\z/) {
 298                 # old mail: inbox.comp.foo.$SLICE_IDX
 299                 my $mb_top = $1;
 300                 $uid_base = $2 * UID_SLICE;
 301                 $ibx = $self->{imapd}->{mailboxes}->{lc $mailbox} or return;
 302                 my $max;
 303                 ($exists, $uidnext, $max) = $ibx->over->imap_status($uid_base,
 304                                                         $uid_base + UID_SLICE);
 305                 ensure_slices_exist($self->{imapd}, $ibx, $max);
 306         } else { # check for dummy inboxes
 307                 $mailbox = lc $mailbox;
 308                 $ibx = $self->{imapd}->{mailboxes}->{$mailbox} or return;
 309
 310                 # if "INBOX.foo.bar" is selected and "INBOX.foo.bar.0",
 311                 # check for new UID ranges (e.g. "INBOX.foo.bar.1")
 312                 if (my $z = $self->{imapd}->{mailboxes}->{"$mailbox.0"}) {
 313                         ensure_slices_exist($self->{imapd}, $z, $z->over->max);
 314                 }
 315
 316                 $uid_base = $exists = 0;
 317                 $uidnext = 1;
 318         }
 319         ($ibx, $exists, $uidnext, $uid_base);
 320 }
 321
 322 sub cmd_examine ($$$) {
 323         my ($self, $tag, $mailbox) = @_;
 324         my ($ibx, $exists, $uidnext, $base) = inbox_lookup($self, $mailbox);
 325         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 326         $self->{uid_base} = $base;
 327
 328         # XXX: do we need this? RFC 5162/7162
 329         my $ret = $self->{ibx} ? "* OK [CLOSED] previous closed\r\n" : '';
 330         $self->{ibx} = $ibx;
 331         $ret .= <<EOF;
 332 * $exists EXISTS\r
 333 * $exists RECENT\r
 334 * FLAGS (\\Seen)\r
 335 * OK [PERMANENTFLAGS ()] Read-only mailbox\r
 336 * OK [UNSEEN $exists]\r
 337 * OK [UIDNEXT $uidnext]\r
 338 * OK [UIDVALIDITY $ibx->{uidvalidity}]\r
 339 $tag OK [READ-ONLY] EXAMINE/SELECT done\r
 340 EOF
 341 }
 342
 343 sub _esc ($) {
 344         my ($v) = @_;
 345         if (!defined($v)) {
 346                 'NIL';
 347         } elsif ($v =~ /[{"\r\n%*\\\[]/) { # literal string
 348                 '{' . length($v) . "}\r\n" . $v;
 349         } else { # quoted string
 350                 qq{"$v"}
 351         }
 352 }
 353
 354 sub addr_envelope ($$;$) {
 355         my ($eml, $x, $y) = @_;
 356         my $v = $eml->header_raw($x) //
 357                 ($y ? $eml->header_raw($y) : undef) // return 'NIL';
 358
 359         my @x = $Address->parse($v) or return 'NIL';
 360         '(' . join('',
 361                 map { '(' . join(' ',
 362                                 _esc($_->name), 'NIL',
 363                                 _esc($_->user), _esc($_->host)
 364                         ) . ')'
 365                 } @x) .
 366         ')';
 367 }
 368
 369 sub eml_envelope ($) {
 370         my ($eml) = @_;
 371         '(' . join(' ',
 372                 _esc($eml->header_raw('Date')),
 373                 _esc($eml->header_raw('Subject')),
 374                 addr_envelope($eml, 'From'),
 375                 addr_envelope($eml, 'Sender', 'From'),
 376                 addr_envelope($eml, 'Reply-To', 'From'),
 377                 addr_envelope($eml, 'To'),
 378                 addr_envelope($eml, 'Cc'),
 379                 addr_envelope($eml, 'Bcc'),
 380                 _esc($eml->header_raw('In-Reply-To')),
 381                 _esc($eml->header_raw('Message-ID')),
 382         ) . ')';
 383 }
 384
 385 sub _esc_hash ($) {
 386         my ($hash) = @_;
 387         if ($hash && scalar keys %$hash) {
 388                 $hash = [ %$hash ]; # flatten hash into 1-dimensional array
 389                 '(' . join(' ', map { _esc($_) } @$hash) . ')';
 390         } else {
 391                 'NIL';
 392         }
 393 }
 394
 395 sub body_disposition ($) {
 396         my ($eml) = @_;
 397         my $cd = $eml->header_raw('Content-Disposition') or return 'NIL';
 398         $cd = parse_content_disposition($cd);
 399         my $buf = '('._esc($cd->{type});
 400         $buf .= ' ' . _esc_hash(delete $cd->{attributes});
 401         $buf .= ')';
 402 }
 403
 404 sub body_leaf ($$;$) {
 405         my ($eml, $structure, $hold) = @_;
 406         my $buf = '';
 407         $eml->{is_submsg} and # parent was a message/(rfc822|news|global)
 408                 $buf .= eml_envelope($eml). ' ';
 409         my $ct = $eml->ct;
 410         $buf .= '('._esc($ct->{type}).' ';
 411         $buf .= _esc($ct->{subtype});
 412         $buf .= ' ' . _esc_hash(delete $ct->{attributes});
 413         $buf .= ' ' . _esc($eml->header_raw('Content-ID'));
 414         $buf .= ' ' . _esc($eml->header_raw('Content-Description'));
 415         my $cte = $eml->header_raw('Content-Transfer-Encoding') // '7bit';
 416         $buf .= ' ' . _esc($cte);
 417         $buf .= ' ' . $eml->{imap_body_len};
 418         $buf .= ' '.($eml->body_raw =~ tr/\n/\n/) if lc($ct->{type}) eq 'text';
 419
 420         # for message/(rfc822|global|news), $hold[0] should have envelope
 421         $buf .= ' ' . (@$hold ? join('', @$hold) : 'NIL') if $hold;
 422
 423         if ($structure) {
 424                 $buf .= ' '._esc($eml->header_raw('Content-MD5'));
 425                 $buf .= ' '. body_disposition($eml);
 426                 $buf .= ' '._esc($eml->header_raw('Content-Language'));
 427                 $buf .= ' '._esc($eml->header_raw('Content-Location'));
 428         }
 429         $buf .= ')';
 430 }
 431
 432 sub body_parent ($$$) {
 433         my ($eml, $structure, $hold) = @_;
 434         my $ct = $eml->ct;
 435         my $type = lc($ct->{type});
 436         if ($type eq 'multipart') {
 437                 my $buf = '(';
 438                 $buf .= @$hold ? join('', @$hold) : 'NIL';
 439                 $buf .= ' '._esc($ct->{subtype});
 440                 if ($structure) {
 441                         $buf .= ' '._esc_hash(delete $ct->{attributes});
 442                         $buf .= ' '.body_disposition($eml);
 443                         $buf .= ' '._esc($eml->header_raw('Content-Language'));
 444                         $buf .= ' '._esc($eml->header_raw('Content-Location'));
 445                 }
 446                 $buf .= ')';
 447                 @$hold = ($buf);
 448         } else { # message/(rfc822|global|news)
 449                 @$hold = (body_leaf($eml, $structure, $hold));
 450         }
 451 }
 452
 453 # this is gross, but we need to process the parent part AFTER
 454 # the child parts are done
 455 sub bodystructure_prep {
 456         my ($p, $q) = @_;
 457         my ($eml, $depth) = @$p; # ignore idx
 458         # set length here, as $eml->{bdy} gets deleted for message/rfc822
 459         $eml->{imap_body_len} = length($eml->body_raw);
 460         push @$q, $eml, $depth;
 461 }
 462
 463 # for FETCH BODY and FETCH BODYSTRUCTURE
 464 sub fetch_body ($;$) {
 465         my ($eml, $structure) = @_;
 466         my @q;
 467         $eml->each_part(\&bodystructure_prep, \@q, 0, 1);
 468         my $cur_depth = 0;
 469         my @hold;
 470         do {
 471                 my ($part, $depth) = splice(@q, -2);
 472                 my $is_mp_parent = $depth == ($cur_depth - 1);
 473                 $cur_depth = $depth;
 474
 475                 if ($is_mp_parent) {
 476                         body_parent($part, $structure, \@hold);
 477                 } else {
 478                         unshift @hold, body_leaf($part, $structure);
 479                 }
 480         } while (@q);
 481         join('', @hold);
 482 }
 483
 484 sub requeue_once ($) {
 485         my ($self) = @_;
 486         # COMPRESS users all share the same DEFLATE context.
 487         # Flush it here to ensure clients don't see
 488         # each other's data
 489         $self->zflush;
 490
 491         # no recursion, schedule another call ASAP,
 492         # but only after all pending writes are done.
 493         # autovivify wbuf:
 494         my $new_size = push(@{$self->{wbuf}}, \&long_step);
 495
 496         # wbuf may be populated by $cb, no need to rearm if so:
 497         $self->requeue if $new_size == 1;
 498 }
 499
 500 # my ($msn, $UID) = @_;
 501 sub fetch_msn_uid ($$) { '* '.(${$_[0]}++).' FETCH (UID '.$_[1] }
 502
 503 sub fetch_run_ops {
 504         my ($self, $msn, $smsg, $bref, $ops, $partial) = @_;
 505         $self->msg_more(fetch_msn_uid($msn, $smsg->{num}));
 506         my ($eml, $k);
 507         for (my $i = 0; $i < @$ops;) {
 508                 $k = $ops->[$i++];
 509                 $ops->[$i++]->($self, $k, $smsg, $bref, $eml);
 510         }
 511         partial_emit($self, $partial, $eml) if $partial;
 512         $self->msg_more(")\r\n");
 513 }
 514
 515 sub fetch_blob_cb { # called by git->cat_async via git_async_cat
 516         my ($bref, $oid, $type, $size, $fetch_arg) = @_;
 517         my ($self, undef, $msgs, $range_info, $ops, $partial) = @$fetch_arg;
 518         my $smsg = shift @$msgs or die 'BUG: no smsg';
 519         if (!defined($oid)) {
 520                 # it's possible to have TOCTOU if an admin runs
 521                 # public-inbox-(edit|purge), just move onto the next message
 522                 return requeue_once($self);
 523         } else {
 524                 $smsg->{blob} eq $oid or die "BUG: $smsg->{blob} != $oid";
 525         }
 526         fetch_run_ops($self, $range_info->[3], $smsg, $bref, $ops, $partial);
 527         requeue_once($self);
 528 }
 529
 530 sub emit_rfc822 {
 531         my ($self, $k, undef, $bref) = @_;
 532         $self->msg_more(" $k {" . length($$bref)."}\r\n");
 533         $self->msg_more($$bref);
 534 }
 535
 536 # Mail::IMAPClient::message_string cares about this by default,
 537 # (->Ignoresizeerrors attribute).  Admins are encouraged to
 538 # --reindex for IMAP support, anyways.
 539 sub emit_rfc822_size {
 540         my ($self, $k, $smsg) = @_;
 541         $self->msg_more(' RFC822.SIZE ' . $smsg->{bytes});
 542 }
 543
 544 sub emit_internaldate {
 545         my ($self, undef, $smsg) = @_;
 546         $self->msg_more(' INTERNALDATE "'.$smsg->internaldate.'"');
 547 }
 548
 549 sub emit_flags { $_[0]->msg_more(' FLAGS ()') }
 550
 551 sub emit_envelope {
 552         my ($self, undef, undef, undef, $eml) = @_;
 553         $self->msg_more(' ENVELOPE '.eml_envelope($eml));
 554 }
 555
 556 sub emit_rfc822_header {
 557         my ($self, $k, undef, undef, $eml) = @_;
 558         $self->msg_more(" $k {".length(${$eml->{hdr}})."}\r\n");
 559         $self->msg_more(${$eml->{hdr}});
 560 }
 561
 562 # n.b. this is sorted to be after any emit_eml_new ops
 563 sub emit_rfc822_text {
 564         my ($self, $k, undef, $bref) = @_;
 565         $self->msg_more(" $k {".length($$bref)."}\r\n");
 566         $self->msg_more($$bref);
 567 }
 568
 569 sub emit_bodystructure {
 570         my ($self, undef, undef, undef, $eml) = @_;
 571         $self->msg_more(' BODYSTRUCTURE '.fetch_body($eml, 1));
 572 }
 573
 574 sub emit_body {
 575         my ($self, undef, undef, undef, $eml) = @_;
 576         $self->msg_more(' BODY '.fetch_body($eml));
 577 }
 578
 579 # set $eml once ($_[4] == $eml, $_[3] == $bref)
 580 sub op_eml_new { $_[4] = PublicInbox::Eml->new($_[3]) }
 581
 582 # s/From / fixes old bug from import (pre-a0c07cba0e5d8b6a)
 583 sub to_crlf_full {
 584         ${$_[0]} =~ s/(?<!\r)\n/\r\n/sg;
 585         ${$_[0]} =~ s/\A[\r\n]*From [^\r\n]*\r\n//s;
 586 }
 587
 588 sub op_crlf_bref { to_crlf_full($_[3]) }
 589
 590 sub op_crlf_hdr { to_crlf_full($_[4]->{hdr}) }
 591
 592 sub op_crlf_bdy { ${$_[4]->{bdy}} =~ s/(?<!\r)\n/\r\n/sg if $_[4]->{bdy} }
 593
 594 sub uid_clamp ($$$) {
 595         my ($self, $beg, $end) = @_;
 596         my $uid_min = $self->{uid_base} + 1;
 597         my $uid_end = $uid_min + UID_SLICE - 1;
 598         $$beg = $uid_min if $$beg < $uid_min;
 599         $$end = $uid_end if $$end > $uid_end;
 600 }
 601
 602 sub range_step ($$) {
 603         my ($self, $range_csv) = @_;
 604         my ($beg, $end, $range);
 605         if ($$range_csv =~ s/\A([^,]+),//) {
 606                 $range = $1;
 607         } else {
 608                 $range = $$range_csv;
 609                 $$range_csv = undef;
 610         }
 611         my $uid_base = $self->{uid_base};
 612         my $uid_end = $uid_base + UID_SLICE;
 613         if ($range =~ /\A([0-9]+):([0-9]+)\z/) {
 614                 ($beg, $end) = ($1 + 0, $2 + 0);
 615                 uid_clamp($self, \$beg, \$end);
 616         } elsif ($range =~ /\A([0-9]+):\*\z/) {
 617                 $beg = $1 + 0;
 618                 $end = $self->{ibx}->over->max;
 619                 $end = $uid_end if $end > $uid_end;
 620                 $beg = $end if $beg > $end;
 621                 uid_clamp($self, \$beg, \$end);
 622         } elsif ($range =~ /\A[0-9]+\z/) {
 623                 $beg = $end = $range + 0;
 624                 # just let the caller do an out-of-range query if a single
 625                 # UID is out-of-range
 626                 ++$beg if ($beg <= $uid_base || $end > $uid_end);
 627         } else {
 628                 return 'BAD fetch range';
 629         }
 630         my $msn = $beg - $uid_base;
 631         [ $beg, $end, $$range_csv, \$msn ];
 632 }
 633
 634 sub refill_range ($$$) {
 635         my ($self, $msgs, $range_info) = @_;
 636         my ($beg, $end, $range_csv) = @$range_info;
 637         if (scalar(@$msgs = @{$self->{ibx}->over->query_xover($beg, $end)})) {
 638                 $range_info->[0] = $msgs->[-1]->{num} + 1;
 639                 return;
 640         }
 641         return 'OK Fetch done' if !$range_csv;
 642         my $next_range = range_step($self, \$range_csv);
 643         return $next_range if !ref($next_range); # error
 644         @$range_info = @$next_range;
 645         undef; # keep looping
 646 }
 647
 648 sub fetch_blob { # long_response
 649         my ($self, $tag, $msgs, $range_info, $ops, $partial) = @_;
 650         while (!@$msgs) { # rare
 651                 if (my $end = refill_range($self, $msgs, $range_info)) {
 652                         $self->write(\"$tag $end\r\n");
 653                         return;
 654                 }
 655         }
 656         git_async_cat($self->{ibx}->git, $msgs->[0]->{blob},
 657                         \&fetch_blob_cb, \@_);
 658 }
 659
 660 sub fetch_smsg { # long_response
 661         my ($self, $tag, $msgs, $range_info, $ops) = @_;
 662         while (!@$msgs) { # rare
 663                 if (my $end = refill_range($self, $msgs, $range_info)) {
 664                         $self->write(\"$tag $end\r\n");
 665                         return;
 666                 }
 667         }
 668         fetch_run_ops($self, $range_info->[3], $_, undef, $ops) for @$msgs;
 669         @$msgs = ();
 670         1; # more
 671 }
 672
 673 sub refill_uids ($$$;$) {
 674         my ($self, $uids, $range_info, $sql) = @_;
 675         my ($beg, $end, $range_csv) = @$range_info;
 676         my $over = $self->{ibx}->over;
 677         while (1) {
 678                 if (scalar(@$uids = @{$over->uid_range($beg, $end, $sql)})) {
 679                         $range_info->[0] = $uids->[-1] + 1; # update $beg
 680                         return;
 681                 } elsif (!$range_csv) {
 682                         return 0;
 683                 } else {
 684                         my $next_range = range_step($self, \$range_csv);
 685                         return $next_range if !ref($next_range); # error
 686                         ($beg, $end, $range_csv) = @$range_info = @$next_range;
 687                         # continue looping
 688                 }
 689         }
 690 }
 691
 692 sub fetch_uid { # long_response
 693         my ($self, $tag, $uids, $range_info, $ops) = @_;
 694         if (defined(my $err = refill_uids($self, $uids, $range_info))) {
 695                 $err ||= 'OK Fetch done';
 696                 $self->write("$tag $err\r\n");
 697                 return;
 698         }
 699         my ($i, $k);
 700         my $msn = $range_info->[3];
 701         for (@$uids) {
 702                 $self->msg_more(fetch_msn_uid($msn, $_));
 703                 for ($i = 0; $i < @$ops;) {
 704                         $k = $ops->[$i++];
 705                         $ops->[$i++]->($self, $k);
 706                 }
 707                 $self->msg_more(")\r\n");
 708         }
 709         @$uids = ();
 710         1; # more
 711 }
 712
 713 sub cmd_status ($$$;@) {
 714         my ($self, $tag, $mailbox, @items) = @_;
 715         return "$tag BAD no items\r\n" if !scalar(@items);
 716         ($items[0] !~ s/\A\(//s || $items[-1] !~ s/\)\z//s) and
 717                 return "$tag BAD invalid args\r\n";
 718         my ($ibx, $exists, $uidnext) = inbox_lookup($self, $mailbox);
 719         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 720         my @it;
 721         for my $it (@items) {
 722                 $it = uc($it);
 723                 push @it, $it;
 724                 if ($it =~ /\A(?:MESSAGES|UNSEEN|RECENT)\z/) {
 725                         push @it, $exists;
 726                 } elsif ($it eq 'UIDNEXT') {
 727                         push @it, $uidnext;
 728                 } elsif ($it eq 'UIDVALIDITY') {
 729                         push @it, $ibx->{uidvalidity};
 730                 } else {
 731                         return "$tag BAD invalid item\r\n";
 732                 }
 733         }
 734         return "$tag BAD no items\r\n" if !@it;
 735         "* STATUS $mailbox (".join(' ', @it).")\r\n" .
 736         "$tag OK Status done\r\n";
 737 }
 738
 739 my %patmap = ('*' => '.*', '%' => '[^\.]*');
 740 sub cmd_list ($$$$) {
 741         my ($self, $tag, $refname, $wildcard) = @_;
 742         my $l = $self->{imapd}->{inboxlist};
 743         if ($refname eq '' && $wildcard eq '') {
 744                 # request for hierarchy delimiter
 745                 $l = [ qq[* LIST (\\Noselect) "." ""\r\n] ];
 746         } elsif ($refname ne '' || $wildcard ne '*') {
 747                 $wildcard =~ s!([^a-z0-9_])!$patmap{$1} // "\Q$1"!egi;
 748                 $l = [ grep(/ \Q$refname\E$wildcard\r\n\z/is, @$l) ];
 749         }
 750         \(join('', @$l, "$tag OK List done\r\n"));
 751 }
 752
 753 sub cmd_lsub ($$$$) {
 754         my (undef, $tag) = @_; # same args as cmd_list
 755         "$tag OK Lsub done\r\n";
 756 }
 757
 758 sub eml_index_offs_i { # PublicInbox::Eml::each_part callback
 759         my ($p, $all) = @_;
 760         my ($eml, undef, $idx) = @$p;
 761         if ($idx && lc($eml->ct->{type}) eq 'multipart') {
 762                 $eml->{imap_bdy} = $eml->{bdy} // \'';
 763         }
 764         $all->{$idx} = $eml; # $idx => Eml
 765 }
 766
 767 # prepares an index for BODY[$SECTION_IDX] fetches
 768 sub eml_body_idx ($$) {
 769         my ($eml, $section_idx) = @_;
 770         my $idx = $eml->{imap_all_parts} //= do {
 771                 my $all = {};
 772                 $eml->each_part(\&eml_index_offs_i, $all, 0, 1);
 773                 # top-level of multipart, BODY[0] not allowed (nz-number)
 774                 delete $all->{0};
 775                 $all;
 776         };
 777         $idx->{$section_idx};
 778 }
 779
 780 # BODY[($SECTION_IDX)?(.$SECTION_NAME)?]<$offset.$bytes>
 781 sub partial_body {
 782         my ($eml, $section_idx, $section_name) = @_;
 783         if (defined $section_idx) {
 784                 $eml = eml_body_idx($eml, $section_idx) or return;
 785         }
 786         if (defined $section_name) {
 787                 if ($section_name eq 'MIME') {
 788                         # RFC 3501 6.4.5 states:
 789                         #       The MIME part specifier MUST be prefixed
 790                         #       by one or more numeric part specifiers
 791                         return unless defined $section_idx;
 792                         return $eml->header_obj->as_string . "\r\n";
 793                 }
 794                 my $bdy = $eml->{bdy} // $eml->{imap_bdy} // \'';
 795                 $eml = PublicInbox::Eml->new($$bdy);
 796                 if ($section_name eq 'TEXT') {
 797                         return $eml->body_raw;
 798                 } elsif ($section_name eq 'HEADER') {
 799                         return $eml->header_obj->as_string . "\r\n";
 800                 } else {
 801                         die "BUG: bad section_name=$section_name";
 802                 }
 803         }
 804         ${$eml->{bdy} // $eml->{imap_bdy} // \''};
 805 }
 806
 807 # similar to what's in PublicInbox::Eml::re_memo, but doesn't memoize
 808 # to avoid OOM with malicious users
 809 sub hdrs_regexp ($) {
 810         my ($hdrs) = @_;
 811         my $names = join('|', map { "\Q$_" } split(/[ \t]+/, $hdrs));
 812         qr/^(?:$names):[ \t]*[^\n]*\r?\n # 1st line
 813                 # continuation lines:
 814                 (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*
 815                 /ismx;
 816 }
 817
 818 # BODY[($SECTION_IDX.)?HEADER.FIELDS.NOT ($HDRS)]<$offset.$bytes>
 819 sub partial_hdr_not {
 820         my ($eml, $section_idx, $hdrs_re) = @_;
 821         if (defined $section_idx) {
 822                 $eml = eml_body_idx($eml, $section_idx) or return;
 823         }
 824         my $str = $eml->header_obj->as_string;
 825         $str =~ s/$hdrs_re//g;
 826         $str =~ s/(?<!\r)\n/\r\n/sg;
 827         $str .= "\r\n";
 828 }
 829
 830 # BODY[($SECTION_IDX.)?HEADER.FIELDS ($HDRS)]<$offset.$bytes>
 831 sub partial_hdr_get {
 832         my ($eml, $section_idx, $hdrs_re) = @_;
 833         if (defined $section_idx) {
 834                 $eml = eml_body_idx($eml, $section_idx) or return;
 835         }
 836         my $str = $eml->header_obj->as_string;
 837         $str = join('', ($str =~ m/($hdrs_re)/g));
 838         $str =~ s/(?<!\r)\n/\r\n/sg;
 839         $str .= "\r\n";
 840 }
 841
 842 sub partial_prepare ($$$$) {
 843         my ($need, $partial, $want, $att) = @_;
 844
 845         # recombine [ "BODY[1.HEADER.FIELDS", "(foo", "bar)]" ]
 846         # back to: "BODY[1.HEADER.FIELDS (foo bar)]"
 847         return unless $att =~ /\ABODY\[/s;
 848         until (rindex($att, ']') >= 0) {
 849                 my $next = shift @$want or return;
 850                 $att .= ' ' . uc($next);
 851         }
 852         if ($att =~ /\ABODY\[([0-9]+(?:\.[0-9]+)*)? # 1 - section_idx
 853                         (?:\.(HEADER|MIME|TEXT))? # 2 - section_name
 854                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 3, 4
 855                 $partial->{$att} = [ \&partial_body, $1, $2, $3, $4 ];
 856                 $$need |= CRLF_BREF|EML_HDR|EML_BDY;
 857         } elsif ($att =~ /\ABODY\[(?:([0-9]+(?:\.[0-9]+)*)\.)? # 1 - section_idx
 858                                 (?:HEADER\.FIELDS(\.NOT)?)\x20 # 2
 859                                 \(([A-Z0-9\-\x20]+)\) # 3 - hdrs
 860                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 4 5
 861                 my $tmp = $partial->{$att} = [ $2 ? \&partial_hdr_not
 862                                                 : \&partial_hdr_get,
 863                                                 $1, undef, $4, $5 ];
 864                 $tmp->[2] = hdrs_regexp($3);
 865
 866                 # don't emit CRLF_HDR instruction, here, partial_hdr_*
 867                 # will do CRLF conversion with only the extracted result
 868                 # and not waste time converting lines we don't care about.
 869                 $$need |= EML_HDR;
 870         } else {
 871                 undef;
 872         }
 873 }
 874
 875 sub partial_emit ($$$) {
 876         my ($self, $partial, $eml) = @_;
 877         for (@$partial) {
 878                 my ($k, $cb, @args) = @$_;
 879                 my ($offset, $len) = splice(@args, -2);
 880                 # $cb is partial_body|partial_hdr_get|partial_hdr_not
 881                 my $str = $cb->($eml, @args) // '';
 882                 if (defined $offset) {
 883                         if (defined $len) {
 884                                 $str = substr($str, $offset, $len);
 885                                 $k =~ s/\.$len>\z/>/ or warn
 886 "BUG: unable to remove `.$len>' from `$k'";
 887                         } else {
 888                                 $str = substr($str, $offset);
 889                                 $len = length($str);
 890                         }
 891                 } else {
 892                         $len = length($str);
 893                 }
 894                 $self->msg_more(" $k {$len}\r\n");
 895                 $self->msg_more($str);
 896         }
 897 }
 898
 899 sub fetch_compile ($) {
 900         my ($want) = @_;
 901         if ($want->[0] =~ s/\A\(//s) {
 902                 $want->[-1] =~ s/\)\z//s or return 'BAD no rparen';
 903         }
 904         my (%partial, %seen, @op);
 905         my $need = 0;
 906         while (defined(my $att = shift @$want)) {
 907                 $att = uc($att);
 908                 next if $att eq 'UID'; # always returned
 909                 $att =~ s/\ABODY\.PEEK\[/BODY\[/; # we're read-only
 910                 my $x = $FETCH_ATT{$att};
 911                 if ($x) {
 912                         while (my ($k, $fl_cb) = each %$x) {
 913                                 next if $seen{$k}++;
 914                                 $need |= $fl_cb->[0];
 915                                 push @op, [ @$fl_cb, $k ];
 916                         }
 917                 } elsif (!partial_prepare(\$need, \%partial, $want, $att)) {
 918                         return "BAD param: $att";
 919                 }
 920         }
 921         my @r;
 922
 923         # stabilize partial order for consistency and ease-of-debugging:
 924         if (scalar keys %partial) {
 925                 $need |= NEED_BLOB;
 926                 $r[2] = [ map { [ $_, @{$partial{$_}} ] } sort keys %partial ];
 927         }
 928
 929         push @op, $OP_EML_NEW if ($need & (EML_HDR|EML_BDY));
 930
 931         # do we need CRLF conversion?
 932         if ($need & CRLF_BREF) {
 933                 push @op, $OP_CRLF_BREF;
 934         } elsif (my $crlf = ($need & (CRLF_HDR|CRLF_BDY))) {
 935                 if ($crlf == (CRLF_HDR|CRLF_BDY)) {
 936                         push @op, $OP_CRLF_BREF;
 937                 } elsif ($need & CRLF_HDR) {
 938                         push @op, $OP_CRLF_HDR;
 939                 } else {
 940                         push @op, $OP_CRLF_BDY;
 941                 }
 942         }
 943
 944         $r[0] = $need & NEED_BLOB ? \&fetch_blob :
 945                 ($need & NEED_SMSG ? \&fetch_smsg : \&fetch_uid);
 946
 947         # r[1] = [ $key1, $cb1, $key2, $cb2, ... ]
 948         use sort 'stable'; # makes output more consistent
 949         $r[1] = [ map { ($_->[2], $_->[1]) } sort { $a->[0] <=> $b->[0] } @op ];
 950         @r;
 951 }
 952
 953 sub cmd_uid_fetch ($$$$;@) {
 954         my ($self, $tag, $range_csv, @want) = @_;
 955         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 956         my ($cb, $ops, $partial) = fetch_compile(\@want);
 957         return "$tag $cb\r\n" unless $ops;
 958
 959         $range_csv = 'bad' if $range_csv !~ $valid_range;
 960         my $range_info = range_step($self, \$range_csv);
 961         return "$tag $range_info\r\n" if !ref($range_info);
 962         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 963 }
 964
 965 # returns an arrayref of UIDs, so MSNs can be translated via:
 966 # $msn2uid->[$MSN-1] => $UID
 967 sub msn2uid ($) {
 968         my ($self) = @_;
 969         my $x = $self->{uid_base};
 970         $self->{ibx}->over->uid_range($x + 1, $x + UID_SLICE);
 971 }
 972
 973 sub msn_to_uid_range ($$) {
 974         my $msn2uid = $_[0];
 975         $_[1] =~ s!([0-9]+)!$msn2uid->[$1 - 1] // ($msn2uid->[-1] + 1)!sge;
 976 }
 977
 978 sub cmd_fetch ($$$$;@) {
 979         my ($self, $tag, $range_csv, @want) = @_;
 980         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 981         my ($cb, $ops, $partial) = fetch_compile(\@want);
 982         return "$tag $cb\r\n" unless $ops;
 983
 984         # cb is one of fetch_blob, fetch_smsg, fetch_uid
 985         $range_csv = 'bad' if $range_csv !~ $valid_range;
 986         msn_to_uid_range(msn2uid($self), $range_csv);
 987         my $range_info = range_step($self, \$range_csv);
 988         return "$tag $range_info\r\n" if !ref($range_info);
 989         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 990 }
 991
 992 sub parse_date ($) { # 02-Oct-1993
 993         my ($date_text) = @_;
 994         my ($dd, $mon, $yyyy) = split(/-/, $_[0], 3);
 995         defined($yyyy) or return;
 996         my $mm = $MoY{$mon} // return;
 997         $dd =~ /\A[0123]?[0-9]\z/ or return;
 998         $yyyy =~ /\A[0-9]{4,}\z/ or return; # Y10K-compatible!
 999         timegm(0, 0, 0, $dd, $mm, $yyyy);
1000 }
1001
1002 sub search_uid_range { # long_response
1003         my ($self, $tag, $sql, $range_info) = @_;
1004         my $uids = [];
1005         if (defined(my $err = refill_uids($self, $uids, $range_info, $sql))) {
1006                 $err ||= 'OK Search done';
1007                 $self->write("\r\n$tag $err\r\n");
1008                 return;
1009         }
1010         $self->msg_more(join(' ', '', @$uids));
1011         1; # more
1012 }
1013
1014 sub date_search {
1015         my ($q, $k, $d) = @_;
1016         my $sql = $q->{sql};
1017
1018         # Date: header
1019         if ($k eq 'SENTON') {
1020                 my $end = $d + 86399; # no leap day...
1021                 my $da = strftime('%Y%m%d%H%M%S', gmtime($d));
1022                 my $db = strftime('%Y%m%d%H%M%S', gmtime($end));
1023                 $q->{xap} .= " dt:$da..$db";
1024                 $$sql .= " AND ds >= $d AND ds <= $end" if defined($sql);
1025         } elsif ($k eq 'SENTBEFORE') {
1026                 $q->{xap} .= ' d:..'.strftime('%Y%m%d', gmtime($d));
1027                 $$sql .= " AND ds <= $d" if defined($sql);
1028         } elsif ($k eq 'SENTSINCE') {
1029                 $q->{xap} .= ' d:'.strftime('%Y%m%d', gmtime($d)).'..';
1030                 $$sql .= " AND ds >= $d" if defined($sql);
1031
1032         # INTERNALDATE (Received)
1033         } elsif ($k eq 'ON') {
1034                 my $end = $d + 86399; # no leap day...
1035                 $q->{xap} .= " ts:$d..$end";
1036                 $$sql .= " AND ts >= $d AND ts <= $end" if defined($sql);
1037         } elsif ($k eq 'BEFORE') {
1038                 $q->{xap} .= " ts:..$d";
1039                 $$sql .= " AND ts <= $d" if defined($sql);
1040         } elsif ($k eq 'SINCE') {
1041                 $q->{xap} .= " ts:$d..";
1042                 $$sql .= " AND ts >= $d" if defined($sql);
1043         } else {
1044                 die "BUG: $k not recognized";
1045         }
1046 }
1047
1048 # IMAP to Xapian search key mapping
1049 my %I2X = (
1050         SUBJECT => 's:',
1051         BODY => 'b:',
1052         FROM => 'f:',
1053         TEXT => '', # n.b. does not include all headers
1054         TO => 't:',
1055         CC => 'c:',
1056         # BCC => 'bcc:', # TODO
1057         # KEYWORD # TODO ? dfpre,dfpost,...
1058 );
1059
1060 # IMAP allows searching arbitrary headers via "HEADER $HDR_NAME $HDR_VAL"
1061 # which gets silly expensive.  We only allow the headers we already index.
1062 my %H2X = (%I2X, 'MESSAGE-ID' => 'm:', 'LIST-ID' => 'l:');
1063
1064 sub xap_append ($$$$) {
1065         my ($q, $rest, $k, $xk) = @_;
1066         delete $q->{sql}; # can't use over.sqlite3
1067         defined(my $arg = shift @$rest) or return "BAD $k no arg";
1068
1069         # AFAIK Xapian can't handle [*"] in probabilistic terms
1070         $arg =~ tr/*"//d;
1071         ${$q->{xap}} .= qq[ $xk"$arg"];
1072         undef;
1073 }
1074
1075 sub parse_query {
1076         my ($self, $rest) = @_;
1077         if (uc($rest->[0]) eq 'CHARSET') {
1078                 shift @$rest;
1079                 defined(my $c = shift @$rest) or return 'BAD missing charset';
1080                 $c =~ /\A(?:UTF-8|US-ASCII)\z/ or return 'NO [BADCHARSET]';
1081         }
1082
1083         my $sql = ''; # date conditions, {sql} deleted if Xapian is needed
1084         my $xap = '';
1085         my $q = { sql => \$sql, xap => \$xap };
1086         my $msn2uid;
1087         while (@$rest) {
1088                 my $k = uc(shift @$rest);
1089                 # default criteria
1090                 next if $k =~ /\A(?:ALL|RECENT|UNSEEN|NEW)\z/;
1091                 next if $k eq 'AND'; # the default, until we support OR
1092                 if ($k =~ $valid_range) { # convert sequence numbers to UIDs
1093                         msn_to_uid_range($msn2uid //= msn2uid($self), $k);
1094                         push @{$q->{uid}}, $k;
1095                 } elsif ($k eq 'UID') {
1096                         $k = shift(@$rest) // '';
1097                         $k =~ $valid_range or return 'BAD UID range';
1098                         push @{$q->{uid}}, $k;
1099                 } elsif ($k =~ /\A(?:SENT)?(?:SINCE|ON|BEFORE)\z/) {
1100                         my $d = parse_date(shift(@$rest) // '');
1101                         defined $d or return "BAD $k date format";
1102                         date_search($q, $k, $d);
1103                 } elsif ($k =~ /\A(?:SMALLER|LARGER)\z/) {
1104                         delete $q->{sql}; # can't use over.sqlite3
1105                         my $bytes = shift(@$rest) // '';
1106                         $bytes =~ /\A[0-9]+\z/ or return "BAD $k not a number";
1107                         $xap .= ' bytes:' . ($k eq 'SMALLER' ?
1108                                                         '..'.(--$bytes) :
1109                                                         (++$bytes).'..');
1110                 } elsif ($k eq 'HEADER') {
1111                         $k = uc(shift(@$rest) // '');
1112                         my $xk = $H2X{$k} or
1113                                 return "BAD HEADER $k not supported";
1114                         my $err = xap_append($q, $rest, $k, $xk);
1115                         return $err if $err;
1116                 } elsif (defined(my $xk = $I2X{$k})) {
1117                         my $err = xap_append($q, $rest, $k, $xk);
1118                         return $err if $err;
1119                 } else {
1120                         # TODO: parentheses, OR, NOT ...
1121                         return "BAD $k not supported (yet?)";
1122                 }
1123         }
1124
1125         # favor using over.sqlite3 if possible, since Xapian is optional
1126         if (exists $q->{sql}) {
1127                 delete($q->{xap});
1128                 delete($q->{sql}) if $sql eq '';
1129         } elsif (!$self->{ibx}->search) {
1130                 return 'BAD Xapian not configured for mailbox';
1131         }
1132         my $max = $self->{ibx}->over->max;
1133         if (my $uid = delete $q->{uid}) {
1134                 my $range_csv = join(',', @$uid);
1135                 do {
1136                         my $nxt = range_step($self, \$range_csv);
1137                         my ($beg, $end) = @$nxt;
1138                         if ($xap) {
1139                                 $xap .= " uid:$beg..$end";
1140                         } elsif ($beg == $end) {
1141                                 $sql .= " AND num = $beg";
1142                         } else {
1143                                 $sql .= " AND num >= $beg AND num <= $end";
1144                         }
1145                 } while ($range_csv);
1146         }
1147         my $beg = 1;
1148         uid_clamp($self, \$beg, \$max);
1149         $q->{range_info} = [ $beg, $max ];
1150         $q;
1151 }
1152
1153 sub refill_xap ($$$$) {
1154         my ($self, $uids, $range_info, $q) = @_;
1155         my ($beg, $end) = @$range_info;
1156         my $srch = $self->{ibx}->search;
1157         my $opt = { mset => 2, limit => 1000 };
1158         my $nshard = $srch->{nshard} // 1;
1159         while (1) {
1160                 my $mset = $srch->query("$$q uid:$beg..$end", $opt);
1161                 @$uids = map { mdocid($nshard, $_) } $mset->items;
1162                 if (@$uids) {
1163                         $range_info->[0] = $uids->[-1] + 1; # update $beg
1164                         return;
1165                 } else { # all done
1166                         return 0;
1167                 }
1168         }
1169 }
1170
1171 sub search_xap_range { # long_response
1172         my ($self, $tag, $q, $range_info) = @_;
1173         my $uids = [];
1174         if (defined(my $err = refill_xap($self, $uids, $range_info, $q))) {
1175                 $err ||= 'OK Search done';
1176                 $self->write("\r\n$tag $err\r\n");
1177                 return;
1178         }
1179         $self->msg_more(join(' ', '', @$uids));
1180         1; # more
1181 }
1182
1183 sub cmd_uid_search ($$$;) {
1184         my ($self, $tag) = splice(@_, 0, 2);
1185         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
1186         my $q = parse_query($self, \@_);
1187         return "$tag $q\r\n" if !ref($q);
1188         my ($sql, $range_info) = delete @$q{qw(sql range_info)};
1189         if (!scalar(keys %$q)) { # overview.sqlite3
1190                 $self->msg_more('* SEARCH');
1191                 long_response($self, \&search_uid_range,
1192                                 $tag, $sql, $range_info);
1193         } elsif ($q = $q->{xap}) {
1194                 $self->msg_more('* SEARCH');
1195                 long_response($self, \&search_xap_range,
1196                                 $tag, $q, $range_info);
1197         } else {
1198                 "$tag BAD Error\r\n";
1199         }
1200 }
1201
1202 # note: MSN SEARCH is NOT supported.  Do any widely-used MUAs
1203 # rely on MSNs from SEARCH results?  Let us know at meta@public-inbox.org
1204
1205 sub args_ok ($$) { # duplicated from PublicInbox::NNTP
1206         my ($cb, $argc) = @_;
1207         my $tot = prototype $cb;
1208         my ($nreq, undef) = split(';', $tot);
1209         $nreq = ($nreq =~ tr/$//) - 1;
1210         $tot = ($tot =~ tr/$//) - 1;
1211         ($argc <= $tot && $argc >= $nreq);
1212 }
1213
1214 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
1215 sub process_line ($$) {
1216         my ($self, $l) = @_;
1217
1218         # TODO: IMAP allows literals for big requests to upload messages
1219         # (which we don't support) but maybe some big search queries use it.
1220         my ($tag, $req, @args) = parse_line('[ \t]+', 0, $l);
1221         pop(@args) if (@args && !defined($args[-1]));
1222         if (@args && uc($req) eq 'UID') {
1223                 $req .= "_".(shift @args);
1224         }
1225         my $res = eval {
1226                 if (my $cmd = $self->can('cmd_'.lc($req // ''))) {
1227                         defined($self->{-idle_tag}) ?
1228                                 "$self->{-idle_tag} BAD expected DONE\r\n" :
1229                                 $cmd->($self, $tag, @args);
1230                 } elsif (uc($tag // '') eq 'DONE' && !defined($req)) {
1231                         cmd_done($self, $tag);
1232                 } else { # this is weird
1233                         auth_challenge_ok($self) //
1234                                         ($tag // '*') .
1235                                         ' BAD Error in IMAP command '.
1236                                         ($req // '(???)').
1237                                         ": Unknown command\r\n";
1238                 }
1239         };
1240         my $err = $@;
1241         if ($err && $self->{sock}) {
1242                 $l =~ s/\r?\n//s;
1243                 err($self, 'error from: %s (%s)', $l, $err);
1244                 $tag //= '*';
1245                 $res = "$tag BAD program fault - command not performed\r\n";
1246         }
1247         return 0 unless defined $res;
1248         $self->write($res);
1249 }
1250
1251 sub long_step {
1252         my ($self) = @_;
1253         # wbuf is unset or empty, here; {long} may add to it
1254         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
1255         my $more = eval { $cb->($self, @args) };
1256         if ($@ || !$self->{sock}) { # something bad happened...
1257                 delete $self->{long_cb};
1258                 my $elapsed = now() - $t0;
1259                 if ($@) {
1260                         err($self,
1261                             "%s during long response[$fd] - %0.6f",
1262                             $@, $elapsed);
1263                 }
1264                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
1265                 $self->close;
1266         } elsif ($more) { # $self->{wbuf}:
1267                 $self->update_idle_time;
1268
1269                 # control passed to $more may be a GitAsyncCat object
1270                 requeue_once($self) if !ref($more);
1271         } else { # all done!
1272                 delete $self->{long_cb};
1273                 my $elapsed = now() - $t0;
1274                 my $fd = fileno($self->{sock});
1275                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
1276                 my $wbuf = $self->{wbuf}; # do NOT autovivify
1277
1278                 $self->requeue unless $wbuf && @$wbuf;
1279         }
1280 }
1281
1282 sub err ($$;@) {
1283         my ($self, $fmt, @args) = @_;
1284         printf { $self->{imapd}->{err} } $fmt."\n", @args;
1285 }
1286
1287 sub out ($$;@) {
1288         my ($self, $fmt, @args) = @_;
1289         printf { $self->{imapd}->{out} } $fmt."\n", @args;
1290 }
1291
1292 sub long_response ($$;@) {
1293         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
1294
1295         my $sock = $self->{sock} or return;
1296         # make sure we disable reading during a long response,
1297         # clients should not be sending us stuff and making us do more
1298         # work while we are stream a response to them
1299         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
1300         long_step($self); # kick off!
1301         undef;
1302 }
1303
1304 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1305 sub event_step {
1306         my ($self) = @_;
1307
1308         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1309
1310         $self->update_idle_time;
1311         # only read more requests if we've drained the write buffer,
1312         # otherwise we can be buffering infinitely w/o backpressure
1313
1314         my $rbuf = $self->{rbuf} // \(my $x = '');
1315         my $line = index($$rbuf, "\n");
1316         while ($line < 0) {
1317                 if (length($$rbuf) >= LINE_MAX) {
1318                         $self->write(\"\* BAD request too long\r\n");
1319                         return $self->close;
1320                 }
1321                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1322                 $line = index($$rbuf, "\n");
1323         }
1324         $line = substr($$rbuf, 0, $line + 1, '');
1325         $line =~ s/\r?\n\z//s;
1326         return $self->close if $line =~ /[[:cntrl:]]/s;
1327         my $t0 = now();
1328         my $fd = fileno($self->{sock});
1329         my $r = eval { process_line($self, $line) };
1330         my $pending = $self->{wbuf} ? ' pending' : '';
1331         out($self, "[$fd] %s - %0.6f$pending - $r", $line, now() - $t0);
1332
1333         return $self->close if $r < 0;
1334         $self->rbuf_idle($rbuf);
1335         $self->update_idle_time;
1336
1337         # maybe there's more pipelined data, or we'll have
1338         # to register it for socket-readiness notifications
1339         $self->requeue unless $pending;
1340 }
1341
1342 sub compressed { undef }
1343
1344 sub zflush {} # overridden by IMAPdeflate
1345
1346 # RFC 4978
1347 sub cmd_compress ($$$) {
1348         my ($self, $tag, $alg) = @_;
1349         return "$tag BAD DEFLATE only\r\n" if uc($alg) ne "DEFLATE";
1350         return "$tag BAD COMPRESS active\r\n" if $self->compressed;
1351
1352         # CRIME made TLS compression obsolete
1353         # return "$tag NO [COMPRESSIONACTIVE]\r\n" if $self->tls_compressed;
1354
1355         PublicInbox::IMAPdeflate->enable($self, $tag);
1356         $self->requeue;
1357         undef
1358 }
1359
1360 sub cmd_starttls ($$) {
1361         my ($self, $tag) = @_;
1362         my $sock = $self->{sock} or return;
1363         if ($sock->can('stop_SSL') || $self->compressed) {
1364                 return "$tag BAD TLS or compression already enabled\r\n";
1365         }
1366         my $opt = $self->{imapd}->{accept_tls} or
1367                 return "$tag BAD can not initiate TLS negotiation\r\n";
1368         $self->write(\"$tag OK begin TLS negotiation now\r\n");
1369         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
1370         $self->requeue if PublicInbox::DS::accept_tls_step($self);
1371         undef;
1372 }
1373
1374 # for graceful shutdown in PublicInbox::Daemon:
1375 sub busy {
1376         my ($self, $now) = @_;
1377         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1378 }
1379
1380 sub close {
1381         my ($self) = @_;
1382         if (my $ibx = delete $self->{ibx}) {
1383                 stop_idle($self, $ibx);
1384         }
1385         $self->SUPER::close; # PublicInbox::DS::close
1386 }
1387
1388 # we're read-only, so SELECT and EXAMINE do the same thing
1389 no warnings 'once';
1390 *cmd_select = \&cmd_examine;
1391
1392 package PublicInbox::IMAP_preauth;
1393 our @ISA = qw(PublicInbox::IMAP);
1394
1395 sub logged_in { 0 }
1396
1397 1;