lib/PublicInbox/IPC.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # base class for remote IPC calls and workqueues, requires Storable or Sereal
   5 package PublicInbox::IPC;
   6 use strict;
   7 use v5.10.1;
   8 use Carp qw(confess croak);
   9 use PublicInbox::DS qw(dwaitpid);
  10 use PublicInbox::Spawn;
  11 use POSIX qw(WNOHANG);
  12 use Socket qw(AF_UNIX MSG_EOR);
  13 my $SEQPACKET = eval { Socket::SOCK_SEQPACKET() }; # portable enough?
  14 use constant PIPE_BUF => $^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF();
  15 my $WQ_MAX_WORKERS = 4096;
  16 my ($enc, $dec);
  17 # ->imports at BEGIN turns sereal_*_with_object into custom ops on 5.14+
  18 # and eliminate method call overhead
  19 BEGIN {
  20         eval {
  21                 require Sereal::Encoder;
  22                 require Sereal::Decoder;
  23                 Sereal::Encoder->import('sereal_encode_with_object');
  24                 Sereal::Decoder->import('sereal_decode_with_object');
  25                 ($enc, $dec) = (Sereal::Encoder->new, Sereal::Decoder->new);
  26         };
  27 };
  28
  29 if ($enc && $dec) { # should be custom ops
  30         *freeze = sub ($) { sereal_encode_with_object $enc, $_[0] };
  31         *thaw = sub ($) { sereal_decode_with_object $dec, $_[0], my $ret };
  32 } else {
  33         eval { # some distros have Storable as a separate package from Perl
  34                 require Storable;
  35                 Storable->import(qw(freeze thaw));
  36                 $enc = 1;
  37         } // warn("Storable (part of Perl) missing: $@\n");
  38 }
  39
  40 my $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  41 my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  42         require PublicInbox::CmdIPC4;
  43         $recv_cmd //= PublicInbox::CmdIPC4->can('recv_cmd4');
  44         PublicInbox::CmdIPC4->can('send_cmd4');
  45 };
  46
  47 sub wq_set_recv_modes {
  48         my ($self, @modes) = @_;
  49         $self->{-wq_recv_modes} = \@modes;
  50 }
  51
  52 sub _get_rec ($) {
  53         my ($r) = @_;
  54         defined(my $len = <$r>) or return;
  55         chop($len) eq "\n" or croak "no LF byte in $len";
  56         defined(my $n = read($r, my $buf, $len)) or croak "read error: $!";
  57         $n == $len or croak "short read: $n != $len";
  58         thaw($buf);
  59 }
  60
  61 sub _pack_rec ($) {
  62         my ($ref) = @_;
  63         my $buf = freeze($ref);
  64         length($buf) . "\n" . $buf;
  65 }
  66
  67 sub _send_rec ($$) {
  68         my ($w, $ref) = @_;
  69         print $w _pack_rec($ref) or croak "print: $!";
  70 }
  71
  72 sub ipc_return ($$$) {
  73         my ($w, $ret, $exc) = @_;
  74         _send_rec($w, $exc ? bless(\$exc, 'PublicInbox::IPC::Die') : $ret);
  75 }
  76
  77 sub ipc_worker_loop ($$$) {
  78         my ($self, $r_req, $w_res) = @_;
  79         my ($rec, $wantarray, $sub, @args);
  80         local $/ = "\n";
  81         while ($rec = _get_rec($r_req)) {
  82                 ($wantarray, $sub, @args) = @$rec;
  83                 # no waiting if client doesn't care,
  84                 # this is the overwhelmingly likely case
  85                 if (!defined($wantarray)) {
  86                         eval { $self->$sub(@args) };
  87                         warn "$$ die: $@ (from nowait $sub)\n" if $@;
  88                 } elsif ($wantarray) {
  89                         my @ret = eval { $self->$sub(@args) };
  90                         ipc_return($w_res, \@ret, $@);
  91                 } else { # '' => wantscalar
  92                         my $ret = eval { $self->$sub(@args) };
  93                         ipc_return($w_res, \$ret, $@);
  94                 }
  95         }
  96 }
  97
  98 # starts a worker if Sereal or Storable is installed
  99 sub ipc_worker_spawn {
 100         my ($self, $ident, $oldset) = @_;
 101         return unless $enc; # no Sereal or Storable
 102         return if ($self->{-ipc_ppid} // -1) == $$; # idempotent
 103         delete(@$self{qw(-ipc_req -ipc_res -ipc_ppid -ipc_pid)});
 104         pipe(my ($r_req, $w_req)) or die "pipe: $!";
 105         pipe(my ($r_res, $w_res)) or die "pipe: $!";
 106         my $sigset = $oldset // PublicInbox::DS::block_signals();
 107         my $parent = $$;
 108         $self->ipc_atfork_prepare;
 109         defined(my $pid = fork) or die "fork: $!";
 110         if ($pid == 0) {
 111                 eval { PublicInbox::DS->Reset };
 112                 $w_req = $r_res = undef;
 113                 $w_res->autoflush(1);
 114                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
 115                 local $0 = $ident;
 116                 PublicInbox::DS::sig_setmask($sigset);
 117                 my $on_destroy = $self->ipc_atfork_child;
 118                 eval { ipc_worker_loop($self, $r_req, $w_res) };
 119                 die "worker $ident PID:$$ died: $@\n" if $@;
 120                 exit;
 121         }
 122         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 123         $r_req = $w_res = undef;
 124         $w_req->autoflush(1);
 125         $self->{-ipc_req} = $w_req;
 126         $self->{-ipc_res} = $r_res;
 127         $self->{-ipc_ppid} = $$;
 128         $self->{-ipc_pid} = $pid;
 129 }
 130
 131 sub ipc_worker_reap { # dwaitpid callback
 132         my ($self, $pid) = @_;
 133         warn "PID:$pid died with \$?=$?\n" if $?;
 134 }
 135
 136 # for base class, override in sub classes
 137 sub ipc_atfork_prepare {}
 138
 139 sub ipc_atfork_child {
 140         my ($self) = @_;
 141         my $io = delete($self->{-ipc_atfork_child_close}) or return;
 142         close($_) for @$io;
 143         undef;
 144 }
 145
 146 # idempotent, can be called regardless of whether worker is active or not
 147 sub ipc_worker_stop {
 148         my ($self) = @_;
 149         my ($pid, $ppid) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 150         my ($w_req, $r_res) = delete(@$self{qw(-ipc_req -ipc_res)});
 151         if (!$w_req && !$r_res) {
 152                 die "unexpected PID:$pid without IPC pipes" if $pid;
 153                 return; # idempotent
 154         }
 155         die 'no PID with IPC pipes' unless $pid;
 156         $w_req = $r_res = undef;
 157
 158         return if $$ != $ppid;
 159         dwaitpid($pid, \&ipc_worker_reap, $self);
 160 }
 161
 162 # use this if we have multiple readers reading curl or "pigz -dc"
 163 # and writing to the same store
 164 sub ipc_lock_init {
 165         my ($self, $f) = @_;
 166         require PublicInbox::Lock;
 167         $self->{-ipc_lock} //= bless { lock_path => $f }, 'PublicInbox::Lock'
 168 }
 169
 170 sub ipc_async_wait ($$) {
 171         my ($self, $max) = @_; # max == -1 to wait for all
 172         my $aif = $self->{-async_inflight} or return;
 173         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 174         while (my ($sub, $bytes, $cb, $cb_arg) = splice(@$aif, 0, 4)) {
 175                 my $ret = _get_rec($r_res) //
 176                         die "no response on $sub (req.size=$bytes)";
 177                 $self->{-async_inflight_bytes} -= $bytes;
 178
 179                 eval { $cb->($cb_arg, $ret) };
 180                 warn "E: $sub callback error: $@\n" if $@;
 181                 return if --$max == 0;
 182         }
 183 }
 184
 185 # call $self->$sub(@args), on a worker if ipc_worker_spawn was used
 186 sub ipc_do {
 187         my ($self, $sub, @args) = @_;
 188         if (my $w_req = $self->{-ipc_req}) { # run in worker
 189                 my $ipc_lock = $self->{-ipc_lock};
 190                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 191                 if (defined(wantarray)) {
 192                         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 193                         ipc_async_wait($self, -1);
 194                         _send_rec($w_req, [ wantarray, $sub, @args ]);
 195                         my $ret = _get_rec($r_res) // die "no response on $sub";
 196                         die $$ret if ref($ret) eq 'PublicInbox::IPC::Die';
 197                         wantarray ? @$ret : $$ret;
 198                 } else { # likely, fire-and-forget into pipe
 199                         _send_rec($w_req, [ undef , $sub, @args ]);
 200                 }
 201         } else { # run locally
 202                 $self->$sub(@args);
 203         }
 204 }
 205
 206 sub ipc_async {
 207         my ($self, $sub, $sub_args, $cb, $cb_arg) = @_;
 208         if (my $w_req = $self->{-ipc_req}) { # run in worker
 209                 my $rec = _pack_rec([ 1, $sub, @$sub_args ]);
 210                 my $cur_bytes = \($self->{-async_inflight_bytes} //= 0);
 211                 while (($$cur_bytes + length($rec)) > PIPE_BUF) {
 212                         ipc_async_wait($self, 1);
 213                 }
 214                 my $ipc_lock = $self->{-ipc_lock};
 215                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 216                 print $w_req $rec or croak "print: $!";
 217                 $$cur_bytes += length($rec);
 218                 push @{$self->{-async_inflight}},
 219                                 $sub, length($rec), $cb, $cb_arg;
 220         } else {
 221                 my $ret = [ eval { $self->$sub(@$sub_args) } ];
 222                 if (my $exc = $@) {
 223                         $ret = ( bless(\$exc, 'PublicInbox::IPC::Die') );
 224                 }
 225                 eval { $cb->($cb_arg, $ret) };
 226                 warn "E: $sub callback error: $@\n" if $@;
 227         }
 228 }
 229
 230 # needed when there's multiple IPC workers and the parent forking
 231 # causes newer siblings to inherit older siblings sockets
 232 sub ipc_sibling_atfork_child {
 233         my ($self) = @_;
 234         my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 235         delete(@$self{qw(-ipc_req -ipc_res)});
 236         $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
 237 }
 238
 239 sub _close_recvd ($) {
 240         my ($self) = @_;
 241         my $x = $self->{-wq_recv_modes};
 242         my $end = $x ? $#$x : 2;
 243         close($_) for (grep { defined } (delete @$self{0..$end}));
 244 }
 245
 246 sub wq_worker_loop ($) {
 247         my ($self) = @_;
 248         my $buf;
 249         my $len = $self->{wq_req_len} // (4096 * 33);
 250         my ($sub, $args);
 251         my $s2 = $self->{-wq_s2} // die 'BUG: no -wq_s2';
 252         local $SIG{PIPE} = sub {
 253                 my $cur_sub = $sub;
 254                 _close_recvd($self);
 255                 die(bless(\$cur_sub, 'PublicInbox::SIGPIPE')) if $cur_sub;
 256         };
 257         while (1) {
 258                 my (@fds) = $recv_cmd->($s2, $buf, $len) or return; # EOF
 259                 my $i = 0;
 260                 my @m = @{$self->{-wq_recv_modes} // [qw( +<&= >&= >&= )]};
 261                 for my $fd (@fds) {
 262                         my $mode = shift(@m);
 263                         if (open(my $cmdfh, $mode, $fd)) {
 264                                 $self->{$i++} = $cmdfh;
 265                                 $cmdfh->autoflush(1);
 266                         } else {
 267                                 die "$$ open($mode$fd) (FD:$i): $!";
 268                         }
 269                 }
 270                 # Sereal dies on truncated data, Storable returns undef
 271                 $args = thaw($buf) //
 272                         die "thaw error on buffer of size:".length($buf);
 273                 eval {
 274                         $sub = shift @$args;
 275                         eval { $self->$sub(@$args) };
 276                         undef $sub; # quiet SIG{PIPE} handler
 277                         die $@ if $@;
 278                 };
 279                 warn "$$ wq_worker: $@" if $@ &&
 280                                         ref($@) ne 'PublicInbox::SIGPIPE';
 281                 # need to close explicitly to avoid warnings after SIGPIPE
 282                 _close_recvd($self);
 283         }
 284 }
 285
 286 sub wq_do { # always async
 287         my ($self, $sub, $ios, @args) = @_;
 288         if (my $s1 = $self->{-wq_s1}) { # run in worker
 289                 my $fds = [ map { fileno($_) } @$ios ];
 290                 $send_cmd->($s1, $fds, freeze([$sub, @args]), MSG_EOR);
 291         } else {
 292                 @$self{0..$#$ios} = @$ios;
 293                 eval { $self->$sub(@args) };
 294                 warn "wq_do: $@" if $@ && ref($@) ne 'PublicInbox::SIGPIPE';
 295                 delete @$self{0..$#$ios}; # don't close
 296         }
 297 }
 298
 299 sub _wq_worker_start ($$) {
 300         my ($self, $oldset) = @_;
 301         my $pid = fork // die "fork: $!";
 302         if ($pid == 0) {
 303                 eval { PublicInbox::DS->Reset };
 304                 close(delete $self->{-wq_s1});
 305                 delete $self->{qw(-wq_workers -wq_ppid)};
 306                 $SIG{$_} = 'IGNORE' for (qw(PIPE TTOU TTIN));
 307                 $SIG{$_} = 'DEFAULT' for (qw(TERM QUIT INT CHLD));
 308                 local $0 = $self->{-wq_ident};
 309                 PublicInbox::DS::sig_setmask($oldset);
 310                 # ensure we properly exit even if warn() dies:
 311                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 312                 my $on_destroy = $self->ipc_atfork_child;
 313                 eval { wq_worker_loop($self) };
 314                 warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
 315                 undef $on_destroy;
 316                 undef $end; # trigger exit
 317         } else {
 318                 $self->{-wq_workers}->{$pid} = \undef;
 319         }
 320 }
 321
 322 # starts workqueue workers if Sereal or Storable is installed
 323 sub wq_workers_start {
 324         my ($self, $ident, $nr_workers, $oldset) = @_;
 325         ($enc && $send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
 326         return if $self->{-wq_s1}; # idempotent
 327         my ($s1, $s2);
 328         socketpair($s1, $s2, AF_UNIX, $SEQPACKET, 0) or die "socketpair: $!";
 329         $self->ipc_atfork_prepare;
 330         $nr_workers //= 4;
 331         $nr_workers = $WQ_MAX_WORKERS if $nr_workers > $WQ_MAX_WORKERS;
 332         my $sigset = $oldset // PublicInbox::DS::block_signals();
 333         $self->{-wq_workers} = {};
 334         $self->{-wq_ident} = $ident;
 335         $self->{-wq_s1} = $s1;
 336         $self->{-wq_s2} = $s2;
 337         _wq_worker_start($self, $sigset) for (1..$nr_workers);
 338         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 339         $self->{-wq_ppid} = $$;
 340 }
 341
 342 sub wq_worker_incr { # SIGTTIN handler
 343         my ($self, $oldset) = @_;
 344         $self->{-wq_s2} or return;
 345         return if wq_workers($self) >= $WQ_MAX_WORKERS;
 346         $self->ipc_atfork_prepare;
 347         my $sigset = $oldset // PublicInbox::DS::block_signals();
 348         _wq_worker_start($self, $sigset);
 349         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 350 }
 351
 352 sub wq_exit { # wakes up wq_worker_decr_wait
 353         send($_[0]->{-wq_s2}, $$, MSG_EOR) // die "$$ send: $!";
 354         exit;
 355 }
 356
 357 sub wq_worker_decr { # SIGTTOU handler, kills first idle worker
 358         my ($self) = @_;
 359         return unless wq_workers($self);
 360         my $s2 = $self->{-wq_s2} // die 'BUG: no wq_s2';
 361         $self->wq_do('wq_exit', [ $s2, $s2, $s2 ]);
 362         # caller must call wq_worker_decr_wait in main loop
 363 }
 364
 365 sub wq_worker_decr_wait {
 366         my ($self, $timeout) = @_;
 367         return if $self->{-wq_ppid} != $$; # can't reap siblings or parents
 368         my $s1 = $self->{-wq_s1} // croak 'BUG: no wq_s1';
 369         vec(my $rin = '', fileno($s1), 1) = 1;
 370         select(my $rout = $rin, undef, undef, $timeout) or
 371                 croak 'timed out waiting for wq_exit';
 372         recv($s1, my $pid, 64, 0) // croak "recv: $!";
 373         my $workers = $self->{-wq_workers} // croak 'BUG: no wq_workers';
 374         delete $workers->{$pid} // croak "BUG: PID:$pid invalid";
 375         dwaitpid($pid, \&ipc_worker_reap, $self);
 376 }
 377
 378 # set or retrieve number of workers
 379 sub wq_workers {
 380         my ($self, $nr) = @_;
 381         my $cur = $self->{-wq_workers} or return;
 382         if (defined $nr) {
 383                 while (scalar(keys(%$cur)) > $nr) {
 384                         $self->wq_worker_decr;
 385                         $self->wq_worker_decr_wait;
 386                 }
 387                 $self->wq_worker_incr while scalar(keys(%$cur)) < $nr;
 388         }
 389         scalar(keys(%$cur));
 390 }
 391
 392 sub wq_close {
 393         my ($self) = @_;
 394         delete @$self{qw(-wq_s1 -wq_s2)} or return;
 395         my $ppid = delete $self->{-wq_ppid} or return;
 396         my $workers = delete $self->{-wq_workers} // die 'BUG: no wq_workers';
 397         return if $ppid != $$; # can't reap siblings or parents
 398         for my $pid (keys %$workers) {
 399                 dwaitpid($pid, \&ipc_worker_reap, $self);
 400         }
 401 }
 402
 403 sub WQ_MAX_WORKERS { $WQ_MAX_WORKERS }
 404
 405 sub DESTROY {
 406         wq_close($_[0]);
 407         ipc_worker_stop($_[0]);
 408 }
 409
 410 1;