lib/PublicInbox/IPC.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # base class for remote IPC calls and workqueues, requires Storable or Sereal
   5 # - ipc_do and ipc_worker_* is for a single worker/producer and uses pipes
   6 # - wq_io_do and wq_worker* is for a single producer and multiple workers,
   7 #   using SOCK_SEQPACKET for work distribution
   8 # use ipc_do when you need work done on a certain process
   9 # use wq_io_do when your work can be done on any idle worker
  10 package PublicInbox::IPC;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(Exporter);
  14 use Carp qw(croak);
  15 use PublicInbox::DS qw(dwaitpid);
  16 use PublicInbox::Spawn;
  17 use PublicInbox::OnDestroy;
  18 use PublicInbox::WQWorker;
  19 use Socket qw(AF_UNIX MSG_EOR SOCK_STREAM);
  20 my $MY_MAX_ARG_STRLEN = 4096 * 33; # extra 4K for serialization
  21 my $SEQPACKET = eval { Socket::SOCK_SEQPACKET() }; # portable enough?
  22 our @EXPORT_OK = qw(ipc_freeze ipc_thaw);
  23 my ($enc, $dec);
  24 # ->imports at BEGIN turns sereal_*_with_object into custom ops on 5.14+
  25 # and eliminate method call overhead
  26 BEGIN {
  27         eval {
  28                 require Sereal::Encoder;
  29                 require Sereal::Decoder;
  30                 Sereal::Encoder->import('sereal_encode_with_object');
  31                 Sereal::Decoder->import('sereal_decode_with_object');
  32                 ($enc, $dec) = (Sereal::Encoder->new, Sereal::Decoder->new);
  33         };
  34 };
  35
  36 if ($enc && $dec) { # should be custom ops
  37         *ipc_freeze = sub ($) { sereal_encode_with_object $enc, $_[0] };
  38         *ipc_thaw = sub ($) { sereal_decode_with_object $dec, $_[0], my $ret };
  39 } else {
  40         require Storable;
  41         *ipc_freeze = \&Storable::freeze;
  42         *ipc_thaw = \&Storable::thaw;
  43 }
  44
  45 my $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  46 my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  47         require PublicInbox::CmdIPC4;
  48         $recv_cmd //= PublicInbox::CmdIPC4->can('recv_cmd4');
  49         PublicInbox::CmdIPC4->can('send_cmd4');
  50 };
  51
  52 sub _get_rec ($) {
  53         my ($r) = @_;
  54         defined(my $len = <$r>) or return;
  55         chop($len) eq "\n" or croak "no LF byte in $len";
  56         defined(my $n = read($r, my $buf, $len)) or croak "read error: $!";
  57         $n == $len or croak "short read: $n != $len";
  58         ipc_thaw($buf);
  59 }
  60
  61 sub _send_rec ($$) {
  62         my ($w, $ref) = @_;
  63         my $buf = ipc_freeze($ref);
  64         print $w length($buf), "\n", $buf or croak "print: $!";
  65 }
  66
  67 sub ipc_return ($$$) {
  68         my ($w, $ret, $exc) = @_;
  69         _send_rec($w, $exc ? bless(\$exc, 'PublicInbox::IPC::Die') : $ret);
  70 }
  71
  72 sub ipc_worker_loop ($$$) {
  73         my ($self, $r_req, $w_res) = @_;
  74         my ($rec, $wantarray, $sub, @args);
  75         local $/ = "\n";
  76         while ($rec = _get_rec($r_req)) {
  77                 ($wantarray, $sub, @args) = @$rec;
  78                 # no waiting if client doesn't care,
  79                 # this is the overwhelmingly likely case
  80                 if (!defined($wantarray)) {
  81                         eval { $self->$sub(@args) };
  82                         warn "$$ die: $@ (from nowait $sub)\n" if $@;
  83                 } elsif ($wantarray) {
  84                         my @ret = eval { $self->$sub(@args) };
  85                         ipc_return($w_res, \@ret, $@);
  86                 } else { # '' => wantscalar
  87                         my $ret = eval { $self->$sub(@args) };
  88                         ipc_return($w_res, \$ret, $@);
  89                 }
  90         }
  91 }
  92
  93 # starts a worker if Sereal or Storable is installed
  94 sub ipc_worker_spawn {
  95         my ($self, $ident, $oldset, $fields) = @_;
  96         return if ($self->{-ipc_ppid} // -1) == $$; # idempotent
  97         delete(@$self{qw(-ipc_req -ipc_res -ipc_ppid -ipc_pid)});
  98         pipe(my ($r_req, $w_req)) or die "pipe: $!";
  99         pipe(my ($r_res, $w_res)) or die "pipe: $!";
 100         my $sigset = $oldset // PublicInbox::DS::block_signals();
 101         $self->ipc_atfork_prepare;
 102         my $seed = rand(0xffffffff);
 103         my $pid = fork // die "fork: $!";
 104         if ($pid == 0) {
 105                 srand($seed);
 106                 eval { PublicInbox::DS->Reset };
 107                 delete @$self{qw(-wq_s1 -wq_s2 -wq_workers -wq_ppid)};
 108                 $w_req = $r_res = undef;
 109                 $w_res->autoflush(1);
 110                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
 111                 local $0 = $ident;
 112                 # ensure we properly exit even if warn() dies:
 113                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 114                 eval {
 115                         $fields //= {};
 116                         local @$self{keys %$fields} = values(%$fields);
 117                         my $on_destroy = $self->ipc_atfork_child;
 118                         local %SIG = %SIG;
 119                         PublicInbox::DS::sig_setmask($sigset);
 120                         ipc_worker_loop($self, $r_req, $w_res);
 121                 };
 122                 warn "worker $ident PID:$$ died: $@\n" if $@;
 123                 undef $end; # trigger exit
 124         }
 125         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 126         $r_req = $w_res = undef;
 127         $w_req->autoflush(1);
 128         $self->{-ipc_req} = $w_req;
 129         $self->{-ipc_res} = $r_res;
 130         $self->{-ipc_ppid} = $$;
 131         $self->{-ipc_pid} = $pid;
 132 }
 133
 134 sub ipc_worker_reap { # dwaitpid callback
 135         my ($args, $pid) = @_;
 136         return if !$?;
 137         # TERM(15) is our default exit signal, PIPE(13) is likely w/ pager
 138         my $s = $? & 127;
 139         warn "PID:$pid died with \$?=$?\n" if $s != 15 && $s != 13;
 140 }
 141
 142 sub wq_wait_old {
 143         my ($self, $cb, @args) = @_;
 144         my $pids = delete $self->{"-wq_old_pids.$$"} or return;
 145         dwaitpid($_, $cb // \&ipc_worker_reap, [$self, @args]) for @$pids;
 146 }
 147
 148 # for base class, override in sub classes
 149 sub ipc_atfork_prepare {}
 150
 151 sub wq_atexit_child {}
 152
 153 sub ipc_atfork_child {
 154         my ($self) = @_;
 155         my $io = delete($self->{-ipc_atfork_child_close}) or return;
 156         close($_) for @$io;
 157         undef;
 158 }
 159
 160 # idempotent, can be called regardless of whether worker is active or not
 161 sub ipc_worker_stop {
 162         my ($self, $args) = @_;
 163         my ($pid, $ppid) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 164         my ($w_req, $r_res) = delete(@$self{qw(-ipc_req -ipc_res)});
 165         if (!$w_req && !$r_res) {
 166                 die "unexpected PID:$pid without IPC pipes" if $pid;
 167                 return; # idempotent
 168         }
 169         die 'no PID with IPC pipes' unless $pid;
 170         $w_req = $r_res = undef;
 171
 172         return if $$ != $ppid;
 173         dwaitpid($pid, \&ipc_worker_reap, [$self, $args]);
 174 }
 175
 176 # use this if we have multiple readers reading curl or "pigz -dc"
 177 # and writing to the same store
 178 sub ipc_lock_init {
 179         my ($self, $f) = @_;
 180         $f // die 'BUG: no filename given';
 181         require PublicInbox::Lock;
 182         $self->{-ipc_lock} //= bless { lock_path => $f }, 'PublicInbox::Lock'
 183 }
 184
 185 # call $self->$sub(@args), on a worker if ipc_worker_spawn was used
 186 sub ipc_do {
 187         my ($self, $sub, @args) = @_;
 188         if (my $w_req = $self->{-ipc_req}) { # run in worker
 189                 my $ipc_lock = $self->{-ipc_lock};
 190                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 191                 if (defined(wantarray)) {
 192                         my $r_res = $self->{-ipc_res} or die 'no ipc_res';
 193                         _send_rec($w_req, [ wantarray, $sub, @args ]);
 194                         my $ret = _get_rec($r_res) // die "no response on $sub";
 195                         die $$ret if ref($ret) eq 'PublicInbox::IPC::Die';
 196                         wantarray ? @$ret : $$ret;
 197                 } else { # likely, fire-and-forget into pipe
 198                         _send_rec($w_req, [ undef , $sub, @args ]);
 199                 }
 200         } else { # run locally
 201                 $self->$sub(@args);
 202         }
 203 }
 204
 205 # needed when there's multiple IPC workers and the parent forking
 206 # causes newer siblings to inherit older siblings sockets
 207 sub ipc_sibling_atfork_child {
 208         my ($self) = @_;
 209         my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 210         delete(@$self{qw(-ipc_req -ipc_res)});
 211         $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
 212 }
 213
 214 sub recv_and_run {
 215         my ($self, $s2, $len, $full_stream) = @_;
 216         my @fds = $recv_cmd->($s2, my $buf, $len // $MY_MAX_ARG_STRLEN);
 217         return if scalar(@fds) && !defined($fds[0]);
 218         my $n = length($buf) or return 0;
 219         my $nfd = 0;
 220         for my $fd (@fds) {
 221                 if (open(my $cmdfh, '+<&=', $fd)) {
 222                         $self->{$nfd++} = $cmdfh;
 223                         $cmdfh->autoflush(1);
 224                 } else {
 225                         die "$$ open(+<&=$fd) (FD:$nfd): $!";
 226                 }
 227         }
 228         while ($full_stream && $n < $len) {
 229                 my $r = sysread($s2, $buf, $len - $n, $n) // croak "read: $!";
 230                 croak "read EOF after $n/$len bytes" if $r == 0;
 231                 $n = length($buf);
 232         }
 233         # Sereal dies on truncated data, Storable returns undef
 234         my $args = ipc_thaw($buf) // die "thaw error on buffer of size: $n";
 235         undef $buf;
 236         my $sub = shift @$args;
 237         eval { $self->$sub(@$args) };
 238         warn "$$ $0 wq_worker: $@" if $@;
 239         delete @$self{0..($nfd-1)};
 240         $n;
 241 }
 242
 243 sub wq_worker_loop ($) {
 244         my ($self, $bcast_a) = @_;
 245         my $wqw = PublicInbox::WQWorker->new($self);
 246         PublicInbox::WQWorker->new($self, '-wq_bcast2');
 247         PublicInbox::DS->SetPostLoopCallback(sub { $wqw->{sock} });
 248         PublicInbox::DS->EventLoop;
 249         PublicInbox::DS->Reset;
 250 }
 251
 252 sub do_sock_stream { # via wq_io_do, for big requests
 253         my ($self, $len) = @_;
 254         recv_and_run($self, my $s2 = delete $self->{0}, $len, 1);
 255 }
 256
 257 sub wq_broadcast {
 258         my ($self, $sub, @args) = @_;
 259         if (my $wkr = $self->{-wq_workers}) {
 260                 for my $bcast1 (values %$wkr) {
 261                         my $buf = ipc_freeze([$sub, @args]);
 262                         send($bcast1, $buf, MSG_EOR) // croak "send: $!";
 263                         # XXX shouldn't have to deal with EMSGSIZE here...
 264                 }
 265         } else {
 266                 eval { $self->$sub(@args) };
 267                 warn "wq_broadcast: $@" if $@;
 268         }
 269 }
 270
 271 sub stream_in_full ($$$) {
 272         my ($s1, $fds, $buf) = @_;
 273         socketpair(my $r, my $w, AF_UNIX, SOCK_STREAM, 0) or
 274                 croak "socketpair: $!";
 275         my $n = $send_cmd->($s1, [ fileno($r) ],
 276                         ipc_freeze(['do_sock_stream', length($buf)]),
 277                         MSG_EOR) // croak "sendmsg: $!";
 278         undef $r;
 279         $n = $send_cmd->($w, $fds, $buf, 0) // croak "sendmsg: $!";
 280         while ($n < length($buf)) {
 281                 my $x = syswrite($w, $buf, length($buf) - $n, $n) //
 282                                 croak "syswrite: $!";
 283                 croak "syswrite wrote 0 bytes" if $x == 0;
 284                 $n += $x;
 285         }
 286 }
 287
 288 sub wq_io_do { # always async
 289         my ($self, $sub, $ios, @args) = @_;
 290         if (my $s1 = $self->{-wq_s1}) { # run in worker
 291                 my $fds = [ map { fileno($_) } @$ios ];
 292                 my $buf = ipc_freeze([$sub, @args]);
 293                 if (length($buf) > $MY_MAX_ARG_STRLEN) {
 294                         stream_in_full($s1, $fds, $buf);
 295                 } else {
 296                         my $n = $send_cmd->($s1, $fds, $buf, MSG_EOR);
 297                         return if defined($n); # likely
 298                         $!{ETOOMANYREFS} and
 299                                 croak "sendmsg: $! (check RLIMIT_NOFILE)";
 300                         $!{EMSGSIZE} ? stream_in_full($s1, $fds, $buf) :
 301                         croak("sendmsg: $!");
 302                 }
 303         } else {
 304                 @$self{0..$#$ios} = @$ios;
 305                 eval { $self->$sub(@args) };
 306                 warn "wq_io_do: $@" if $@;
 307                 delete @$self{0..$#$ios}; # don't close
 308         }
 309 }
 310
 311 sub _wq_worker_start ($$$) {
 312         my ($self, $oldset, $fields) = @_;
 313         my ($bcast1, $bcast2);
 314         socketpair($bcast1, $bcast2, AF_UNIX, $SEQPACKET, 0) or
 315                                                 die "socketpair: $!";
 316         my $seed = rand(0xffffffff);
 317         my $pid = fork // die "fork: $!";
 318         if ($pid == 0) {
 319                 srand($seed);
 320                 undef $bcast1;
 321                 eval { PublicInbox::DS->Reset };
 322                 delete @$self{qw(-wq_s1 -wq_ppid)};
 323                 $self->{-wq_worker_nr} =
 324                                 keys %{delete($self->{-wq_workers}) // {}};
 325                 $SIG{$_} = 'IGNORE' for (qw(PIPE));
 326                 $SIG{$_} = 'DEFAULT' for (qw(TTOU TTIN TERM QUIT INT CHLD));
 327                 local $0 = "$self->{-wq_ident} $self->{-wq_worker_nr}";
 328                 # ensure we properly exit even if warn() dies:
 329                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 330                 eval {
 331                         $fields //= {};
 332                         local @$self{keys %$fields} = values(%$fields);
 333                         my $on_destroy = $self->ipc_atfork_child;
 334                         local %SIG = %SIG;
 335                         PublicInbox::DS::sig_setmask($oldset);
 336                         $self->{-wq_bcast2} = $bcast2;
 337                         wq_worker_loop($self);
 338                 };
 339                 warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
 340                 undef $end; # trigger exit
 341         } else {
 342                 $self->{-wq_workers}->{$pid} = $bcast1;
 343         }
 344 }
 345
 346 # starts workqueue workers if Sereal or Storable is installed
 347 sub wq_workers_start {
 348         my ($self, $ident, $nr_workers, $oldset, $fields) = @_;
 349         ($send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
 350         return if $self->{-wq_s1}; # idempotent
 351         $self->{-wq_s1} = $self->{-wq_s2} = undef;
 352         socketpair($self->{-wq_s1}, $self->{-wq_s2}, AF_UNIX, $SEQPACKET, 0) or
 353                 die "socketpair: $!";
 354         $self->ipc_atfork_prepare;
 355         $nr_workers //= $self->{-wq_nr_workers};
 356         my $sigset = $oldset // PublicInbox::DS::block_signals();
 357         $self->{-wq_workers} = {};
 358         $self->{-wq_ident} = $ident;
 359         _wq_worker_start($self, $sigset, $fields) for (1..$nr_workers);
 360         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 361         $self->{-wq_ppid} = $$;
 362 }
 363
 364 sub wq_worker_incr { # SIGTTIN handler
 365         my ($self, $oldset, $fields) = @_;
 366         $self->{-wq_s2} or return;
 367         die "-wq_nr_workers locked" if defined $self->{-wq_nr_workers};
 368         $self->ipc_atfork_prepare;
 369         my $sigset = $oldset // PublicInbox::DS::block_signals();
 370         _wq_worker_start($self, $sigset, $fields);
 371         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 372 }
 373
 374 sub wq_exit { # wakes up wq_worker_decr_wait
 375         send($_[0]->{-wq_s2}, $$, MSG_EOR) // die "$$ send: $!";
 376         exit;
 377 }
 378
 379 sub wq_worker_decr { # SIGTTOU handler, kills first idle worker
 380         my ($self) = @_;
 381         return unless wq_workers($self);
 382         die "-wq_nr_workers locked" if defined $self->{-wq_nr_workers};
 383         $self->wq_io_do('wq_exit');
 384         # caller must call wq_worker_decr_wait in main loop
 385 }
 386
 387 sub wq_worker_decr_wait {
 388         my ($self, $timeout, $cb, @args) = @_;
 389         return if $self->{-wq_ppid} != $$; # can't reap siblings or parents
 390         die "-wq_nr_workers locked" if defined $self->{-wq_nr_workers};
 391         my $s1 = $self->{-wq_s1} // croak 'BUG: no wq_s1';
 392         vec(my $rin = '', fileno($s1), 1) = 1;
 393         select(my $rout = $rin, undef, undef, $timeout) or
 394                 croak 'timed out waiting for wq_exit';
 395         recv($s1, my $pid, 64, 0) // croak "recv: $!";
 396         my $workers = $self->{-wq_workers} // croak 'BUG: no wq_workers';
 397         delete $workers->{$pid} // croak "BUG: PID:$pid invalid";
 398         dwaitpid($pid, $cb // \&ipc_worker_reap, [ $self, @args ]);
 399 }
 400
 401 # set or retrieve number of workers
 402 sub wq_workers {
 403         my ($self, $nr, $cb, @args) = @_;
 404         my $cur = $self->{-wq_workers} or return;
 405         if (defined $nr) {
 406                 while (scalar(keys(%$cur)) > $nr) {
 407                         $self->wq_worker_decr;
 408                         $self->wq_worker_decr_wait(undef, $cb, @args);
 409                 }
 410                 $self->wq_worker_incr while scalar(keys(%$cur)) < $nr;
 411         }
 412         scalar(keys(%$cur));
 413 }
 414
 415 sub wq_close {
 416         my ($self, $nohang, $cb, @args) = @_;
 417         delete @$self{qw(-wq_s1 -wq_s2)} or return;
 418         my $ppid = delete $self->{-wq_ppid} or return;
 419         my $workers = delete $self->{-wq_workers} // die 'BUG: no wq_workers';
 420         return if $ppid != $$; # can't reap siblings or parents
 421         my @pids = map { $_ + 0 } keys %$workers;
 422         if ($nohang) {
 423                 push @{$self->{"-wq_old_pids.$$"}}, @pids;
 424         } else {
 425                 $cb //= \&ipc_worker_reap;
 426                 unshift @args, $self;
 427                 dwaitpid($_, $cb, \@args) for @pids;
 428         }
 429 }
 430
 431 sub wq_kill_old {
 432         my ($self, $sig) = @_;
 433         my $pids = $self->{"-wq_old_pids.$$"} or return;
 434         kill($sig // 'TERM', @$pids);
 435 }
 436
 437 sub wq_kill {
 438         my ($self, $sig) = @_;
 439         my $workers = $self->{-wq_workers} or return;
 440         kill($sig // 'TERM', keys %$workers);
 441 }
 442
 443 sub DESTROY {
 444         my ($self) = @_;
 445         my $ppid = $self->{-wq_ppid};
 446         wq_kill($self) if $ppid && $ppid == $$;
 447         my $err = $?;
 448         wq_close($self);
 449         wq_wait_old($self);
 450         ipc_worker_stop($self);
 451         $? = $err if $err;
 452 }
 453
 454 sub detect_nproc () {
 455         # _SC_NPROCESSORS_ONLN = 84 on both Linux glibc and musl
 456         return POSIX::sysconf(84) if $^O eq 'linux';
 457         return POSIX::sysconf(58) if $^O eq 'freebsd';
 458         # TODO: more OSes
 459
 460         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
 461         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
 462                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
 463         }
 464         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
 465                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
 466         }
 467
 468         # should we bother with `sysctl hw.ncpu`?  Those only give
 469         # us total processor count, not online processor count.
 470         undef
 471 }
 472
 473 1;