lib/PublicInbox/IMAP.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents an IMAP client connected to
   5 # public-inbox-imapd.  Much of this was taken from NNTP, but
   6 # further refined while experimenting on future ideas to handle
   7 # slow storage.
   8 #
   9 # data notes:
  10 #
  11 # * NNTP article numbers are UIDs, mm->created_at is UIDVALIDITY
  12 #
  13 # * public-inboxes are sliced into mailboxes of 50K messages
  14 #   to not overload MUAs: $NEWSGROUP_NAME.$SLICE_INDEX
  15 #   Slices are similar in concept to v2 "epochs".  Epochs
  16 #   are for the limitations of git clients, while slices are
  17 #   for the limitations of IMAP clients.
  18 #
  19 # * sequence numbers are estimated based on slice
  20
  21 package PublicInbox::IMAP;
  22 use strict;
  23 use base qw(PublicInbox::DS);
  24 use fields qw(imapd ibx long_cb -login_tag
  25         uid_base -idle_tag -idle_max);
  26 use PublicInbox::Eml;
  27 use PublicInbox::EmlContentFoo qw(parse_content_disposition);
  28 use PublicInbox::DS qw(now);
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use PublicInbox::GitAsyncCat;
  31 use Text::ParseWords qw(parse_line);
  32 use Errno qw(EAGAIN);
  33 use Time::Local qw(timegm);
  34 use POSIX qw(strftime);
  35 use Hash::Util qw(unlock_hash); # dependency of fields for perl 5.10+, anyways
  36 use PublicInbox::Search;
  37 *mdocid = \&PublicInbox::Search::mdocid;
  38
  39 my $Address;
  40 for my $mod (qw(Email::Address::XS Mail::Address)) {
  41         eval "require $mod" or next;
  42         $Address = $mod and last;
  43 }
  44 die "neither Email::Address::XS nor Mail::Address loaded: $@" if !$Address;
  45
  46 sub LINE_MAX () { 8000 } # RFC 2683 3.2.1.5
  47
  48 # changing this will cause grief for clients which cache
  49 sub UID_SLICE () { 50_000 }
  50
  51 # these values area also used for sorting
  52 sub NEED_SMSG () { 1 }
  53 sub NEED_BLOB () { NEED_SMSG|2 }
  54 sub CRLF_BREF () { 4 }
  55 sub EML_HDR () { 8 }
  56 sub CRLF_HDR () { 16 }
  57 sub EML_BDY () { 32 }
  58 sub CRLF_BDY () { 64 }
  59 my $OP_EML_NEW = [ EML_HDR - 1, \&op_eml_new ];
  60 my $OP_CRLF_BREF = [ CRLF_BREF, \&op_crlf_bref ];
  61 my $OP_CRLF_HDR = [ CRLF_HDR, \&op_crlf_hdr ];
  62 my $OP_CRLF_BDY = [ CRLF_BDY, \&op_crlf_bdy ];
  63
  64 my %FETCH_NEED = (
  65         'BODY[HEADER]' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  66         'BODY[TEXT]' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  67         'BODY[]' => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  68         'RFC822.HEADER' => [ NEED_BLOB|EML_HDR|CRLF_HDR, \&emit_rfc822_header ],
  69         'RFC822.TEXT' => [ NEED_BLOB|EML_BDY|CRLF_BDY, \&emit_rfc822_text ],
  70         'RFC822.SIZE' => [ NEED_SMSG, \&emit_rfc822_size ],
  71         RFC822 => [ NEED_BLOB|CRLF_BREF, \&emit_rfc822 ],
  72         BODY => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_body ],
  73         BODYSTRUCTURE => [ NEED_BLOB|EML_HDR|EML_BDY, \&emit_bodystructure ],
  74         ENVELOPE => [ NEED_BLOB|EML_HDR, \&emit_envelope ],
  75         FLAGS => [ 0, \&emit_flags ],
  76         INTERNALDATE => [ NEED_SMSG, \&emit_internaldate ],
  77 );
  78 my %FETCH_ATT = map { $_ => [ $_ ] } keys %FETCH_NEED;
  79
  80 # aliases (RFC 3501 section 6.4.5)
  81 $FETCH_ATT{FAST} = [ qw(FLAGS INTERNALDATE RFC822.SIZE) ];
  82 $FETCH_ATT{ALL} = [ @{$FETCH_ATT{FAST}}, 'ENVELOPE' ];
  83 $FETCH_ATT{FULL} = [ @{$FETCH_ATT{ALL}}, 'BODY' ];
  84
  85 for my $att (keys %FETCH_ATT) {
  86         my %h = map { $_ => $FETCH_NEED{$_} } @{$FETCH_ATT{$att}};
  87         $FETCH_ATT{$att} = \%h;
  88 }
  89 undef %FETCH_NEED;
  90
  91 my $valid_range = '[0-9]+|[0-9]+:[0-9]+|[0-9]+:\*';
  92 $valid_range = qr/\A(?:$valid_range)(?:,(?:$valid_range))*\z/;
  93
  94 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  95 my %MoY;
  96 @MoY{@MoY} = (0..11);
  97
  98 # RFC 3501 5.4. Autologout Timer needs to be >= 30min
  99 $PublicInbox::DS::EXPTIME = 60 * 30;
 100
 101 sub greet ($) {
 102         my ($self) = @_;
 103         my $capa = capa($self);
 104         $self->write(\"* OK [$capa] public-inbox-imapd ready\r\n");
 105 }
 106
 107 sub new ($$$) {
 108         my ($class, $sock, $imapd) = @_;
 109         my $self = fields::new('PublicInbox::IMAP_preauth');
 110         unlock_hash(%$self);
 111         my $ev = EPOLLIN;
 112         my $wbuf;
 113         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
 114                 return CORE::close($sock) if $! != EAGAIN;
 115                 $ev = PublicInbox::TLS::epollbit();
 116                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
 117         }
 118         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
 119         $self->{imapd} = $imapd;
 120         if ($wbuf) {
 121                 $self->{wbuf} = $wbuf;
 122         } else {
 123                 greet($self);
 124         }
 125         $self->update_idle_time;
 126         $self;
 127 }
 128
 129 sub logged_in { 1 }
 130
 131 sub capa ($) {
 132         my ($self) = @_;
 133
 134         # dovecot advertises IDLE pre-login; perhaps because some clients
 135         # depend on it, so we'll do the same
 136         my $capa = 'CAPABILITY IMAP4rev1 IDLE';
 137         if ($self->logged_in) {
 138                 $capa .= ' COMPRESS=DEFLATE';
 139         } else {
 140                 if (!($self->{sock} // $self)->can('accept_SSL') &&
 141                         $self->{imapd}->{accept_tls}) {
 142                         $capa .= ' STARTTLS';
 143                 }
 144                 $capa .= ' AUTH=ANONYMOUS';
 145         }
 146 }
 147
 148 sub login_success ($$) {
 149         my ($self, $tag) = @_;
 150         bless $self, 'PublicInbox::IMAP';
 151         my $capa = capa($self);
 152         "$tag OK [$capa] Logged in\r\n";
 153 }
 154
 155 sub auth_challenge_ok ($) {
 156         my ($self) = @_;
 157         my $tag = delete($self->{-login_tag}) or return;
 158         login_success($self, $tag);
 159 }
 160
 161 sub cmd_login ($$$$) {
 162         my ($self, $tag) = @_; # ignore ($user, $password) = ($_[2], $_[3])
 163         login_success($self, $tag);
 164 }
 165
 166 sub cmd_close ($$) {
 167         my ($self, $tag) = @_;
 168         delete $self->{uid_base};
 169         delete $self->{ibx} ? "$tag OK Close done\r\n"
 170                                 : "$tag BAD No mailbox\r\n";
 171 }
 172
 173 sub cmd_logout ($$) {
 174         my ($self, $tag) = @_;
 175         delete $self->{-idle_tag};
 176         $self->write(\"* BYE logging out\r\n$tag OK Logout done\r\n");
 177         $self->shutdn; # PublicInbox::DS::shutdn
 178         undef;
 179 }
 180
 181 sub cmd_authenticate ($$$) {
 182         my ($self, $tag) = @_; # $method = $_[2], should be "ANONYMOUS"
 183         $self->{-login_tag} = $tag;
 184         "+\r\n"; # challenge
 185 }
 186
 187 sub cmd_capability ($$) {
 188         my ($self, $tag) = @_;
 189         '* '.capa($self)."\r\n$tag OK Capability done\r\n";
 190 }
 191
 192 sub cmd_noop ($$) { "$_[1] OK Noop done\r\n" }
 193
 194 # called by PublicInbox::InboxIdle
 195 sub on_inbox_unlock {
 196         my ($self, $ibx) = @_;
 197         my $new = $ibx->over->max;
 198         my $uid_base = $self->{uid_base} // 0;
 199         my $uid_end = $uid_base + UID_SLICE;
 200         defined(my $old = $self->{-idle_max}) or die 'BUG: -idle_max unset';
 201         $new = $uid_end if $new > $uid_end;
 202         if ($new > $old) {
 203                 $self->{-idle_max} = $new;
 204                 $new -= $uid_base;
 205                 $old -= $uid_base;
 206                 $self->msg_more("* $_ EXISTS\r\n") for (($old + 1)..($new - 1));
 207                 $self->write(\"* $new EXISTS\r\n");
 208         } elsif ($new == $uid_end) { # max exceeded $uid_end
 209                 # continue idling w/o inotify
 210                 delete $self->{-idle_max};
 211                 my $sock = $self->{sock} or return;
 212                 $ibx->unsubscribe_unlock(fileno($sock));
 213         }
 214 }
 215
 216 # called every X minute(s) or so by PublicInbox::DS::later
 217 my $IDLERS = {};
 218 my $idle_timer;
 219 sub idle_tick_all {
 220         my $old = $IDLERS;
 221         $IDLERS = {};
 222         for my $i (values %$old) {
 223                 next if ($i->{wbuf} || !exists($i->{-idle_tag}));
 224                 $i->update_idle_time or next;
 225                 $IDLERS->{fileno($i->{sock})} = $i;
 226                 $i->write(\"* OK Still here\r\n");
 227         }
 228         $idle_timer = scalar keys %$IDLERS ?
 229                         PublicInbox::DS::later(\&idle_tick_all) : undef;
 230 }
 231
 232 sub cmd_idle ($$) {
 233         my ($self, $tag) = @_;
 234         # IDLE seems allowed by dovecot w/o a mailbox selected *shrug*
 235         my $ibx = $self->{ibx} or return "$tag BAD no mailbox selected\r\n";
 236         $self->{-idle_tag} = $tag;
 237         my $max = $ibx->over->max;
 238         my $uid_end = $self->{uid_base} + UID_SLICE;
 239         my $sock = $self->{sock} or return;
 240         my $fd = fileno($sock);
 241         # only do inotify on most recent slice
 242         if ($max < $uid_end) {
 243                 $ibx->subscribe_unlock($fd, $self);
 244                 $self->{imapd}->idler_start;
 245                 $self->{-idle_max} = $max;
 246         }
 247         $idle_timer //= PublicInbox::DS::later(\&idle_tick_all);
 248         $IDLERS->{$fd} = $self;
 249         \"+ idling\r\n"
 250 }
 251
 252 sub stop_idle ($$) {
 253         my ($self, $ibx);
 254         my $sock = $self->{sock} or return;
 255         my $fd = fileno($sock);
 256         delete $IDLERS->{$fd};
 257         $ibx->unsubscribe_unlock($fd);
 258 }
 259
 260 sub cmd_done ($$) {
 261         my ($self, $tag) = @_; # $tag is "DONE" (case-insensitive)
 262         defined(my $idle_tag = delete $self->{-idle_tag}) or
 263                 return "$tag BAD not idle\r\n";
 264         my $ibx = $self->{ibx} or do {
 265                 warn "BUG: idle_tag set w/o inbox";
 266                 return "$tag BAD internal bug\r\n";
 267         };
 268         stop_idle($self, $ibx);
 269         "$idle_tag OK Idle done\r\n";
 270 }
 271
 272 sub ensure_slices_exist ($$$) {
 273         my ($imapd, $ibx, $max) = @_;
 274         defined(my $mb_top = $ibx->{newsgroup}) or return;
 275         my $mailboxes = $imapd->{mailboxes};
 276         my @created;
 277         for (my $i = int($max/UID_SLICE); $i >= 0; --$i) {
 278                 my $sub_mailbox = "$mb_top.$i";
 279                 last if exists $mailboxes->{$sub_mailbox};
 280                 $mailboxes->{$sub_mailbox} = $ibx;
 281                 $sub_mailbox =~ s/\Ainbox\./INBOX./i; # more familiar to users
 282                 push @created, $sub_mailbox;
 283         }
 284         return unless @created;
 285         my $l = $imapd->{inboxlist} or return;
 286         push @$l, map { qq[* LIST (\\HasNoChildren) "." $_\r\n] } @created;
 287 }
 288
 289 sub inbox_lookup ($$) {
 290         my ($self, $mailbox) = @_;
 291         my ($ibx, $exists, $uidnext, $uid_base);
 292         if ($mailbox =~ /\A(.+)\.([0-9]+)\z/) {
 293                 # old mail: inbox.comp.foo.$SLICE_IDX
 294                 my $mb_top = $1;
 295                 $uid_base = $2 * UID_SLICE;
 296                 $ibx = $self->{imapd}->{mailboxes}->{lc $mailbox} or return;
 297                 my $max;
 298                 ($exists, $uidnext, $max) = $ibx->over->imap_status($uid_base,
 299                                                         $uid_base + UID_SLICE);
 300                 ensure_slices_exist($self->{imapd}, $ibx, $max);
 301         } else { # check for dummy inboxes
 302                 $mailbox = lc $mailbox;
 303                 $ibx = $self->{imapd}->{mailboxes}->{$mailbox} or return;
 304
 305                 # if "INBOX.foo.bar" is selected and "INBOX.foo.bar.0",
 306                 # check for new UID ranges (e.g. "INBOX.foo.bar.1")
 307                 if (my $z = $self->{imapd}->{mailboxes}->{"$mailbox.0"}) {
 308                         ensure_slices_exist($self->{imapd}, $z, $z->over->max);
 309                 }
 310
 311                 $uid_base = $exists = 0;
 312                 $uidnext = 1;
 313         }
 314         ($ibx, $exists, $uidnext, $uid_base);
 315 }
 316
 317 sub cmd_examine ($$$) {
 318         my ($self, $tag, $mailbox) = @_;
 319         my ($ibx, $exists, $uidnext, $base) = inbox_lookup($self, $mailbox);
 320         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 321         $self->{uid_base} = $base;
 322
 323         # XXX: do we need this? RFC 5162/7162
 324         my $ret = $self->{ibx} ? "* OK [CLOSED] previous closed\r\n" : '';
 325         $self->{ibx} = $ibx;
 326         $ret .= <<EOF;
 327 * $exists EXISTS\r
 328 * $exists RECENT\r
 329 * FLAGS (\\Seen)\r
 330 * OK [PERMANENTFLAGS ()] Read-only mailbox\r
 331 * OK [UNSEEN $exists]\r
 332 * OK [UIDNEXT $uidnext]\r
 333 * OK [UIDVALIDITY $ibx->{uidvalidity}]\r
 334 $tag OK [READ-ONLY] EXAMINE/SELECT done\r
 335 EOF
 336 }
 337
 338 sub _esc ($) {
 339         my ($v) = @_;
 340         if (!defined($v)) {
 341                 'NIL';
 342         } elsif ($v =~ /[{"\r\n%*\\\[]/) { # literal string
 343                 '{' . length($v) . "}\r\n" . $v;
 344         } else { # quoted string
 345                 qq{"$v"}
 346         }
 347 }
 348
 349 sub addr_envelope ($$;$) {
 350         my ($eml, $x, $y) = @_;
 351         my $v = $eml->header_raw($x) //
 352                 ($y ? $eml->header_raw($y) : undef) // return 'NIL';
 353
 354         my @x = $Address->parse($v) or return 'NIL';
 355         '(' . join('',
 356                 map { '(' . join(' ',
 357                                 _esc($_->name), 'NIL',
 358                                 _esc($_->user), _esc($_->host)
 359                         ) . ')'
 360                 } @x) .
 361         ')';
 362 }
 363
 364 sub eml_envelope ($) {
 365         my ($eml) = @_;
 366         '(' . join(' ',
 367                 _esc($eml->header_raw('Date')),
 368                 _esc($eml->header_raw('Subject')),
 369                 addr_envelope($eml, 'From'),
 370                 addr_envelope($eml, 'Sender', 'From'),
 371                 addr_envelope($eml, 'Reply-To', 'From'),
 372                 addr_envelope($eml, 'To'),
 373                 addr_envelope($eml, 'Cc'),
 374                 addr_envelope($eml, 'Bcc'),
 375                 _esc($eml->header_raw('In-Reply-To')),
 376                 _esc($eml->header_raw('Message-ID')),
 377         ) . ')';
 378 }
 379
 380 sub _esc_hash ($) {
 381         my ($hash) = @_;
 382         if ($hash && scalar keys %$hash) {
 383                 $hash = [ %$hash ]; # flatten hash into 1-dimensional array
 384                 '(' . join(' ', map { _esc($_) } @$hash) . ')';
 385         } else {
 386                 'NIL';
 387         }
 388 }
 389
 390 sub body_disposition ($) {
 391         my ($eml) = @_;
 392         my $cd = $eml->header_raw('Content-Disposition') or return 'NIL';
 393         $cd = parse_content_disposition($cd);
 394         my $buf = '('._esc($cd->{type});
 395         $buf .= ' ' . _esc_hash(delete $cd->{attributes});
 396         $buf .= ')';
 397 }
 398
 399 sub body_leaf ($$;$) {
 400         my ($eml, $structure, $hold) = @_;
 401         my $buf = '';
 402         $eml->{is_submsg} and # parent was a message/(rfc822|news|global)
 403                 $buf .= eml_envelope($eml). ' ';
 404         my $ct = $eml->ct;
 405         $buf .= '('._esc($ct->{type}).' ';
 406         $buf .= _esc($ct->{subtype});
 407         $buf .= ' ' . _esc_hash(delete $ct->{attributes});
 408         $buf .= ' ' . _esc($eml->header_raw('Content-ID'));
 409         $buf .= ' ' . _esc($eml->header_raw('Content-Description'));
 410         my $cte = $eml->header_raw('Content-Transfer-Encoding') // '7bit';
 411         $buf .= ' ' . _esc($cte);
 412         $buf .= ' ' . $eml->{imap_body_len};
 413         $buf .= ' '.($eml->body_raw =~ tr/\n/\n/) if lc($ct->{type}) eq 'text';
 414
 415         # for message/(rfc822|global|news), $hold[0] should have envelope
 416         $buf .= ' ' . (@$hold ? join('', @$hold) : 'NIL') if $hold;
 417
 418         if ($structure) {
 419                 $buf .= ' '._esc($eml->header_raw('Content-MD5'));
 420                 $buf .= ' '. body_disposition($eml);
 421                 $buf .= ' '._esc($eml->header_raw('Content-Language'));
 422                 $buf .= ' '._esc($eml->header_raw('Content-Location'));
 423         }
 424         $buf .= ')';
 425 }
 426
 427 sub body_parent ($$$) {
 428         my ($eml, $structure, $hold) = @_;
 429         my $ct = $eml->ct;
 430         my $type = lc($ct->{type});
 431         if ($type eq 'multipart') {
 432                 my $buf = '(';
 433                 $buf .= @$hold ? join('', @$hold) : 'NIL';
 434                 $buf .= ' '._esc($ct->{subtype});
 435                 if ($structure) {
 436                         $buf .= ' '._esc_hash(delete $ct->{attributes});
 437                         $buf .= ' '.body_disposition($eml);
 438                         $buf .= ' '._esc($eml->header_raw('Content-Language'));
 439                         $buf .= ' '._esc($eml->header_raw('Content-Location'));
 440                 }
 441                 $buf .= ')';
 442                 @$hold = ($buf);
 443         } else { # message/(rfc822|global|news)
 444                 @$hold = (body_leaf($eml, $structure, $hold));
 445         }
 446 }
 447
 448 # this is gross, but we need to process the parent part AFTER
 449 # the child parts are done
 450 sub bodystructure_prep {
 451         my ($p, $q) = @_;
 452         my ($eml, $depth) = @$p; # ignore idx
 453         # set length here, as $eml->{bdy} gets deleted for message/rfc822
 454         $eml->{imap_body_len} = length($eml->body_raw);
 455         push @$q, $eml, $depth;
 456 }
 457
 458 # for FETCH BODY and FETCH BODYSTRUCTURE
 459 sub fetch_body ($;$) {
 460         my ($eml, $structure) = @_;
 461         my @q;
 462         $eml->each_part(\&bodystructure_prep, \@q, 0, 1);
 463         my $cur_depth = 0;
 464         my @hold;
 465         do {
 466                 my ($part, $depth) = splice(@q, -2);
 467                 my $is_mp_parent = $depth == ($cur_depth - 1);
 468                 $cur_depth = $depth;
 469
 470                 if ($is_mp_parent) {
 471                         body_parent($part, $structure, \@hold);
 472                 } else {
 473                         unshift @hold, body_leaf($part, $structure);
 474                 }
 475         } while (@q);
 476         join('', @hold);
 477 }
 478
 479 sub requeue_once ($) {
 480         my ($self) = @_;
 481         # COMPRESS users all share the same DEFLATE context.
 482         # Flush it here to ensure clients don't see
 483         # each other's data
 484         $self->zflush;
 485
 486         # no recursion, schedule another call ASAP,
 487         # but only after all pending writes are done.
 488         # autovivify wbuf:
 489         my $new_size = push(@{$self->{wbuf}}, \&long_step);
 490
 491         # wbuf may be populated by $cb, no need to rearm if so:
 492         $self->requeue if $new_size == 1;
 493 }
 494
 495 # my ($msn, $UID) = @_;
 496 sub fetch_msn_uid ($$) { '* '.(${$_[0]}++).' FETCH (UID '.$_[1] }
 497
 498 sub fetch_run_ops {
 499         my ($self, $msn, $smsg, $bref, $ops, $partial) = @_;
 500         $self->msg_more(fetch_msn_uid($msn, $smsg->{num}));
 501         my ($eml, $k);
 502         for (my $i = 0; $i < @$ops;) {
 503                 $k = $ops->[$i++];
 504                 $ops->[$i++]->($self, $k, $smsg, $bref, $eml);
 505         }
 506         partial_emit($self, $partial, $eml) if $partial;
 507         $self->msg_more(")\r\n");
 508 }
 509
 510 sub fetch_blob_cb { # called by git->cat_async via git_async_cat
 511         my ($bref, $oid, $type, $size, $fetch_arg) = @_;
 512         my ($self, undef, $msgs, $range_info, $ops, $partial) = @$fetch_arg;
 513         my $smsg = shift @$msgs or die 'BUG: no smsg';
 514         if (!defined($oid)) {
 515                 # it's possible to have TOCTOU if an admin runs
 516                 # public-inbox-(edit|purge), just move onto the next message
 517                 return requeue_once($self);
 518         } else {
 519                 $smsg->{blob} eq $oid or die "BUG: $smsg->{blob} != $oid";
 520         }
 521         fetch_run_ops($self, $range_info->[3], $smsg, $bref, $ops, $partial);
 522         requeue_once($self);
 523 }
 524
 525 sub emit_rfc822 {
 526         my ($self, $k, undef, $bref) = @_;
 527         $self->msg_more(" $k {" . length($$bref)."}\r\n");
 528         $self->msg_more($$bref);
 529 }
 530
 531 # Mail::IMAPClient::message_string cares about this by default,
 532 # (->Ignoresizeerrors attribute).  Admins are encouraged to
 533 # --reindex for IMAP support, anyways.
 534 sub emit_rfc822_size {
 535         my ($self, $k, $smsg) = @_;
 536         $self->msg_more(' RFC822.SIZE ' . $smsg->{bytes});
 537 }
 538
 539 sub emit_internaldate {
 540         my ($self, undef, $smsg) = @_;
 541         $self->msg_more(' INTERNALDATE "'.$smsg->internaldate.'"');
 542 }
 543
 544 sub emit_flags { $_[0]->msg_more(' FLAGS ()') }
 545
 546 sub emit_envelope {
 547         my ($self, undef, undef, undef, $eml) = @_;
 548         $self->msg_more(' ENVELOPE '.eml_envelope($eml));
 549 }
 550
 551 sub emit_rfc822_header {
 552         my ($self, $k, undef, undef, $eml) = @_;
 553         $self->msg_more(" $k {".length(${$eml->{hdr}})."}\r\n");
 554         $self->msg_more(${$eml->{hdr}});
 555 }
 556
 557 # n.b. this is sorted to be after any emit_eml_new ops
 558 sub emit_rfc822_text {
 559         my ($self, $k, undef, $bref) = @_;
 560         $self->msg_more(" $k {".length($$bref)."}\r\n");
 561         $self->msg_more($$bref);
 562 }
 563
 564 sub emit_bodystructure {
 565         my ($self, undef, undef, undef, $eml) = @_;
 566         $self->msg_more(' BODYSTRUCTURE '.fetch_body($eml, 1));
 567 }
 568
 569 sub emit_body {
 570         my ($self, undef, undef, undef, $eml) = @_;
 571         $self->msg_more(' BODY '.fetch_body($eml));
 572 }
 573
 574 # set $eml once ($_[4] == $eml, $_[3] == $bref)
 575 sub op_eml_new { $_[4] = PublicInbox::Eml->new($_[3]) }
 576
 577 # s/From / fixes old bug from import (pre-a0c07cba0e5d8b6a)
 578 sub to_crlf_full {
 579         ${$_[0]} =~ s/(?<!\r)\n/\r\n/sg;
 580         ${$_[0]} =~ s/\A[\r\n]*From [^\r\n]*\r\n//s;
 581 }
 582
 583 sub op_crlf_bref { to_crlf_full($_[3]) }
 584
 585 sub op_crlf_hdr { to_crlf_full($_[4]->{hdr}) }
 586
 587 sub op_crlf_bdy { ${$_[4]->{bdy}} =~ s/(?<!\r)\n/\r\n/sg if $_[4]->{bdy} }
 588
 589 sub uid_clamp ($$$) {
 590         my ($self, $beg, $end) = @_;
 591         my $uid_min = $self->{uid_base} + 1;
 592         my $uid_end = $uid_min + UID_SLICE - 1;
 593         $$beg = $uid_min if $$beg < $uid_min;
 594         $$end = $uid_end if $$end > $uid_end;
 595 }
 596
 597 sub range_step ($$) {
 598         my ($self, $range_csv) = @_;
 599         my ($beg, $end, $range);
 600         if ($$range_csv =~ s/\A([^,]+),//) {
 601                 $range = $1;
 602         } else {
 603                 $range = $$range_csv;
 604                 $$range_csv = undef;
 605         }
 606         my $uid_base = $self->{uid_base};
 607         my $uid_end = $uid_base + UID_SLICE;
 608         if ($range =~ /\A([0-9]+):([0-9]+)\z/) {
 609                 ($beg, $end) = ($1 + 0, $2 + 0);
 610                 uid_clamp($self, \$beg, \$end);
 611         } elsif ($range =~ /\A([0-9]+):\*\z/) {
 612                 $beg = $1 + 0;
 613                 $end = $self->{ibx}->over->max;
 614                 $end = $uid_end if $end > $uid_end;
 615                 $beg = $end if $beg > $end;
 616                 uid_clamp($self, \$beg, \$end);
 617         } elsif ($range =~ /\A[0-9]+\z/) {
 618                 $beg = $end = $range + 0;
 619                 # just let the caller do an out-of-range query if a single
 620                 # UID is out-of-range
 621                 ++$beg if ($beg <= $uid_base || $end > $uid_end);
 622         } else {
 623                 return 'BAD fetch range';
 624         }
 625         my $msn = $beg - $uid_base;
 626         [ $beg, $end, $$range_csv, \$msn ];
 627 }
 628
 629 sub refill_range ($$$) {
 630         my ($self, $msgs, $range_info) = @_;
 631         my ($beg, $end, $range_csv) = @$range_info;
 632         if (scalar(@$msgs = @{$self->{ibx}->over->query_xover($beg, $end)})) {
 633                 $range_info->[0] = $msgs->[-1]->{num} + 1;
 634                 return;
 635         }
 636         return 'OK Fetch done' if !$range_csv;
 637         my $next_range = range_step($self, \$range_csv);
 638         return $next_range if !ref($next_range); # error
 639         @$range_info = @$next_range;
 640         undef; # keep looping
 641 }
 642
 643 sub fetch_blob { # long_response
 644         my ($self, $tag, $msgs, $range_info, $ops, $partial) = @_;
 645         while (!@$msgs) { # rare
 646                 if (my $end = refill_range($self, $msgs, $range_info)) {
 647                         $self->write(\"$tag $end\r\n");
 648                         return;
 649                 }
 650         }
 651         git_async_cat($self->{ibx}->git, $msgs->[0]->{blob},
 652                         \&fetch_blob_cb, \@_);
 653 }
 654
 655 sub fetch_smsg { # long_response
 656         my ($self, $tag, $msgs, $range_info, $ops) = @_;
 657         while (!@$msgs) { # rare
 658                 if (my $end = refill_range($self, $msgs, $range_info)) {
 659                         $self->write(\"$tag $end\r\n");
 660                         return;
 661                 }
 662         }
 663         fetch_run_ops($self, $range_info->[3], $_, undef, $ops) for @$msgs;
 664         @$msgs = ();
 665         1; # more
 666 }
 667
 668 sub refill_uids ($$$;$) {
 669         my ($self, $uids, $range_info, $sql) = @_;
 670         my ($beg, $end, $range_csv) = @$range_info;
 671         my $over = $self->{ibx}->over;
 672         while (1) {
 673                 if (scalar(@$uids = @{$over->uid_range($beg, $end, $sql)})) {
 674                         $range_info->[0] = $uids->[-1] + 1; # update $beg
 675                         return;
 676                 } elsif (!$range_csv) {
 677                         return 0;
 678                 } else {
 679                         my $next_range = range_step($self, \$range_csv);
 680                         return $next_range if !ref($next_range); # error
 681                         ($beg, $end, $range_csv) = @$range_info = @$next_range;
 682                         # continue looping
 683                 }
 684         }
 685 }
 686
 687 sub fetch_uid { # long_response
 688         my ($self, $tag, $uids, $range_info, $ops) = @_;
 689         if (defined(my $err = refill_uids($self, $uids, $range_info))) {
 690                 $err ||= 'OK Fetch done';
 691                 $self->write("$tag $err\r\n");
 692                 return;
 693         }
 694         my ($i, $k);
 695         my $msn = $range_info->[3];
 696         for (@$uids) {
 697                 $self->msg_more(fetch_msn_uid($msn, $_));
 698                 for ($i = 0; $i < @$ops;) {
 699                         $k = $ops->[$i++];
 700                         $ops->[$i++]->($self, $k);
 701                 }
 702                 $self->msg_more(")\r\n");
 703         }
 704         @$uids = ();
 705         1; # more
 706 }
 707
 708 sub cmd_status ($$$;@) {
 709         my ($self, $tag, $mailbox, @items) = @_;
 710         return "$tag BAD no items\r\n" if !scalar(@items);
 711         ($items[0] !~ s/\A\(//s || $items[-1] !~ s/\)\z//s) and
 712                 return "$tag BAD invalid args\r\n";
 713         my ($ibx, $exists, $uidnext) = inbox_lookup($self, $mailbox);
 714         return "$tag NO Mailbox doesn't exist: $mailbox\r\n" if !$ibx;
 715         my @it;
 716         for my $it (@items) {
 717                 $it = uc($it);
 718                 push @it, $it;
 719                 if ($it =~ /\A(?:MESSAGES|UNSEEN|RECENT)\z/) {
 720                         push @it, $exists;
 721                 } elsif ($it eq 'UIDNEXT') {
 722                         push @it, $uidnext;
 723                 } elsif ($it eq 'UIDVALIDITY') {
 724                         push @it, $ibx->{uidvalidity};
 725                 } else {
 726                         return "$tag BAD invalid item\r\n";
 727                 }
 728         }
 729         return "$tag BAD no items\r\n" if !@it;
 730         "* STATUS $mailbox (".join(' ', @it).")\r\n" .
 731         "$tag OK Status done\r\n";
 732 }
 733
 734 my %patmap = ('*' => '.*', '%' => '[^\.]*');
 735 sub cmd_list ($$$$) {
 736         my ($self, $tag, $refname, $wildcard) = @_;
 737         my $l = $self->{imapd}->{inboxlist};
 738         if ($refname eq '' && $wildcard eq '') {
 739                 # request for hierarchy delimiter
 740                 $l = [ qq[* LIST (\\Noselect) "." ""\r\n] ];
 741         } elsif ($refname ne '' || $wildcard ne '*') {
 742                 $wildcard =~ s!([^a-z0-9_])!$patmap{$1} // "\Q$1"!egi;
 743                 $l = [ grep(/ \Q$refname\E$wildcard\r\n\z/is, @$l) ];
 744         }
 745         \(join('', @$l, "$tag OK List done\r\n"));
 746 }
 747
 748 sub cmd_lsub ($$$$) {
 749         my (undef, $tag) = @_; # same args as cmd_list
 750         "$tag OK Lsub done\r\n";
 751 }
 752
 753 sub eml_index_offs_i { # PublicInbox::Eml::each_part callback
 754         my ($p, $all) = @_;
 755         my ($eml, undef, $idx) = @$p;
 756         if ($idx && lc($eml->ct->{type}) eq 'multipart') {
 757                 $eml->{imap_bdy} = $eml->{bdy} // \'';
 758         }
 759         $all->{$idx} = $eml; # $idx => Eml
 760 }
 761
 762 # prepares an index for BODY[$SECTION_IDX] fetches
 763 sub eml_body_idx ($$) {
 764         my ($eml, $section_idx) = @_;
 765         my $idx = $eml->{imap_all_parts} //= do {
 766                 my $all = {};
 767                 $eml->each_part(\&eml_index_offs_i, $all, 0, 1);
 768                 # top-level of multipart, BODY[0] not allowed (nz-number)
 769                 delete $all->{0};
 770                 $all;
 771         };
 772         $idx->{$section_idx};
 773 }
 774
 775 # BODY[($SECTION_IDX)?(.$SECTION_NAME)?]<$offset.$bytes>
 776 sub partial_body {
 777         my ($eml, $section_idx, $section_name) = @_;
 778         if (defined $section_idx) {
 779                 $eml = eml_body_idx($eml, $section_idx) or return;
 780         }
 781         if (defined $section_name) {
 782                 if ($section_name eq 'MIME') {
 783                         # RFC 3501 6.4.5 states:
 784                         #       The MIME part specifier MUST be prefixed
 785                         #       by one or more numeric part specifiers
 786                         return unless defined $section_idx;
 787                         return $eml->header_obj->as_string . "\r\n";
 788                 }
 789                 my $bdy = $eml->{bdy} // $eml->{imap_bdy} // \'';
 790                 $eml = PublicInbox::Eml->new($$bdy);
 791                 if ($section_name eq 'TEXT') {
 792                         return $eml->body_raw;
 793                 } elsif ($section_name eq 'HEADER') {
 794                         return $eml->header_obj->as_string . "\r\n";
 795                 } else {
 796                         die "BUG: bad section_name=$section_name";
 797                 }
 798         }
 799         ${$eml->{bdy} // $eml->{imap_bdy} // \''};
 800 }
 801
 802 # similar to what's in PublicInbox::Eml::re_memo, but doesn't memoize
 803 # to avoid OOM with malicious users
 804 sub hdrs_regexp ($) {
 805         my ($hdrs) = @_;
 806         my $names = join('|', map { "\Q$_" } split(/[ \t]+/, $hdrs));
 807         qr/^(?:$names):[ \t]*[^\n]*\r?\n # 1st line
 808                 # continuation lines:
 809                 (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*
 810                 /ismx;
 811 }
 812
 813 # BODY[($SECTION_IDX.)?HEADER.FIELDS.NOT ($HDRS)]<$offset.$bytes>
 814 sub partial_hdr_not {
 815         my ($eml, $section_idx, $hdrs_re) = @_;
 816         if (defined $section_idx) {
 817                 $eml = eml_body_idx($eml, $section_idx) or return;
 818         }
 819         my $str = $eml->header_obj->as_string;
 820         $str =~ s/$hdrs_re//g;
 821         $str =~ s/(?<!\r)\n/\r\n/sg;
 822         $str .= "\r\n";
 823 }
 824
 825 # BODY[($SECTION_IDX.)?HEADER.FIELDS ($HDRS)]<$offset.$bytes>
 826 sub partial_hdr_get {
 827         my ($eml, $section_idx, $hdrs_re) = @_;
 828         if (defined $section_idx) {
 829                 $eml = eml_body_idx($eml, $section_idx) or return;
 830         }
 831         my $str = $eml->header_obj->as_string;
 832         $str = join('', ($str =~ m/($hdrs_re)/g));
 833         $str =~ s/(?<!\r)\n/\r\n/sg;
 834         $str .= "\r\n";
 835 }
 836
 837 sub partial_prepare ($$$$) {
 838         my ($need, $partial, $want, $att) = @_;
 839
 840         # recombine [ "BODY[1.HEADER.FIELDS", "(foo", "bar)]" ]
 841         # back to: "BODY[1.HEADER.FIELDS (foo bar)]"
 842         return unless $att =~ /\ABODY\[/s;
 843         until (rindex($att, ']') >= 0) {
 844                 my $next = shift @$want or return;
 845                 $att .= ' ' . uc($next);
 846         }
 847         if ($att =~ /\ABODY\[([0-9]+(?:\.[0-9]+)*)? # 1 - section_idx
 848                         (?:\.(HEADER|MIME|TEXT))? # 2 - section_name
 849                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 3, 4
 850                 $partial->{$att} = [ \&partial_body, $1, $2, $3, $4 ];
 851                 $$need |= CRLF_BREF|EML_HDR|EML_BDY;
 852         } elsif ($att =~ /\ABODY\[(?:([0-9]+(?:\.[0-9]+)*)\.)? # 1 - section_idx
 853                                 (?:HEADER\.FIELDS(\.NOT)?)\x20 # 2
 854                                 \(([A-Z0-9\-\x20]+)\) # 3 - hdrs
 855                         \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 4 5
 856                 my $tmp = $partial->{$att} = [ $2 ? \&partial_hdr_not
 857                                                 : \&partial_hdr_get,
 858                                                 $1, undef, $4, $5 ];
 859                 $tmp->[2] = hdrs_regexp($3);
 860
 861                 # don't emit CRLF_HDR instruction, here, partial_hdr_*
 862                 # will do CRLF conversion with only the extracted result
 863                 # and not waste time converting lines we don't care about.
 864                 $$need |= EML_HDR;
 865         } else {
 866                 undef;
 867         }
 868 }
 869
 870 sub partial_emit ($$$) {
 871         my ($self, $partial, $eml) = @_;
 872         for (@$partial) {
 873                 my ($k, $cb, @args) = @$_;
 874                 my ($offset, $len) = splice(@args, -2);
 875                 # $cb is partial_body|partial_hdr_get|partial_hdr_not
 876                 my $str = $cb->($eml, @args) // '';
 877                 if (defined $offset) {
 878                         if (defined $len) {
 879                                 $str = substr($str, $offset, $len);
 880                                 $k =~ s/\.$len>\z/>/ or warn
 881 "BUG: unable to remove `.$len>' from `$k'";
 882                         } else {
 883                                 $str = substr($str, $offset);
 884                                 $len = length($str);
 885                         }
 886                 } else {
 887                         $len = length($str);
 888                 }
 889                 $self->msg_more(" $k {$len}\r\n");
 890                 $self->msg_more($str);
 891         }
 892 }
 893
 894 sub fetch_compile ($) {
 895         my ($want) = @_;
 896         if ($want->[0] =~ s/\A\(//s) {
 897                 $want->[-1] =~ s/\)\z//s or return 'BAD no rparen';
 898         }
 899         my (%partial, %seen, @op);
 900         my $need = 0;
 901         while (defined(my $att = shift @$want)) {
 902                 $att = uc($att);
 903                 next if $att eq 'UID'; # always returned
 904                 $att =~ s/\ABODY\.PEEK\[/BODY\[/; # we're read-only
 905                 my $x = $FETCH_ATT{$att};
 906                 if ($x) {
 907                         while (my ($k, $fl_cb) = each %$x) {
 908                                 next if $seen{$k}++;
 909                                 $need |= $fl_cb->[0];
 910                                 push @op, [ @$fl_cb, $k ];
 911                         }
 912                 } elsif (!partial_prepare(\$need, \%partial, $want, $att)) {
 913                         return "BAD param: $att";
 914                 }
 915         }
 916         my @r;
 917
 918         # stabilize partial order for consistency and ease-of-debugging:
 919         if (scalar keys %partial) {
 920                 $need |= NEED_BLOB;
 921                 $r[2] = [ map { [ $_, @{$partial{$_}} ] } sort keys %partial ];
 922         }
 923
 924         push @op, $OP_EML_NEW if ($need & (EML_HDR|EML_BDY));
 925
 926         # do we need CRLF conversion?
 927         if ($need & CRLF_BREF) {
 928                 push @op, $OP_CRLF_BREF;
 929         } elsif (my $crlf = ($need & (CRLF_HDR|CRLF_BDY))) {
 930                 if ($crlf == (CRLF_HDR|CRLF_BDY)) {
 931                         push @op, $OP_CRLF_BREF;
 932                 } elsif ($need & CRLF_HDR) {
 933                         push @op, $OP_CRLF_HDR;
 934                 } else {
 935                         push @op, $OP_CRLF_BDY;
 936                 }
 937         }
 938
 939         $r[0] = $need & NEED_BLOB ? \&fetch_blob :
 940                 ($need & NEED_SMSG ? \&fetch_smsg : \&fetch_uid);
 941
 942         # r[1] = [ $key1, $cb1, $key2, $cb2, ... ]
 943         use sort 'stable'; # makes output more consistent
 944         $r[1] = [ map { ($_->[2], $_->[1]) } sort { $a->[0] <=> $b->[0] } @op ];
 945         @r;
 946 }
 947
 948 sub cmd_uid_fetch ($$$$;@) {
 949         my ($self, $tag, $range_csv, @want) = @_;
 950         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 951         my ($cb, $ops, $partial) = fetch_compile(\@want);
 952         return "$tag $cb\r\n" unless $ops;
 953
 954         $range_csv = 'bad' if $range_csv !~ $valid_range;
 955         my $range_info = range_step($self, \$range_csv);
 956         return "$tag $range_info\r\n" if !ref($range_info);
 957         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 958 }
 959
 960 sub msn_to_uid_range ($$) {
 961         my $uid_base = $_[0]->{uid_base};
 962         $_[1] =~ s/([0-9]+)/$uid_base + $1/sge;
 963 }
 964
 965 sub cmd_fetch ($$$$;@) {
 966         my ($self, $tag, $range_csv, @want) = @_;
 967         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
 968         my ($cb, $ops, $partial) = fetch_compile(\@want);
 969         return "$tag $cb\r\n" unless $ops;
 970
 971         # cb is one of fetch_blob, fetch_smsg, fetch_uid
 972         $range_csv = 'bad' if $range_csv !~ $valid_range;
 973         msn_to_uid_range($self, $range_csv);
 974         my $range_info = range_step($self, \$range_csv);
 975         return "$tag $range_info\r\n" if !ref($range_info);
 976         long_response($self, $cb, $tag, [], $range_info, $ops, $partial);
 977 }
 978
 979 sub parse_date ($) { # 02-Oct-1993
 980         my ($date_text) = @_;
 981         my ($dd, $mon, $yyyy) = split(/-/, $_[0], 3);
 982         defined($yyyy) or return;
 983         my $mm = $MoY{$mon} // return;
 984         $dd =~ /\A[0123]?[0-9]\z/ or return;
 985         $yyyy =~ /\A[0-9]{4,}\z/ or return; # Y10K-compatible!
 986         timegm(0, 0, 0, $dd, $mm, $yyyy);
 987 }
 988
 989 sub search_uid_range { # long_response
 990         my ($self, $tag, $sql, $range_info) = @_;
 991         my $uids = [];
 992         if (defined(my $err = refill_uids($self, $uids, $range_info, $sql))) {
 993                 $err ||= 'OK Search done';
 994                 $self->write("\r\n$tag $err\r\n");
 995                 return;
 996         }
 997         $self->msg_more(join(' ', '', @$uids));
 998         1; # more
 999 }
1000
1001 sub date_search {
1002         my ($q, $k, $d) = @_;
1003         my $sql = $q->{sql};
1004
1005         # Date: header
1006         if ($k eq 'SENTON') {
1007                 my $end = $d + 86399; # no leap day...
1008                 my $da = strftime('%Y%m%d%H%M%S', gmtime($d));
1009                 my $db = strftime('%Y%m%d%H%M%S', gmtime($end));
1010                 $q->{xap} .= " dt:$da..$db";
1011                 $$sql .= " AND ds >= $d AND ds <= $end" if defined($sql);
1012         } elsif ($k eq 'SENTBEFORE') {
1013                 $q->{xap} .= ' d:..'.strftime('%Y%m%d', gmtime($d));
1014                 $$sql .= " AND ds <= $d" if defined($sql);
1015         } elsif ($k eq 'SENTSINCE') {
1016                 $q->{xap} .= ' d:'.strftime('%Y%m%d', gmtime($d)).'..';
1017                 $$sql .= " AND ds >= $d" if defined($sql);
1018
1019         # INTERNALDATE (Received)
1020         } elsif ($k eq 'ON') {
1021                 my $end = $d + 86399; # no leap day...
1022                 $q->{xap} .= " ts:$d..$end";
1023                 $$sql .= " AND ts >= $d AND ts <= $end" if defined($sql);
1024         } elsif ($k eq 'BEFORE') {
1025                 $q->{xap} .= " ts:..$d";
1026                 $$sql .= " AND ts <= $d" if defined($sql);
1027         } elsif ($k eq 'SINCE') {
1028                 $q->{xap} .= " ts:$d..";
1029                 $$sql .= " AND ts >= $d" if defined($sql);
1030         } else {
1031                 die "BUG: $k not recognized";
1032         }
1033 }
1034
1035 # IMAP to Xapian search key mapping
1036 my %I2X = (
1037         SUBJECT => 's:',
1038         BODY => 'b:',
1039         FROM => 'f:',
1040         TEXT => '', # n.b. does not include all headers
1041         TO => 't:',
1042         CC => 'c:',
1043         # BCC => 'bcc:', # TODO
1044         # KEYWORD # TODO ? dfpre,dfpost,...
1045 );
1046
1047 # IMAP allows searching arbitrary headers via "HEADER $HDR_NAME $HDR_VAL"
1048 # which gets silly expensive.  We only allow the headers we already index.
1049 my %H2X = (%I2X, 'MESSAGE-ID' => 'm:', 'LIST-ID' => 'l:');
1050
1051 sub xap_append ($$$$) {
1052         my ($q, $rest, $k, $xk) = @_;
1053         delete $q->{sql}; # can't use over.sqlite3
1054         defined(my $arg = shift @$rest) or return "BAD $k no arg";
1055
1056         # AFAIK Xapian can't handle [*"] in probabilistic terms
1057         $arg =~ tr/*"//d;
1058         ${$q->{xap}} .= qq[ $xk"$arg"];
1059         undef;
1060 }
1061
1062 sub parse_query {
1063         my ($self, $rest) = @_;
1064         if (uc($rest->[0]) eq 'CHARSET') {
1065                 shift @$rest;
1066                 defined(my $c = shift @$rest) or return 'BAD missing charset';
1067                 $c =~ /\A(?:UTF-8|US-ASCII)\z/ or return 'NO [BADCHARSET]';
1068         }
1069
1070         my $sql = ''; # date conditions, {sql} deleted if Xapian is needed
1071         my $xap = '';
1072         my $q = { sql => \$sql, xap => \$xap };
1073         while (@$rest) {
1074                 my $k = uc(shift @$rest);
1075                 # default criteria
1076                 next if $k =~ /\A(?:ALL|RECENT|UNSEEN|NEW)\z/;
1077                 next if $k eq 'AND'; # the default, until we support OR
1078                 if ($k =~ $valid_range) { # convert sequence numbers to UIDs
1079                         msn_to_uid_range($self, $k);
1080                         push @{$q->{uid}}, $k;
1081                 } elsif ($k eq 'UID') {
1082                         $k = shift(@$rest) // '';
1083                         $k =~ $valid_range or return 'BAD UID range';
1084                         push @{$q->{uid}}, $k;
1085                 } elsif ($k =~ /\A(?:SENT)?(?:SINCE|ON|BEFORE)\z/) {
1086                         my $d = parse_date(shift(@$rest) // '');
1087                         defined $d or return "BAD $k date format";
1088                         date_search($q, $k, $d);
1089                 } elsif ($k =~ /\A(?:SMALLER|LARGER)\z/) {
1090                         delete $q->{sql}; # can't use over.sqlite3
1091                         my $bytes = shift(@$rest) // '';
1092                         $bytes =~ /\A[0-9]+\z/ or return "BAD $k not a number";
1093                         $xap .= ' bytes:' . ($k eq 'SMALLER' ?
1094                                                         '..'.(--$bytes) :
1095                                                         (++$bytes).'..');
1096                 } elsif ($k eq 'HEADER') {
1097                         $k = uc(shift(@$rest) // '');
1098                         my $xk = $H2X{$k} or
1099                                 return "BAD HEADER $k not supported";
1100                         my $err = xap_append($q, $rest, $k, $xk);
1101                         return $err if $err;
1102                 } elsif (defined(my $xk = $I2X{$k})) {
1103                         my $err = xap_append($q, $rest, $k, $xk);
1104                         return $err if $err;
1105                 } else {
1106                         # TODO: parentheses, OR, NOT ...
1107                         return "BAD $k not supported (yet?)";
1108                 }
1109         }
1110
1111         # favor using over.sqlite3 if possible, since Xapian is optional
1112         if (exists $q->{sql}) {
1113                 delete($q->{xap});
1114                 delete($q->{sql}) if $sql eq '';
1115         } elsif (!$self->{ibx}->search) {
1116                 return 'BAD Xapian not configured for mailbox';
1117         }
1118         my $max = $self->{ibx}->over->max;
1119         if (my $uid = delete $q->{uid}) {
1120                 my $range_csv = join(',', @$uid);
1121                 do {
1122                         my $nxt = range_step($self, \$range_csv);
1123                         my ($beg, $end) = @$nxt;
1124                         if ($xap) {
1125                                 $xap .= " uid:$beg..$end";
1126                         } elsif ($beg == $end) {
1127                                 $sql .= " AND num = $beg";
1128                         } else {
1129                                 $sql .= " AND num >= $beg AND num <= $end";
1130                         }
1131                 } while ($range_csv);
1132         }
1133         my $beg = 1;
1134         uid_clamp($self, \$beg, \$max);
1135         $q->{range_info} = [ $beg, $max ];
1136         $q;
1137 }
1138
1139 sub refill_xap ($$$$) {
1140         my ($self, $uids, $range_info, $q) = @_;
1141         my ($beg, $end) = @$range_info;
1142         my $srch = $self->{ibx}->search;
1143         my $opt = { mset => 2, limit => 1000 };
1144         my $nshard = $srch->{nshard} // 1;
1145         while (1) {
1146                 my $mset = $srch->query("$$q uid:$beg..$end", $opt);
1147                 @$uids = map { mdocid($nshard, $_) } $mset->items;
1148                 if (@$uids) {
1149                         $range_info->[0] = $uids->[-1] + 1; # update $beg
1150                         return;
1151                 } else { # all done
1152                         return 0;
1153                 }
1154         }
1155 }
1156
1157 sub search_xap_range { # long_response
1158         my ($self, $tag, $q, $range_info) = @_;
1159         my $uids = [];
1160         if (defined(my $err = refill_xap($self, $uids, $range_info, $q))) {
1161                 $err ||= 'OK Search done';
1162                 $self->write("\r\n$tag $err\r\n");
1163                 return;
1164         }
1165         $self->msg_more(join(' ', '', @$uids));
1166         1; # more
1167 }
1168
1169 sub cmd_uid_search ($$$;) {
1170         my ($self, $tag) = splice(@_, 0, 2);
1171         my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
1172         my $q = parse_query($self, \@_);
1173         return "$tag $q\r\n" if !ref($q);
1174         my ($sql, $range_info) = delete @$q{qw(sql range_info)};
1175         if (!scalar(keys %$q)) { # overview.sqlite3
1176                 $self->msg_more('* SEARCH');
1177                 long_response($self, \&search_uid_range,
1178                                 $tag, $sql, $range_info);
1179         } elsif ($q = $q->{xap}) {
1180                 $self->msg_more('* SEARCH');
1181                 long_response($self, \&search_xap_range,
1182                                 $tag, $q, $range_info);
1183         } else {
1184                 "$tag BAD Error\r\n";
1185         }
1186 }
1187
1188 # note: MSN SEARCH is NOT supported.  Do any widely-used MUAs
1189 # rely on MSNs from SEARCH results?  Let us know at meta@public-inbox.org
1190
1191 sub args_ok ($$) { # duplicated from PublicInbox::NNTP
1192         my ($cb, $argc) = @_;
1193         my $tot = prototype $cb;
1194         my ($nreq, undef) = split(';', $tot);
1195         $nreq = ($nreq =~ tr/$//) - 1;
1196         $tot = ($tot =~ tr/$//) - 1;
1197         ($argc <= $tot && $argc >= $nreq);
1198 }
1199
1200 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
1201 sub process_line ($$) {
1202         my ($self, $l) = @_;
1203
1204         # TODO: IMAP allows literals for big requests to upload messages
1205         # (which we don't support) but maybe some big search queries use it.
1206         my ($tag, $req, @args) = parse_line('[ \t]+', 0, $l);
1207         pop(@args) if (@args && !defined($args[-1]));
1208         if (@args && uc($req) eq 'UID') {
1209                 $req .= "_".(shift @args);
1210         }
1211         my $res = eval {
1212                 if (my $cmd = $self->can('cmd_'.lc($req // ''))) {
1213                         defined($self->{-idle_tag}) ?
1214                                 "$self->{-idle_tag} BAD expected DONE\r\n" :
1215                                 $cmd->($self, $tag, @args);
1216                 } elsif (uc($tag // '') eq 'DONE' && !defined($req)) {
1217                         cmd_done($self, $tag);
1218                 } else { # this is weird
1219                         auth_challenge_ok($self) //
1220                                         ($tag // '*') .
1221                                         ' BAD Error in IMAP command '.
1222                                         ($req // '(???)').
1223                                         ": Unknown command\r\n";
1224                 }
1225         };
1226         my $err = $@;
1227         if ($err && $self->{sock}) {
1228                 $l =~ s/\r?\n//s;
1229                 err($self, 'error from: %s (%s)', $l, $err);
1230                 $tag //= '*';
1231                 $res = "$tag BAD program fault - command not performed\r\n";
1232         }
1233         return 0 unless defined $res;
1234         $self->write($res);
1235 }
1236
1237 sub long_step {
1238         my ($self) = @_;
1239         # wbuf is unset or empty, here; {long} may add to it
1240         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
1241         my $more = eval { $cb->($self, @args) };
1242         if ($@ || !$self->{sock}) { # something bad happened...
1243                 delete $self->{long_cb};
1244                 my $elapsed = now() - $t0;
1245                 if ($@) {
1246                         err($self,
1247                             "%s during long response[$fd] - %0.6f",
1248                             $@, $elapsed);
1249                 }
1250                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
1251                 $self->close;
1252         } elsif ($more) { # $self->{wbuf}:
1253                 $self->update_idle_time;
1254
1255                 # control passed to $more may be a GitAsyncCat object
1256                 requeue_once($self) if !ref($more);
1257         } else { # all done!
1258                 delete $self->{long_cb};
1259                 my $elapsed = now() - $t0;
1260                 my $fd = fileno($self->{sock});
1261                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
1262                 my $wbuf = $self->{wbuf}; # do NOT autovivify
1263
1264                 $self->requeue unless $wbuf && @$wbuf;
1265         }
1266 }
1267
1268 sub err ($$;@) {
1269         my ($self, $fmt, @args) = @_;
1270         printf { $self->{imapd}->{err} } $fmt."\n", @args;
1271 }
1272
1273 sub out ($$;@) {
1274         my ($self, $fmt, @args) = @_;
1275         printf { $self->{imapd}->{out} } $fmt."\n", @args;
1276 }
1277
1278 sub long_response ($$;@) {
1279         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
1280
1281         my $sock = $self->{sock} or return;
1282         # make sure we disable reading during a long response,
1283         # clients should not be sending us stuff and making us do more
1284         # work while we are stream a response to them
1285         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
1286         long_step($self); # kick off!
1287         undef;
1288 }
1289
1290 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1291 sub event_step {
1292         my ($self) = @_;
1293
1294         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1295
1296         $self->update_idle_time;
1297         # only read more requests if we've drained the write buffer,
1298         # otherwise we can be buffering infinitely w/o backpressure
1299
1300         my $rbuf = $self->{rbuf} // \(my $x = '');
1301         my $line = index($$rbuf, "\n");
1302         while ($line < 0) {
1303                 if (length($$rbuf) >= LINE_MAX) {
1304                         $self->write(\"\* BAD request too long\r\n");
1305                         return $self->close;
1306                 }
1307                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1308                 $line = index($$rbuf, "\n");
1309         }
1310         $line = substr($$rbuf, 0, $line + 1, '');
1311         $line =~ s/\r?\n\z//s;
1312         return $self->close if $line =~ /[[:cntrl:]]/s;
1313         my $t0 = now();
1314         my $fd = fileno($self->{sock});
1315         my $r = eval { process_line($self, $line) };
1316         my $pending = $self->{wbuf} ? ' pending' : '';
1317         out($self, "[$fd] %s - %0.6f$pending - $r", $line, now() - $t0);
1318
1319         return $self->close if $r < 0;
1320         $self->rbuf_idle($rbuf);
1321         $self->update_idle_time;
1322
1323         # maybe there's more pipelined data, or we'll have
1324         # to register it for socket-readiness notifications
1325         $self->requeue unless $pending;
1326 }
1327
1328 sub compressed { undef }
1329
1330 sub zflush {} # overridden by IMAPdeflate
1331
1332 # RFC 4978
1333 sub cmd_compress ($$$) {
1334         my ($self, $tag, $alg) = @_;
1335         return "$tag BAD DEFLATE only\r\n" if uc($alg) ne "DEFLATE";
1336         return "$tag BAD COMPRESS active\r\n" if $self->compressed;
1337
1338         # CRIME made TLS compression obsolete
1339         # return "$tag NO [COMPRESSIONACTIVE]\r\n" if $self->tls_compressed;
1340
1341         PublicInbox::IMAPdeflate->enable($self, $tag);
1342         $self->requeue;
1343         undef
1344 }
1345
1346 sub cmd_starttls ($$) {
1347         my ($self, $tag) = @_;
1348         my $sock = $self->{sock} or return;
1349         if ($sock->can('stop_SSL') || $self->compressed) {
1350                 return "$tag BAD TLS or compression already enabled\r\n";
1351         }
1352         my $opt = $self->{imapd}->{accept_tls} or
1353                 return "$tag BAD can not initiate TLS negotiation\r\n";
1354         $self->write(\"$tag OK begin TLS negotiation now\r\n");
1355         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
1356         $self->requeue if PublicInbox::DS::accept_tls_step($self);
1357         undef;
1358 }
1359
1360 # for graceful shutdown in PublicInbox::Daemon:
1361 sub busy {
1362         my ($self, $now) = @_;
1363         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1364 }
1365
1366 sub close {
1367         my ($self) = @_;
1368         if (my $ibx = delete $self->{ibx}) {
1369                 stop_idle($self, $ibx);
1370         }
1371         $self->SUPER::close; # PublicInbox::DS::close
1372 }
1373
1374 # we're read-only, so SELECT and EXAMINE do the same thing
1375 no warnings 'once';
1376 *cmd_select = \&cmd_examine;
1377
1378 package PublicInbox::IMAP_preauth;
1379 our @ISA = qw(PublicInbox::IMAP);
1380
1381 sub logged_in { 0 }
1382
1383 1;