lib/PublicInbox/IPC.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # base class for remote IPC calls and workqueues, requires Storable or Sereal
   5 # - ipc_do and ipc_worker_* is for a single worker/producer and uses pipes
   6 # - wq_io_do and wq_worker* is for a single producer and multiple workers,
   7 #   using SOCK_SEQPACKET for work distribution
   8 # use ipc_do when you need work done on a certain process
   9 # use wq_io_do when your work can be done on any idle worker
  10 package PublicInbox::IPC;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(Exporter);
  14 use Carp qw(croak);
  15 use PublicInbox::DS qw(dwaitpid);
  16 use PublicInbox::Spawn;
  17 use PublicInbox::OnDestroy;
  18 use PublicInbox::WQWorker;
  19 use Socket qw(AF_UNIX MSG_EOR SOCK_STREAM);
  20 my $SEQPACKET = eval { Socket::SOCK_SEQPACKET() }; # portable enough?
  21 our @EXPORT_OK = qw(ipc_freeze ipc_thaw);
  22 my $WQ_MAX_WORKERS = 4096;
  23 my ($enc, $dec);
  24 # ->imports at BEGIN turns sereal_*_with_object into custom ops on 5.14+
  25 # and eliminate method call overhead
  26 BEGIN {
  27         eval {
  28                 require Sereal::Encoder;
  29                 require Sereal::Decoder;
  30                 Sereal::Encoder->import('sereal_encode_with_object');
  31                 Sereal::Decoder->import('sereal_decode_with_object');
  32                 ($enc, $dec) = (Sereal::Encoder->new, Sereal::Decoder->new);
  33         };
  34 };
  35
  36 if ($enc && $dec) { # should be custom ops
  37         *ipc_freeze = sub ($) { sereal_encode_with_object $enc, $_[0] };
  38         *ipc_thaw = sub ($) { sereal_decode_with_object $dec, $_[0], my $ret };
  39 } else {
  40         require Storable;
  41         *ipc_freeze = \&Storable::freeze;
  42         *ipc_thaw = \&Storable::thaw;
  43 }
  44
  45 my $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  46 my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  47         require PublicInbox::CmdIPC4;
  48         $recv_cmd //= PublicInbox::CmdIPC4->can('recv_cmd4');
  49         PublicInbox::CmdIPC4->can('send_cmd4');
  50 };
  51
  52 sub _get_rec ($) {
  53         my ($r) = @_;
  54         defined(my $len = <$r>) or return;
  55         chop($len) eq "\n" or croak "no LF byte in $len";
  56         defined(my $n = read($r, my $buf, $len)) or croak "read error: $!";
  57         $n == $len or croak "short read: $n != $len";
  58         ipc_thaw($buf);
  59 }
  60
  61 sub _send_rec ($$) {
  62         my ($w, $ref) = @_;
  63         my $buf = ipc_freeze($ref);
  64         print $w length($buf), "\n", $buf or croak "print: $!";
  65 }
  66
  67 sub ipc_return ($$$) {
  68         my ($w, $ret, $exc) = @_;
  69         _send_rec($w, $exc ? bless(\$exc, 'PublicInbox::IPC::Die') : $ret);
  70 }
  71
  72 sub ipc_worker_loop ($$$) {
  73         my ($self, $r_req, $w_res) = @_;
  74         my ($rec, $wantarray, $sub, @args);
  75         local $/ = "\n";
  76         while ($rec = _get_rec($r_req)) {
  77                 ($wantarray, $sub, @args) = @$rec;
  78                 # no waiting if client doesn't care,
  79                 # this is the overwhelmingly likely case
  80                 if (!defined($wantarray)) {
  81                         eval { $self->$sub(@args) };
  82                         warn "$$ die: $@ (from nowait $sub)\n" if $@;
  83                 } elsif ($wantarray) {
  84                         my @ret = eval { $self->$sub(@args) };
  85                         ipc_return($w_res, \@ret, $@);
  86                 } else { # '' => wantscalar
  87                         my $ret = eval { $self->$sub(@args) };
  88                         ipc_return($w_res, \$ret, $@);
  89                 }
  90         }
  91 }
  92
  93 # starts a worker if Sereal or Storable is installed
  94 sub ipc_worker_spawn {
  95         my ($self, $ident, $oldset, $fields) = @_;
  96         return if ($self->{-ipc_ppid} // -1) == $$; # idempotent
  97         delete(@$self{qw(-ipc_req -ipc_res -ipc_ppid -ipc_pid)});
  98         pipe(my ($r_req, $w_req)) or die "pipe: $!";
  99         pipe(my ($r_res, $w_res)) or die "pipe: $!";
 100         my $sigset = $oldset // PublicInbox::DS::block_signals();
 101         $self->ipc_atfork_prepare;
 102         my $seed = rand(0xffffffff);
 103         my $pid = fork // die "fork: $!";
 104         if ($pid == 0) {
 105                 srand($seed);
 106                 eval { PublicInbox::DS->Reset };
 107                 delete @$self{qw(-wq_s1 -wq_s2 -wq_workers -wq_ppid)};
 108                 $w_req = $r_res = undef;
 109                 $w_res->autoflush(1);
 110                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
 111                 local $0 = $ident;
 112                 PublicInbox::DS::sig_setmask($sigset);
 113                 # ensure we properly exit even if warn() dies:
 114                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 115                 eval {
 116                         $fields //= {};
 117                         local @$self{keys %$fields} = values(%$fields);
 118                         my $on_destroy = $self->ipc_atfork_child;
 119                         local %SIG = %SIG;
 120                         ipc_worker_loop($self, $r_req, $w_res);
 121                 };
 122                 warn "worker $ident PID:$$ died: $@\n" if $@;
 123                 undef $end; # trigger exit
 124         }
 125         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 126         $r_req = $w_res = undef;
 127         $w_req->autoflush(1);
 128         $self->{-ipc_req} = $w_req;
 129         $self->{-ipc_res} = $r_res;
 130         $self->{-ipc_ppid} = $$;
 131         $self->{-ipc_pid} = $pid;
 132 }
 133
 134 sub ipc_worker_reap { # dwaitpid callback
 135         my ($args, $pid) = @_;
 136         return if !$?;
 137         # TERM(15) is our default exit signal, PIPE(13) is likely w/ pager
 138         my $s = $? & 127;
 139         warn "PID:$pid died with \$?=$?\n" if $s != 15 && $s != 13;
 140 }
 141
 142 sub wq_wait_old {
 143         my ($self, $cb, @args) = @_;
 144         my $pids = delete $self->{"-wq_old_pids.$$"} or return;
 145         dwaitpid($_, $cb // \&ipc_worker_reap, [$self, @args]) for @$pids;
 146 }
 147
 148 # for base class, override in sub classes
 149 sub ipc_atfork_prepare {}
 150
 151 sub wq_atexit_child {}
 152
 153 sub ipc_atfork_child {
 154         my ($self) = @_;
 155         my $io = delete($self->{-ipc_atfork_child_close}) or return;
 156         close($_) for @$io;
 157         undef;
 158 }
 159
 160 # idempotent, can be called regardless of whether worker is active or not
 161 sub ipc_worker_stop {
 162         my ($self, $args) = @_;
 163         my ($pid, $ppid) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 164         my ($w_req, $r_res) = delete(@$self{qw(-ipc_req -ipc_res)});
 165         if (!$w_req && !$r_res) {
 166                 die "unexpected PID:$pid without IPC pipes" if $pid;
 167                 return; # idempotent
 168         }
 169         die 'no PID with IPC pipes' unless $pid;
 170         $w_req = $r_res = undef;
 171
 172         return if $$ != $ppid;
 173         dwaitpid($pid, \&ipc_worker_reap, [$self, $args]);
 174 }
 175
 176 # use this if we have multiple readers reading curl or "pigz -dc"
 177 # and writing to the same store
 178 sub ipc_lock_init {
 179         my ($self, $f) = @_;
 180         require PublicInbox::Lock;
 181         $self->{-ipc_lock} //= bless { lock_path => $f }, 'PublicInbox::Lock'
 182 }
 183
 184 # call $self->$sub(@args), on a worker if ipc_worker_spawn was used
 185 sub ipc_do {
 186         my ($self, $sub, @args) = @_;
 187         if (my $w_req = $self->{-ipc_req}) { # run in worker
 188                 my $ipc_lock = $self->{-ipc_lock};
 189                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 190                 if (defined(wantarray)) {
 191                         my $r_res = $self->{-ipc_res} or die 'no ipc_res';
 192                         _send_rec($w_req, [ wantarray, $sub, @args ]);
 193                         my $ret = _get_rec($r_res) // die "no response on $sub";
 194                         die $$ret if ref($ret) eq 'PublicInbox::IPC::Die';
 195                         wantarray ? @$ret : $$ret;
 196                 } else { # likely, fire-and-forget into pipe
 197                         _send_rec($w_req, [ undef , $sub, @args ]);
 198                 }
 199         } else { # run locally
 200                 $self->$sub(@args);
 201         }
 202 }
 203
 204 # needed when there's multiple IPC workers and the parent forking
 205 # causes newer siblings to inherit older siblings sockets
 206 sub ipc_sibling_atfork_child {
 207         my ($self) = @_;
 208         my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 209         delete(@$self{qw(-ipc_req -ipc_res)});
 210         $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
 211 }
 212
 213 sub recv_and_run {
 214         my ($self, $s2, $len, $full_stream) = @_;
 215         my @fds = $recv_cmd->($s2, my $buf, $len);
 216         return if scalar(@fds) && !defined($fds[0]);
 217         my $n = length($buf) or return 0;
 218         my $nfd = 0;
 219         for my $fd (@fds) {
 220                 if (open(my $cmdfh, '+<&=', $fd)) {
 221                         $self->{$nfd++} = $cmdfh;
 222                         $cmdfh->autoflush(1);
 223                 } else {
 224                         die "$$ open(+<&=$fd) (FD:$nfd): $!";
 225                 }
 226         }
 227         while ($full_stream && $n < $len) {
 228                 my $r = sysread($s2, $buf, $len - $n, $n) // croak "read: $!";
 229                 croak "read EOF after $n/$len bytes" if $r == 0;
 230                 $n = length($buf);
 231         }
 232         # Sereal dies on truncated data, Storable returns undef
 233         my $args = ipc_thaw($buf) // die "thaw error on buffer of size: $n";
 234         undef $buf;
 235         my $sub = shift @$args;
 236         eval { $self->$sub(@$args) };
 237         warn "$$ wq_worker: $@" if $@;
 238         delete @$self{0..($nfd-1)};
 239         $n;
 240 }
 241
 242 sub wq_worker_loop ($) {
 243         my ($self) = @_;
 244         my $wqw = PublicInbox::WQWorker->new($self);
 245         PublicInbox::DS->SetPostLoopCallback(sub { $wqw->{sock} });
 246         PublicInbox::DS->EventLoop;
 247         PublicInbox::DS->Reset;
 248 }
 249
 250 sub do_sock_stream { # via wq_io_do, for big requests
 251         my ($self, $len) = @_;
 252         recv_and_run($self, delete $self->{0}, $len, 1);
 253 }
 254
 255 sub wq_io_do { # always async
 256         my ($self, $sub, $ios, @args) = @_;
 257         if (my $s1 = $self->{-wq_s1}) { # run in worker
 258                 my $fds = [ map { fileno($_) } @$ios ];
 259                 my $buf = ipc_freeze([$sub, @args]);
 260                 my $n = $send_cmd->($s1, $fds, $buf, MSG_EOR);
 261                 return if defined($n); # likely
 262                 croak "sendmsg: $! (check RLIMIT_NOFILE)" if $!{ETOOMANYREFS};
 263                 croak "sendmsg: $!" if !$!{EMSGSIZE};
 264                 socketpair(my $r, my $w, AF_UNIX, SOCK_STREAM, 0) or
 265                         croak "socketpair: $!";
 266                 $n = $send_cmd->($s1, [ fileno($r) ],
 267                                 ipc_freeze(['do_sock_stream', length($buf)]),
 268                                 MSG_EOR) // croak "sendmsg: $!";
 269                 undef $r;
 270                 $n = $send_cmd->($w, $fds, $buf, 0) // croak "sendmsg: $!";
 271                 while ($n < length($buf)) {
 272                         my $x = syswrite($w, $buf, length($buf) - $n, $n) //
 273                                         croak "syswrite: $!";
 274                         croak "syswrite wrote 0 bytes" if $x == 0;
 275                         $n += $x;
 276                 }
 277         } else {
 278                 @$self{0..$#$ios} = @$ios;
 279                 eval { $self->$sub(@args) };
 280                 warn "wq_io_do: $@" if $@;
 281                 delete @$self{0..$#$ios}; # don't close
 282         }
 283 }
 284
 285 sub _wq_worker_start ($$$) {
 286         my ($self, $oldset, $fields) = @_;
 287         my $seed = rand(0xffffffff);
 288         my $pid = fork // die "fork: $!";
 289         if ($pid == 0) {
 290                 srand($seed);
 291                 eval { PublicInbox::DS->Reset };
 292                 delete @$self{qw(-wq_s1 -wq_workers -wq_ppid)};
 293                 $SIG{$_} = 'IGNORE' for (qw(PIPE));
 294                 $SIG{$_} = 'DEFAULT' for (qw(TTOU TTIN TERM QUIT INT CHLD));
 295                 local $0 = $self->{-wq_ident};
 296                 PublicInbox::DS::sig_setmask($oldset);
 297                 # ensure we properly exit even if warn() dies:
 298                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 299                 eval {
 300                         $fields //= {};
 301                         local @$self{keys %$fields} = values(%$fields);
 302                         my $on_destroy = $self->ipc_atfork_child;
 303                         local %SIG = %SIG;
 304                         wq_worker_loop($self);
 305                 };
 306                 warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
 307                 undef $end; # trigger exit
 308         } else {
 309                 $self->{-wq_workers}->{$pid} = \undef;
 310         }
 311 }
 312
 313 # starts workqueue workers if Sereal or Storable is installed
 314 sub wq_workers_start {
 315         my ($self, $ident, $nr_workers, $oldset, $fields) = @_;
 316         ($send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
 317         return if $self->{-wq_s1}; # idempotent
 318         $self->{-wq_s1} = $self->{-wq_s2} = undef;
 319         socketpair($self->{-wq_s1}, $self->{-wq_s2}, AF_UNIX, $SEQPACKET, 0) or
 320                 die "socketpair: $!";
 321         $self->ipc_atfork_prepare;
 322         $nr_workers //= 4;
 323         $nr_workers = $WQ_MAX_WORKERS if $nr_workers > $WQ_MAX_WORKERS;
 324         my $sigset = $oldset // PublicInbox::DS::block_signals();
 325         $self->{-wq_workers} = {};
 326         $self->{-wq_ident} = $ident;
 327         _wq_worker_start($self, $sigset, $fields) for (1..$nr_workers);
 328         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 329         $self->{-wq_ppid} = $$;
 330 }
 331
 332 sub wq_worker_incr { # SIGTTIN handler
 333         my ($self, $oldset, $fields) = @_;
 334         $self->{-wq_s2} or return;
 335         return if wq_workers($self) >= $WQ_MAX_WORKERS;
 336         $self->ipc_atfork_prepare;
 337         my $sigset = $oldset // PublicInbox::DS::block_signals();
 338         _wq_worker_start($self, $sigset, $fields);
 339         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 340 }
 341
 342 sub wq_exit { # wakes up wq_worker_decr_wait
 343         send($_[0]->{-wq_s2}, $$, MSG_EOR) // die "$$ send: $!";
 344         exit;
 345 }
 346
 347 sub wq_worker_decr { # SIGTTOU handler, kills first idle worker
 348         my ($self) = @_;
 349         return unless wq_workers($self);
 350         $self->wq_io_do('wq_exit');
 351         # caller must call wq_worker_decr_wait in main loop
 352 }
 353
 354 sub wq_worker_decr_wait {
 355         my ($self, $timeout, $cb, @args) = @_;
 356         return if $self->{-wq_ppid} != $$; # can't reap siblings or parents
 357         my $s1 = $self->{-wq_s1} // croak 'BUG: no wq_s1';
 358         vec(my $rin = '', fileno($s1), 1) = 1;
 359         select(my $rout = $rin, undef, undef, $timeout) or
 360                 croak 'timed out waiting for wq_exit';
 361         recv($s1, my $pid, 64, 0) // croak "recv: $!";
 362         my $workers = $self->{-wq_workers} // croak 'BUG: no wq_workers';
 363         delete $workers->{$pid} // croak "BUG: PID:$pid invalid";
 364         dwaitpid($pid, $cb // \&ipc_worker_reap, [ $self, @args ]);
 365 }
 366
 367 # set or retrieve number of workers
 368 sub wq_workers {
 369         my ($self, $nr, $cb, @args) = @_;
 370         my $cur = $self->{-wq_workers} or return;
 371         if (defined $nr) {
 372                 while (scalar(keys(%$cur)) > $nr) {
 373                         $self->wq_worker_decr;
 374                         $self->wq_worker_decr_wait(undef, $cb, @args);
 375                 }
 376                 $self->wq_worker_incr while scalar(keys(%$cur)) < $nr;
 377         }
 378         scalar(keys(%$cur));
 379 }
 380
 381 sub wq_close {
 382         my ($self, $nohang, $cb, @args) = @_;
 383         delete @$self{qw(-wq_s1 -wq_s2)} or return;
 384         my $ppid = delete $self->{-wq_ppid} or return;
 385         my $workers = delete $self->{-wq_workers} // die 'BUG: no wq_workers';
 386         return if $ppid != $$; # can't reap siblings or parents
 387         my @pids = map { $_ + 0 } keys %$workers;
 388         if ($nohang) {
 389                 push @{$self->{"-wq_old_pids.$$"}}, @pids;
 390         } else {
 391                 $cb //= \&ipc_worker_reap;
 392                 unshift @args, $self;
 393                 dwaitpid($_, $cb, \@args) for @pids;
 394         }
 395 }
 396
 397 sub wq_kill_old {
 398         my ($self) = @_;
 399         my $pids = $self->{"-wq_old_pids.$$"} or return;
 400         kill 'TERM', @$pids;
 401 }
 402
 403 sub wq_kill {
 404         my ($self, $sig) = @_;
 405         my $workers = $self->{-wq_workers} or return;
 406         kill($sig // 'TERM', keys %$workers);
 407 }
 408
 409 sub WQ_MAX_WORKERS { $WQ_MAX_WORKERS }
 410
 411 sub DESTROY {
 412         my ($self) = @_;
 413         my $ppid = $self->{-wq_ppid};
 414         wq_kill($self) if $ppid && $ppid == $$;
 415         wq_close($self);
 416         wq_wait_old($self);
 417         ipc_worker_stop($self);
 418 }
 419
 420 sub detect_nproc () {
 421         # _SC_NPROCESSORS_ONLN = 84 on both Linux glibc and musl
 422         return POSIX::sysconf(84) if $^O eq 'linux';
 423         return POSIX::sysconf(58) if $^O eq 'freebsd';
 424         # TODO: more OSes
 425
 426         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
 427         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
 428                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
 429         }
 430         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
 431                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
 432         }
 433
 434         # should we bother with `sysctl hw.ncpu`?  Those only give
 435         # us total processor count, not online processor count.
 436         undef
 437 }
 438
 439 1;