lib/PublicInbox/IPC.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # base class for remote IPC calls and workqueues, requires Storable or Sereal
   5 # - ipc_do and ipc_worker_* is for a single worker/producer and uses pipes
   6 # - wq_io_do and wq_worker* is for a single producer and multiple workers,
   7 #   using SOCK_SEQPACKET for work distribution
   8 # use ipc_do when you need work done on a certain process
   9 # use wq_io_do when your work can be done on any idle worker
  10 package PublicInbox::IPC;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(Exporter);
  14 use Carp qw(croak);
  15 use PublicInbox::DS qw(dwaitpid);
  16 use PublicInbox::Spawn;
  17 use PublicInbox::OnDestroy;
  18 use PublicInbox::WQWorker;
  19 use Socket qw(AF_UNIX MSG_EOR SOCK_STREAM);
  20 my $MY_MAX_ARG_STRLEN = 4096 * 33; # extra 4K for serialization
  21 my $SEQPACKET = eval { Socket::SOCK_SEQPACKET() }; # portable enough?
  22 our @EXPORT_OK = qw(ipc_freeze ipc_thaw);
  23 my ($enc, $dec);
  24 # ->imports at BEGIN turns sereal_*_with_object into custom ops on 5.14+
  25 # and eliminate method call overhead
  26 BEGIN {
  27         eval {
  28                 require Sereal::Encoder;
  29                 require Sereal::Decoder;
  30                 Sereal::Encoder->import('sereal_encode_with_object');
  31                 Sereal::Decoder->import('sereal_decode_with_object');
  32                 ($enc, $dec) = (Sereal::Encoder->new, Sereal::Decoder->new);
  33         };
  34 };
  35
  36 if ($enc && $dec) { # should be custom ops
  37         *ipc_freeze = sub ($) { sereal_encode_with_object $enc, $_[0] };
  38         *ipc_thaw = sub ($) { sereal_decode_with_object $dec, $_[0], my $ret };
  39 } else {
  40         require Storable;
  41         *ipc_freeze = \&Storable::freeze;
  42         *ipc_thaw = \&Storable::thaw;
  43 }
  44
  45 my $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  46 our $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  47         require PublicInbox::CmdIPC4;
  48         $recv_cmd //= PublicInbox::CmdIPC4->can('recv_cmd4');
  49         PublicInbox::CmdIPC4->can('send_cmd4');
  50 } // do {
  51         require PublicInbox::Syscall;
  52         $recv_cmd //= PublicInbox::Syscall->can('recv_cmd4');
  53         PublicInbox::Syscall->can('send_cmd4');
  54 };
  55
  56 sub _get_rec ($) {
  57         my ($r) = @_;
  58         defined(my $len = <$r>) or return;
  59         chop($len) eq "\n" or croak "no LF byte in $len";
  60         defined(my $n = read($r, my $buf, $len)) or croak "read error: $!";
  61         $n == $len or croak "short read: $n != $len";
  62         ipc_thaw($buf);
  63 }
  64
  65 sub _send_rec ($$) {
  66         my ($w, $ref) = @_;
  67         my $buf = ipc_freeze($ref);
  68         print $w length($buf), "\n", $buf or croak "print: $!";
  69 }
  70
  71 sub ipc_return ($$$) {
  72         my ($w, $ret, $exc) = @_;
  73         _send_rec($w, $exc ? bless(\$exc, 'PublicInbox::IPC::Die') : $ret);
  74 }
  75
  76 sub ipc_worker_loop ($$$) {
  77         my ($self, $r_req, $w_res) = @_;
  78         my ($rec, $wantarray, $sub, @args);
  79         local $/ = "\n";
  80         while ($rec = _get_rec($r_req)) {
  81                 ($wantarray, $sub, @args) = @$rec;
  82                 # no waiting if client doesn't care,
  83                 # this is the overwhelmingly likely case
  84                 if (!defined($wantarray)) {
  85                         eval { $self->$sub(@args) };
  86                         warn "$$ die: $@ (from nowait $sub)\n" if $@;
  87                 } elsif ($wantarray) {
  88                         my @ret = eval { $self->$sub(@args) };
  89                         ipc_return($w_res, \@ret, $@);
  90                 } else { # '' => wantscalar
  91                         my $ret = eval { $self->$sub(@args) };
  92                         ipc_return($w_res, \$ret, $@);
  93                 }
  94         }
  95 }
  96
  97 # starts a worker if Sereal or Storable is installed
  98 sub ipc_worker_spawn {
  99         my ($self, $ident, $oldset, $fields) = @_;
 100         return if ($self->{-ipc_ppid} // -1) == $$; # idempotent
 101         delete(@$self{qw(-ipc_req -ipc_res -ipc_ppid -ipc_pid)});
 102         pipe(my ($r_req, $w_req)) or die "pipe: $!";
 103         pipe(my ($r_res, $w_res)) or die "pipe: $!";
 104         my $sigset = $oldset // PublicInbox::DS::block_signals();
 105         $self->ipc_atfork_prepare;
 106         my $seed = rand(0xffffffff);
 107         my $pid = fork // die "fork: $!";
 108         if ($pid == 0) {
 109                 srand($seed);
 110                 eval { Net::SSLeay::randomize() };
 111                 eval { PublicInbox::DS->Reset };
 112                 delete @$self{qw(-wq_s1 -wq_s2 -wq_workers -wq_ppid)};
 113                 $w_req = $r_res = undef;
 114                 $w_res->autoflush(1);
 115                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
 116                 local $0 = $ident;
 117                 # ensure we properly exit even if warn() dies:
 118                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 119                 eval {
 120                         $fields //= {};
 121                         local @$self{keys %$fields} = values(%$fields);
 122                         my $on_destroy = $self->ipc_atfork_child;
 123                         local @SIG{keys %SIG} = values %SIG;
 124                         PublicInbox::DS::sig_setmask($sigset);
 125                         ipc_worker_loop($self, $r_req, $w_res);
 126                 };
 127                 warn "worker $ident PID:$$ died: $@\n" if $@;
 128                 undef $end; # trigger exit
 129         }
 130         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 131         $r_req = $w_res = undef;
 132         $w_req->autoflush(1);
 133         $self->{-ipc_req} = $w_req;
 134         $self->{-ipc_res} = $r_res;
 135         $self->{-ipc_ppid} = $$;
 136         $self->{-ipc_pid} = $pid;
 137 }
 138
 139 sub ipc_worker_reap { # dwaitpid callback
 140         my ($args, $pid) = @_;
 141         my ($self, @uargs) = @$args;
 142         delete $self->{-wq_workers}->{$pid};
 143         return $self->{-reap_do}->($args, $pid) if $self->{-reap_do};
 144         return if !$?;
 145         my $s = $? & 127;
 146         # TERM(15) is our default exit signal, PIPE(13) is likely w/ pager
 147         warn "$self->{-wq_ident} PID:$pid died \$?=$?\n" if $s != 15 && $s != 13
 148 }
 149
 150 sub wq_wait_async {
 151         my ($self, $cb, @uargs) = @_;
 152         local $PublicInbox::DS::in_loop = 1;
 153         $self->{-reap_do} = $cb;
 154         my @pids = keys %{$self->{-wq_workers}};
 155         dwaitpid($_, \&ipc_worker_reap, [ $self, @uargs ]) for @pids;
 156 }
 157
 158 # for base class, override in sub classes
 159 sub ipc_atfork_prepare {}
 160
 161 sub wq_atexit_child {}
 162
 163 sub ipc_atfork_child {
 164         my ($self) = @_;
 165         my $io = delete($self->{-ipc_atfork_child_close}) or return;
 166         close($_) for @$io;
 167         undef;
 168 }
 169
 170 # idempotent, can be called regardless of whether worker is active or not
 171 sub ipc_worker_stop {
 172         my ($self) = @_;
 173         my ($pid, $ppid) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 174         my ($w_req, $r_res) = delete(@$self{qw(-ipc_req -ipc_res)});
 175         if (!$w_req && !$r_res) {
 176                 die "unexpected PID:$pid without IPC pipes" if $pid;
 177                 return; # idempotent
 178         }
 179         die 'no PID with IPC pipes' unless $pid;
 180         $w_req = $r_res = undef;
 181
 182         return if $$ != $ppid;
 183         dwaitpid($pid, \&ipc_worker_reap, [$self]);
 184 }
 185
 186 # use this if we have multiple readers reading curl or "pigz -dc"
 187 # and writing to the same store
 188 sub ipc_lock_init {
 189         my ($self, $f) = @_;
 190         $f // die 'BUG: no filename given';
 191         require PublicInbox::Lock;
 192         $self->{-ipc_lock} //= bless { lock_path => $f }, 'PublicInbox::Lock'
 193 }
 194
 195 sub _wait_return ($$) {
 196         my ($r_res, $sub) = @_;
 197         my $ret = _get_rec($r_res) // die "no response on $sub";
 198         die $$ret if ref($ret) eq 'PublicInbox::IPC::Die';
 199         wantarray ? @$ret : $$ret;
 200 }
 201
 202 # call $self->$sub(@args), on a worker if ipc_worker_spawn was used
 203 sub ipc_do {
 204         my ($self, $sub, @args) = @_;
 205         if (my $w_req = $self->{-ipc_req}) { # run in worker
 206                 my $ipc_lock = $self->{-ipc_lock};
 207                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 208                 if (defined(wantarray)) {
 209                         my $r_res = $self->{-ipc_res} or die 'no ipc_res';
 210                         _send_rec($w_req, [ wantarray, $sub, @args ]);
 211                         _wait_return($r_res, $sub);
 212                 } else { # likely, fire-and-forget into pipe
 213                         _send_rec($w_req, [ undef , $sub, @args ]);
 214                 }
 215         } else { # run locally
 216                 $self->$sub(@args);
 217         }
 218 }
 219
 220 # needed when there's multiple IPC workers and the parent forking
 221 # causes newer siblings to inherit older siblings sockets
 222 sub ipc_sibling_atfork_child {
 223         my ($self) = @_;
 224         my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 225         delete(@$self{qw(-ipc_req -ipc_res)});
 226         $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
 227 }
 228
 229 sub recv_and_run {
 230         my ($self, $s2, $len, $full_stream) = @_;
 231         my @fds = $recv_cmd->($s2, my $buf, $len // $MY_MAX_ARG_STRLEN);
 232         return if scalar(@fds) && !defined($fds[0]);
 233         my $n = length($buf) or return 0;
 234         my $nfd = 0;
 235         for my $fd (@fds) {
 236                 if (open(my $cmdfh, '+<&=', $fd)) {
 237                         $self->{$nfd++} = $cmdfh;
 238                         $cmdfh->autoflush(1);
 239                 } else {
 240                         die "$$ open(+<&=$fd) (FD:$nfd): $!";
 241                 }
 242         }
 243         while ($full_stream && $n < $len) {
 244                 my $r = sysread($s2, $buf, $len - $n, $n) // croak "read: $!";
 245                 croak "read EOF after $n/$len bytes" if $r == 0;
 246                 $n = length($buf);
 247         }
 248         # Sereal dies on truncated data, Storable returns undef
 249         my $args = ipc_thaw($buf) // die "thaw error on buffer of size: $n";
 250         undef $buf;
 251         my $sub = shift @$args;
 252         eval { $self->$sub(@$args) };
 253         warn "$$ $0 wq_worker: $sub: $@" if $@;
 254         delete @$self{0..($nfd-1)};
 255         $n;
 256 }
 257
 258 sub wq_worker_loop ($$) {
 259         my ($self, $bcast2) = @_;
 260         my $wqw = PublicInbox::WQWorker->new($self, $self->{-wq_s2});
 261         PublicInbox::WQWorker->new($self, $bcast2) if $bcast2;
 262         PublicInbox::DS->SetPostLoopCallback(sub { $wqw->{sock} });
 263         PublicInbox::DS::event_loop();
 264         PublicInbox::DS->Reset;
 265 }
 266
 267 sub do_sock_stream { # via wq_io_do, for big requests
 268         my ($self, $len) = @_;
 269         recv_and_run($self, my $s2 = delete $self->{0}, $len, 1);
 270 }
 271
 272 sub wq_broadcast {
 273         my ($self, $sub, @args) = @_;
 274         if (my $wkr = $self->{-wq_workers}) {
 275                 my $buf = ipc_freeze([$sub, @args]);
 276                 for my $bcast1 (values %$wkr) {
 277                         my $sock = $bcast1 // $self->{-wq_s1} // next;
 278                         send($sock, $buf, MSG_EOR) // croak "send: $!";
 279                         # XXX shouldn't have to deal with EMSGSIZE here...
 280                 }
 281         } else {
 282                 eval { $self->$sub(@args) };
 283                 warn "wq_broadcast: $@" if $@;
 284         }
 285 }
 286
 287 sub stream_in_full ($$$) {
 288         my ($s1, $fds, $buf) = @_;
 289         socketpair(my $r, my $w, AF_UNIX, SOCK_STREAM, 0) or
 290                 croak "socketpair: $!";
 291         my $n = $send_cmd->($s1, [ fileno($r) ],
 292                         ipc_freeze(['do_sock_stream', length($buf)]),
 293                         MSG_EOR) // croak "sendmsg: $!";
 294         undef $r;
 295         $n = $send_cmd->($w, $fds, $buf, 0) // croak "sendmsg: $!";
 296         while ($n < length($buf)) {
 297                 my $x = syswrite($w, $buf, length($buf) - $n, $n) //
 298                                 croak "syswrite: $!";
 299                 croak "syswrite wrote 0 bytes" if $x == 0;
 300                 $n += $x;
 301         }
 302 }
 303
 304 sub wq_io_do { # always async
 305         my ($self, $sub, $ios, @args) = @_;
 306         if (my $s1 = $self->{-wq_s1}) { # run in worker
 307                 my $fds = [ map { fileno($_) } @$ios ];
 308                 my $buf = ipc_freeze([$sub, @args]);
 309                 if (length($buf) > $MY_MAX_ARG_STRLEN) {
 310                         stream_in_full($s1, $fds, $buf);
 311                 } else {
 312                         my $n = $send_cmd->($s1, $fds, $buf, MSG_EOR);
 313                         return if defined($n); # likely
 314                         $!{ETOOMANYREFS} and
 315                                 croak "sendmsg: $! (check RLIMIT_NOFILE)";
 316                         $!{EMSGSIZE} ? stream_in_full($s1, $fds, $buf) :
 317                                 croak("sendmsg: $!");
 318                 }
 319         } else {
 320                 @$self{0..$#$ios} = @$ios;
 321                 eval { $self->$sub(@args) };
 322                 warn "wq_io_do: $@" if $@;
 323                 delete @$self{0..$#$ios}; # don't close
 324         }
 325 }
 326
 327 sub wq_sync_run {
 328         my ($self, $wantarray, $sub, @args) = @_;
 329         if ($wantarray) {
 330                 my @ret = eval { $self->$sub(@args) };
 331                 ipc_return($self->{0}, \@ret, $@);
 332         } else { # '' => wantscalar
 333                 my $ret = eval { $self->$sub(@args) };
 334                 ipc_return($self->{0}, \$ret, $@);
 335         }
 336 }
 337
 338 sub wq_do {
 339         my ($self, $sub, @args) = @_;
 340         if (defined(wantarray)) {
 341                 pipe(my ($r, $w)) or die "pipe: $!";
 342                 wq_io_do($self, 'wq_sync_run', [ $w ], wantarray, $sub, @args);
 343                 undef $w;
 344                 _wait_return($r, $sub);
 345         } else {
 346                 wq_io_do($self, $sub, [], @args);
 347         }
 348 }
 349
 350 sub prepare_nonblock {
 351         ($_[0]->{-wq_s1} // die 'BUG: no {-wq_s1}')->blocking(0);
 352         $_[0]->{-reap_do} or die 'BUG: {-reap_do} needed for nonblock';
 353         require PublicInbox::WQBlocked;
 354 }
 355
 356 sub wq_nonblock_do { # always async
 357         my ($self, $sub, @args) = @_;
 358         my $buf = ipc_freeze([$sub, @args]);
 359         if ($self->{wqb}) { # saturated once, assume saturated forever
 360                 $self->{wqb}->flush_send($buf);
 361         } else {
 362                 $send_cmd->($self->{-wq_s1}, [], $buf, MSG_EOR) //
 363                         ($!{EAGAIN} ? PublicInbox::WQBlocked->new($self, $buf)
 364                                         : croak("sendmsg: $!"));
 365         }
 366 }
 367
 368 sub _wq_worker_start ($$$$) {
 369         my ($self, $oldset, $fields, $one) = @_;
 370         my ($bcast1, $bcast2);
 371         $one or socketpair($bcast1, $bcast2, AF_UNIX, $SEQPACKET, 0) or
 372                                                         die "socketpair: $!";
 373         my $seed = rand(0xffffffff);
 374         my $pid = fork // die "fork: $!";
 375         if ($pid == 0) {
 376                 srand($seed);
 377                 eval { Net::SSLeay::randomize() };
 378                 undef $bcast1;
 379                 eval { PublicInbox::DS->Reset };
 380                 delete @$self{qw(-wq_s1 -wq_ppid)};
 381                 $self->{-wq_worker_nr} =
 382                                 keys %{delete($self->{-wq_workers}) // {}};
 383                 $SIG{$_} = 'DEFAULT' for (qw(TTOU TTIN TERM QUIT INT CHLD));
 384                 local $0 = $one ? $self->{-wq_ident} :
 385                         "$self->{-wq_ident} $self->{-wq_worker_nr}";
 386                 # ensure we properly exit even if warn() dies:
 387                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 388                 eval {
 389                         $fields //= {};
 390                         local @$self{keys %$fields} = values(%$fields);
 391                         my $on_destroy = $self->ipc_atfork_child;
 392                         local @SIG{keys %SIG} = values %SIG;
 393                         PublicInbox::DS::sig_setmask($oldset);
 394                         wq_worker_loop($self, $bcast2);
 395                 };
 396                 warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
 397                 undef $end; # trigger exit
 398         } else {
 399                 $self->{-wq_workers}->{$pid} = $bcast1;
 400         }
 401 }
 402
 403 # starts workqueue workers if Sereal or Storable is installed
 404 sub wq_workers_start {
 405         my ($self, $ident, $nr_workers, $oldset, $fields) = @_;
 406         ($send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
 407         return if $self->{-wq_s1}; # idempotent
 408         $self->{-wq_s1} = $self->{-wq_s2} = undef;
 409         socketpair($self->{-wq_s1}, $self->{-wq_s2}, AF_UNIX, $SEQPACKET, 0) or
 410                 die "socketpair: $!";
 411         $self->ipc_atfork_prepare;
 412         $nr_workers //= $self->{-wq_nr_workers}; # was set earlier
 413         my $sigset = $oldset // PublicInbox::DS::block_signals();
 414         $self->{-wq_workers} = {};
 415         $self->{-wq_ident} = $ident;
 416         my $one = $nr_workers == 1;
 417         $self->{-wq_nr_workers} = $nr_workers;
 418         _wq_worker_start($self, $sigset, $fields, $one) for (1..$nr_workers);
 419         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 420         $self->{-wq_ppid} = $$;
 421 }
 422
 423 sub wq_close {
 424         my ($self) = @_;
 425         if (my $wqb = delete $self->{wqb}) {
 426                 $self->{-reap_do} or die 'BUG: {-reap_do} unset';
 427                 $wqb->enq_close;
 428         }
 429         delete @$self{qw(-wq_s1 -wq_s2)} or return;
 430         return if $self->{-reap_do};
 431         my @pids = keys %{$self->{-wq_workers}};
 432         dwaitpid($_, \&ipc_worker_reap, [ $self ]) for @pids;
 433 }
 434
 435 sub wq_kill {
 436         my ($self, $sig) = @_;
 437         kill($sig // 'TERM', keys %{$self->{-wq_workers}});
 438 }
 439
 440 sub DESTROY {
 441         my ($self) = @_;
 442         my $ppid = $self->{-wq_ppid};
 443         wq_kill($self) if $ppid && $ppid == $$;
 444         wq_close($self);
 445         ipc_worker_stop($self);
 446 }
 447
 448 sub detect_nproc () {
 449         # _SC_NPROCESSORS_ONLN = 84 on both Linux glibc and musl
 450         return POSIX::sysconf(84) if $^O eq 'linux';
 451         return POSIX::sysconf(58) if $^O eq 'freebsd';
 452         # TODO: more OSes
 453
 454         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
 455         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
 456                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
 457         }
 458         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
 459                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
 460         }
 461
 462         # should we bother with `sysctl hw.ncpu`?  Those only give
 463         # us total processor count, not online processor count.
 464         undef
 465 }
 466
 467 1;