lib/PublicInbox/Import.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # git fast-import-based ssoma-mda MDA replacement
   5 # This is only ever run by public-inbox-mda and public-inbox-learn,
   6 # not the WWW or NNTP code which only requires read-only access.
   7 package PublicInbox::Import;
   8 use strict;
   9 use warnings;
  10 use base qw(PublicInbox::Lock);
  11 use PublicInbox::Spawn qw(spawn);
  12 use PublicInbox::MID qw(mids mid_mime mid2path);
  13 use PublicInbox::Address;
  14 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  15 use PublicInbox::ContentId qw(content_digest);
  16 use PublicInbox::MDA;
  17
  18 sub new {
  19         my ($class, $git, $name, $email, $ibx) = @_;
  20         my $ref = 'refs/heads/master';
  21         if ($ibx) {
  22                 $ref = $ibx->{ref_head} || 'refs/heads/master';
  23                 $name ||= $ibx->{name};
  24                 $email ||= $ibx->{-primary_address};
  25         }
  26         bless {
  27                 git => $git,
  28                 ident => "$name <$email>",
  29                 mark => 1,
  30                 ref => $ref,
  31                 inbox => $ibx,
  32                 path_type => '2/38', # or 'v2'
  33                 lock_path => "$git->{git_dir}/ssoma.lock", # v2 changes this
  34                 bytes_added => 0,
  35         }, $class
  36 }
  37
  38 # idempotent start function
  39 sub gfi_start {
  40         my ($self) = @_;
  41
  42         return ($self->{in}, $self->{out}) if $self->{pid};
  43
  44         my ($in_r, $in_w, $out_r, $out_w);
  45         pipe($in_r, $in_w) or die "pipe failed: $!";
  46         pipe($out_r, $out_w) or die "pipe failed: $!";
  47         my $git = $self->{git};
  48
  49         $self->lock_acquire;
  50
  51         local $/ = "\n";
  52         my $ref = $self->{ref};
  53         chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $ref));
  54         if ($self->{path_type} ne '2/38' && $self->{tip}) {
  55                 local $/ = "\0";
  56                 my @tree = $git->qx(qw(ls-tree -r -z --name-only), $ref);
  57                 chomp @tree;
  58                 $self->{-tree} = { map { $_ => 1 } @tree };
  59         }
  60
  61         my $git_dir = $git->{git_dir};
  62         my @cmd = ('git', "--git-dir=$git_dir", qw(fast-import
  63                         --quiet --done --date-format=raw));
  64         my $rdr = { 0 => fileno($out_r), 1 => fileno($in_w) };
  65         my $pid = spawn(\@cmd, undef, $rdr);
  66         die "spawn fast-import failed: $!" unless defined $pid;
  67         $out_w->autoflush(1);
  68         $self->{in} = $in_r;
  69         $self->{out} = $out_w;
  70         $self->{pid} = $pid;
  71         $self->{nchg} = 0;
  72         binmode $out_w, ':raw' or die "binmode :raw failed: $!";
  73         binmode $in_r, ':raw' or die "binmode :raw failed: $!";
  74         ($in_r, $out_w);
  75 }
  76
  77 sub wfail () { die "write to fast-import failed: $!" }
  78
  79 sub now_raw () { time . ' +0000' }
  80
  81 sub norm_body ($) {
  82         my ($mime) = @_;
  83         my $b = $mime->body_raw;
  84         $b =~ s/(\r?\n)+\z//s;
  85         $b
  86 }
  87
  88 # only used for v1 (ssoma) inboxes
  89 sub _check_path ($$$$) {
  90         my ($r, $w, $tip, $path) = @_;
  91         return if $tip eq '';
  92         print $w "ls $tip $path\n" or wfail;
  93         local $/ = "\n";
  94         defined(my $info = <$r>) or die "EOF from fast-import: $!";
  95         $info =~ /\Amissing / ? undef : $info;
  96 }
  97
  98 sub check_remove_v1 {
  99         my ($r, $w, $tip, $path, $mime) = @_;
 100
 101         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
 102         $info =~ m!\A100644 blob ([a-f0-9]{40})\t!s or die "not blob: $info";
 103         my $blob = $1;
 104
 105         print $w "cat-blob $blob\n" or wfail;
 106         local $/ = "\n";
 107         $info = <$r>;
 108         defined $info or die "EOF from fast-import / cat-blob: $!";
 109         $info =~ /\A[a-f0-9]{40} blob (\d+)\n\z/ or
 110                                 die "unexpected cat-blob response: $info";
 111         my $left = $1;
 112         my $offset = 0;
 113         my $buf = '';
 114         my $n;
 115         while ($left > 0) {
 116                 $n = read($r, $buf, $left, $offset);
 117                 defined($n) or die "read cat-blob failed: $!";
 118                 $n == 0 and die 'fast-export (cat-blob) died';
 119                 $left -= $n;
 120                 $offset += $n;
 121         }
 122         $n = read($r, my $lf, 1);
 123         defined($n) or die "read final byte of cat-blob failed: $!";
 124         die "bad read on final byte: <$lf>" if $lf ne "\n";
 125         my $cur = PublicInbox::MIME->new(\$buf);
 126         my $cur_s = $cur->header('Subject');
 127         $cur_s = '' unless defined $cur_s;
 128         my $cur_m = $mime->header('Subject');
 129         $cur_m = '' unless defined $cur_m;
 130         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
 131                 return ('MISMATCH', $cur);
 132         }
 133         (undef, $cur);
 134 }
 135
 136 sub checkpoint {
 137         my ($self) = @_;
 138         return unless $self->{pid};
 139         print { $self->{out} } "checkpoint\n" or wfail;
 140         undef;
 141 }
 142
 143 sub progress {
 144         my ($self, $msg) = @_;
 145         return unless $self->{pid};
 146         print { $self->{out} } "progress $msg\n" or wfail;
 147         $self->{in}->getline eq "progress $msg\n" or die
 148                 "progress $msg not received\n";
 149         undef;
 150 }
 151
 152 sub _update_git_info ($$) {
 153         my ($self, $do_gc) = @_;
 154         # for compatibility with existing ssoma installations
 155         # we can probably remove this entirely by 2020
 156         my $git_dir = $self->{git}->{git_dir};
 157         my @cmd = ('git', "--git-dir=$git_dir");
 158         my $index = "$git_dir/ssoma.index";
 159         if (-e $index && !$ENV{FAST}) {
 160                 my $env = { GIT_INDEX_FILE => $index };
 161                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
 162         }
 163         run_die([@cmd, 'update-server-info'], undef);
 164         ($self->{path_type} eq '2/38') and eval {
 165                 require PublicInbox::SearchIdx;
 166                 my $inbox = $self->{inbox} || $git_dir;
 167                 my $s = PublicInbox::SearchIdx->new($inbox);
 168                 $s->index_sync({ ref => $self->{ref} });
 169         };
 170         eval { run_die([@cmd, qw(gc --auto)], undef) } if $do_gc;
 171 }
 172
 173 sub barrier {
 174         my ($self) = @_;
 175
 176         # For safety, we ensure git checkpoint is complete before because
 177         # the data in git is still more important than what is in Xapian
 178         # in v2.  Performance may be gained by delaying the ->progress
 179         # call but we lose safety
 180         if ($self->{nchg}) {
 181                 $self->checkpoint;
 182                 $self->progress('checkpoint');
 183                 _update_git_info($self, 0);
 184                 $self->{nchg} = 0;
 185         }
 186 }
 187
 188 # used for v2
 189 sub get_mark {
 190         my ($self, $mark) = @_;
 191         die "not active\n" unless $self->{pid};
 192         my ($r, $w) = $self->gfi_start;
 193         print $w "get-mark $mark\n" or wfail;
 194         defined(my $oid = <$r>) or die "get-mark failed, need git 2.6.0+\n";
 195         chomp($oid);
 196         $oid;
 197 }
 198
 199 # returns undef on non-existent
 200 # ('MISMATCH', Email::MIME) on mismatch
 201 # (:MARK, Email::MIME) on success
 202 #
 203 # v2 callers should check with Xapian before calling this as
 204 # it is not idempotent.
 205 sub remove {
 206         my ($self, $mime, $msg) = @_; # mime = Email::MIME
 207
 208         my $path_type = $self->{path_type};
 209         my ($path, $err, $cur, $blob);
 210
 211         my ($r, $w) = $self->gfi_start;
 212         my $tip = $self->{tip};
 213         if ($path_type eq '2/38') {
 214                 $path = mid2path(v1_mid0($mime));
 215                 ($err, $cur) = check_remove_v1($r, $w, $tip, $path, $mime);
 216                 return ($err, $cur) if $err;
 217         } else {
 218                 my $sref;
 219                 if (ref($mime) eq 'SCALAR') { # optimization used by V2Writable
 220                         $sref = $mime;
 221                 } else { # XXX should not be necessary:
 222                         my $str = $mime->as_string;
 223                         $sref = \$str;
 224                 }
 225                 my $len = length($$sref);
 226                 $blob = $self->{mark}++;
 227                 print $w "blob\nmark :$blob\ndata $len\n",
 228                         $$sref, "\n" or wfail;
 229         }
 230
 231         my $ref = $self->{ref};
 232         my $commit = $self->{mark}++;
 233         my $parent = $tip =~ /\A:/ ? $tip : undef;
 234         unless ($parent) {
 235                 print $w "reset $ref\n" or wfail;
 236         }
 237         my $ident = $self->{ident};
 238         my $now = now_raw();
 239         $msg ||= 'rm';
 240         my $len = length($msg) + 1;
 241         print $w "commit $ref\nmark :$commit\n",
 242                 "author $ident $now\n",
 243                 "committer $ident $now\n",
 244                 "data $len\n$msg\n\n",
 245                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 246         if (defined $path) {
 247                 print $w "D $path\n\n" or wfail;
 248         } else {
 249                 clean_tree_v2($self, $w, 'd');
 250                 print $w "M 100644 :$blob d\n\n" or wfail;
 251         }
 252         $self->{nchg}++;
 253         (($self->{tip} = ":$commit"), $cur);
 254 }
 255
 256 sub git_timestamp {
 257         my ($ts, $zone) = @_;
 258         $ts = 0 if $ts < 0; # git uses unsigned times
 259         "$ts $zone";
 260 }
 261
 262 sub extract_author_info ($) {
 263         my ($mime) = @_;
 264
 265         my $sender = '';
 266         my $from = $mime->header('From');
 267         my ($email) = PublicInbox::Address::emails($from);
 268         my ($name) = PublicInbox::Address::names($from);
 269         if (!defined($name) || !defined($email)) {
 270                 $sender = $mime->header('Sender');
 271                 if (!defined($name)) {
 272                         ($name) = PublicInbox::Address::names($sender);
 273                 }
 274                 if (!defined($email)) {
 275                         ($email) = PublicInbox::Address::emails($sender);
 276                 }
 277         }
 278         if (defined $email) {
 279                 # quiet down wide character warnings with utf8::encode
 280                 utf8::encode($email);
 281         } else {
 282                 $email = '';
 283                 warn "no email in From: $from or Sender: $sender\n";
 284         }
 285
 286         # git gets confused with:
 287         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
 288         # ref:
 289         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
 290         if (defined $name) {
 291                 $name =~ tr/<>//d;
 292                 utf8::encode($name);
 293         } else {
 294                 $name = '';
 295                 warn "no name in From: $from or Sender: $sender\n";
 296         }
 297         ($name, $email);
 298 }
 299
 300 # kill potentially confusing/misleading headers
 301 sub drop_unwanted_headers ($) {
 302         my ($mime) = @_;
 303
 304         $mime->header_set($_) for qw(bytes lines content-length status);
 305         $mime->header_set($_) for @PublicInbox::MDA::BAD_HEADERS;
 306 }
 307
 308 # used by V2Writable, too
 309 sub append_mid ($$) {
 310         my ($hdr, $mid0) = @_;
 311         # @cur is likely empty if we need to call this sub, but it could
 312         # have random unparseable crap which we'll preserve, too.
 313         my @cur = $hdr->header_raw('Message-ID');
 314         $hdr->header_set('Message-ID', @cur, "<$mid0>");
 315 }
 316
 317 sub v1_mid0 ($) {
 318         my ($mime) = @_;
 319         my $hdr = $mime->header_obj;
 320         my $mids = mids($hdr);
 321
 322         if (!scalar(@$mids)) { # spam often has no Message-Id
 323                 my $mid0 = digest2mid(content_digest($mime));
 324                 append_mid($hdr, $mid0);
 325                 return $mid0;
 326         }
 327         $mids->[0];
 328 }
 329 sub clean_tree_v2 ($$$) {
 330         my ($self, $w, $keep) = @_;
 331         my $tree = $self->{-tree} or return; #v2 only
 332         delete $tree->{$keep};
 333         foreach (keys %$tree) {
 334                 print $w "D $_\n" or wfail;
 335         }
 336         %$tree = ($keep => 1);
 337 }
 338
 339 # returns undef on duplicate
 340 # returns the :MARK of the most recent commit
 341 sub add {
 342         my ($self, $mime, $check_cb) = @_; # mime = Email::MIME
 343
 344         my ($name, $email) = extract_author_info($mime);
 345         my $hdr = $mime->header_obj;
 346         my @at = msg_datestamp($hdr);
 347         my @ct = msg_timestamp($hdr);
 348         my $author_time_raw = git_timestamp(@at);
 349         my $commit_time_raw = git_timestamp(@ct);
 350         my $subject = $mime->header('Subject');
 351         $subject = '(no subject)' unless defined $subject;
 352         my $path_type = $self->{path_type};
 353
 354         my $path;
 355         if ($path_type eq '2/38') {
 356                 $path = mid2path(v1_mid0($mime));
 357         } else { # v2 layout, one file:
 358                 $path = 'm';
 359         }
 360
 361         my ($r, $w) = $self->gfi_start;
 362         my $tip = $self->{tip};
 363         if ($path_type eq '2/38') {
 364                 _check_path($r, $w, $tip, $path) and return;
 365         }
 366
 367         drop_unwanted_headers($mime);
 368
 369         # spam check:
 370         if ($check_cb) {
 371                 $mime = $check_cb->($mime) or return;
 372         }
 373
 374         my $blob = $self->{mark}++;
 375         my $str = $mime->as_string;
 376         my $n = length($str);
 377         $self->{bytes_added} += $n;
 378         print $w "blob\nmark :$blob\ndata ", $n, "\n" or wfail;
 379         print $w $str, "\n" or wfail;
 380
 381         # v2: we need this for Xapian
 382         if ($self->{want_object_info}) {
 383                 my $oid = $self->get_mark(":$blob");
 384                 $self->{last_object} = [ $oid, $n, \$str ];
 385         }
 386         my $ref = $self->{ref};
 387         my $commit = $self->{mark}++;
 388         my $parent = $tip =~ /\A:/ ? $tip : undef;
 389
 390         unless ($parent) {
 391                 print $w "reset $ref\n" or wfail;
 392         }
 393
 394         utf8::encode($subject);
 395         print $w "commit $ref\nmark :$commit\n",
 396                 "author $name <$email> $author_time_raw\n",
 397                 "committer $self->{ident} $commit_time_raw\n" or wfail;
 398         print $w "data ", (length($subject) + 1), "\n",
 399                 $subject, "\n\n" or wfail;
 400         if ($tip ne '') {
 401                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 402         }
 403         clean_tree_v2($self, $w, $path);
 404         print $w "M 100644 :$blob $path\n\n" or wfail;
 405         $self->{nchg}++;
 406         $self->{tip} = ":$commit";
 407 }
 408
 409 sub run_die ($;$$) {
 410         my ($cmd, $env, $rdr) = @_;
 411         my $pid = spawn($cmd, $env, $rdr);
 412         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 413         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 414         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
 415 }
 416
 417 sub done {
 418         my ($self) = @_;
 419         my $w = delete $self->{out} or return;
 420         my $r = delete $self->{in} or die 'BUG: missing {in} when done';
 421         print $w "done\n" or wfail;
 422         my $pid = delete $self->{pid} or die 'BUG: missing {pid} when done';
 423         waitpid($pid, 0) == $pid or die 'fast-import did not finish';
 424         $? == 0 or die "fast-import failed: $?";
 425
 426         _update_git_info($self, 1) if delete $self->{nchg};
 427
 428         $self->lock_release;
 429 }
 430
 431 sub atfork_child {
 432         my ($self) = @_;
 433         foreach my $f (qw(in out)) {
 434                 close $self->{$f} or die "failed to close import[$f]: $!\n";
 435         }
 436 }
 437
 438 sub digest2mid ($) {
 439         my ($dig) = @_;
 440         my $b64 = $dig->clone->b64digest;
 441         # Make our own URLs nicer:
 442         # See "Base 64 Encoding with URL and Filename Safe Alphabet" in RFC4648
 443         $b64 =~ tr!+/=!-_!d;
 444
 445         # We can make this more meaningful with a date prefix or other things,
 446         # but this is only needed for crap that fails to generate a Message-ID
 447         # or reuses one.  In other words, it's usually spammers who hit this
 448         # so they don't deserve nice Message-IDs :P
 449         $b64 . '@localhost';
 450 }
 451
 452 sub clean_purge_buffer {
 453         my ($oids, $buf) = @_;
 454         my $cmt_msg = 'purged '.join(' ',@$oids)."\n";
 455         @$oids = ();
 456
 457         foreach my $i (0..$#$buf) {
 458                 my $l = $buf->[$i];
 459                 if ($l =~ /^author .* (\d+ [\+-]?\d+)$/) {
 460                         $buf->[$i] = "author <> $1\n";
 461                 } elsif ($l =~ /^data (\d+)/) {
 462                         $buf->[$i++] = "data " . length($cmt_msg) . "\n";
 463                         $buf->[$i] = $cmt_msg;
 464                         last;
 465                 }
 466         }
 467 }
 468
 469 sub purge_oids {
 470         my ($self, $purge) = @_;
 471         my $tmp = "refs/heads/purge-".((keys %$purge)[0]);
 472         my $old = $self->{'ref'};
 473         my $git = $self->{git};
 474         my @export = (qw(fast-export --no-data --use-done-feature), $old);
 475         my ($rd, $pid) = $git->popen(@export);
 476         my ($r, $w) = $self->gfi_start;
 477         my @buf;
 478         my $npurge = 0;
 479         my @oids;
 480         my ($done, $mark);
 481         my $tree = $self->{-tree};
 482         while (<$rd>) {
 483                 if (/^reset (?:.+)/) {
 484                         push @buf, "reset $tmp\n";
 485                 } elsif (/^commit (?:.+)/) {
 486                         if (@buf) {
 487                                 $w->print(@buf) or wfail;
 488                                 @buf = ();
 489                         }
 490                         push @buf, "commit $tmp\n";
 491                 } elsif (/^data (\d+)/) {
 492                         # only commit message, so $len is small:
 493                         my $len = $1; # + 1 for trailing "\n"
 494                         push @buf, $_;
 495                         my $n = read($rd, my $buf, $len) or die "read: $!";
 496                         $len == $n or die "short read ($n < $len)";
 497                         push @buf, $buf;
 498                 } elsif (/^M 100644 ([a-f0-9]+) (\w+)/) {
 499                         my ($oid, $path) = ($1, $2);
 500                         if ($purge->{$oid}) {
 501                                 push @oids, $oid;
 502                                 delete $tree->{$path};
 503                         } else {
 504                                 $tree->{$path} = 1;
 505                                 push @buf, $_;
 506                         }
 507                 } elsif (/^D (\w+)/) {
 508                         my $path = $1;
 509                         push @buf, $_ if $tree->{$path};
 510                 } elsif ($_ eq "\n") {
 511                         if (@oids) {
 512                                 my $out = join('', @buf);
 513                                 $out =~ s/^/# /sgm;
 514                                 warn "purge rewriting\n", $out, "\n";
 515                                 clean_purge_buffer(\@oids, \@buf);
 516                                 $npurge++;
 517                         }
 518                         $w->print(@buf, "\n") or wfail;
 519                         @buf = ();
 520                 } elsif ($_ eq "done\n") {
 521                         $done = 1;
 522                 } elsif (/^mark :(\d+)$/) {
 523                         push @buf, $_;
 524                         $mark = $1;
 525                 } else {
 526                         push @buf, $_;
 527                 }
 528         }
 529         if (@buf) {
 530                 $w->print(@buf) or wfail;
 531         }
 532         die 'done\n not seen from fast-export' unless $done;
 533         chomp(my $cmt = $self->get_mark(":$mark")) if $npurge;
 534         $self->{nchg} = 0; # prevent _update_git_info until update-ref:
 535         $self->done;
 536         my @git = ('git', "--git-dir=$git->{git_dir}");
 537
 538         run_die([@git, qw(update-ref), $old, $tmp]) if $npurge;
 539
 540         run_die([@git, qw(update-ref -d), $tmp]);
 541
 542         return if $npurge == 0;
 543
 544         run_die([@git, qw(-c gc.reflogExpire=now gc --prune=all)]);
 545         my $err = 0;
 546         foreach my $oid (keys %$purge) {
 547                 my @info = $git->check($oid);
 548                 if (@info) {
 549                         warn "$oid not purged\n";
 550                         $err++;
 551                 }
 552         }
 553         _update_git_info($self, 0);
 554         die "Failed to purge $err object(s)\n" if $err;
 555         $cmt;
 556 }
 557
 558 1;
 559 __END__
 560 =pod
 561
 562 =head1 NAME
 563
 564 PublicInbox::Import - message importer for public-inbox
 565
 566 =head1 VERSION
 567
 568 version 1.0
 569
 570 =head1 SYNOPSYS
 571
 572         use Email::MIME;
 573         use PublicInbox::Git;
 574         use PublicInbox::Import;
 575
 576         chomp(my $git_dir = `git rev-parse --git-dir`);
 577         $git_dir or die "GIT_DIR= must be specified\n";
 578         my $git = PublicInbox::Git->new($git_dir);
 579         my @committer = ('inbox', 'inbox@example.org');
 580         my $im = PublicInbox::Import->new($git, @committer);
 581
 582         # to add a message:
 583         my $message = "From: <u\@example.org>\n".
 584                 "Subject: test message \n" .
 585                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
 586                 "Message-ID: <m\@example.org>\n".
 587                 "\ntest message";
 588         my $parsed = Email::MIME->new($message);
 589         my $ret = $im->add($parsed);
 590         if (!defined $ret) {
 591                 warn "duplicate: ",
 592                         $parsed->header_obj->header_raw('Message-ID'), "\n";
 593         } else {
 594                 print "imported at mark $ret\n";
 595         }
 596         $im->done;
 597
 598         # to remove a message
 599         my $junk = Email::MIME->new($message);
 600         my ($mark, $orig) = $im->remove($junk);
 601         if ($mark eq 'MISSING') {
 602                 print "not found\n";
 603         } elsif ($mark eq 'MISMATCH') {
 604                 print "Message exists but does not match\n\n",
 605                         $orig->as_string, "\n",;
 606         } else {
 607                 print "removed at mark $mark\n\n",
 608                         $orig->as_string, "\n";
 609         }
 610         $im->done;
 611
 612 =head1 DESCRIPTION
 613
 614 An importer and remover for public-inboxes which takes L<Email::MIME>
 615 messages as input and stores them in a ssoma repository as
 616 documented in L<https://ssoma.public-inbox.org/ssoma_repository.txt>,
 617 except it does not allow duplicate Message-IDs.
 618
 619 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
 620
 621 =head1 METHODS
 622
 623 =cut
 624
 625 =head2 new
 626
 627         my $im = PublicInbox::Import->new($git, @committer);
 628
 629 Initialize a new PublicInbox::Import object.
 630
 631 =head2 add
 632
 633         my $parsed = Email::MIME->new($message);
 634         $im->add($parsed);
 635
 636 Adds a message to to the git repository.  This will acquire
 637 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
 638
 639 Messages added will not be visible to other processes until L</done>
 640 is called, but L</remove> may be called on them.
 641
 642 =head2 remove
 643
 644         my $junk = Email::MIME->new($message);
 645         my ($code, $orig) = $im->remove($junk);
 646
 647 Removes a message from the repository.  On success, it returns
 648 a ':'-prefixed numeric code representing the git-fast-import
 649 mark and the original messages as an Email::MIME object.
 650 If the message could not be found, the code is "MISSING"
 651 and the original message is undef.  If there is a mismatch where
 652 the "Message-ID" is matched but the subject and body do not match,
 653 the returned code is "MISMATCH" and the conflicting message
 654 is returned as orig.
 655
 656 =head2 done
 657
 658 Finalizes the L<git-fast-import(1)> and unlocks the repository.
 659 Calling this is required to finalize changes to a repository.
 660
 661 =head1 SEE ALSO
 662
 663 L<Email::MIME>
 664
 665 =head1 CONTACT
 666
 667 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 668
 669 The mail archives are hosted at L<https://public-inbox.org/meta/>
 670
 671 =head1 COPYRIGHT
 672
 673 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 674
 675 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 676
 677 =cut