lib/PublicInbox/Import.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # git fast-import-based ssoma-mda MDA replacement
   5 # This is only ever run by public-inbox-mda, public-inbox-learn
   6 # and public-inbox-watch. Not the WWW or NNTP code which only
   7 # requires read-only access.
   8 package PublicInbox::Import;
   9 use strict;
  10 use warnings;
  11 use base qw(PublicInbox::Lock);
  12 use PublicInbox::Spawn qw(spawn);
  13 use PublicInbox::MID qw(mids mid_mime mid2path);
  14 use PublicInbox::Address;
  15 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  16 use PublicInbox::ContentId qw(content_digest);
  17 use PublicInbox::MDA;
  18 use POSIX qw(strftime);
  19
  20 sub new {
  21         # we can't change arg order, this is documented in POD
  22         # and external projects may rely on it:
  23         my ($class, $git, $name, $email, $ibx) = @_;
  24         my $ref = 'refs/heads/master';
  25         if ($ibx) {
  26                 $ref = $ibx->{ref_head} || 'refs/heads/master';
  27                 $name ||= $ibx->{name};
  28                 $email ||= $ibx->{-primary_address};
  29                 $git ||= $ibx->git;
  30         }
  31         bless {
  32                 git => $git,
  33                 ident => "$name <$email>",
  34                 mark => 1,
  35                 ref => $ref,
  36                 -inbox => $ibx,
  37                 path_type => '2/38', # or 'v2'
  38                 lock_path => "$git->{git_dir}/ssoma.lock", # v2 changes this
  39                 bytes_added => 0,
  40         }, $class
  41 }
  42
  43 # idempotent start function
  44 sub gfi_start {
  45         my ($self) = @_;
  46
  47         return ($self->{in}, $self->{out}) if $self->{pid};
  48
  49         my ($in_r, $in_w, $out_r, $out_w);
  50         pipe($in_r, $in_w) or die "pipe failed: $!";
  51         pipe($out_r, $out_w) or die "pipe failed: $!";
  52         my $git = $self->{git};
  53
  54         $self->lock_acquire;
  55
  56         local $/ = "\n";
  57         my $ref = $self->{ref};
  58         chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $ref));
  59         if ($self->{path_type} ne '2/38' && $self->{tip}) {
  60                 local $/ = "\0";
  61                 my @tree = $git->qx(qw(ls-tree -r -z --name-only), $ref);
  62                 chomp @tree;
  63                 $self->{-tree} = { map { $_ => 1 } @tree };
  64         }
  65
  66         my $git_dir = $git->{git_dir};
  67         my @cmd = ('git', "--git-dir=$git_dir", qw(fast-import
  68                         --quiet --done --date-format=raw));
  69         my $rdr = { 0 => $out_r, 1 => $in_w };
  70         my $pid = spawn(\@cmd, undef, $rdr);
  71         die "spawn fast-import failed: $!" unless defined $pid;
  72         $out_w->autoflush(1);
  73         $self->{in} = $in_r;
  74         $self->{out} = $out_w;
  75         $self->{pid} = $pid;
  76         $self->{nchg} = 0;
  77         binmode $out_w, ':raw' or die "binmode :raw failed: $!";
  78         binmode $in_r, ':raw' or die "binmode :raw failed: $!";
  79         ($in_r, $out_w);
  80 }
  81
  82 sub wfail () { die "write to fast-import failed: $!" }
  83
  84 sub now_raw () { time . ' +0000' }
  85
  86 sub norm_body ($) {
  87         my ($mime) = @_;
  88         my $b = $mime->body_raw;
  89         $b =~ s/(\r?\n)+\z//s;
  90         $b
  91 }
  92
  93 # only used for v1 (ssoma) inboxes
  94 sub _check_path ($$$$) {
  95         my ($r, $w, $tip, $path) = @_;
  96         return if $tip eq '';
  97         print $w "ls $tip $path\n" or wfail;
  98         local $/ = "\n";
  99         defined(my $info = <$r>) or die "EOF from fast-import: $!";
 100         $info =~ /\Amissing / ? undef : $info;
 101 }
 102
 103 sub _cat_blob ($$$) {
 104         my ($r, $w, $oid) = @_;
 105         print $w "cat-blob $oid\n" or wfail;
 106         local $/ = "\n";
 107         my $info = <$r>;
 108         defined $info or die "EOF from fast-import / cat-blob: $!";
 109         $info =~ /\A[a-f0-9]{40} blob ([0-9]+)\n\z/ or return;
 110         my $left = $1;
 111         my $offset = 0;
 112         my $buf = '';
 113         my $n;
 114         while ($left > 0) {
 115                 $n = read($r, $buf, $left, $offset);
 116                 defined($n) or die "read cat-blob failed: $!";
 117                 $n == 0 and die 'fast-export (cat-blob) died';
 118                 $left -= $n;
 119                 $offset += $n;
 120         }
 121         $n = read($r, my $lf, 1);
 122         defined($n) or die "read final byte of cat-blob failed: $!";
 123         die "bad read on final byte: <$lf>" if $lf ne "\n";
 124
 125         # fixup some bugginess in old versions:
 126         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 127         \$buf;
 128 }
 129
 130 sub cat_blob {
 131         my ($self, $oid) = @_;
 132         my ($r, $w) = $self->gfi_start;
 133         _cat_blob($r, $w, $oid);
 134 }
 135
 136 sub check_remove_v1 {
 137         my ($r, $w, $tip, $path, $mime) = @_;
 138
 139         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
 140         $info =~ m!\A100644 blob ([a-f0-9]{40})\t!s or die "not blob: $info";
 141         my $oid = $1;
 142         my $msg = _cat_blob($r, $w, $oid) or die "BUG: cat-blob $1 failed";
 143         my $cur = PublicInbox::MIME->new($msg);
 144         my $cur_s = $cur->header('Subject');
 145         $cur_s = '' unless defined $cur_s;
 146         my $cur_m = $mime->header('Subject');
 147         $cur_m = '' unless defined $cur_m;
 148         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
 149                 return ('MISMATCH', $cur);
 150         }
 151         (undef, $cur);
 152 }
 153
 154 sub checkpoint {
 155         my ($self) = @_;
 156         return unless $self->{pid};
 157         print { $self->{out} } "checkpoint\n" or wfail;
 158         undef;
 159 }
 160
 161 sub progress {
 162         my ($self, $msg) = @_;
 163         return unless $self->{pid};
 164         print { $self->{out} } "progress $msg\n" or wfail;
 165         $self->{in}->getline eq "progress $msg\n" or die
 166                 "progress $msg not received\n";
 167         undef;
 168 }
 169
 170 sub _update_git_info ($$) {
 171         my ($self, $do_gc) = @_;
 172         # for compatibility with existing ssoma installations
 173         # we can probably remove this entirely by 2020
 174         my $git_dir = $self->{git}->{git_dir};
 175         my @cmd = ('git', "--git-dir=$git_dir");
 176         my $index = "$git_dir/ssoma.index";
 177         if (-e $index && !$ENV{FAST}) {
 178                 my $env = { GIT_INDEX_FILE => $index };
 179                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
 180         }
 181         run_die([@cmd, 'update-server-info']);
 182         my $ibx = $self->{-inbox};
 183         ($ibx && $self->{path_type} eq '2/38') and eval {
 184                 require PublicInbox::SearchIdx;
 185                 my $s = PublicInbox::SearchIdx->new($ibx);
 186                 $s->index_sync({ ref => $self->{ref} });
 187         };
 188         eval { run_die([@cmd, qw(gc --auto)]) } if $do_gc;
 189 }
 190
 191 sub barrier {
 192         my ($self) = @_;
 193
 194         # For safety, we ensure git checkpoint is complete before because
 195         # the data in git is still more important than what is in Xapian
 196         # in v2.  Performance may be gained by delaying the ->progress
 197         # call but we lose safety
 198         if ($self->{nchg}) {
 199                 $self->checkpoint;
 200                 $self->progress('checkpoint');
 201                 _update_git_info($self, 0);
 202                 $self->{nchg} = 0;
 203         }
 204 }
 205
 206 # used for v2
 207 sub get_mark {
 208         my ($self, $mark) = @_;
 209         die "not active\n" unless $self->{pid};
 210         my ($r, $w) = $self->gfi_start;
 211         print $w "get-mark $mark\n" or wfail;
 212         defined(my $oid = <$r>) or die "get-mark failed, need git 2.6.0+\n";
 213         chomp($oid);
 214         $oid;
 215 }
 216
 217 # returns undef on non-existent
 218 # ('MISMATCH', Email::MIME) on mismatch
 219 # (:MARK, Email::MIME) on success
 220 #
 221 # v2 callers should check with Xapian before calling this as
 222 # it is not idempotent.
 223 sub remove {
 224         my ($self, $mime, $msg) = @_; # mime = Email::MIME
 225
 226         my $path_type = $self->{path_type};
 227         my ($path, $err, $cur, $blob);
 228
 229         my ($r, $w) = $self->gfi_start;
 230         my $tip = $self->{tip};
 231         if ($path_type eq '2/38') {
 232                 $path = mid2path(v1_mid0($mime));
 233                 ($err, $cur) = check_remove_v1($r, $w, $tip, $path, $mime);
 234                 return ($err, $cur) if $err;
 235         } else {
 236                 my $sref;
 237                 if (ref($mime) eq 'SCALAR') { # optimization used by V2Writable
 238                         $sref = $mime;
 239                 } else { # XXX should not be necessary:
 240                         my $str = $mime->as_string;
 241                         $sref = \$str;
 242                 }
 243                 my $len = length($$sref);
 244                 $blob = $self->{mark}++;
 245                 print $w "blob\nmark :$blob\ndata $len\n",
 246                         $$sref, "\n" or wfail;
 247         }
 248
 249         my $ref = $self->{ref};
 250         my $commit = $self->{mark}++;
 251         my $parent = $tip =~ /\A:/ ? $tip : undef;
 252         unless ($parent) {
 253                 print $w "reset $ref\n" or wfail;
 254         }
 255         my $ident = $self->{ident};
 256         my $now = now_raw();
 257         $msg ||= 'rm';
 258         my $len = length($msg) + 1;
 259         print $w "commit $ref\nmark :$commit\n",
 260                 "author $ident $now\n",
 261                 "committer $ident $now\n",
 262                 "data $len\n$msg\n\n",
 263                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 264         if (defined $path) {
 265                 print $w "D $path\n\n" or wfail;
 266         } else {
 267                 clean_tree_v2($self, $w, 'd');
 268                 print $w "M 100644 :$blob d\n\n" or wfail;
 269         }
 270         $self->{nchg}++;
 271         (($self->{tip} = ":$commit"), $cur);
 272 }
 273
 274 sub git_timestamp {
 275         my ($ts, $zone) = @_;
 276         $ts = 0 if $ts < 0; # git uses unsigned times
 277         "$ts $zone";
 278 }
 279
 280 sub extract_cmt_info ($) {
 281         my ($mime) = @_;
 282
 283         my $sender = '';
 284         my $from = $mime->header('From');
 285         $from ||= '';
 286         my ($email) = PublicInbox::Address::emails($from);
 287         my ($name) = PublicInbox::Address::names($from);
 288         if (!defined($name) || !defined($email)) {
 289                 $sender = $mime->header('Sender');
 290                 $sender ||= '';
 291                 if (!defined($name)) {
 292                         ($name) = PublicInbox::Address::names($sender);
 293                 }
 294                 if (!defined($email)) {
 295                         ($email) = PublicInbox::Address::emails($sender);
 296                 }
 297         }
 298         if (defined $email) {
 299                 # quiet down wide character warnings with utf8::encode
 300                 utf8::encode($email);
 301         } else {
 302                 $email = '';
 303                 warn "no email in From: $from or Sender: $sender\n";
 304         }
 305
 306         # git gets confused with:
 307         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
 308         # ref:
 309         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
 310         if (defined $name) {
 311                 $name =~ tr/<>//d;
 312                 utf8::encode($name);
 313         } else {
 314                 $name = '';
 315                 warn "no name in From: $from or Sender: $sender\n";
 316         }
 317
 318         my $hdr = $mime->header_obj;
 319
 320         my $subject = $hdr->header('Subject');
 321         $subject = '(no subject)' unless defined $subject;
 322         # Mime decoding can create nulls replace them with spaces to protect git
 323         $subject =~ tr/\0/ /;
 324         utf8::encode($subject);
 325         my $at = git_timestamp(my @at = msg_datestamp($hdr));
 326         my $ct = git_timestamp(my @ct = msg_timestamp($hdr));
 327         ($name, $email, $at, $ct, $subject);
 328 }
 329
 330 # kill potentially confusing/misleading headers
 331 sub drop_unwanted_headers ($) {
 332         my ($mime) = @_;
 333
 334         $mime->header_set($_) for qw(bytes lines content-length status);
 335         $mime->header_set($_) for @PublicInbox::MDA::BAD_HEADERS;
 336 }
 337
 338 # used by V2Writable, too
 339 sub append_mid ($$) {
 340         my ($hdr, $mid0) = @_;
 341         # @cur is likely empty if we need to call this sub, but it could
 342         # have random unparseable crap which we'll preserve, too.
 343         my @cur = $hdr->header_raw('Message-ID');
 344         $hdr->header_set('Message-ID', @cur, "<$mid0>");
 345 }
 346
 347 sub v1_mid0 ($) {
 348         my ($mime) = @_;
 349         my $hdr = $mime->header_obj;
 350         my $mids = mids($hdr);
 351
 352         if (!scalar(@$mids)) { # spam often has no Message-Id
 353                 my $mid0 = digest2mid(content_digest($mime), $hdr);
 354                 append_mid($hdr, $mid0);
 355                 return $mid0;
 356         }
 357         $mids->[0];
 358 }
 359 sub clean_tree_v2 ($$$) {
 360         my ($self, $w, $keep) = @_;
 361         my $tree = $self->{-tree} or return; #v2 only
 362         delete $tree->{$keep};
 363         foreach (keys %$tree) {
 364                 print $w "D $_\n" or wfail;
 365         }
 366         %$tree = ($keep => 1);
 367 }
 368
 369 # returns undef on duplicate
 370 # returns the :MARK of the most recent commit
 371 sub add {
 372         my ($self, $mime, $check_cb) = @_; # mime = Email::MIME
 373
 374         my ($name, $email, $at, $ct, $subject) = extract_cmt_info($mime);
 375         my $path_type = $self->{path_type};
 376         my $path;
 377         if ($path_type eq '2/38') {
 378                 $path = mid2path(v1_mid0($mime));
 379         } else { # v2 layout, one file:
 380                 $path = 'm';
 381         }
 382
 383         my ($r, $w) = $self->gfi_start;
 384         my $tip = $self->{tip};
 385         if ($path_type eq '2/38') {
 386                 _check_path($r, $w, $tip, $path) and return;
 387         }
 388
 389         drop_unwanted_headers($mime);
 390
 391         # spam check:
 392         if ($check_cb) {
 393                 $mime = $check_cb->($mime) or return;
 394         }
 395
 396         my $blob = $self->{mark}++;
 397         my $raw_email = $mime->{-public_inbox_raw} // $mime->as_string;
 398         my $n = length($raw_email);
 399         $self->{bytes_added} += $n;
 400         print $w "blob\nmark :$blob\ndata ", $n, "\n" or wfail;
 401         print $w $raw_email, "\n" or wfail;
 402
 403         # v2: we need this for Xapian
 404         if ($self->{want_object_info}) {
 405                 my $oid = $self->get_mark(":$blob");
 406                 $self->{last_object} = [ $oid, $n, \$raw_email ];
 407         }
 408         my $ref = $self->{ref};
 409         my $commit = $self->{mark}++;
 410         my $parent = $tip =~ /\A:/ ? $tip : undef;
 411
 412         unless ($parent) {
 413                 print $w "reset $ref\n" or wfail;
 414         }
 415
 416         print $w "commit $ref\nmark :$commit\n",
 417                 "author $name <$email> $at\n",
 418                 "committer $self->{ident} $ct\n" or wfail;
 419         print $w "data ", (length($subject) + 1), "\n",
 420                 $subject, "\n\n" or wfail;
 421         if ($tip ne '') {
 422                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 423         }
 424         clean_tree_v2($self, $w, $path);
 425         print $w "M 100644 :$blob $path\n\n" or wfail;
 426         $self->{nchg}++;
 427         $self->{tip} = ":$commit";
 428 }
 429
 430 sub run_die ($;$$) {
 431         my ($cmd, $env, $rdr) = @_;
 432         my $pid = spawn($cmd, $env, $rdr);
 433         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 434         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 435         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
 436 }
 437
 438 sub init_bare {
 439         my ($dir) = @_;
 440         my @cmd = (qw(git init --bare -q), $dir);
 441         run_die(\@cmd);
 442         # set a reasonable default:
 443         @cmd = (qw/git config/, "--file=$dir/config",
 444                 'repack.writeBitmaps', 'true');
 445         run_die(\@cmd);
 446 }
 447
 448 sub done {
 449         my ($self) = @_;
 450         my $w = delete $self->{out} or return;
 451         my $r = delete $self->{in} or die 'BUG: missing {in} when done';
 452         print $w "done\n" or wfail;
 453         my $pid = delete $self->{pid} or die 'BUG: missing {pid} when done';
 454         waitpid($pid, 0) == $pid or die 'fast-import did not finish';
 455         $? == 0 or die "fast-import failed: $?";
 456
 457         _update_git_info($self, 1) if delete $self->{nchg};
 458
 459         $self->lock_release;
 460
 461         $self->{git}->cleanup;
 462 }
 463
 464 sub atfork_child {
 465         my ($self) = @_;
 466         foreach my $f (qw(in out)) {
 467                 next unless defined($self->{$f});
 468                 close $self->{$f} or die "failed to close import[$f]: $!\n";
 469         }
 470 }
 471
 472 sub digest2mid ($$) {
 473         my ($dig, $hdr) = @_;
 474         my $b64 = $dig->clone->b64digest;
 475         # Make our own URLs nicer:
 476         # See "Base 64 Encoding with URL and Filename Safe Alphabet" in RFC4648
 477         $b64 =~ tr!+/=!-_!d;
 478
 479         # Add a date prefix to prevent a leading '-' in case that trips
 480         # up some tools (e.g. if a Message-ID were a expected as a
 481         # command-line arg)
 482         my $dt = msg_datestamp($hdr);
 483         $dt = POSIX::strftime('%Y%m%d%H%M%S', gmtime($dt));
 484         "$dt.$b64" . '@z';
 485 }
 486
 487 sub rewrite_commit ($$$$) {
 488         my ($self, $oids, $buf, $mime) = @_;
 489         my ($name, $email, $at, $ct, $subject);
 490         if ($mime) {
 491                 ($name, $email, $at, $ct, $subject) = extract_cmt_info($mime);
 492         } else {
 493                 $name = $email = '';
 494                 $subject = 'purged '.join(' ', @$oids);
 495         }
 496         @$oids = ();
 497         $subject .= "\n";
 498         foreach my $i (0..$#$buf) {
 499                 my $l = $buf->[$i];
 500                 if ($l =~ /^author .* ([0-9]+ [\+-]?[0-9]+)$/) {
 501                         $at //= $1;
 502                         $buf->[$i] = "author $name <$email> $at\n";
 503                 } elsif ($l =~ /^committer .* ([0-9]+ [\+-]?[0-9]+)$/) {
 504                         $ct //= $1;
 505                         $buf->[$i] = "committer $self->{ident} $ct\n";
 506                 } elsif ($l =~ /^data ([0-9]+)/) {
 507                         $buf->[$i++] = "data " . length($subject) . "\n";
 508                         $buf->[$i] = $subject;
 509                         last;
 510                 }
 511         }
 512 }
 513
 514 # returns the new commit OID if a replacement was done
 515 # returns undef if nothing was done
 516 sub replace_oids {
 517         my ($self, $mime, $replace_map) = @_; # oid => raw string
 518         my $tmp = "refs/heads/replace-".((keys %$replace_map)[0]);
 519         my $old = $self->{'ref'};
 520         my $git = $self->{git};
 521         my @export = (qw(fast-export --no-data --use-done-feature), $old);
 522         my $rd = $git->popen(@export);
 523         my ($r, $w) = $self->gfi_start;
 524         my @buf;
 525         my $nreplace = 0;
 526         my @oids;
 527         my ($done, $mark);
 528         my $tree = $self->{-tree};
 529         while (<$rd>) {
 530                 if (/^reset (?:.+)/) {
 531                         push @buf, "reset $tmp\n";
 532                 } elsif (/^commit (?:.+)/) {
 533                         if (@buf) {
 534                                 $w->print(@buf) or wfail;
 535                                 @buf = ();
 536                         }
 537                         push @buf, "commit $tmp\n";
 538                 } elsif (/^data ([0-9]+)/) {
 539                         # only commit message, so $len is small:
 540                         my $len = $1; # + 1 for trailing "\n"
 541                         push @buf, $_;
 542                         my $n = read($rd, my $buf, $len) or die "read: $!";
 543                         $len == $n or die "short read ($n < $len)";
 544                         push @buf, $buf;
 545                 } elsif (/^M 100644 ([a-f0-9]+) (\w+)/) {
 546                         my ($oid, $path) = ($1, $2);
 547                         $tree->{$path} = 1;
 548                         my $sref = $replace_map->{$oid};
 549                         if (defined $sref) {
 550                                 push @oids, $oid;
 551                                 my $n = length($$sref);
 552                                 push @buf, "M 100644 inline $path\ndata $n\n";
 553                                 push @buf, $$sref; # hope CoW works...
 554                                 push @buf, "\n";
 555                         } else {
 556                                 push @buf, $_;
 557                         }
 558                 } elsif (/^D (\w+)/) {
 559                         my $path = $1;
 560                         push @buf, $_ if $tree->{$path};
 561                 } elsif ($_ eq "\n") {
 562                         if (@oids) {
 563                                 if (!$mime) {
 564                                         my $out = join('', @buf);
 565                                         $out =~ s/^/# /sgm;
 566                                         warn "purge rewriting\n", $out, "\n";
 567                                 }
 568                                 rewrite_commit($self, \@oids, \@buf, $mime);
 569                                 $nreplace++;
 570                         }
 571                         $w->print(@buf, "\n") or wfail;
 572                         @buf = ();
 573                 } elsif ($_ eq "done\n") {
 574                         $done = 1;
 575                 } elsif (/^mark :([0-9]+)$/) {
 576                         push @buf, $_;
 577                         $mark = $1;
 578                 } else {
 579                         push @buf, $_;
 580                 }
 581         }
 582         close $rd or die "close fast-export failed: $?";
 583         if (@buf) {
 584                 $w->print(@buf) or wfail;
 585         }
 586         die 'done\n not seen from fast-export' unless $done;
 587         chomp(my $cmt = $self->get_mark(":$mark")) if $nreplace;
 588         $self->{nchg} = 0; # prevent _update_git_info until update-ref:
 589         $self->done;
 590         my @git = ('git', "--git-dir=$git->{git_dir}");
 591
 592         run_die([@git, qw(update-ref), $old, $tmp]) if $nreplace;
 593
 594         run_die([@git, qw(update-ref -d), $tmp]);
 595
 596         return if $nreplace == 0;
 597
 598         run_die([@git, qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
 599
 600         # check that old OIDs are gone
 601         my $err = 0;
 602         foreach my $oid (keys %$replace_map) {
 603                 my @info = $git->check($oid);
 604                 if (@info) {
 605                         warn "$oid not replaced\n";
 606                         $err++;
 607                 }
 608         }
 609         _update_git_info($self, 0);
 610         die "Failed to replace $err object(s)\n" if $err;
 611         $cmt;
 612 }
 613
 614 1;
 615 __END__
 616 =pod
 617
 618 =head1 NAME
 619
 620 PublicInbox::Import - message importer for public-inbox v1 inboxes
 621
 622 =head1 VERSION
 623
 624 version 1.0
 625
 626 =head1 SYNOPSIS
 627
 628         use Email::MIME;
 629         use PublicInbox::Git;
 630         use PublicInbox::Import;
 631
 632         chomp(my $git_dir = `git rev-parse --git-dir`);
 633         $git_dir or die "GIT_DIR= must be specified\n";
 634         my $git = PublicInbox::Git->new($git_dir);
 635         my @committer = ('inbox', 'inbox@example.org');
 636         my $im = PublicInbox::Import->new($git, @committer);
 637
 638         # to add a message:
 639         my $message = "From: <u\@example.org>\n".
 640                 "Subject: test message \n" .
 641                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
 642                 "Message-ID: <m\@example.org>\n".
 643                 "\ntest message";
 644         my $parsed = Email::MIME->new($message);
 645         my $ret = $im->add($parsed);
 646         if (!defined $ret) {
 647                 warn "duplicate: ",
 648                         $parsed->header_obj->header_raw('Message-ID'), "\n";
 649         } else {
 650                 print "imported at mark $ret\n";
 651         }
 652         $im->done;
 653
 654         # to remove a message
 655         my $junk = Email::MIME->new($message);
 656         my ($mark, $orig) = $im->remove($junk);
 657         if ($mark eq 'MISSING') {
 658                 print "not found\n";
 659         } elsif ($mark eq 'MISMATCH') {
 660                 print "Message exists but does not match\n\n",
 661                         $orig->as_string, "\n",;
 662         } else {
 663                 print "removed at mark $mark\n\n",
 664                         $orig->as_string, "\n";
 665         }
 666         $im->done;
 667
 668 =head1 DESCRIPTION
 669
 670 An importer and remover for public-inboxes which takes L<Email::MIME>
 671 messages as input and stores them in a git repository as
 672 documented in L<https://public-inbox.org/public-inbox-v1-format.txt>,
 673 except it does not allow duplicate Message-IDs.
 674
 675 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
 676
 677 =head1 METHODS
 678
 679 =cut
 680
 681 =head2 new
 682
 683         my $im = PublicInbox::Import->new($git, @committer);
 684
 685 Initialize a new PublicInbox::Import object.
 686
 687 =head2 add
 688
 689         my $parsed = Email::MIME->new($message);
 690         $im->add($parsed);
 691
 692 Adds a message to to the git repository.  This will acquire
 693 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
 694
 695 Messages added will not be visible to other processes until L</done>
 696 is called, but L</remove> may be called on them.
 697
 698 =head2 remove
 699
 700         my $junk = Email::MIME->new($message);
 701         my ($code, $orig) = $im->remove($junk);
 702
 703 Removes a message from the repository.  On success, it returns
 704 a ':'-prefixed numeric code representing the git-fast-import
 705 mark and the original messages as an Email::MIME object.
 706 If the message could not be found, the code is "MISSING"
 707 and the original message is undef.  If there is a mismatch where
 708 the "Message-ID" is matched but the subject and body do not match,
 709 the returned code is "MISMATCH" and the conflicting message
 710 is returned as orig.
 711
 712 =head2 done
 713
 714 Finalizes the L<git-fast-import(1)> and unlocks the repository.
 715 Calling this is required to finalize changes to a repository.
 716
 717 =head1 SEE ALSO
 718
 719 L<Email::MIME>
 720
 721 =head1 CONTACT
 722
 723 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 724
 725 The mail archives are hosted at L<https://public-inbox.org/meta/>
 726
 727 =head1 COPYRIGHT
 728
 729 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 730
 731 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 732
 733 =cut