lib/PublicInbox/IMAP.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents an IMAP client connected to
   5 # public-inbox-imapd.  Much of this was taken from NNTP, but
   6 # further refined while experimenting on future ideas to handle
   7 # slow storage.
   8 #
   9 # data notes:
  10 # * NNTP article numbers are UIDs
  11
  12 package PublicInbox::IMAP;
  13 use strict;
  14 use base qw(PublicInbox::DS);
  15 use fields qw(imapd ibx long_cb -login_tag
  16         uid_base -idle_tag -idle_max);
  17 use PublicInbox::Eml;
  18 use PublicInbox::EmlContentFoo qw(parse_content_disposition);
  19 use PublicInbox::DS qw(now);
  20 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  21 use PublicInbox::GitAsyncCat;
  22 use Text::ParseWords qw(parse_line);
  23 use Errno qw(EAGAIN);
  24 use Time::Local qw(timegm);
  25 use POSIX qw(strftime);
  26 use Hash::Util qw(unlock_hash); # dependency of fields for perl 5.10+, anyways
  27
  28 my $Address;
  29 for my $mod (qw(Email::Address::XS Mail::Address)) {
  30         eval "require $mod" or next;
  31         $Address = $mod and last;
  32 }
  33 die "neither Email::Address::XS nor Mail::Address loaded: $@" if !$Address;
  34
  35 sub LINE_MAX () { 8000 } # RFC 2683 3.2.1.5
  36
  37 # changing this will cause grief for clients which cache
  38 sub UID_BLOCK () { 50_000 }
  39
  40 # these values area also used for sorting
  41 sub NEED_SMSG () { 1 }
  42 sub NEED_BLOB () { NEED_SMSG|2 }
  43 sub CRLF_BREF () { 4 }
  44 sub EML_HDR () { 8 }
  45 sub CRLF_HDR () { 16 }
  46 sub EML_BDY () { 32 }
  47 sub CRLF_BDY () { 64 }
  48 my $OP_EML_NEW = [ EML_HDR - 1, \&op_eml_new ];
  49 my $OP_CRLF_BREF = [ CRLF_BREF, \&op_crlf_bref ];
  50 my $OP_CRLF_HDR = [ CRLF_HDR, \&op_crlf_hdr ];
  51 my $OP_CRLF_BDY = [ CRLF_BDY, \&op_crlf_bdy ];
  52
  53 my %FETCH_NEED = (
  54         'BODY[HEADER]' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  55         'BODY[TEXT]' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  56         'BODY[]' => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  57         'RFC822.HEADER' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  58         'RFC822.TEXT' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  59         'RFC822.SIZE' => [ NEED_SMSG, \&emit_rfc822_size ],
  60         RFC822 => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  61         BODY => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_body ],
  62         BODYSTRUCTURE => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_bodystructure ],
  63         ENVELOPE => [ NEED_BLOB|EML_HDR, \&emit_envelope ],
  64         FLAGS => [ 0, \&emit_flags ],
  65         INTERNALDATE => [ NEED_SMSG, \&emit_internaldate ],
  66 );
  67 my %FETCH_ATT = map { $_ => [ $_ ] } keys %FETCH_NEED;
  68
  69 # aliases (RFC 3501 section 6.4.5)
  70 $FETCH_ATT{FAST} = [ qw(FLAGS INTERNALDATE RFC822.SIZE) ];
  71 $FETCH_ATT{ALL} = [ @{$FETCH_ATT{FAST}}, 'ENVELOPE' ];
  72 $FETCH_ATT{FULL} = [ @{$FETCH_ATT{ALL}}, 'BODY' ];
  73
  74 for my $att (keys %FETCH_ATT) {
  75         my %h = map { $_ => $FETCH_NEED{$_} } @{$FETCH_ATT{$att}};
  76         $FETCH_ATT{$att} = \%h;
  77 }
  78 undef %FETCH_NEED;
  79
  80 my $valid_range = '[0-9]+|[0-9]+:[0-9]+|[0-9]+:\*';
  81 $valid_range = qr/\A(?:$valid_range)(?:,(?:$valid_range))*\z/;
  82
  83 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  84 my %MoY;
  85 @MoY{@MoY} = (0..11);
  86
  87 # RFC 3501 5.4. Autologout Timer needs to be >= 30min
  88 $PublicInbox::DS::EXPTIME = 60 * 30;
  89
  90 sub greet ($) {
  91         my ($self) = @_;
  92         my $capa = capa($self);
  93         $self->write(\"* OK [$capa] public-inbox-imapd ready\r\n");
  94 }
  95
  96 sub new ($$$) {
  97         my ($class, $sock, $imapd) = @_;
  98         my $self = fields::new('PublicInbox::IMAP_preauth');
  99         unlock_hash(%$self);
 100         my $ev = EPOLLIN;
 101         my $wbuf;
 102         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
 103                 return CORE::close($sock) if $! != EAGAIN;
 104                 $ev = PublicInbox::TLS::epollbit();
 105                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
 106         }
 107         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
 108         $self->{imapd} = $imapd;
 109         if ($wbuf) {
 110                 $self->{wbuf} = $wbuf;
 111         } else {
 112                 greet($self);
 113         }
 114         $self->update_idle_time;
 115         $self;
 116 }
 117
 118 sub logged_in { 1 }
 119
 120 sub capa ($) {
 121         my ($self) = @_;
 122
 123         # dovecot advertises IDLE pre-login; perhaps because some clients
 124         # depend on it, so we'll do the same
 125         my $capa = 'CAPABILITY IMAP4rev1 IDLE';
 126         if ($self->logged_in) {
 127                 $capa .= ' COMPRESS=DEFLATE';
 128         } else {
 129                 if (!($self->{sock} // $self)->can('accept_SSL') &&
 130                         $self->{imapd}->{accept_tls}) {
 131                         $capa .= ' STARTTLS';
 132                 }
 133                 $capa .= ' AUTH=ANONYMOUS';
 134         }
 135 }
 136
 137 sub login_success ($$) {
 138         my ($self, $tag) = @_;
 139         bless $self, 'PublicInbox::IMAP';
 140         my $capa = capa($self);
 141         "$tag OK [$capa] Logged in\r\n";
 142 }
 143
 144 sub auth_challenge_ok ($) {
 145         my ($self) = @_;
 146         my $tag = delete($self->{-login_tag}) or return;
 147         login_success($self, $tag);
 148 }
 149
 150 sub cmd_login ($$$$) {
 151         my ($self, $tag) = @_; # ignore ($user, $password) = ($_[2], $_[3])
 152         login_success($self, $tag);
 153 }
 154
 155 sub cmd_close ($$) {
 156         my ($self, $tag) = @_;
 157         delete $self->{uid_base};
 158         delete $self->{ibx} ? "$tag OK Close done\r\n"
 159                                 : "$tag BAD No mailbox\r\n";
 160 }
 161
 162 sub cmd_logout ($$) {
 163         my ($self, $tag) = @_;
 164         delete $self->{-idle_tag};
 165         $self->write(\"* BYE logging out\r\n$tag OK Logout done\r\n");
 166         $self->shutdn; # PublicInbox::DS::shutdn
 167         undef;
 168 }
 169
 170 sub cmd_authenticate ($$$) {
 171         my ($self, $tag) = @_; # $method = $_[2], should be "ANONYMOUS"
 172         $self->{-login_tag} = $tag;
 173         "+\r\n"; # challenge
 174 }
 175
 176 sub cmd_capability ($$) {
 177         my ($self, $tag) = @_;
 178         '* '.capa($self)."\r\n$tag OK Capability done\r\n";
 179 }
 180
 181 sub cmd_noop ($$) { "$_[1] OK Noop done\r\n" }
 182
 183 # called by PublicInbox::InboxIdle
 184 sub on_inbox_unlock {
 185         my ($self, $ibx) = @_;
 186         my $new = $ibx->over->max;
 187         my $uid_base = $self->{uid_base} // 0;
 188         my $uid_end = $uid_base + UID_BLOCK;
 189         defined(my $old = $self->{-idle_max}) or die 'BUG: -idle_max unset';
 190         $new = $uid_end if $new > $uid_end;
 191         if ($new > $old) {
 192                 $self->{-idle_max} = $new;
 193                 $new -= $uid_base;
 194                 $old -= $uid_base;
 195                 $self->msg_more("* $_ EXISTS\r\n") for (($old + 1)..($new - 1));
 196                 $self->write(\"* $new EXISTS\r\n");
 197         } elsif ($new == $uid_end) { # max exceeded $uid_end
 198                 # continue idling w/o inotify
 199                 delete $self->{-idle_max};
 200                 my $sock = $self->{sock} or return;
 201                 $ibx->unsubscribe_unlock(fileno($sock));
 202         }
 203 }
 204
 205 # called every X minute(s) or so by PublicInbox::DS::later
 206 my $IDLERS = {};
 207 my $idle_timer;
 208 sub idle_tick_all {
 209         my $old = $IDLERS;
 210         $IDLERS = {};
 211         for my $i (values %$old) {
 212                 next if ($i->{wbuf} || !exists($i->{-idle_tag}));
 213                 $i->update_idle_time or next;
 214                 $IDLERS->{fileno($i->{sock})} = $i;
 215                 $i->write(\"* OK Still here\r\n");
 216         }
 217         $idle_timer = scalar keys %$IDLERS ?
 218                         PublicInbox::DS::later(\&idle_tick_all) : undef;
 219 }
 220
 221 sub cmd_idle ($$) {
 222         my ($self, $tag) = @_;
 223         # IDLE seems allowed by dovecot w/o a mailbox selected *shrug*
 224         my $ibx = $self->{ibx} or return "$tag BAD no mailbox selected\r\n";
 225         $self->{-idle_tag} = $tag;
 226         my $max = $ibx->over->max;
 227         my $uid_end = $self->{uid_base} + UID_BLOCK;
 228         my $sock = $self->{sock} or return;
 229         my $fd = fileno($sock);
 230         # only do inotify on most recent slice
 231         if ($max < $uid_end) {
 232                 $ibx->subscribe_unlock($fd, $self);
 233                 $self->{imapd}->idler_start;
 234                 $self->{-idle_max} = $max;
 235         }
 236         $idle_timer //= PublicInbox::DS::later(\&idle_tick_all);
 237         $IDLERS->{$fd} = $self;
 238         \"+ idling\r\n"
 239 }
 240
 241 sub stop_idle ($$) {
 242         my ($self, $ibx);
 243         my $sock = $self->{sock} or return;
 244         my $fd = fileno($sock);
 245         delete $IDLERS->{$fd};
 246         $ibx->unsubscribe_unlock($fd);
 247 }
 248
 249 sub cmd_done ($$) {
 250         my ($self, $tag) = @_; # $tag is "DONE" (case-insensitive)
 251         defined(my $idle_tag = delete $self->{-idle_tag}) or
 252                 return "$tag BAD not idle\r\n";
 253         my $ibx = $self->{ibx} or do {
 254                 warn "BUG: idle_tag set w/o inbox";
 255                 return "$tag BAD internal bug\r\n";
 256         };
 257         stop_idle($self, $ibx);
 258         "$idle_tag OK Idle done\r\n";
 259 }
 260
 261 sub ensure_ranges_exist ($$$) {
 262         my ($imapd, $ibx, $max) = @_;
 263         defined(my $mb_top = $ibx->{newsgroup}) or return;
 264         my $mailboxes = $imapd->{mailboxes};
 265         my @created;
 266         for (my $i = int($max/UID_BLOCK); $i >= 0; --$i) {
 267                 my $sub_mailbox = "$mb_top.$i";
 268                 last if exists $mailboxes->{$sub_mailbox};
 269                 $mailboxes->{$sub_mailbox} = $ibx;
 270                 $sub_mailbox =~ s/\Ainbox\./INBOX./i; # more familiar to users
 271                 push @created, $sub_mailbox;
 272         }
 273         return unless @created;
 274         my $l = $imapd->{inboxlist} or return;
 275         push @$l, map { qq[* LIST (\\HasNoChildren) "." $_\r\n] } @created;
 276 }
 277
 278 sub inbox_lookup ($$) {
 279         my ($self, $mailbox) = @_;
 280         my ($ibx, $exists, $uidnext, $uid_base);
 281         if ($mailbox =~ /\A(.+)\.([0-9]+)\z/) {
 282                 # old mail: inbox.comp.foo.$uid_block_idx
 283                 my $mb_top = $1;
 284                 $uid_base = $2 * UID_BLOCK;
 285                 $ibx = $self->{imapd}->{mailboxes}->{lc $mailbox} or return;
 286                 my $max;
 287                 ($exists, $uidnext, $max) = $ibx->over->imap_status($uid_base,
 288                                                         $uid_base + UID_BLOCK);
 289                 ensure_ranges_exist($self->{imapd}, $ibx, $max);
 290         } else { # check for dummy inboxes
 291                 $mailbox = lc $mailbox;
 292                 $ibx = $self->{imapd}->{mailboxes}->{$mailbox} or return;
 293
 294                 # if "INBOX.foo.bar" is selected and "INBOX.foo.bar.0",
 295                 # check for new UID ranges (e.g. "INBOX.foo.bar.1")
 296                 if (my $z = $self->{imapd}->{mailboxes}->{"$mailbox.0"}) {
 297                         ensure_ranges_exist($self->{imapd}, $z, $z->over->max);
 298                 }
 299
 300                 $uid_base = $exists = 0;
 301                 $uidnext = 1;
 302         }
 303         ($ibx, $exists, $uidnext, $uid_base);
 304 }
 305
 306 sub cmd_examine ($$$) {
 307         my ($self, $tag, $mailbox) = @_;
 308         my ($ibx, $exists, $uidnext, $base) = inbox_lookup($self, $mailbox);
 309         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 310         $self->{uid_base} = $base;
 311
 312         # XXX: do we need this? RFC 5162/7162
 313         my $ret = $self->{ibx} ? "* OK [CLOSED] previous closed\r\n" : '';
 314         $self->{ibx} = $ibx;
 315         $ret .= <<EOF;
 316 * $exists EXISTS\r
 317 * $exists RECENT\r
 318 * FLAGS (\\Seen)\r
 319 * OK [PERMANENTFLAGS ()] Read-only mailbox\r
 320 * OK [UNSEEN $exists]\r
 321 * OK [UIDNEXT $uidnext]\r
 322 * OK [UIDVALIDITY $ibx->{uidvalidity}]\r
 323 $tag OK [READ-ONLY] EXAMINE/SELECT done\r
 324 EOF
 325 }
 326
 327 sub _esc ($) {
 328         my ($v) = @_;
 329         if (!defined($v)) {
 330                 'NIL';
 331         } elsif ($v =~ /[{"\r\n%*\\\[]/) { # literal string
 332                 '{' . length($v) . "}\r\n" . $v;
 333         } else { # quoted string
 334                 qq{"$v"}
 335         }
 336 }
 337
 338 sub addr_envelope ($$;$) {
 339         my ($eml, $x, $y) = @_;
 340         my $v = $eml->header_raw($x) //
 341                 ($y ? $eml->header_raw($y) : undef) // return 'NIL';
 342
 343         my @x = $Address->parse($v) or return 'NIL';
 344         '(' . join('',
 345                 map { '(' . join(' ',
 346                                 _esc($_->name), 'NIL',
 347                                 _esc($_->user), _esc($_->host)
 348                         ) . ')'
 349                 } @x) .
 350         ')';
 351 }
 352
 353 sub eml_envelope ($) {
 354         my ($eml) = @_;
 355         '(' . join(' ',
 356                 _esc($eml->header_raw('Date')),
 357                 _esc($eml->header_raw('Subject')),
 358                 addr_envelope($eml, 'From'),
 359                 addr_envelope($eml, 'Sender', 'From'),
 360                 addr_envelope($eml, 'Reply-To', 'From'),
 361                 addr_envelope($eml, 'To'),
 362                 addr_envelope($eml, 'Cc'),
 363                 addr_envelope($eml, 'Bcc'),
 364                 _esc($eml->header_raw('In-Reply-To')),
 365                 _esc($eml->header_raw('Message-ID')),
 366         ) . ')';
 367 }
 368
 369 sub _esc_hash ($) {
 370         my ($hash) = @_;
 371         if ($hash && scalar keys %$hash) {
 372                 $hash = [ %$hash ]; # flatten hash into 1-dimensional array
 373                 '(' . join(' ', map { _esc($_) } @$hash) . ')';
 374         } else {
 375                 'NIL';
 376         }
 377 }
 378
 379 sub body_disposition ($) {
 380         my ($eml) = @_;
 381         my $cd = $eml->header_raw('Content-Disposition') or return 'NIL';
 382         $cd = parse_content_disposition($cd);
 383         my $buf = '('._esc($cd->{type});
 384         $buf .= ' ' . _esc_hash(delete $cd->{attributes});
 385         $buf .= ')';
 386 }
 387
 388 sub body_leaf ($$;$) {
 389         my ($eml, $structure, $hold) = @_;
 390         my $buf = '';
 391         $eml->{is_submsg} and # parent was a message/(rfc822|news|global)
 392                 $buf .= eml_envelope($eml). ' ';
 393         my $ct = $eml->ct;
 394         $buf .= '('._esc($ct->{type}).' ';
 395         $buf .= _esc($ct->{subtype});
 396         $buf .= ' ' . _esc_hash(delete $ct->{attributes});
 397         $buf .= ' ' . _esc($eml->header_raw('Content-ID'));
 398         $buf .= ' ' . _esc($eml->header_raw('Content-Description'));
 399         my $cte = $eml->header_raw('Content-Transfer-Encoding') // '7bit';
 400         $buf .= ' ' . _esc($cte);
 401         $buf .= ' ' . $eml->{imap_body_len};
 402         $buf .= ' '.($eml->body_raw =~ tr/\n/\n/) if lc($ct->{type}) eq 'text';
 403
 404         # for message/(rfc822|global|news), $hold[0] should have envelope
 405         $buf .= ' ' . (@$hold ? join('', @$hold) : 'NIL') if $hold;
 406
 407         if ($structure) {
 408                 $buf .= ' '._esc($eml->header_raw('Content-MD5'));
 409                 $buf .= ' '. body_disposition($eml);
 410                 $buf .= ' '._esc($eml->header_raw('Content-Language'));
 411                 $buf .= ' '._esc($eml->header_raw('Content-Location'));
 412         }
 413         $buf .= ')';
 414 }
 415
 416 sub body_parent ($$$) {
 417         my ($eml, $structure, $hold) = @_;
 418         my $ct = $eml->ct;
 419         my $type = lc($ct->{type});
 420         if ($type eq 'multipart') {
 421                 my $buf = '(';
 422                 $buf .= @$hold ? join('', @$hold) : 'NIL';
 423                 $buf .= ' '._esc($ct->{subtype});
 424                 if ($structure) {
 425                         $buf .= ' '._esc_hash(delete $ct->{attributes});
 426                         $buf .= ' '.body_disposition($eml);
 427                         $buf .= ' '._esc($eml->header_raw('Content-Language'));
 428                         $buf .= ' '._esc($eml->header_raw('Content-Location'));
 429                 }
 430                 $buf .= ')';
 431                 @$hold = ($buf);
 432         } else { # message/(rfc822|global|news)
 433                 @$hold = (body_leaf($eml, $structure, $hold));
 434         }
 435 }
 436
 437 # this is gross, but we need to process the parent part AFTER
 438 # the child parts are done
 439 sub bodystructure_prep {
 440         my ($p, $q) = @_;
 441         my ($eml, $depth) = @$p; # ignore idx
 442         # set length here, as $eml->{bdy} gets deleted for message/rfc822
 443         $eml->{imap_body_len} = length($eml->body_raw);
 444         push @$q, $eml, $depth;
 445 }
 446
 447 # for FETCH BODY and FETCH BODYSTRUCTURE
 448 sub fetch_body ($;$) {
 449         my ($eml, $structure) = @_;
 450         my @q;
 451         $eml->each_part(\&bodystructure_prep, \@q, 0, 1);
 452         my $cur_depth = 0;
 453         my @hold;
 454         do {
 455                 my ($part, $depth) = splice(@q, -2);
 456                 my $is_mp_parent = $depth == ($cur_depth - 1);
 457                 $cur_depth = $depth;
 458
 459                 if ($is_mp_parent) {
 460                         body_parent($part, $structure, \@hold);
 461                 } else {
 462                         unshift @hold, body_leaf($part, $structure);
 463                 }
 464         } while (@q);
 465         join('', @hold);
 466 }
 467
 468 sub requeue_once ($) {
 469         my ($self) = @_;
 470         # COMPRESS users all share the same DEFLATE context.
 471         # Flush it here to ensure clients don't see
 472         # each other's data
 473         $self->zflush;
 474
 475         # no recursion, schedule another call ASAP,
 476         # but only after all pending writes are done.
 477         # autovivify wbuf:
 478         my $new_size = push(@{$self->{wbuf}}, \&long_step);
 479
 480         # wbuf may be populated by $cb, no need to rearm if so:
 481         $self->requeue if $new_size == 1;
 482 }
 483
 484 # my ($msn, $UID) = @_;
 485 sub fetch_msn_uid ($$) { '* '.(${$_[0]}++).' FETCH (UID '.$_[1] }
 486
 487 sub fetch_run_ops {
 488         my ($self, $msn, $smsg, $bref, $ops, $partial) = @_;
 489         $self->msg_more(fetch_msn_uid($msn, $smsg->{num}));
 490         my ($eml, $k);
 491         for (my $i = 0; $i < @$ops;) {
 492                 $k = $ops->[$i++];
 493                 $ops->[$i++]->($self, $k, $smsg, $bref, $eml);
 494         }
 495         partial_emit($self, $partial, $eml) if $partial;
 496         $self->msg_more(")\r\n");
 497 }
 498
 499 sub fetch_blob_cb { # called by git->cat_async via git_async_cat
 500         my ($bref, $oid, $type, $size, $fetch_arg) = @_;
 501         my ($self, undef, $msgs, $range_info, $ops, $partial) = @$fetch_arg;
 502         my $smsg = shift @$msgs or die 'BUG: no smsg';
 503         if (!defined($oid)) {
 504                 # it's possible to have TOCTOU if an admin runs
 505                 # public-inbox-(edit|purge), just move onto the next message
 506                 return requeue_once($self);
 507         } else {
 508                 $smsg->{blob} eq $oid or die "BUG: $smsg->{blob} != $oid";
 509         }
 510         fetch_run_ops($self, $range_info->[3], $smsg, $bref, $ops, $partial);
 511         requeue_once($self);
 512 }
 513
 514 sub emit_rfc822 {
 515         my ($self, $k, undef, $bref) = @_;
 516         $self->msg_more(" $k {" . length($$bref)."}\r\n");
 517         $self->msg_more($$bref);
 518 }
 519
 520 # Mail::IMAPClient::message_string cares about this by default,
 521 # (->Ignoresizeerrors attribute).  Admins are encouraged to
 522 # --reindex for IMAP support, anyways.
 523 sub emit_rfc822_size {
 524         my ($self, $k, $smsg) = @_;
 525         $self->msg_more(' RFC822.SIZE ' . $smsg->{bytes});
 526 }
 527
 528 sub emit_internaldate {
 529         my ($self, undef, $smsg) = @_;
 530         $self->msg_more(' INTERNALDATE "'.$smsg->internaldate.'"');
 531 }
 532
 533 sub emit_flags { $_[0]->msg_more(' FLAGS ()') }
 534
 535 sub emit_envelope {
 536         my ($self, undef, undef, undef, $eml) = @_;
 537         $self->msg_more(' ENVELOPE '.eml_envelope($eml));
 538 }
 539
 540 sub emit_rfc822_header {
 541         my ($self, $k, undef, undef, $eml) = @_;
 542         $self->msg_more(" $k {".length(${$eml->{hdr}})."}\r\n");
 543         $self->msg_more(${$eml->{hdr}});
 544 }
 545
 546 # n.b. this is sorted to be after any emit_eml_new ops
 547 sub emit_rfc822_text {
 548         my ($self, $k, undef, $bref) = @_;
 549         $self->msg_more(" $k {".length($$bref)."}\r\n");
 550         $self->msg_more($$bref);
 551 }
 552
 553 sub emit_bodystructure {
 554         my ($self, undef, undef, undef, $eml) = @_;
 555         $self->msg_more(' BODYSTRUCTURE '.fetch_body($eml, 1));
 556 }
 557
 558 sub emit_body {
 559         my ($self, undef, undef, undef, $eml) = @_;
 560         $self->msg_more(' BODY '.fetch_body($eml));
 561 }
 562
 563 # set $eml once ($_[4] == $eml, $_[3] == $bref)
 564 sub op_eml_new { $_[4] = PublicInbox::Eml->new($_[3]) }
 565
 566 # s/From / fixes old bug from import (pre-a0c07cba0e5d8b6a)
 567 sub to_crlf_full {
 568         ${$_[0]} =~ s/(?<!\r)\n/\r\n/sg;
 569         ${$_[0]} =~ s/\A[\r\n]*From [^\r\n]*\r\n//s;
 570 }
 571
 572 sub op_crlf_bref { to_crlf_full($_[3]) }
 573
 574 sub op_crlf_hdr { to_crlf_full($_[4]->{hdr}) }
 575
 576 sub op_crlf_bdy { ${$_[4]->{bdy}} =~ s/(?<!\r)\n/\r\n/sg if $_[4]->{bdy} }
 577
 578 sub uid_clamp ($$$) {
 579         my ($self, $beg, $end) = @_;
 580         my $uid_min = $self->{uid_base} + 1;
 581         my $uid_end = $uid_min + UID_BLOCK - 1;
 582         $$beg = $uid_min if $$beg < $uid_min;
 583         $$end = $uid_end if $$end > $uid_end;
 584 }
 585
 586 sub range_step ($$) {
 587         my ($self, $range_csv) = @_;
 588         my ($beg, $end, $range);
 589         if ($$range_csv =~ s/\A([^,]+),//) {
 590                 $range = $1;
 591         } else {
 592                 $range = $$range_csv;
 593                 $$range_csv = undef;
 594         }
 595         if ($range =~ /\A([0-9]+):([0-9]+)\z/) {
 596                 ($beg, $end) = ($1 + 0, $2 + 0);
 597         } elsif ($range =~ /\A([0-9]+):\*\z/) {
 598                 $beg = $1 + 0;
 599                 $end = $self->{ibx}->over->max;
 600                 my $uid_end = $self->{uid_base} + UID_BLOCK;
 601                 $end = $uid_end if $end > $uid_end;
 602                 $beg = $end if $beg > $end;
 603         } elsif ($range =~ /\A[0-9]+\z/) {
 604                 $beg = $end = $range + 0;
 605                 undef $range;
 606         } else {
 607                 return 'BAD fetch range';
 608         }
 609         uid_clamp($self, \$beg, \$end) if defined($range);
 610         my $msn = $beg - $self->{uid_base};
 611         [ $beg, $end, $$range_csv, \$msn ];
 612 }
 613
 614 sub refill_range ($$$) {
 615         my ($self, $msgs, $range_info) = @_;
 616         my ($beg, $end, $range_csv) = @$range_info;
 617         if (scalar(@$msgs = @{$self->{ibx}->over->query_xover($beg, $end)})) {
 618                 $range_info->[0] = $msgs->[-1]->{num} + 1;
 619                 return;
 620         }
 621         return 'OK Fetch done' if !$range_csv;
 622         my $next_range = range_step($self, \$range_csv);
 623         return $next_range if !ref($next_range); # error
 624         @$range_info = @$next_range;
 625         undef; # keep looping
 626 }
 627
 628 sub fetch_blob { # long_response
 629         my ($self, $tag, $msgs, $range_info, $ops, $partial) = @_;
 630         while (!@$msgs) { # rare
 631                 if (my $end = refill_range($self, $msgs, $range_info)) {
 632                         $self->write(\"$tag $end\r\n");
 633                         return;
 634                 }
 635         }
 636         git_async_cat($self->{ibx}->git, $msgs->[0]->{blob},
 637                         \&fetch_blob_cb, \@_);
 638 }
 639
 640 sub fetch_smsg { # long_response
 641         my ($self, $tag, $msgs, $range_info, $ops) = @_;
 642         while (!@$msgs) { # rare
 643                 if (my $end = refill_range($self, $msgs, $range_info)) {
 644                         $self->write(\"$tag $end\r\n");
 645                         return;
 646                 }
 647         }
 648         fetch_run_ops($self, $range_info->[3], $_, undef, $ops) for @$msgs;
 649         @$msgs = ();
 650         1; # more
 651 }
 652
 653 sub refill_uids ($$$;$) {
 654         my ($self, $uids, $range_info, $sql) = @_;
 655         my ($beg, $end, $range_csv) = @$range_info;
 656         my $over = $self->{ibx}->over;
 657         while (1) {
 658                 if (scalar(@$uids = @{$over->uid_range($beg, $end, $sql)})) {
 659                         $range_info->[0] = $uids->[-1] + 1; # update $beg
 660                         return;
 661                 } elsif (!$range_csv) {
 662                         return 0;
 663                 } else {
 664                         my $next_range = range_step($self, \$range_csv);
 665                         return $next_range if !ref($next_range); # error
 666                         ($beg, $end, $range_csv) = @$range_info = @$next_range;
 667                         # continue looping
 668                 }
 669         }
 670 }
 671
 672 sub fetch_uid { # long_response
 673         my ($self, $tag, $uids, $range_info, $ops) = @_;
 674         if (defined(my $err = refill_uids($self, $uids, $range_info))) {
 675                 $err ||= 'OK Fetch done';
 676                 $self->write("$tag $err\r\n");
 677                 return;
 678         }
 679         my ($i, $k);
 680         my $msn = $range_info->[3];
 681         for (@$uids) {
 682                 $self->msg_more(fetch_msn_uid($msn, $_));
 683                 for ($i = 0; $i < @$ops;) {
 684                         $k = $ops->[$i++];
 685                         $ops->[$i++]->($self, $k);
 686                 }
 687                 $self->msg_more(")\r\n");
 688         }
 689         @$uids = ();
 690         1; # more
 691 }
 692
 693 sub cmd_status ($$$;@) {
 694         my ($self, $tag, $mailbox, @items) = @_;
 695         return "$tag BAD no items\r\n" if !scalar(@items);
 696         ($items[0] !~ s/\A\(//s || $items[-1] !~ s/\)\z//s) and
 697                 return "$tag BAD invalid args\r\n";
 698         my ($ibx, $exists, $uidnext) = inbox_lookup($self, $mailbox);
 699         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 700         my @it;
 701         for my $it (@items) {
 702                 $it = uc($it);
 703                 push @it, $it;
 704                 if ($it =~ /\A(?:MESSAGES|UNSEEN|RECENT)\z/) {
 705                         push @it, $exists;
 706                 } elsif ($it eq 'UIDNEXT') {
 707                         push @it, $uidnext;
 708                 } elsif ($it eq 'UIDVALIDITY') {
 709                         push @it, $ibx->{uidvalidity};
 710                 } else {
 711                         return "$tag BAD invalid item\r\n";
 712                 }
 713         }
 714         return "$tag BAD no items\r\n" if !@it;
 715         "* STATUS $mailbox (".join(' ', @it).")\r\n" .
 716         "$tag OK Status done\r\n";
 717 }
 718
 719 my %patmap = ('*' => '.*', '%' => '[^\.]*');
 720 sub cmd_list ($$$$) {
 721         my ($self, $tag, $refname, $wildcard) = @_;
 722         my $l = $self->{imapd}->{inboxlist};
 723         if ($refname eq '' && $wildcard eq '') {
 724                 # request for hierarchy delimiter
 725                 $l = [ qq[* LIST (\\Noselect) "." ""\r\n] ];
 726         } elsif ($refname ne '' || $wildcard ne '*') {
 727                 $wildcard =~ s!([^a-z0-9_])!$patmap{$1} // "\Q$1"!egi;
 728                 $l = [ grep(/ \Q$refname\E$wildcard\r\n\z/is, @$l) ];
 729         }
 730         \(join('', @$l, "$tag OK List done\r\n"));
 731 }
 732
 733 sub cmd_lsub ($$$$) {
 734         my (undef, $tag) = @_; # same args as cmd_list
 735         "$tag OK Lsub done\r\n";
 736 }
 737
 738 sub eml_index_offs_i { # PublicInbox::Eml::each_part callback
 739         my ($p, $all) = @_;
 740         my ($eml, undef, $idx) = @$p;
 741         if ($idx && lc($eml->ct->{type}) eq 'multipart') {
 742                 $eml->{imap_bdy} = $eml->{bdy} // \'';
 743         }
 744         $all->{$idx} = $eml; # $idx => Eml
 745 }
 746
 747 # prepares an index for BODY[$SECTION_IDX] fetches
 748 sub eml_body_idx ($$) {
 749         my ($eml, $section_idx) = @_;
 750         my $idx = $eml->{imap_all_parts} //= do {
 751                 my $all = {};
 752                 $eml->each_part(\&eml_index_offs_i, $all, 0, 1);
 753                 # top-level of multipart, BODY[0] not allowed (nz-number)
 754                 delete $all->{0};
 755                 $all;
 756         };
 757         $idx->{$section_idx};
 758 }
 759
 760 # BODY[($SECTION_IDX)?(.$SECTION_NAME)?]<$offset.$bytes>
 761 sub partial_body {
 762         my ($eml, $section_idx, $section_name) = @_;
 763         if (defined $section_idx) {
 764                 $eml = eml_body_idx($eml, $section_idx) or return;
 765         }
 766         if (defined $section_name) {
 767                 if ($section_name eq 'MIME') {
 768                         # RFC 3501 6.4.5 states:
 769                         #       The MIME part specifier MUST be prefixed
 770                         #       by one or more numeric part specifiers
 771                         return unless defined $section_idx;
 772                         return $eml->header_obj->as_string . "\r\n";
 773                 }
 774                 my $bdy = $eml->{bdy} // $eml->{imap_bdy} // \'';
 775                 $eml = PublicInbox::Eml->new($$bdy);
 776                 if ($section_name eq 'TEXT') {
 777                         return $eml->body_raw;
 778                 } elsif ($section_name eq 'HEADER') {
 779                         return $eml->header_obj->as_string . "\r\n";
 780                 } else {
 781                         die "BUG: bad section_name=$section_name";
 782                 }
 783         }
 784         ${$eml->{bdy} // $eml->{imap_bdy} // \''};
 785 }
 786
 787 # similar to what's in PublicInbox::Eml::re_memo, but doesn't memoize
 788 # to avoid OOM with malicious users
 789 sub hdrs_regexp ($) {
 790         my ($hdrs) = @_;
 791         my $names = join('|', map { "\Q$_" } split(/[ \t]+/, $hdrs));
 792         qr/^(?:$names):[ \t]*[^\n]*\r?\n # 1st line
 793                 # continuation lines:
 794                 (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*
 795                 /ismx;
 796 }
 797
 798 # BODY[($SECTION_IDX.)?HEADER.FIELDS.NOT ($HDRS)]<$offset.$bytes>
 799 sub partial_hdr_not {
 800         my ($eml, $section_idx, $hdrs_re) = @_;
 801         if (defined $section_idx) {
 802                 $eml = eml_body_idx($eml, $section_idx) or return;
 803         }
 804         my $str = $eml->header_obj->as_string;
 805         $str =~ s/$hdrs_re//g;
 806         $str =~ s/(?<!\r)\n/\r\n/sg;
 807         $str .= "\r\n";
 808 }
 809
 810 # BODY[($SECTION_IDX.)?HEADER.FIELDS ($HDRS)]<$offset.$bytes>
 811 sub partial_hdr_get {
 812         my ($eml, $section_idx, $hdrs_re) = @_;
 813         if (defined $section_idx) {
 814                 $eml = eml_body_idx($eml, $section_idx) or return;
 815         }
 816         my $str = $eml->header_obj->as_string;
 817         $str = join('', ($str =~ m/($hdrs_re)/g));
 818         $str =~ s/(?<!\r)\n/\r\n/sg;
 819         $str .= "\r\n";
 820 }
 821
 822 sub partial_prepare ($$$$) {
 823         my ($need, $partial, $want, $att) = @_;
 824
 825         # recombine [ "BODY[1.HEADER.FIELDS", "(foo", "bar)]" ]
 826         # back to: "BODY[1.HEADER.FIELDS (foo bar)]"
 827         return unless $att =~ /\ABODY\[/s;
 828         until (rindex($att, ']') >= 0) {
 829                 my $next = shift @$want or return;
 830                 $att .= ' ' . uc($next);
 831         }
 832         if ($att =~ /\ABODY\[([0-9]+(?:\.[0-9]+)*)? # 1 - section_idx
 833                         (?:\.(HEADER|MIME|TEXT))? # 2 - section_name
 834                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 3, 4
 835                 $partial->{$att} = [ \&partial_body, $1, $2, $3, $4 ];
 836                 $$need |= CRLF_BREF|EML_HDR|EML_BDY;
 837         } elsif ($att =~ /\ABODY\[(?:([0-9]+(?:\.[0-9]+)*)\.)? # 1 - section_idx
 838                                 (?:HEADER\.FIELDS(\.NOT)?)\x20 # 2
 839                                 \(([A-Z0-9\-\x20]+)\) # 3 - hdrs
 840                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 4 5
 841                 my $tmp = $partial->{$att} = [ $2 ? \&partial_hdr_not
 842                                                 : \&partial_hdr_get,
 843                                                 $1, undef, $4, $5 ];
 844                 $tmp->[2] = hdrs_regexp($3);
 845
 846                 # don't emit CRLF_HDR instruction, here, partial_hdr_*
 847                 # will do CRLF conversion with only the extracted result
 848                 # and not waste time converting lines we don't care about.
 849                 $$need |= EML_HDR;
 850         } else {
 851                 undef;
 852         }
 853 }
 854
 855 sub partial_emit ($$$) {
 856         my ($self, $partial, $eml) = @_;
 857         for (@$partial) {
 858                 my ($k, $cb, @args) = @$_;
 859                 my ($offset, $len) = splice(@args, -2);
 860                 # $cb is partial_body|partial_hdr_get|partial_hdr_not
 861                 my $str = $cb->($eml, @args) // '';
 862                 if (defined $offset) {
 863                         if (defined $len) {
 864                                 $str = substr($str, $offset, $len);
 865                                 $k =~ s/\.$len>\z/>/ or warn
 866 "BUG: unable to remove `.$len>' from `$k'";
 867                         } else {
 868                                 $str = substr($str, $offset);
 869                                 $len = length($str);
 870                         }
 871                 } else {
 872                         $len = length($str);
 873                 }
 874                 $self->msg_more(" $k {$len}\r\n");
 875                 $self->msg_more($str);
 876         }
 877 }
 878
 879 sub fetch_compile ($) {
 880         my ($want) = @_;
 881         if ($want->[0] =~ s/\A\(//s) {
 882                 $want->[-1] =~ s/\)\z//s or return 'BAD no rparen';
 883         }
 884         my (%partial, %seen, @op);
 885         my $need = 0;
 886         while (defined(my $att = shift @$want)) {
 887                 $att = uc($att);
 888                 next if $att eq 'UID'; # always returned
 889                 $att =~ s/\ABODY\.PEEK\[/BODY\[/; # we're read-only
 890                 my $x = $FETCH_ATT{$att};
 891                 if ($x) {
 892                         while (my ($k, $fl_cb) = each %$x) {
 893                                 next if $seen{$k}++;
 894                                 $need |= $fl_cb->[0];
 895                                 push @op, [ @$fl_cb, $k ];
 896                         }
 897                 } elsif (!partial_prepare(\$need, \%partial, $want, $att)) {
 898                         return "BAD param: $att";
 899                 }
 900         }
 901         my @r;
 902
 903         # stabilize partial order for consistency and ease-of-debugging:
 904         if (scalar keys %partial) {
 905                 $need |= NEED_BLOB;
 906                 $r[2] = [ map { [ $_, @{$partial{$_}} ] } sort keys %partial ];
 907         }
 908
 909         push @op, $OP_EML_NEW if ($need & (EML_HDR|EML_BDY));
 910
 911         # do we need CRLF conversion?
 912         if ($need & CRLF_BREF) {
 913                 push @op, $OP_CRLF_BREF;
 914         } elsif (my $crlf = ($need & (CRLF_HDR|CRLF_BDY))) {
 915                 if ($crlf == (CRLF_HDR|CRLF_BDY)) {
 916                         push @op, $OP_CRLF_BREF;
 917                 } elsif ($need & CRLF_HDR) {
 918                         push @op, $OP_CRLF_HDR;
 919                 } else {
 920                         push @op, $OP_CRLF_BDY;
 921                 }
 922         }
 923
 924         $r[0] = $need & NEED_BLOB ? \&fetch_blob :
 925                 ($need & NEED_SMSG ? \&fetch_smsg : \&fetch_uid);
 926
 927         # r[1] = [ $key1, $cb1, $key2, $cb2, ... ]
 928         use sort 'stable'; # makes output more consistent
 929         $r[1] = [ map { ($_->[2], $_->[1]) } sort { $a->[0] <=> $b->[0] } @op ];
 930         @r;
 931 }
 932
 933 sub cmd_uid_fetch ($$$$;@) {
 934         my ($self, $tag, $range_csv, @want) = @_;
 935         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 936         my ($cb, $ops, $partial) = fetch_compile(\@want);
 937         return "$tag $cb\r\n" unless $ops;
 938
 939         $range_csv = 'bad' if $range_csv !~ $valid_range;
 940         my $range_info = range_step($self, \$range_csv);
 941         return "$tag $range_info\r\n" if !ref($range_info);
 942         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 943 }
 944
 945 sub msn_to_uid_range ($$) {
 946         my $uid_base = $_[0]->{uid_base};
 947         $_[1] =~ s/([0-9]+)/$uid_base + $1/sge;
 948 }
 949
 950 sub cmd_fetch ($$$$;@) {
 951         my ($self, $tag, $range_csv, @want) = @_;
 952         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 953         my ($cb, $ops, $partial) = fetch_compile(\@want);
 954         return "$tag $cb\r\n" unless $ops;
 955
 956         # cb is one of fetch_blob, fetch_smsg, fetch_uid
 957         $range_csv = 'bad' if $range_csv !~ $valid_range;
 958         msn_to_uid_range($self, $range_csv);
 959         my $range_info = range_step($self, \$range_csv);
 960         return "$tag $range_info\r\n" if !ref($range_info);
 961         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 962 }
 963
 964 sub parse_date ($) { # 02-Oct-1993
 965         my ($date_text) = @_;
 966         my ($dd, $mon, $yyyy) = split(/-/, $_[0], 3);
 967         defined($yyyy) or return;
 968         my $mm = $MoY{$mon} // return;
 969         $dd =~ /\A[0123]?[0-9]\z/ or return;
 970         $yyyy =~ /\A[0-9]{4,}\z/ or return; # Y10K-compatible!
 971         timegm(0, 0, 0, $dd, $mm, $yyyy);
 972 }
 973
 974 sub uid_search_uid_range { # long_response
 975         my ($self, $tag, $uids, $sql, $range_info) = @_;
 976         if (defined(my $err = refill_uids($self, $uids, $range_info, $sql))) {
 977                 $err ||= 'OK Search done';
 978                 $self->write("\r\n$tag $err\r\n");
 979                 return;
 980         }
 981         $self->msg_more(join(' ', '', @$uids));
 982         @$uids = ();
 983         1; # more
 984 }
 985
 986 sub date_search {
 987         my ($q, $k, $d) = @_;
 988         my $sql = $q->{sql};
 989
 990         # Date: header
 991         if ($k eq 'SENTON') {
 992                 my $end = $d + 86399; # no leap day...
 993                 my $da = strftime('%Y%m%d%H%M%S', gmtime($d));
 994                 my $db = strftime('%Y%m%d%H%M%S', gmtime($end));
 995                 $q->{xap} .= " dt:$da..$db";
 996                 $$sql .= " AND ds >= $d AND ds <= $end" if defined($sql);
 997         } elsif ($k eq 'SENTBEFORE') {
 998                 $q->{xap} .= ' d:..'.strftime('%Y%m%d', gmtime($d));
 999                 $$sql .= " AND ds <= $d" if defined($sql);
1000         } elsif ($k eq 'SENTSINCE') {
1001                 $q->{xap} .= ' d:'.strftime('%Y%m%d', gmtime($d)).'..';
1002                 $$sql .= " AND ds >= $d" if defined($sql);
1003
1004         # INTERNALDATE (Received)
1005         } elsif ($k eq 'ON') {
1006                 my $end = $d + 86399; # no leap day...
1007                 $q->{xap} .= " ts:$d..$end";
1008                 $$sql .= " AND ts >= $d AND ts <= $end" if defined($sql);
1009         } elsif ($k eq 'BEFORE') {
1010                 $q->{xap} .= " ts:..$d";
1011                 $$sql .= " AND ts <= $d" if defined($sql);
1012         } elsif ($k eq 'SINCE') {
1013                 $q->{xap} .= " ts:$d..";
1014                 $$sql .= " AND ts >= $d" if defined($sql);
1015         } else {
1016                 die "BUG: $k not recognized";
1017         }
1018 }
1019
1020 # IMAP to Xapian search key mapping
1021 my %I2X = (
1022         SUBJECT => 's:',
1023         BODY => 'b:',
1024         FROM => 'f:',
1025         TEXT => '', # n.b. does not include all headers
1026         TO => 't:',
1027         CC => 'c:',
1028         # BCC => 'bcc:', # TODO
1029         # KEYWORD # TODO ? dfpre,dfpost,...
1030 );
1031
1032 sub parse_query {
1033         my ($self, $rest) = @_;
1034         if (uc($rest->[0]) eq 'CHARSET') {
1035                 shift @$rest;
1036                 defined(my $c = shift @$rest) or return 'BAD missing charset';
1037                 $c =~ /\A(?:UTF-8|US-ASCII)\z/ or return 'NO [BADCHARSET]';
1038         }
1039
1040         my $sql = ''; # date conditions, {sql} deleted if Xapian is needed
1041         my $q = { xap => '', sql => \$sql };
1042         while (@$rest) {
1043                 my $k = uc(shift @$rest);
1044                 # default criteria
1045                 next if $k =~ /\A(?:ALL|RECENT|UNSEEN|NEW)\z/;
1046                 next if $k eq 'AND'; # the default, until we support OR
1047                 if ($k =~ $valid_range) { # convert sequence numbers to UIDs
1048                         msn_to_uid_range($self, $k);
1049                         push @{$q->{uid}}, $k;
1050                 } elsif ($k eq 'UID') {
1051                         $k = shift(@$rest) // '';
1052                         $k =~ $valid_range or return 'BAD UID range';
1053                         push @{$q->{uid}}, $k;
1054                 } elsif ($k =~ /\A(?:SENT)?(?:SINCE|ON|BEFORE)\z/) {
1055                         my $d = parse_date(shift(@$rest) // '');
1056                         defined $d or return "BAD $k date format";
1057                         date_search($q, $k, $d);
1058                 } elsif ($k =~ /\A(?:SMALLER|LARGER)\z/) {
1059                         delete $q->{sql}; # can't use over.sqlite3
1060                         my $bytes = shift(@$rest) // '';
1061                         $bytes =~ /\A[0-9]+\z/ or return "BAD $k not a number";
1062                         $q->{xap} .= ' bytes:' . ($k eq 'SMALLER' ?
1063                                                         '..'.(--$bytes) :
1064                                                         (++$bytes).'..');
1065                 } elsif (defined(my $xk = $I2X{$k})) {
1066                         delete $q->{sql}; # can't use over.sqlite3
1067                         my $arg = shift @$rest;
1068                         defined($arg) or return "BAD $k no arg";
1069
1070                         # Xapian can't handle [*"] in probabilistic terms
1071                         $arg =~ tr/*"//d;
1072                         $q->{xap} .= qq[ $xk:"$arg"];
1073                 } else {
1074                         # TODO: parentheses, OR, NOT ...
1075                         return "BAD $k not supported (yet?)";
1076                 }
1077         }
1078
1079         # favor using over.sqlite3 if possible, since Xapian is optional
1080         if (exists $q->{sql}) {
1081                 delete($q->{xap});
1082                 delete($q->{sql}) if $sql eq '';
1083         } elsif (!$self->{ibx}->search) {
1084                 return 'BAD Xapian not configured for mailbox';
1085         }
1086
1087         if (my $uid = delete $q->{uid}) {
1088                 $q->{uid} = join(',', @$uid);
1089         }
1090         $q;
1091 }
1092
1093 sub cmd_uid_search ($$$;) {
1094         my ($self, $tag) = splice(@_, 0, 2);
1095         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
1096         my $q = parse_query($self, \@_);
1097         return "$tag $q\r\n" if !ref($q);
1098         my $sql = delete $q->{sql};
1099         my $range_csv = delete $q->{uid} // '1:*';
1100         my $range_info = range_step($self, \$range_csv);
1101         return "$tag $range_info\r\n" if !ref($range_info);
1102         if (!scalar(keys %$q)) {
1103                 $self->msg_more('* SEARCH');
1104                 long_response($self, \&uid_search_uid_range,
1105                                 $tag, [], $sql, $range_info);
1106         } else {
1107                 "$tag BAD Error\r\n";
1108         }
1109 }
1110
1111 sub args_ok ($$) { # duplicated from PublicInbox::NNTP
1112         my ($cb, $argc) = @_;
1113         my $tot = prototype $cb;
1114         my ($nreq, undef) = split(';', $tot);
1115         $nreq = ($nreq =~ tr/$//) - 1;
1116         $tot = ($tot =~ tr/$//) - 1;
1117         ($argc <= $tot && $argc >= $nreq);
1118 }
1119
1120 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
1121 sub process_line ($$) {
1122         my ($self, $l) = @_;
1123         my ($tag, $req, @args) = parse_line('[ \t]+', 0, $l);
1124         pop(@args) if (@args && !defined($args[-1]));
1125         if (@args && uc($req) eq 'UID') {
1126                 $req .= "_".(shift @args);
1127         }
1128         my $res = eval {
1129                 if (my $cmd = $self->can('cmd_'.lc($req // ''))) {
1130                         defined($self->{-idle_tag}) ?
1131                                 "$self->{-idle_tag} BAD expected DONE\r\n" :
1132                                 $cmd->($self, $tag, @args);
1133                 } elsif (uc($tag // '') eq 'DONE' && !defined($req)) {
1134                         cmd_done($self, $tag);
1135                 } else { # this is weird
1136                         auth_challenge_ok($self) //
1137                                         ($tag // '*') .
1138                                         ' BAD Error in IMAP command '.
1139                                         ($req // '(???)').
1140                                         ": Unknown command\r\n";
1141                 }
1142         };
1143         my $err = $@;
1144         if ($err && $self->{sock}) {
1145                 $l =~ s/\r?\n//s;
1146                 err($self, 'error from: %s (%s)', $l, $err);
1147                 $tag //= '*';
1148                 $res = "$tag BAD program fault - command not performed\r\n";
1149         }
1150         return 0 unless defined $res;
1151         $self->write($res);
1152 }
1153
1154 sub long_step {
1155         my ($self) = @_;
1156         # wbuf is unset or empty, here; {long} may add to it
1157         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
1158         my $more = eval { $cb->($self, @args) };
1159         if ($@ || !$self->{sock}) { # something bad happened...
1160                 delete $self->{long_cb};
1161                 my $elapsed = now() - $t0;
1162                 if ($@) {
1163                         err($self,
1164                             "%s during long response[$fd] - %0.6f",
1165                             $@, $elapsed);
1166                 }
1167                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
1168                 $self->close;
1169         } elsif ($more) { # $self->{wbuf}:
1170                 $self->update_idle_time;
1171
1172                 # control passed to $more may be a GitAsyncCat object
1173                 requeue_once($self) if !ref($more);
1174         } else { # all done!
1175                 delete $self->{long_cb};
1176                 my $elapsed = now() - $t0;
1177                 my $fd = fileno($self->{sock});
1178                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
1179                 my $wbuf = $self->{wbuf}; # do NOT autovivify
1180
1181                 $self->requeue unless $wbuf && @$wbuf;
1182         }
1183 }
1184
1185 sub err ($$;@) {
1186         my ($self, $fmt, @args) = @_;
1187         printf { $self->{imapd}->{err} } $fmt."\n", @args;
1188 }
1189
1190 sub out ($$;@) {
1191         my ($self, $fmt, @args) = @_;
1192         printf { $self->{imapd}->{out} } $fmt."\n", @args;
1193 }
1194
1195 sub long_response ($$;@) {
1196         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
1197
1198         my $sock = $self->{sock} or return;
1199         # make sure we disable reading during a long response,
1200         # clients should not be sending us stuff and making us do more
1201         # work while we are stream a response to them
1202         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
1203         long_step($self); # kick off!
1204         undef;
1205 }
1206
1207 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1208 sub event_step {
1209         my ($self) = @_;
1210
1211         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1212
1213         $self->update_idle_time;
1214         # only read more requests if we've drained the write buffer,
1215         # otherwise we can be buffering infinitely w/o backpressure
1216
1217         my $rbuf = $self->{rbuf} // \(my $x = '');
1218         my $line = index($$rbuf, "\n");
1219         while ($line < 0) {
1220                 if (length($$rbuf) >= LINE_MAX) {
1221                         $self->write(\"\* BAD request too long\r\n");
1222                         return $self->close;
1223                 }
1224                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1225                 $line = index($$rbuf, "\n");
1226         }
1227         $line = substr($$rbuf, 0, $line + 1, '');
1228         $line =~ s/\r?\n\z//s;
1229         return $self->close if $line =~ /[[:cntrl:]]/s;
1230         my $t0 = now();
1231         my $fd = fileno($self->{sock});
1232         my $r = eval { process_line($self, $line) };
1233         my $pending = $self->{wbuf} ? ' pending' : '';
1234         out($self, "[$fd] %s - %0.6f$pending - $r", $line, now() - $t0);
1235
1236         return $self->close if $r < 0;
1237         $self->rbuf_idle($rbuf);
1238         $self->update_idle_time;
1239
1240         # maybe there's more pipelined data, or we'll have
1241         # to register it for socket-readiness notifications
1242         $self->requeue unless $pending;
1243 }
1244
1245 sub compressed { undef }
1246
1247 sub zflush {} # overridden by IMAPdeflate
1248
1249 # RFC 4978
1250 sub cmd_compress ($$$) {
1251         my ($self, $tag, $alg) = @_;
1252         return "$tag BAD DEFLATE only\r\n" if uc($alg) ne "DEFLATE";
1253         return "$tag BAD COMPRESS active\r\n" if $self->compressed;
1254
1255         # CRIME made TLS compression obsolete
1256         # return "$tag NO [COMPRESSIONACTIVE]\r\n" if $self->tls_compressed;
1257
1258         PublicInbox::IMAPdeflate->enable($self, $tag);
1259         $self->requeue;
1260         undef
1261 }
1262
1263 sub cmd_starttls ($$) {
1264         my ($self, $tag) = @_;
1265         my $sock = $self->{sock} or return;
1266         if ($sock->can('stop_SSL') || $self->compressed) {
1267                 return "$tag BAD TLS or compression already enabled\r\n";
1268         }
1269         my $opt = $self->{imapd}->{accept_tls} or
1270                 return "$tag BAD can not initiate TLS negotiation\r\n";
1271         $self->write(\"$tag OK begin TLS negotiation now\r\n");
1272         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
1273         $self->requeue if PublicInbox::DS::accept_tls_step($self);
1274         undef;
1275 }
1276
1277 # for graceful shutdown in PublicInbox::Daemon:
1278 sub busy {
1279         my ($self, $now) = @_;
1280         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1281 }
1282
1283 sub close {
1284         my ($self) = @_;
1285         if (my $ibx = delete $self->{ibx}) {
1286                 stop_idle($self, $ibx);
1287         }
1288         $self->SUPER::close; # PublicInbox::DS::close
1289 }
1290
1291 # we're read-only, so SELECT and EXAMINE do the same thing
1292 no warnings 'once';
1293 *cmd_select = \&cmd_examine;
1294
1295 package PublicInbox::IMAP_preauth;
1296 our @ISA = qw(PublicInbox::IMAP);
1297
1298 sub logged_in { 0 }
1299
1300 1;